| blob | 1bf858bcbf97244b29172cbc35beea004c33769f |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,2.7)
10 AM_MAINTAINER_MODE
12 API_VER=2.0
13 AC_SUBST(API_VER)
15 AC_PROG_LN_S
17 # In case of cygwin, override LN_S, irrespective of what it determines.
18 # The build uses cygwin, but the actual runtime doesn't.
19 case $host_os in
20 *cygwin* ) LN_S='cp -p';;
21 esac
23 dnl
24 dnl libgc checks
25 dnl
27 gc_headers=no
28 gc=included
29 use_included_gc=no
30 libgc_configure_args=
32 if test -d $srcdir/libgc ; then
33 gc_default=included
34 else
35 gc_default=boehm
36 fi
38 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
39 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
40 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
41 CFLAGS_FOR_LIBGC=$CFLAGS
42 CPPFLAGS_FOR_EGLIB=$CPPFLAGS
43 CFLAGS_FOR_EGLIB=$CFLAGS
45 #
46 # These are the flags that need to be stored in the mono.pc file for
47 # compiling code that will embed Mono
48 #
49 libmono_cflags=""
50 libmono_ldflags=""
51 AC_SUBST(libmono_cflags)
52 AC_SUBST(libmono_ldflags)
54 # Variable to have relocatable .pc files (lib, or lib64)
55 reloc_libdir=`basename ${libdir}`
56 AC_SUBST(reloc_libdir)
58 dnl if linker handles the version script
59 no_version_script=no
61 # Set to yes if Unix sockets cannot be created in an anonymous namespace
62 need_link_unlink=no
64 # Thread configuration inspired by sleepycat's db
65 AC_MSG_CHECKING([host platform characteristics])
66 libgc_threads=no
67 has_dtrace=no
68 parallel_mark=yes
70 case "$host" in
71 powerpc*-*-linux*)
72 # https://bugzilla.novell.com/show_bug.cgi?id=504411
73 disable_munmap=yes
74 ;;
75 esac
77 host_win32=no
78 target_win32=no
79 case "$host" in
80 *-mingw*|*-*-cygwin*)
81 AC_DEFINE(HOST_WIN32,1,[Host Platform is Win32])
82 AC_DEFINE(DISABLE_PORTABILITY,1,[Disable the io-portability layer])
83 AC_DEFINE(PLATFORM_NO_SYMLINKS,1,[This platform does not support symlinks])
84 host_win32=yes
85 if test "x$cross_compiling" = "xno"; then
86 target_win32=yes
87 if test "x$host" == "x$target"; then
88 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32])
89 fi
90 CC="gcc -mno-cygwin -g"
91 CXX="g++ -mno-cygwin -g"
92 # So libgc configure gets -mno-cygwin
93 export CC
94 export CXX
95 else
96 target_win32=yes
97 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32/MinGW])
98 AC_DEFINE(MINGW_CROSS_COMPILE,1,[Cross-compiling using MinGW])
99 fi
100 HOST_CC="gcc"
101 # Windows 2000 is required that includes Internet Explorer 5.01
102 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
103 LDFLAGS="$LDFLAGS -lmswsock -lws2_32 -lole32 -loleaut32 -lpsapi -lversion -ladvapi32 -lwinmm -lkernel32"
104 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
105 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
106 libdl=
107 libgc_threads=win32
108 gc_default=included
109 with_sigaltstack=no
110 LN_S=cp
111 # This forces libgc to use the DllMain based thread registration code on win32
112 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
113 ;;
114 *-*-*netbsd*)
115 host_win32=no
116 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
117 libmono_cflags="-D_REENTRANT"
118 LDFLAGS="$LDFLAGS -pthread"
119 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
120 libmono_ldflags="-pthread"
121 need_link_unlink=yes
122 libdl="-ldl"
123 libgc_threads=pthreads
124 with_sigaltstack=no
125 use_sigposix=yes
126 ;;
127 *-*-*freebsd*)
128 host_win32=no
129 if test "x$PTHREAD_CFLAGS" = "x"; then
130 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
131 libmono_cflags=
132 else
133 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
134 libmono_cflags="$PTHREAD_CFLAGS"
135 fi
136 if test "x$PTHREAD_LIBS" = "x"; then
137 LDFLAGS="$LDFLAGS -pthread"
138 libmono_ldflags="-pthread"
139 else
140 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
141 libmono_ldflags="$PTHREAD_LIBS"
142 fi
143 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
144 need_link_unlink=yes
145 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
146 libdl=
147 libgc_threads=pthreads
148 # This doesn't seem to work as of 7.0 on amd64
149 with_sigaltstack=no
150 # TLS is only partially implemented on -CURRENT (compiler support
151 # but NOT library support)
152 #
153 with_tls=pthread
154 use_sigposix=yes
155 ;;
156 *-*-*openbsd*)
157 host_win32=no
158 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_OPENBSD_THREADS -DPLATFORM_BSD -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
159 if test "x$disable_munmap" != "xyes"; then
160 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
161 fi
162 libmono_cflags="-D_THREAD_SAFE -D_REENTRANT"
163 LDFLAGS="$LDFLAGS -pthread"
164 libmono_ldflags="-pthread"
165 need_link_unlink=yes
166 AC_DEFINE(PTHREAD_POINTER_ID)
167 libdl=
168 gc_default=boehm
169 libgc_threads=pthreads
170 with_sigaltstack=no
171 use_sigposix=yes
172 ;;
173 *-*-linux*)
174 host_win32=no
175 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
176 if test "x$disable_munmap" != "xyes"; then
177 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
178 fi
179 libmono_cflags="-D_REENTRANT"
180 libmono_ldflags="-lpthread"
181 libdl="-ldl"
182 libgc_threads=pthreads
183 AOT_SUPPORTED="yes"
184 use_sigposix=yes
185 ;;
186 *-*-hpux*)
187 host_win32=no
188 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
189 # +ESdbgasm only valid on bundled cc on RISC
190 # silently ignored for ia64
191 if test $GCC != "yes"; then
192 CFLAGS="$CFLAGS +ESdbgasm"
193 # Arrange for run-time dereferencing of null
194 # pointers to produce a SIGSEGV signal.
195 LDFLAGS="$LDFLAGS -z"
196 fi
197 CFLAGS="$CFLAGS +ESdbgasm"
198 LDFLAGS="$LDFLAGS -z"
199 libmono_cflags="-D_REENTRANT"
200 libmono_ldflags="-lpthread"
201 libgc_threads=pthreads
202 need_link_unlink=yes
203 use_sigposix=yes
204 ;;
205 *-*-solaris*)
206 host_win32=no
207 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
208 need_link_unlink=yes
209 libmono_cflags="-D_REENTRANT"
210 libgc_threads=pthreads
211 # This doesn't seem to work on solaris/x86, but the configure test runs
212 with_tls=pthread
213 has_dtrace=yes
214 use_sigposix=yes
215 enable_solaris_tar_check=yes
216 ;;
217 *-*-darwin*)
218 parallel_mark="Disabled_Currently_Hangs_On_MacOSX"
219 host_win32=no
220 platform_darwin=yes
221 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
222 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
223 libmono_cflags="-D_THREAD_SAFE"
224 LDFLAGS="$LDFLAGS -pthread"
225 libmono_ldflags="-pthread"
226 need_link_unlink=yes
227 AC_DEFINE(PTHREAD_POINTER_ID)
228 AC_DEFINE(USE_MACH_SEMA, 1, [...])
229 no_version_script=yes
230 libdl=
231 libgc_threads=pthreads
232 has_dtrace=yes
233 if test "x$cross_compiling" = "xyes"; then
234 has_broken_apple_cpp=yes
235 fi
236 dnl Snow Leopard is horribly broken -- it reports itself as i386-apple-darwin10.0.0, but
237 dnl its gcc defaults to 64-bit mode. They have also deprecated the usage of ucontext
238 dnl we need to set some flags to build our 32-bit binaries on 10.6 properly
239 case "$host" in
240 dnl MacPorts config.guess reports as this
241 x86_64-*-darwin10*)
242 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
243 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
244 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
245 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
246 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
247 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
248 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
249 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
250 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
251 ;;
252 dnl Snow Leopard config.guess reports as this
253 i*86-*-darwin10*)
254 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
255 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
256 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
257 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
258 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
259 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
260 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
261 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
262 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
263 ;;
264 esac
265 ;;
266 *-*-haiku*)
267 host_win32=no
268 CPPFLAGS="$CPPFLAGS -D_REENTRANT -D_THREAD_SAFE"
269 libmono_cflags="-D_REENTRANT -D_THREAD_SAFE"
270 libdl=
271 LIBS="$LIBS -lnetwork"
272 need_link_unlink=yes
273 AC_DEFINE(PTHREAD_POINTER_ID)
274 libgc_threads=pthreads
275 use_sigposix=yes
276 ;;
277 *)
278 AC_MSG_WARN([*** Please add $host to configure.in checks!])
279 host_win32=no
280 libdl="-ldl"
281 ;;
282 esac
283 AC_MSG_RESULT(ok)
285 if test x$need_link_unlink = xyes; then
286 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
287 fi
289 AM_CONDITIONAL(HOST_WIN32, test x$host_win32 = xyes)
290 AM_CONDITIONAL(TARGET_WIN32, test x$target_win32 = xyes)
291 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
292 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
293 AM_CONDITIONAL(PLATFORM_SIGPOSIX, test x$use_sigposix = xyes)
295 AC_CHECK_TOOL(CC, gcc, gcc)
296 AC_PROG_CC
297 AC_CHECK_TOOL(CXX, g++, g++)
298 AC_PROG_CXX
299 AM_PROG_AS
300 AM_PROG_CC_STDC
301 AC_PROG_INSTALL
302 AC_PROG_AWK
303 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
304 : ${CCAS='$(CC)'}
305 # Set ASFLAGS if not already set.
306 : ${CCASFLAGS='$(CFLAGS)'}
307 AC_SUBST(CCAS)
308 AC_SUBST(CCASFLAGS)
310 # AC_PROG_CXX helpfully sets CXX to g++ even if no c++ compiler is found so check
311 # GXX instead. See http://lists.gnu.org/archive/html/bug-autoconf/2002-04/msg00056.html
312 if test "x$CXX" = "xg++"; then
313 if test "x$GXX" != "xyes"; then
314 # automake/libtool is so broken, it requires g++ even if the c++ sources
315 # are inside automake conditionals
316 AC_MSG_ERROR([You need to install g++])
317 fi
318 fi
320 AC_CHECK_PROG(BISON, bison,yes,no)
321 if test "x$BISON" = "xno";
322 then
323 AC_MSG_ERROR([You need to install bison])
324 fi
326 dnl may require a specific autoconf version
327 dnl AC_PROG_CC_FOR_BUILD
328 dnl CC_FOR_BUILD not automatically detected
329 CC_FOR_BUILD=$CC
330 CFLAGS_FOR_BUILD=$CFLAGS
331 BUILD_EXEEXT=
332 if test "x$cross_compiling" = "xyes"; then
333 CC_FOR_BUILD=cc
334 CFLAGS_FOR_BUILD=
335 BUILD_EXEEXT=""
336 fi
337 AC_SUBST(CC_FOR_BUILD)
338 AC_SUBST(CFLAGS_FOR_BUILD)
339 AC_SUBST(HOST_CC)
340 AC_SUBST(BUILD_EXEEXT)
342 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
343 AM_CONDITIONAL(USE_BATCH_FILES, [test x$host_win32 = xyes -a x$cross_compiling = xyes])
345 # Set STDC_HEADERS
346 AC_HEADER_STDC
347 AC_LIBTOOL_WIN32_DLL
348 # This causes monodis to not link correctly
349 #AC_DISABLE_FAST_INSTALL
350 AM_PROG_LIBTOOL
351 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
352 DOLT
354 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
355 AC_SUBST(export_ldflags)
357 # Test whenever ld supports -version-script
358 AC_PROG_LD
359 AC_PROG_LD_GNU
360 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
361 no_version_script=yes
362 fi
364 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
366 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h sys/uio.h)
367 AC_CHECK_HEADERS(sys/user.h sys/socket.h sys/ipc.h sys/sem.h sys/utsname.h alloca.h ucontext.h pwd.h sys/select.h netinet/tcp.h netinet/in.h unistd.h sys/types.h link.h)
370 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
371 if test x$have_zlib = xyes; then
372 AC_TRY_COMPILE([#include <zlib.h>], [
373 void main () {
374 #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
375 }
376 #else
377 #error No good zlib found
378 #endif
379 ],[
380 AC_MSG_RESULT(Using system zlib)
381 zlib_msg="system zlib"
382 ],[
383 AC_MSG_RESULT(Using embedded zlib)
384 have_zlib=no
385 zlib_msg="bundled zlib"
386 ])
387 fi
389 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
390 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
392 # for mono/metadata/debug-symfile.c
393 AC_CHECK_HEADERS(elf.h)
395 # for support
396 AC_CHECK_HEADERS(poll.h)
397 AC_CHECK_HEADERS(sys/poll.h)
398 AC_CHECK_HEADERS(sys/wait.h)
399 AC_CHECK_HEADERS(grp.h)
400 AC_CHECK_HEADERS(syslog.h)
402 # for mono/dis
403 AC_CHECK_HEADERS(wchar.h)
404 AC_CHECK_HEADERS(ieeefp.h)
405 AC_MSG_CHECKING(for isinf)
406 AC_TRY_LINK([#include <math.h>], [
407 int f = isinf (1);
408 ], [
409 AC_MSG_RESULT(yes)
410 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
411 ], [
412 # We'll have to use signals
413 AC_MSG_RESULT(no)
414 ])
417 # not 64 bit clean in cross-compile
418 AC_CHECK_SIZEOF(void *, 4)
420 WARN=''
421 if test x"$GCC" = xyes; then
422 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wwrite-strings'
423 # The runtime code does not respect ANSI C strict aliasing rules
424 CFLAGS="$CFLAGS -fno-strict-aliasing"
426 ORIG_CFLAGS=$CFLAGS
427 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
428 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
429 AC_TRY_COMPILE([], [
430 void main () { }
431 ], [
432 AC_MSG_RESULT(yes)
433 ], [
434 AC_MSG_RESULT(no)
435 CFLAGS=$ORIG_CFLAGS
436 ])
437 else
438 # The Sun Forte compiler complains about inline functions that access static variables
439 # so disable all inlining.
440 case "$host" in
441 *-*-solaris*)
442 CFLAGS="$CFLAGS -Dinline="
443 ;;
444 esac
445 fi
446 CFLAGS="$CFLAGS -g $WARN"
447 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
449 # Where's the 'mcs' source tree?
450 if test -d $srcdir/mcs; then
451 mcsdir=mcs
452 else
453 mcsdir=../mcs
454 fi
456 AC_ARG_WITH(mcs-path, [ --with-mcs-path=/path/to/mcs Specify an alternate mcs source tree],
457 if test x$with_mcs_path != "x" -a -d $with_mcs_path ; then
458 mcsdir=$with_mcs_path
459 fi
460 )
462 #
463 # A sanity check to catch cases where the package was unpacked
464 # with an ancient tar program (Solaris)
465 #
466 AC_ARG_ENABLE(solaris-tar-check,
467 [ --disable-solaris-tar-check disable solaris tar check],
468 do_solaris_tar_check=no, do_solaris_tar_check=yes)
470 if test x"$do_solaris_tar_check" = xyes -a x"$enable_solaris_tar_check" = xyes; then
471 AC_MSG_CHECKING(integrity of package)
472 if test -f $mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
473 then
474 AC_MSG_RESULT(ok)
475 else
476 errorm="Your mono distribution is incomplete; if unpacking from a tar file, make sure you use GNU tar; see http://www.mono-project.com/IncompletePackage for more details"
477 AC_MSG_ERROR([$errorm])
478 fi
479 fi
481 if test "x$with_mcs_path" != "x"; then
482 mcs_topdir=$(cd "$mcsdir" && pwd)
483 mcs_topdir_from_srcdir=$mcs_topdir
484 else
485 mcs_topdir=$(cd "$srcdir/$mcsdir" && pwd)
486 mcs_topdir_from_srcdir='$(top_builddir)'/$mcsdir
487 fi
489 ## Maybe should also disable if mcsdir is invalid. Let's punt the issue for now.
490 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
492 AC_SUBST([mcs_topdir])
493 AC_SUBST([mcs_topdir_from_srcdir])
495 # Where's the 'olive' source tree?
496 if test -d $srcdir/olive; then
497 olivedir=olive
498 else
499 olivedir=../olive
500 fi
502 if test -d $srcdir/$olivedir; then
503 olive_topdir='$(top_srcdir)/'$olivedir
504 fi
506 # gettext: prepare the translation directories.
507 # we do not configure the full gettext, as we consume it dynamically from C#
508 AM_PO_SUBDIRS
510 if test "x$USE_NLS" = "xyes"; then
511 AC_CHECK_PROG(HAVE_MSGFMT, msgfmt,yes,no)
513 if test "x$HAVE_MSGFMT" = "xno"; then
514 AC_MSG_ERROR([msgfmt not found. You need to install the 'gettext' package, or pass --enable-nls=no to configure.])
515 fi
516 fi
518 AC_ARG_WITH([libgdiplus],
519 [ --with-libgdiplus=installed|sibling|<path> Override the libgdiplus used for System.Drawing tests (defaults to installed)],
520 [], [with_libgdiplus=installed])
522 case $with_libgdiplus in
523 no|installed) libgdiplus_loc= ;;
524 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
525 /*) libgdiplus_loc=$with_libgdiplus ;;
526 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
527 esac
528 AC_SUBST([libgdiplus_loc])
530 PKG_PROG_PKG_CONFIG()
531 if test "x$PKG_CONFIG" = "x"; then
532 AC_MSG_ERROR([You need to install pkg-config])
533 fi
535 pkg_config_path=
536 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir Change pkg-config dir to custom dir],
537 if test x$with_crosspkgdir = "x"; then
538 if test -s $PKG_CONFIG_PATH; then
539 pkg_config_path=$PKG_CONFIG_PATH
540 fi
541 else
542 pkg_config_path=$with_crosspkgdir
543 PKG_CONFIG_PATH=$pkg_config_path
544 export PKG_CONFIG_PATH
545 fi
546 )
548 AC_ARG_WITH([glib],
549 [ --with-glib=embedded|system Choose glib API: system or embedded (default to system)],
550 [], [with_glib=system])
552 eglib_dir=
554 ac_configure_args="$ac_configure_args \"CPPFLAGS_FOR_EGLIB=$EGLIB_CPPFLAGS\" \"CFLAGS_FOR_EGLIB=$CFLAGS_FOR_EGLIB\""
555 AC_CONFIG_SUBDIRS(eglib)
557 case $with_glib in
558 embedded)
559 GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
560 GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
561 BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
562 BUILD_GLIB_LIBS="$GLIB_LIBS"
563 GMODULE_CFLAGS="$GLIB_CFLAGS"
564 GMODULE_LIBS="$GLIB_LIBS"
565 eglib_dir=eglib
566 ;;
567 system)
568 echo "PKG_CONFIG_PATH=$PKG_CONFIG_PATH"
569 echo "cross_compiling=$cross_compiling"
570 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
571 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
573 ## Versions of dependencies
574 GLIB_REQUIRED_VERSION=2.4.0
576 dnl
577 dnl No, you will not replace this check with a pkg.m4 check
578 dnl
579 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
580 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
581 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
582 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
583 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
584 else
585 AC_MSG_ERROR([You need at least glib-2.0 $GLIB_REQUIRED_VERSION])
586 fi
587 ;;
588 *)
589 AC_MSG_ERROR([Invalid argument to --with-glib.])
590 esac
591 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
593 AC_SUBST(GLIB_CFLAGS)
594 AC_SUBST(GLIB_LIBS)
595 AC_SUBST(GMODULE_CFLAGS)
596 AC_SUBST(GMODULE_LIBS)
597 AC_SUBST(BUILD_GLIB_CFLAGS)
598 AC_SUBST(BUILD_GLIB_LIBS)
599 AC_SUBST(eglib_dir)
601 if test x$cross_compiling$host_win32 = xnoyes; then
602 AC_MSG_CHECKING(for cygwin glib2-dev package)
603 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
604 AC_MSG_RESULT(found)
605 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
606 else
607 AC_MSG_RESULT(not found, ok)
608 fi
610 AC_MSG_CHECKING(for broken gwin32.h)
611 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
612 if test -f $glib_include/glib/gwin32.h; then
613 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
614 AC_MSG_RESULT(failed)
615 hashmark='#'
616 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
617 fi
618 fi
619 AC_MSG_RESULT(ok)
620 fi
622 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none Defaults to included],[gc=$with_gc],[gc=$gc_default])
624 # Enable support for fast thread-local storage
625 # Some systems have broken support, so we allow to disable it.
626 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation (defaults to __thread)],[],[with_tls=__thread])
628 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
629 # This does not work on some platforms (bug #55253)
630 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack (defaults to yes)],[],[with_sigaltstack=yes])
632 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster) (defaults to yes)],[],[with_static_mono=yes])
634 if test "x$enable_static" = "xno"; then
635 with_static_mono=no
636 fi
638 if test "x$host_win32" = "xyes"; then
639 # Boehm GC requires the runtime to be in its own dll
640 with_static_mono=no
641 fi
643 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
644 AC_ARG_ENABLE(mcs-build, [ --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
646 AC_ARG_WITH(xen_opt, [ --with-xen_opt=yes,no Enable Xen-specific behaviour (defaults to yes)],[],[with_xen_opt=yes])
647 if test "x$with_xen_opt" = "xyes"; then
648 AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
649 ORIG_CFLAGS=$CFLAGS
650 CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
651 AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
652 AC_TRY_COMPILE([], [
653 void main () { }
654 ], [
655 AC_MSG_RESULT(yes)
656 # Pass it to libgc as well
657 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
658 ], [
659 AC_MSG_RESULT(no)
660 CFLAGS=$ORIG_CFLAGS
661 ])
662 fi
664 AC_ARG_ENABLE(quiet-build, [ --enable-quiet-build Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
665 AC_ARG_ENABLE(small-config, [ --enable-small-config Enable tweaks to reduce requirements (and capabilities)], enable_small_config=$enableval, enable_small_config=no)
667 if test x$enable_small_config = xyes; then
668 AC_DEFINE(MONO_SMALL_CONFIG,1,[Reduce runtime requirements (and capabilities)])
669 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -DSMALL_CONFIG"
670 fi
672 if test x$AOT_SUPPORTED != xyes; then
673 AOT_SUPPORTED=no
674 fi
676 AC_ARG_ENABLE(system-aot, [ --enable-system-aot Enable the Ahead-Of-Time compilation of system assemblies during the build (on by default on some platforms)], enable_system_aot=$enableval, enable_system_aot=$AOT_SUPPORTED)
678 DISABLED_FEATURES=none
680 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
681 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
682 reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd,soft_debug.],
683 [
684 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
685 eval "mono_feature_disable_$feature='yes'"
686 done
687 DISABLED_FEATURES=$enable_minimal
688 disabled="Disabled: $enable_minimal"
689 ],[])
691 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
693 if test "x$mono_feature_disable_aot" = "xyes"; then
694 AC_DEFINE(DISABLE_AOT_COMPILER, 1, [Disable AOT Compiler])
695 AC_MSG_NOTICE([Disabled AOT compiler])
696 fi
698 if test "x$mono_feature_disable_profiler" = "xyes"; then
699 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
700 AC_MSG_NOTICE([Disabled support for the profiler])
701 fi
702 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
704 if test "x$mono_feature_disable_decimal" = "xyes"; then
705 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
706 AC_MSG_NOTICE([Disabled support for decimal])
707 fi
709 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
710 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
711 AC_MSG_NOTICE([Disabled support for P/Invoke])
712 fi
714 if test "x$mono_feature_disable_debug" = "xyes"; then
715 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
716 AC_MSG_NOTICE([Disabled support for runtime debugging])
717 fi
719 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
720 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
721 mono_feature_disable_reflection_emit_save=yes
722 AC_MSG_NOTICE([Disabled support for Reflection.Emit])
723 fi
725 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
726 AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
727 AC_MSG_NOTICE([Disabled support for Reflection.Emit.Save])
728 fi
730 if test "x$mono_feature_disable_large_code" = "xyes"; then
731 AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
732 AC_MSG_NOTICE([Disabled support for large assemblies])
733 fi
735 if test "x$mono_feature_disable_logging" = "xyes"; then
736 AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
737 AC_MSG_NOTICE([Disabled support for logging])
738 fi
740 if test "x$mono_feature_disable_com" = "xyes"; then
741 AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
742 AC_MSG_NOTICE([Disabled COM support])
743 fi
745 if test "x$mono_feature_disable_ssa" = "xyes"; then
746 AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
747 AC_MSG_NOTICE([Disabled SSA JIT optimizations])
748 fi
750 if test "x$mono_feature_disable_generics" = "xyes"; then
751 AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
752 AC_MSG_NOTICE([Disabled Generics Support])
753 fi
755 if test "x$mono_feature_disable_shadowcopy" = "xyes"; then
756 AC_DEFINE(DISABLE_SHADOW_COPY, 1, [Disable Shadow Copy for AppDomains])
757 AC_MSG_NOTICE([Disabled Shadow copy for AppDomains])
758 fi
760 if test "x$mono_feature_disable_portability" = "xyes"; then
761 AC_DEFINE(DISABLE_PORTABILITY, 1, [Disables the IO portability layer])
762 AC_MSG_NOTICE([Disabled IO Portability layer])
763 fi
765 if test "x$mono_feature_disable_attach" = "xyes"; then
766 AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
767 AC_MSG_NOTICE([Disabled agent attach])
768 fi
770 if test "x$mono_feature_disable_full_messages" = "xyes"; then
771 AC_DEFINE(DISABLE_FULL_MESSAGES, 1, [Disables building in the full table of WAPI messages])
772 AC_MSG_NOTICE([Disabled full messages for Win32 errors, only core message strings shipped])
773 fi
775 if test "x$mono_feature_disable_verifier" = "xyes"; then
776 AC_DEFINE(DISABLE_VERIFIER, 1, [Disables the verifier])
777 AC_MSG_NOTICE([Disabled the metadata and IL verifiers])
778 fi
780 if test "x$mono_feature_disable_jit" = "xyes"; then
781 AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
782 AC_MSG_NOTICE([Disabled the JIT engine, only full AOT will be supported])
783 fi
785 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
787 if test "x$mono_feature_disable_simd" = "xyes"; then
788 AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
789 AC_MSG_NOTICE([Disabled SIMD support])
790 fi
792 if test "x$mono_feature_disable_soft_debug" = "xyes"; then
793 AC_DEFINE(DISABLE_SOFT_DEBUG, 1, [Disable Soft Debugger Agent.])
794 AC_MSG_NOTICE([Disabled Soft Debugger.])
795 fi
797 AC_MSG_CHECKING(for visibility __attribute__)
798 AC_TRY_COMPILE([], [
799 void __attribute__ ((visibility ("hidden"))) doit (void) {}
800 void main () { doit (); }
801 ], [
802 have_visibility_hidden=yes
803 AC_MSG_RESULT(yes)
804 ], [
805 have_visibility_hidden=no
806 AC_MSG_RESULT(no)
807 ])
809 AC_MSG_CHECKING(for deprecated __attribute__)
810 AC_TRY_COMPILE([
811 int doit (void) __attribute__ ((deprecated));
812 int doit (void) { return 0; }
813 ], [
814 return 0;
815 ], [
816 have_deprecated=yes
817 AC_MSG_RESULT(yes)
818 ], [
819 have_deprecated=no
820 AC_MSG_RESULT(no)
821 ])
823 AC_ARG_ENABLE(parallel-mark, [ --enable-parallel-mark Enables GC Parallel Marking], enable_parallel_mark=$enableval, enable_parallel_mark=$parallel_mark)
824 if test x$enable_parallel_mark = xyes; then
825 libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
826 fi
828 LIBGC_CFLAGS=
829 LIBGC_LIBS=
830 LIBGC_STATIC_LIBS=
831 libgc_dir=
832 case "x$gc" in
833 xboehm|xbohem|xyes)
834 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
835 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
837 if test "x$found_boehm" != "xyes"; then
838 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
839 fi
840 if test "x$gc_headers" != "xyes"; then
841 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
842 fi
844 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
845 AC_SUBST(HAVE_BOEHM_GC)
846 LIBGC_LIBS="-lgc $libdl"
847 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
848 libmono_ldflags="$libmono_ldflags -lgc"
850 # AC_CHECK_FUNCS does not work for some reason...
851 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
852 if test "x$found_gcj_malloc" = "xyes"; then
853 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
854 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
855 else
856 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
857 fi
858 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
859 if test "x$found_gc_enable" = "xyes"; then
860 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have 'GC_enable'])
861 fi
862 ;;
864 xincluded)
865 found_boehm=yes
866 gc_headers=yes
867 use_included_gc=yes
868 libgc_dir=libgc
870 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
871 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
872 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
874 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
875 AC_SUBST(HAVE_BOEHM_GC)
877 AC_DEFINE(HAVE_GC_H, 1, [Have gc.h])
878 AC_DEFINE(USE_INCLUDED_LIBGC, 1, [Use included libgc])
880 # The included libgc contains GCJ support
881 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
882 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have GC_enable])
883 if test x$enable_parallel_mark = xyes; then
884 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
885 else
886 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
887 fi
888 ;;
890 xsgen)
891 found_boehm=no
892 gc_headers=no
893 use_included_gc=no
894 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
895 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
896 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
897 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
898 ;;
900 xnone)
901 AC_MSG_WARN("Compiling mono without GC.")
902 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
903 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
904 ;;
905 *)
906 AC_MSG_ERROR([Invalid argument to --with-gc.])
907 ;;
908 esac
910 AC_ARG_WITH(large-heap, [ --with-large-heap=yes,no Enable support for GC heaps larger than 3GB (defaults to no)], [large_heap=$withval], [large_heap=no])
911 if test "x$large_heap" = "xyes"; then
912 echo "FOO"
913 CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
914 fi
916 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
917 AC_SUBST(LIBGC_CFLAGS)
918 AC_SUBST(LIBGC_LIBS)
919 AC_SUBST(LIBGC_STATIC_LIBS)
920 AC_SUBST(libgc_dir)
922 dnl
923 dnl End of libgc checks
924 dnl
926 dnl *************************************
927 dnl *** Checks for zero length arrays ***
928 dnl *************************************
929 AC_MSG_CHECKING(whether $CC supports zero length arrays)
930 AC_TRY_COMPILE([
931 struct s {
932 int length;
933 char data [0];
934 };
935 ], [], [
936 AC_MSG_RESULT(yes)
937 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 0, [Length of zero length arrays])
938 ], [
939 AC_MSG_RESULT(no)
940 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 1, [Length of zero length arrays])
941 ])
943 if test x$target_win32 = xno; then
945 dnl hires monotonic clock support
946 AC_SEARCH_LIBS(clock_gettime, rt)
948 dnl dynamic loader support
949 AC_CHECK_FUNC(dlopen, DL_LIB="",
950 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
951 )
952 if test x$dl_support = xno; then
953 AC_MSG_WARN([No dynamic loading support available])
954 else
955 LIBS="$LIBS $DL_LIB"
956 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
957 dnl from glib's configure.in
958 AC_CACHE_CHECK([for preceeding underscore in symbols],
959 mono_cv_uscore,[
960 AC_TRY_RUN([#include <dlfcn.h>
961 int mono_underscore_test (void) { return 42; }
962 int main() {
963 void *f1 = (void*)0, *f2 = (void*)0, *handle;
964 handle = dlopen ((void*)0, 0);
965 if (handle) {
966 f1 = dlsym (handle, "mono_underscore_test");
967 f2 = dlsym (handle, "_mono_underscore_test");
968 } return (!f2 || f1);
969 }],
970 [mono_cv_uscore=yes],
971 [mono_cv_uscore=no],
972 [])
973 ])
974 if test "x$mono_cv_uscore" = "xyes"; then
975 MONO_DL_NEED_USCORE=1
976 else
977 MONO_DL_NEED_USCORE=0
978 fi
979 AC_SUBST(MONO_DL_NEED_USCORE)
980 AC_CHECK_FUNC(dlerror)
981 fi
983 dnl ******************************************************************
984 dnl *** Checks for the IKVM JNI interface library ***
985 dnl ******************************************************************
986 AC_ARG_WITH(ikvm-native, [ --with-ikvm-native=yes,no build the IKVM JNI interface library (defaults to yes)],[with_ikvm_native=$withval],[with_ikvm_native=yes])
988 ikvm_native_dir=
989 if test x$with_ikvm_native = xyes; then
990 ikvm_native_dir=ikvm-native
991 jdk_headers_found="IKVM Native"
992 fi
994 AC_SUBST(ikvm_native_dir)
996 AC_CHECK_HEADERS(execinfo.h)
998 AC_CHECK_FUNCS(getgrgid_r)
999 AC_CHECK_FUNCS(getgrnam_r)
1000 AC_CHECK_FUNCS(getpwnam_r)
1001 AC_CHECK_FUNCS(getpwuid_r)
1002 AC_CHECK_FUNCS(getresuid)
1003 AC_CHECK_FUNCS(setresuid)
1004 AC_CHECK_FUNCS(kqueue)
1005 AC_CHECK_FUNCS(backtrace_symbols)
1006 AC_CHECK_FUNCS(mkstemp)
1007 AC_CHECK_FUNCS(mmap)
1008 AC_CHECK_FUNCS(madvise)
1009 AC_CHECK_FUNCS(getrusage)
1010 AC_CHECK_FUNCS(getpriority)
1011 AC_CHECK_FUNCS(setpriority)
1012 AC_CHECK_FUNCS(dl_iterate_phdr)
1014 AC_CHECK_FUNCS(sched_setaffinity)
1016 dnl ****************************************************************
1017 dnl *** Check for sched_setaffinity from glibc versions before ***
1018 dnl *** 2.3.4. The older versions of the function only take 2 ***
1019 dnl *** parameters, not 3. ***
1020 dnl *** ***
1021 dnl *** Because the interface change was not made in a minor ***
1022 dnl *** version rev, the __GLIBC__ and __GLIBC_MINOR__ macros ***
1023 dnl *** won't always indicate the interface sched_affinity has. ***
1024 dnl ****************************************************************
1025 AC_MSG_CHECKING(for sched_setaffinity from glibc < 2.3.4)
1026 AC_TRY_COMPILE([#include <sched.h>], [
1027 int main() {
1028 int mask = 1;
1029 sched_setaffinity(0, &mask);
1030 }
1031 ], [
1032 # Yes, we have it...
1033 AC_MSG_RESULT(yes)
1034 AC_DEFINE(GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY, 1, [Have GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY])
1035 ], [
1036 # We have the new, three-parameter version
1037 AC_MSG_RESULT(no)
1038 ])
1041 dnl ******************************************************************
1042 dnl *** Check for large file support ***
1043 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
1044 dnl ******************************************************************
1046 # Check that off_t can represent 2**63 - 1 correctly, working around
1047 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
1048 # CPPFLAGS and sets $large_offt to yes if the test succeeds
1049 large_offt=no
1050 AC_DEFUN([LARGE_FILES], [
1051 large_CPPFLAGS=$CPPFLAGS
1052 CPPFLAGS="$CPPFLAGS $1"
1053 AC_TRY_RUN([
1054 #include <sys/types.h>
1056 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
1058 int main(void) {
1059 int big_off_t=((BIG_OFF_T%2147483629==721) &&
1060 (BIG_OFF_T%2147483647==1));
1061 if(big_off_t) {
1062 exit(0);
1063 } else {
1064 exit(1);
1065 }
1066 }
1067 ], [
1068 AC_MSG_RESULT(ok)
1069 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
1070 large_CPPFLAGS="$large_CPPFLAGS $1"
1071 large_offt=yes
1072 ], [
1073 AC_MSG_RESULT(no)
1074 ], "")
1075 CPPFLAGS=$large_CPPFLAGS
1076 ])
1078 AC_MSG_CHECKING(if off_t is 64 bits wide)
1079 LARGE_FILES("")
1080 if test $large_offt = no; then
1081 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
1082 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
1083 fi
1084 if test $large_offt = no; then
1085 AC_MSG_WARN([No 64 bit file size support available])
1086 fi
1088 dnl *****************************
1089 dnl *** Checks for libsocket ***
1090 dnl *****************************
1091 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
1093 dnl *******************************
1094 dnl *** Checks for MSG_NOSIGNAL ***
1095 dnl *******************************
1096 AC_MSG_CHECKING(for MSG_NOSIGNAL)
1097 AC_TRY_COMPILE([#include <sys/socket.h>], [
1098 int f = MSG_NOSIGNAL;
1099 ], [
1100 # Yes, we have it...
1101 AC_MSG_RESULT(yes)
1102 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
1103 ], [
1104 # We'll have to use signals
1105 AC_MSG_RESULT(no)
1106 ])
1108 dnl *****************************
1109 dnl *** Checks for SOL_IP ***
1110 dnl *****************************
1111 AC_MSG_CHECKING(for SOL_IP)
1112 AC_TRY_COMPILE([#include <netdb.h>], [
1113 int level = SOL_IP;
1114 ], [
1115 # Yes, we have it...
1116 AC_MSG_RESULT(yes)
1117 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
1118 ], [
1119 # We'll have to use getprotobyname
1120 AC_MSG_RESULT(no)
1121 ])
1123 dnl *****************************
1124 dnl *** Checks for SOL_IPV6 ***
1125 dnl *****************************
1126 AC_MSG_CHECKING(for SOL_IPV6)
1127 AC_TRY_COMPILE([#include <netdb.h>], [
1128 int level = SOL_IPV6;
1129 ], [
1130 # Yes, we have it...
1131 AC_MSG_RESULT(yes)
1132 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
1133 ], [
1134 # We'll have to use getprotobyname
1135 AC_MSG_RESULT(no)
1136 ])
1138 dnl *****************************
1139 dnl *** Checks for SOL_TCP ***
1140 dnl *****************************
1141 AC_MSG_CHECKING(for SOL_TCP)
1142 AC_TRY_COMPILE([#include <netdb.h>], [
1143 int level = SOL_TCP;
1144 ], [
1145 # Yes, we have it...
1146 AC_MSG_RESULT(yes)
1147 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
1148 ], [
1149 # We'll have to use getprotobyname
1150 AC_MSG_RESULT(no)
1151 ])
1153 dnl *****************************
1154 dnl *** Checks for IP_PKTINFO ***
1155 dnl *****************************
1156 AC_MSG_CHECKING(for IP_PKTINFO)
1157 AC_TRY_COMPILE([#include <netdb.h>], [
1158 int level = IP_PKTINFO;
1159 ], [
1160 # Yes, we have it...
1161 AC_MSG_RESULT(yes)
1162 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1163 ], [
1164 AC_MSG_RESULT(no)
1165 ])
1167 dnl *****************************
1168 dnl *** Checks for IPV6_PKTINFO ***
1169 dnl *****************************
1170 AC_MSG_CHECKING(for IPV6_PKTINFO)
1171 AC_TRY_COMPILE([#include <netdb.h>], [
1172 int level = IPV6_PKTINFO;
1173 ], [
1174 # Yes, we have it...
1175 AC_MSG_RESULT(yes)
1176 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
1177 ], [
1178 AC_MSG_RESULT(no)
1179 ])
1181 dnl **********************************
1182 dnl *** Checks for IP_DONTFRAGMENT ***
1183 dnl **********************************
1184 AC_MSG_CHECKING(for IP_DONTFRAGMENT)
1185 AC_TRY_COMPILE([#include <netdb.h>], [
1186 int level = IP_DONTFRAGMENT;
1187 ], [
1188 # Yes, we have it...
1189 AC_MSG_RESULT(yes)
1190 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
1191 ], [
1192 AC_MSG_RESULT(no)
1193 ])
1195 dnl **********************************
1196 dnl *** Checks for IP_MTU_DISCOVER ***
1197 dnl **********************************
1198 AC_MSG_CHECKING(for IP_MTU_DISCOVER)
1199 AC_TRY_COMPILE([#include <netdb.h>], [
1200 int level = IP_MTU_DISCOVER;
1201 ], [
1202 # Yes, we have it...
1203 AC_MSG_RESULT(yes)
1204 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
1205 ], [
1206 AC_MSG_RESULT(no)
1207 ])
1209 dnl *********************************
1210 dnl *** Check for struct ip_mreqn ***
1211 dnl *********************************
1212 AC_MSG_CHECKING(for struct ip_mreqn)
1213 AC_TRY_COMPILE([#include <netinet/in.h>], [
1214 struct ip_mreqn mreq;
1215 mreq.imr_address.s_addr = 0;
1216 ], [
1217 # Yes, we have it...
1218 AC_MSG_RESULT(yes)
1219 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
1220 ], [
1221 # We'll just have to try and use struct ip_mreq
1222 AC_MSG_RESULT(no)
1223 AC_MSG_CHECKING(for struct ip_mreq)
1224 AC_TRY_COMPILE([#include <netinet/in.h>], [
1225 struct ip_mreq mreq;
1226 mreq.imr_interface.s_addr = 0;
1227 ], [
1228 # Yes, we have it...
1229 AC_MSG_RESULT(yes)
1230 AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
1231 ], [
1232 # No multicast support
1233 AC_MSG_RESULT(no)
1234 ])
1235 ])
1237 dnl **********************************
1238 dnl *** Check for gethostbyname2_r ***
1239 dnl **********************************
1240 AC_MSG_CHECKING(for gethostbyname2_r)
1241 AC_TRY_LINK([#include <netdb.h>], [
1242 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1243 ], [
1244 # Yes, we have it...
1245 AC_MSG_RESULT(yes)
1246 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1247 ], [
1248 AC_MSG_RESULT(no)
1249 ])
1251 dnl *****************************
1252 dnl *** Checks for libnsl ***
1253 dnl *****************************
1254 AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1256 AC_CHECK_FUNCS(inet_pton inet_aton)
1258 dnl ***********************************************
1259 dnl *** Checks for size of sockaddr_un.sun_path ***
1260 dnl ***********************************************
1261 # AC_CHECK_SIZEOF can't cope with struct members :-(
1262 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1263 AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1264 [AC_TRY_RUN([
1265 #include <sys/types.h>
1266 #include <stdio.h>
1267 #include <sys/un.h>
1269 int main(void) {
1270 struct sockaddr_un sock_un;
1271 FILE *f=fopen("conftestval", "w");
1272 if(!f) exit(1);
1273 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1274 exit(0);
1275 }
1276 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1277 mono_cv_sizeof_sunpath=0,
1278 mono_cv_sizeof_sunpath=0)])dnl
1279 AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1280 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1282 dnl *****************************
1283 dnl *** Checks for libxnet ***
1284 dnl *****************************
1285 case "${host}" in
1286 *solaris* )
1287 AC_MSG_CHECKING(for Solaris XPG4 support)
1288 if test -f /usr/lib/libxnet.so; then
1289 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1290 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1291 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1292 LIBS="$LIBS -lxnet"
1293 AC_MSG_RESULT(yes)
1294 else
1295 AC_MSG_RESULT(no)
1296 fi
1298 if test "$GCC" = "yes"; then
1299 CFLAGS="$CFLAGS -Wno-char-subscripts"
1300 fi
1301 ;;
1302 esac
1304 dnl *****************************
1305 dnl *** Checks for libpthread ***
1306 dnl *****************************
1307 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1308 # and libpthread does not exist
1309 #
1310 case "${host}" in
1311 *-*-*freebsd*)
1312 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1313 ;;
1314 *-*-*openbsd*)
1315 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1316 ;;
1317 *)
1318 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1319 ;;
1320 esac
1321 AC_CHECK_HEADERS(pthread.h)
1322 AC_CHECK_FUNCS(pthread_mutex_timedlock)
1323 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1324 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1325 AC_TRY_COMPILE([ #include <pthread.h>], [
1326 pthread_mutexattr_t attr;
1327 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1328 ], [
1329 AC_MSG_RESULT(ok)
1330 ], [
1331 AC_MSG_RESULT(no)
1332 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1333 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1334 ])
1335 AC_CHECK_FUNCS(pthread_attr_setstacksize)
1336 AC_CHECK_FUNCS(pthread_attr_getstack pthread_attr_getstacksize)
1337 AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1339 dnl ***********************************
1340 dnl *** Checks for signals
1341 dnl ***********************************
1342 AC_CHECK_HEADERS(signal.h)
1343 AC_CHECK_FUNCS(sigaction)
1345 dnl ***********************************
1346 dnl *** Checks for working __thread ***
1347 dnl ***********************************
1348 AC_MSG_CHECKING(for working __thread)
1349 if test "x$with_tls" != "x__thread"; then
1350 AC_MSG_RESULT(disabled)
1351 else
1352 AC_TRY_RUN([
1353 #include <pthread.h>
1354 __thread int i;
1355 static int res1, res2;
1357 void thread_main (void *arg)
1358 {
1359 i = arg;
1360 sleep (1);
1361 if (arg == 1)
1362 res1 = (i == arg);
1363 else
1364 res2 = (i == arg);
1365 }
1367 int main () {
1368 pthread_t t1, t2;
1370 i = 5;
1372 pthread_create (&t1, NULL, thread_main, 1);
1373 pthread_create (&t2, NULL, thread_main, 2);
1375 pthread_join (t1, NULL);
1376 pthread_join (t2, NULL);
1378 return !(res1 + res2 == 2);
1379 }
1380 ], [
1381 AC_MSG_RESULT(yes)
1382 ], [
1383 AC_MSG_RESULT(no)
1384 with_tls=pthread
1385 ])
1386 fi
1388 dnl **************************************
1389 dnl *** Checks for working sigaltstack ***
1390 dnl **************************************
1391 AC_MSG_CHECKING(for working sigaltstack)
1392 if test "x$with_sigaltstack" != "xyes"; then
1393 AC_MSG_RESULT(disabled)
1394 else
1395 AC_TRY_RUN([
1396 #include <stdio.h>
1397 #include <stdlib.h>
1398 #include <unistd.h>
1399 #include <signal.h>
1400 #include <pthread.h>
1401 #include <sys/wait.h>
1402 #if defined(__FreeBSD__) || defined(__NetBSD__)
1403 #define SA_STACK SA_ONSTACK
1404 #endif
1405 static void
1406 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1407 {
1408 exit (0);
1409 }
1411 static void *
1412 loop (void *ignored)
1413 {
1414 char *ptr = NULL;
1416 *ptr = 0;
1417 return NULL;
1418 }
1420 static void
1421 child ()
1422 {
1423 struct sigaction sa;
1424 struct sigaltstack sas;
1425 pthread_t id;
1426 pthread_attr_t attr;
1428 sa.sa_sigaction = sigsegv_signal_handler;
1429 sigemptyset (&sa.sa_mask);
1430 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1431 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1432 perror ("sigaction");
1433 return;
1434 }
1436 sas.ss_sp = malloc (SIGSTKSZ);
1437 sas.ss_size = SIGSTKSZ;
1438 sas.ss_flags = 0;
1439 if (sigaltstack (&sas, NULL) == -1) {
1440 perror ("sigaltstack");
1441 return;
1442 }
1444 pthread_attr_init (&attr);
1445 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1446 printf ("pthread_create\n");
1447 return;
1448 }
1450 sleep (100);
1451 }
1453 int
1454 main ()
1455 {
1456 pid_t son;
1457 int status;
1458 int i;
1460 son = fork ();
1461 if (son == -1) {
1462 return 1;
1463 }
1465 if (son == 0) {
1466 child ();
1467 return 0;
1468 }
1470 for (i = 0; i < 3; ++i) {
1471 sleep (1);
1472 waitpid (son, &status, WNOHANG);
1473 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1474 return 0;
1475 }
1477 kill (son, SIGKILL);
1478 return 1;
1479 }
1481 ], [
1482 AC_MSG_RESULT(yes)
1483 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1484 ], [
1485 with_sigaltstack=no
1486 AC_MSG_RESULT(no)
1487 ])
1488 fi
1490 dnl ********************************
1491 dnl *** Checks for semaphore lib ***
1492 dnl ********************************
1493 # 'Real Time' functions on Solaris
1494 # posix4 on Solaris 2.6
1495 # pthread (first!) on Linux
1496 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1498 AC_SEARCH_LIBS(shm_open, pthread rt posix4)
1499 AC_CHECK_FUNCS(shm_open)
1501 dnl ********************************
1502 dnl *** Checks for timezone stuff **
1503 dnl ********************************
1504 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1505 AC_TRY_COMPILE([
1506 #include <time.h>
1507 ], [
1508 struct tm tm;
1509 tm.tm_gmtoff = 1;
1510 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1511 if test $ac_cv_struct_tm_gmtoff = yes; then
1512 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1513 else
1514 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1515 AC_TRY_COMPILE([
1516 #include <time.h>
1517 ], [
1518 timezone = 1;
1519 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1520 if test $ac_cv_var_timezone = yes; then
1521 AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1522 else
1523 AC_ERROR(unable to find a way to determine timezone)
1524 fi
1525 fi
1527 dnl *********************************
1528 dnl *** Checks for math functions ***
1529 dnl *********************************
1530 LIBS="$LIBS -lm";
1531 if test "x$has_broken_apple_cpp" != "xyes"; then
1532 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1533 AC_TRY_LINK([#include <math.h>],
1534 [ finite(0.0); ],
1535 AC_DEFINE(HAVE_FINITE, 1, [Have finite]) AC_MSG_RESULT(yes),
1536 AC_MSG_RESULT(no)))
1537 fi
1538 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1539 AC_TRY_LINK([#include <math.h>],
1540 [ isfinite(0.0); ],
1541 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1542 AC_MSG_RESULT(no)))
1544 dnl ****************************************************************
1545 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1546 dnl *** have it in the library (duh)) ***
1547 dnl ****************************************************************
1548 AC_CHECK_FUNCS(poll)
1550 dnl *************************
1551 dnl *** Check for signbit ***
1552 dnl *************************
1553 AC_MSG_CHECKING(for signbit)
1554 AC_TRY_LINK([#include <math.h>], [
1555 int s = signbit(1.0);
1556 ], [
1557 AC_MSG_RESULT(yes)
1558 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1559 ], [
1560 AC_MSG_RESULT(no)
1561 ])
1563 dnl **********************************
1564 dnl *** epoll ***
1565 dnl **********************************
1566 AC_CHECK_HEADERS(sys/epoll.h)
1567 haveepoll=no
1568 AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1569 if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1570 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1571 fi
1573 dnl ******************************
1574 dnl *** Checks for SIOCGIFCONF ***
1575 dnl ******************************
1576 AC_CHECK_HEADERS(sys/ioctl.h)
1577 AC_CHECK_HEADERS(net/if.h)
1578 AC_MSG_CHECKING(for ifreq)
1579 AC_TRY_COMPILE([
1580 #include <stdio.h>
1581 #include <sys/ioctl.h>
1582 #include <net/if.h>
1583 ], [
1584 struct ifconf ifc;
1585 struct ifreq *ifr;
1586 void *x;
1587 ifc.ifc_len = 0;
1588 ifc.ifc_buf = NULL;
1589 x = (void *) &ifr->ifr_addr;
1590 ],[
1591 AC_MSG_RESULT(yes)
1592 AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1593 ], [
1594 AC_MSG_RESULT(no)
1595 ])
1596 dnl **********************************
1597 dnl *** Checks for sin_len ***
1598 dnl **********************************
1599 AC_MSG_CHECKING(for sockaddr_in.sin_len)
1600 AC_TRY_COMPILE([
1601 #include <netinet/in.h>
1602 ], [
1603 struct sockaddr_in saddr;
1604 saddr.sin_len = sizeof (saddr);
1605 ],[
1606 AC_MSG_RESULT(yes)
1607 AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1608 ], [
1609 AC_MSG_RESULT(no)
1610 ])
1611 dnl **********************************
1612 dnl *** Checks for sin6_len ***
1613 dnl **********************************
1614 AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1615 AC_TRY_COMPILE([
1616 #include <netinet/in.h>
1617 ], [
1618 struct sockaddr_in6 saddr6;
1619 saddr6.sin6_len = sizeof (saddr6);
1620 ],[
1621 AC_MSG_RESULT(yes)
1622 AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1623 ], [
1624 AC_MSG_RESULT(no)
1625 ])
1626 dnl **********************************
1627 dnl *** Checks for MonoPosixHelper ***
1628 dnl **********************************
1629 AC_CHECK_HEADERS(checklist.h)
1630 AC_CHECK_HEADERS(fstab.h)
1631 AC_CHECK_HEADERS(attr/xattr.h)
1632 AC_CHECK_HEADERS(sys/extattr.h)
1633 AC_CHECK_HEADERS(sys/sendfile.h)
1634 AC_CHECK_HEADERS(sys/statvfs.h)
1635 AC_CHECK_HEADERS(sys/statfs.h)
1636 AC_CHECK_HEADERS(sys/vfstab.h)
1637 AC_CHECK_HEADERS(sys/xattr.h)
1638 AC_CHECK_HEADERS(sys/mman.h)
1639 AC_CHECK_HEADERS(sys/param.h)
1640 AC_CHECK_HEADERS(sys/mount.h)
1641 AC_CHECK_FUNCS(getdomainname)
1642 AC_CHECK_FUNCS(setdomainname)
1643 AC_CHECK_FUNCS(fgetgrent)
1644 AC_CHECK_FUNCS(fgetpwent)
1645 AC_CHECK_FUNCS(fgetpwent)
1646 AC_CHECK_FUNCS(getfsstat)
1647 AC_CHECK_FUNCS(lutimes)
1648 AC_CHECK_FUNCS(mremap)
1649 AC_CHECK_FUNCS(remap_file_pages)
1650 AC_CHECK_FUNCS(posix_fadvise)
1651 AC_CHECK_FUNCS(posix_fallocate)
1652 AC_CHECK_FUNCS(posix_madvise)
1653 AC_CHECK_FUNCS(vsnprintf)
1654 AC_CHECK_FUNCS(sendfile)
1655 AC_CHECK_FUNCS(sethostid)
1656 AC_CHECK_FUNCS(statfs)
1657 AC_CHECK_FUNCS(fstatfs)
1658 AC_CHECK_FUNCS(statvfs)
1659 AC_CHECK_FUNCS(fstatvfs)
1660 AC_CHECK_FUNCS(stime)
1661 AC_CHECK_FUNCS(strerror_r)
1662 AC_CHECK_FUNCS(ttyname_r)
1663 AC_CHECK_SIZEOF(size_t)
1664 AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1665 [#include <sys/types.h>
1666 #include <sys/stat.h>
1667 #include <unistd.h>])
1668 AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1669 [#include <sys/types.h>
1670 #include <sys/stat.h>
1671 #include <unistd.h>])
1672 AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1673 [#include <sys/time.h>])
1674 AC_CHECK_TYPES([struct flock], [AC_DEFINE(HAVE_STRUCT_FLOCK)], ,
1675 [#include <unistd.h>
1676 #include <fcntl.h>])
1677 AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1678 [#include <sys/poll.h>])
1679 AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1680 [#include <sys/types.h>
1681 #include <sys/stat.h>
1682 #include <unistd.h>])
1683 AC_CHECK_TYPES([struct timespec], [AC_DEFINE(HAVE_STRUCT_TIMESPEC)], ,
1684 [#include <time.h>])
1685 AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1686 [#include <sys/time.h>
1687 #include <sys/types.h>
1688 #include <utime.h>])
1689 AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1690 [#include <sys/time.h>])
1691 AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1692 [#include <sys/types.h>
1693 #include <utime.h>])
1694 AC_CHECK_MEMBERS(
1695 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1696 [#include <sys/types.h>
1697 #include <dirent.h>])
1699 dnl Favour xattr through glibc, but use libattr if we have to
1700 AC_CHECK_FUNC(lsetxattr, ,
1701 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1702 )
1703 AC_SUBST(XATTR_LIB)
1705 dnl kinfo_proc.kp_proc works on darwin but fails on other simil-bsds
1706 AC_CHECK_MEMBERS(
1707 [struct kinfo_proc.kp_proc],,,
1708 [#include <sys/types.h>
1709 #include <sys/param.h>
1710 #include <sys/sysctl.h>
1711 #include <sys/proc.h>
1712 ])
1714 dnl *********************************
1715 dnl *** Checks for Windows compilation ***
1716 dnl *********************************
1717 AC_CHECK_HEADERS(sys/time.h)
1718 AC_CHECK_HEADERS(sys/param.h)
1719 AC_CHECK_HEADERS(dirent.h)
1721 dnl *********************************
1722 dnl *** Check for Console 2.0 I/O ***
1723 dnl *********************************
1724 AC_CHECK_HEADERS([curses.h])
1725 AC_CHECK_HEADERS([term.h], [], [],
1726 [#if HAVE_CURSES_H
1727 #include <curses.h>
1728 #endif
1729 ])
1730 AC_CHECK_HEADERS([termios.h])
1732 dnl * This is provided in io-layer, but on windows it's only available
1733 dnl * on xp+
1734 AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1735 else
1736 jdk_headers_found=no
1737 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1738 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1739 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1740 AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1741 AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1742 AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1743 AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1745 dnl *********************************
1746 dnl *** Check for struct ip_mreqn ***
1747 dnl *********************************
1748 AC_MSG_CHECKING(for struct ip_mreqn)
1749 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1750 struct ip_mreqn mreq;
1751 mreq.imr_address.s_addr = 0;
1752 ], [
1753 # Yes, we have it...
1754 AC_MSG_RESULT(yes)
1755 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1756 ], [
1757 # We'll just have to try and use struct ip_mreq
1758 AC_MSG_RESULT(no)
1759 AC_MSG_CHECKING(for struct ip_mreq)
1760 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1761 struct ip_mreq mreq;
1762 mreq.imr_interface.s_addr = 0;
1763 ], [
1764 # Yes, we have it...
1765 AC_MSG_RESULT(yes)
1766 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1767 ], [
1768 # No multicast support
1769 AC_MSG_RESULT(no)
1770 ])
1771 ])
1772 AC_CHECK_FUNCS(GetProcessId)
1773 fi
1775 dnl socklen_t check
1776 AC_MSG_CHECKING(for socklen_t)
1777 AC_TRY_COMPILE([
1778 #include <sys/types.h>
1779 #include <sys/socket.h>
1780 ],[
1781 socklen_t foo;
1782 ],[
1783 ac_cv_c_socklen_t=yes
1784 AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1785 AC_MSG_RESULT(yes)
1786 ],[
1787 AC_MSG_RESULT(no)
1788 ])
1790 AC_MSG_CHECKING(for array element initializer support)
1791 AC_TRY_COMPILE([#include <sys/socket.h>], [
1792 const int array[] = {[1] = 2,};
1793 ], [
1794 # Yes, we have it...
1795 AC_MSG_RESULT(yes)
1796 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1797 ], [
1798 # We'll have to use signals
1799 AC_MSG_RESULT(no)
1800 ])
1802 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1803 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1804 AC_TRY_LINK([#include <math.h>],
1805 [ static void *p = &trunc; ],
1806 [
1807 AC_DEFINE(HAVE_TRUNC)
1808 AC_MSG_RESULT(yes)
1809 ac_cv_trunc=yes
1810 ],
1811 AC_MSG_RESULT(no)))
1813 if test "x$ac_cv_truncl" != "xyes"; then
1814 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1815 fi
1817 AC_CHECK_FUNCS(round)
1818 AC_CHECK_FUNCS(rint)
1820 dnl ****************************
1821 dnl *** Look for /dev/random ***
1822 dnl ****************************
1824 AC_MSG_CHECKING([if usage of random device is requested])
1825 AC_ARG_ENABLE(dev-random,
1826 [ --disable-dev-random disable the use of the random device (enabled by default)],
1827 try_dev_random=$enableval, try_dev_random=yes)
1829 AC_MSG_RESULT($try_dev_random)
1831 case "{$target}" in
1832 *-openbsd*)
1833 NAME_DEV_RANDOM="/dev/srandom"
1834 ;;
1836 dnl Win32 does not have /dev/random, they have their own method...
1838 *-mingw*|*-*-cygwin*)
1839 ac_cv_have_dev_random=no
1840 ;;
1842 dnl Everywhere else, it's /dev/random
1844 *)
1845 NAME_DEV_RANDOM="/dev/random"
1846 ;;
1847 esac
1849 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1851 dnl Now check if the device actually exists
1853 if test "x$try_dev_random" = "xyes"; then
1854 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1855 [if test -r "$NAME_DEV_RANDOM" ; then
1856 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1857 if test "x$ac_cv_have_dev_random" = "xyes"; then
1858 AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1859 fi
1860 else
1861 AC_MSG_CHECKING(for random device)
1862 ac_cv_have_dev_random=no
1863 AC_MSG_RESULT(has been disabled)
1864 fi
1866 if test "x$host_win32" = "xyes"; then
1867 AC_DEFINE(HAVE_CRYPT_RNG)
1868 fi
1870 if test "x$ac_cv_have_dev_random" = "xno" \
1871 && test "x$host_win32" = "xno"; then
1872 AC_MSG_WARN([[
1873 ***
1874 *** A system-provided entropy source was not found on this system.
1875 *** Because of this, the System.Security.Cryptography random number generator
1876 *** will throw a NotImplemented exception.
1877 ***
1878 *** If you are seeing this message, and you know your system DOES have an
1879 *** entropy collection in place, please contact <crichton@gimp.org> and
1880 *** provide information about the system and how to access the random device.
1881 ***
1882 *** Otherwise you can install either egd or prngd and set the environment
1883 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1884 ***]])
1885 fi
1887 AC_MSG_CHECKING([if inter-process shared handles are requested])
1888 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1889 AC_MSG_RESULT($try_shared_handles)
1890 if test "x$try_shared_handles" != "xyes"; then
1891 AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1892 AC_SUBST(DISABLE_SHARED_HANDLES)
1893 fi
1895 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1896 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1898 AC_MSG_CHECKING([if big-arrays are to be enabled])
1899 AC_ARG_ENABLE(big-arrays, [ --enable-big-arrays Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1900 if test "x$enable_big_arrays" = "xyes" ; then
1901 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1902 AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1903 else
1904 AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1905 fi
1906 fi
1907 AC_MSG_RESULT($enable_big_arrays)
1909 dnl **************
1910 dnl *** DTRACE ***
1911 dnl **************
1913 AC_ARG_ENABLE(dtrace,[ --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1915 if test "x$enable_dtrace" = "xyes"; then
1916 if test "x$has_dtrace" = "xno"; then
1917 AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1918 fi
1919 AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1920 if test "x$DTRACE" = "xno"; then
1921 AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1922 enable_dtrace=no
1923 elif ! $DTRACE -h -s $srcdir/data/mono.d > /dev/null 2>&1; then
1924 AC_MSG_RESULT([dtrace doesn't support -h option, dtrace support disabled.])
1925 enable_dtrace=no
1926 fi
1927 fi
1929 dtrace_g=no
1930 if test "x$enable_dtrace" = "xyes"; then
1931 AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1932 DTRACEFLAGS=
1933 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1934 case "$host" in
1935 powerpc-*-darwin*)
1936 DTRACEFLAGS="-arch ppc64"
1937 ;;
1938 i*86-*-darwin*)
1939 DTRACEFLAGS="-arch x86_64"
1940 ;;
1941 *)
1942 DTRACEFLAGS=-64
1943 ;;
1944 esac
1945 else
1946 case "$host" in
1947 powerpc-*-darwin*)
1948 DTRACEFLAGS="-arch ppc"
1949 ;;
1950 i*86-*-darwin*)
1951 DTRACEFLAGS="-arch i386"
1952 ;;
1953 *)
1954 DTRACEFLAGS=-32
1955 ;;
1956 esac
1957 fi
1958 AC_SUBST(DTRACEFLAGS)
1959 case "$host" in
1960 *-*-solaris*)
1961 dtrace_g=yes
1962 ;;
1963 esac
1964 AC_CHECK_HEADERS([sys/sdt.h])
1965 fi
1966 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
1967 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
1969 dnl **************
1970 dnl *** LLVM ***
1971 dnl **************
1973 AC_ARG_ENABLE(llvm,[ --enable-llvm Enable the experimental LLVM back-end], enable_llvm=$enableval, enable_llvm=no)
1975 if test "x$enable_llvm" = "xyes"; then
1976 AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
1977 if test "x$LLVM_CONFIG" = "xno"; then
1978 AC_MSG_ERROR([llvm-config not found.])
1979 fi
1981 # The output of --cflags seems to include optimizations flags too
1982 LLVM_CFLAGS=`$LLVM_CONFIG --cflags | sed -e 's/-O2//g' | sed -e 's/-O0//g' | sed -e 's/-fomit-frame-pointer//g' | sed -e 's/-fPIC//g'`
1983 # LLVM is compiled with -fno-rtti, so we need this too, since our classes inherit
1984 # from LLVM classes.
1985 LLVM_CXXFLAGS="`$LLVM_CONFIG --cxxflags` -fno-rtti"
1986 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1987 LLVM_LIBS=`$LLVM_CONFIG --libs core bitwriter jit x86codegen`
1988 LLVM_LIBS="$LLVM_LDFLAGS $LLVM_LIBS -lstdc++"
1990 # Should be something like '2.6' or '2.7svn'
1991 llvm_version=`$LLVM_CONFIG --version`
1992 major_version=`echo $llvm_version | cut -c 1`
1993 minor_version=`echo $llvm_version | cut -c 3`
1995 AC_DEFINE_UNQUOTED(LLVM_MAJOR_VERSION, $major_version, [Major version of LLVM libraries])
1996 AC_DEFINE_UNQUOTED(LLVM_MINOR_VERSION, $minor_version, [Minor version of LLVM libraries])
1998 # Have to pass these on the command line since mini-llvm-cpp.h already includes
1999 # llvm's config.h
2000 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MAJOR_VERSION=$major_version -DLLVM_MINOR_VERSION=$minor_version"
2002 AC_SUBST(LLVM_CFLAGS)
2003 AC_SUBST(LLVM_CXXFLAGS)
2004 AC_SUBST(LLVM_LIBS)
2005 AC_SUBST(LLVM_LDFLAGS)
2006 AC_DEFINE(ENABLE_LLVM, 1, [Enable the LLVM back end])
2007 fi
2009 AM_CONDITIONAL(ENABLE_LLVM, [test x$enable_llvm = xyes])
2011 TARGET="unknown"
2012 ACCESS_UNALIGNED="yes"
2014 JIT_SUPPORTED=no
2015 INTERP_SUPPORTED=no
2016 LIBC="libc.so.6"
2017 INTL="libc.so.6"
2018 SQLITE="libsqlite.so.0"
2019 SQLITE3="libsqlite3.so.0"
2020 X11="libX11.so"
2022 sizeof_register="SIZEOF_VOID_P"
2024 jit_wanted=false
2025 interp_wanted=false
2026 case "$host" in
2027 # mips-sgi-irix5.* | mips-sgi-irix6.*)
2028 # TARGET=MIPS;
2029 # ACCESS_UNALIGNED="no"
2030 # ;;
2031 mips*)
2032 TARGET=MIPS;
2033 arch_target=mips;
2034 ACCESS_UNALIGNED="no"
2035 JIT_SUPPORTED=yes
2036 jit_wanted=true
2038 AC_MSG_CHECKING(for mips n32)
2039 AC_TRY_COMPILE([], [
2040 void main () {
2041 #if _MIPS_SIM != _ABIN32
2042 #error Not mips n32
2043 #endif
2044 }
2045 ],[
2046 AC_MSG_RESULT(yes)
2047 sizeof_register=8
2048 ],[
2049 AC_MSG_RESULT(no)
2050 ])
2051 ;;
2052 i*86-*-*)
2053 TARGET=X86;
2054 arch_target=x86;
2055 JIT_SUPPORTED=yes
2056 jit_wanted=true
2057 case $host_os in
2058 solaris*)
2059 LIBC="libc.so"
2060 INTL="libintl.so"
2061 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2062 TARGET=AMD64
2063 arch_target=amd64
2064 fi
2066 # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
2067 # int astruct __attribute__ ((visibility ("hidden")));
2068 # void foo ()
2069 # {
2070 # void *p = &astruct;
2071 # }
2072 # gcc -fPIC --shared -o libfoo.so foo.c
2073 # yields:
2074 # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
2075 # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
2076 have_visibility_hidden=no
2077 ;;
2078 cygwin*)
2079 have_visibility_hidden=no
2080 ;;
2081 haiku*)
2082 LIBC=libroot.so
2083 ;;
2084 esac
2085 ;;
2086 x86_64-*-* | amd64-*-*)
2087 TARGET=AMD64;
2088 arch_target=amd64;
2089 JIT_SUPPORTED=yes
2090 jit_wanted=true
2091 ;;
2092 ia64-*-*)
2093 TARGET=IA64
2094 arch_target=ia64
2095 ACCESS_UNALIGNED="no"
2096 JIT_SUPPORTED=yes
2097 jit_wanted=true
2098 LIBC="libc.so.6.1"
2099 INTL="libc.so.6.1"
2100 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
2101 libmono_ldflags="-lunwind"
2102 ;;
2103 sparc*-*-*)
2104 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2105 TARGET=SPARC64
2106 else
2107 TARGET=SPARC
2108 fi
2109 arch_target=sparc;
2110 JIT_SUPPORTED=yes
2111 ACCESS_UNALIGNED="no"
2112 case $host_os in
2113 linux*) ;;
2114 *)
2115 LIBC="libc.so"
2116 INTL="libintl.so"
2117 esac
2118 jit_wanted=true
2119 if test x"$GCC" = xyes; then
2120 # We don't support v8 cpus
2121 CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
2122 fi
2123 if test x"$AR" = xfalse; then
2124 AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
2125 fi
2126 ;;
2127 alpha*-*-linux* | alpha*-*-osf*)
2128 TARGET=ALPHA;
2129 ACCESS_UNALIGNED="no"
2130 JIT_SUPPORTED=yes
2131 jit_wanted=true
2132 arch_target=alpha;
2133 CFLAGS="$CFLAGS -mieee -O0"
2134 case $host_os in
2135 linux*)
2136 LIBC="libc.so.6.1"
2137 INTL="libc.so.6.1"
2138 esac
2139 ;;
2140 *-mingw*|*-*-cygwin*)
2141 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
2142 have_visibility_hidden=no
2143 INTL="intl"
2144 ;;
2145 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
2146 TARGET=HPPA;
2147 arch_target=hppa;
2148 LIBC="libc.sl"
2149 ACCESS_UNALIGNED="no"
2150 INTERP_SUPPORTED=yes
2151 interp_wanted=true
2152 ;;
2153 hppa*linux*)
2154 TARGET=HPPA;
2155 arch_target=hppa;
2156 ACCESS_UNALIGNED="no"
2157 JIT_SUPPORTED=yes
2158 jit_wanted=true
2159 ;;
2160 macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
2161 powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* | powerpc-*-freebsd* )
2162 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2163 TARGET=POWERPC64;
2164 CPPFLAGS="$CPPFLAGS -D__mono_ppc__ -D__mono_ppc64__"
2165 CFLAGS="$CFLAGS -mminimal-toc"
2166 else
2167 TARGET=POWERPC;
2168 CPPFLAGS="$CPPFLAGS -D__mono_ppc__"
2169 fi
2170 arch_target=ppc;
2171 JIT_SUPPORTED=yes
2172 jit_wanted=true
2173 ;;
2174 arm*-darwin*)
2175 TARGET=ARM;
2176 arch_target=arm;
2177 ACCESS_UNALIGNED="no"
2178 JIT_SUPPORTED=yes
2179 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
2180 jit_wanted=true
2181 ;;
2182 arm*-linux*)
2183 TARGET=ARM;
2184 arch_target=arm;
2185 ACCESS_UNALIGNED="no"
2186 JIT_SUPPORTED=yes
2187 jit_wanted=true
2188 ;;
2189 s390-*-linux*)
2190 TARGET=S390;
2191 arch_target=s390;
2192 ACCESS_UNALIGNED="yes"
2193 JIT_SUPPORTED=yes
2194 jit_wanted=true
2195 # Required CFLAGS for s390[x]. USE_STRING_INLINES is automatic with gcc 4.1
2196 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2197 ;;
2198 s390x-*-linux*)
2199 TARGET=S390x;
2200 arch_target=s390x;
2201 ACCESS_UNALIGNED="yes"
2202 JIT_SUPPORTED=yes
2203 jit_wanted=true
2204 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2205 ;;
2206 esac
2208 if test "x$host" != "x$target"; then
2209 case "$target" in
2210 powerpc64-ps3-linux-gnu)
2211 TARGET=POWERPC64
2212 arch_target=powerpc64
2213 AC_DEFINE(TARGET_PS3, 1, [...])
2214 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2215 # It would be better to just use TARGET_POWERPC64, but lots of code already
2216 # uses this define
2217 AC_DEFINE(__mono_ppc64__, 1, [...])
2218 AC_DEFINE(__mono_ilp32__, 1, [64 bit mode with 4 byte longs and pointers])
2219 sizeof_register=8
2220 target_byte_order=G_BIG_ENDIAN
2221 ;;
2223 powerpc64-xbox360-linux-gnu)
2224 TARGET=POWERPC64
2225 arch_target=powerpc64
2226 AC_DEFINE(TARGET_XBOX360, 1, [...])
2227 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2228 # It would be better to just use TARGET_POWERPC64, but lots of code already
2229 # uses this define
2230 sizeof_register=8
2231 target_byte_order=G_BIG_ENDIAN
2232 ;;
2233 *)
2234 AC_MSG_ERROR([Cross compiling is only supported for targets matching 'powerpc64-{ps3,xbox360}-linux-gnu'])
2235 esac
2236 fi
2238 # FIXME: Define the others as well
2239 case "$TARGET" in
2240 X86)
2241 AC_DEFINE(TARGET_X86, 1, [...])
2242 ;;
2243 AMD64)
2244 AC_DEFINE(TARGET_AMD64, 1, [...])
2245 ;;
2246 ARM)
2247 AC_DEFINE(TARGET_ARM, 1, [...])
2248 ;;
2249 POWERPC)
2250 AC_DEFINE(TARGET_POWERPC, 1, [...])
2251 ;;
2252 POWERPC64)
2253 AC_DEFINE(TARGET_POWERPC, 1, [...])
2254 AC_DEFINE(TARGET_POWERPC64, 1, [...])
2255 ;;
2256 esac
2258 if test "x$sizeof_register" = "x4"; then
2259 AC_DEFINE(SIZEOF_REGISTER,4,[size of machine integer registers])
2260 elif test "x$sizeof_register" = "x8"; then
2261 AC_DEFINE(SIZEOF_REGISTER,8,[size of machine integer registers])
2262 else
2263 AC_DEFINE(SIZEOF_REGISTER,SIZEOF_VOID_P,[size of machine integer registers])
2264 fi
2266 if test "x$target_byte_order" = "xG_BIG_ENDIAN"; then
2267 AC_DEFINE(TARGET_BYTE_ORDER,G_BIG_ENDIAN,[byte order of target])
2268 elif test "x$target_byte_order" = "xG_LITTLE_ENDIAN"; then
2269 AC_DEFINE(TARGET_BYTE_ORDER,G_LITTLE_ENDIAN,[byte order of target])
2270 else
2271 AC_DEFINE(TARGET_BYTE_ORDER,G_BYTE_ORDER,[byte order of target])
2272 fi
2274 if test "x$have_visibility_hidden" = "xyes"; then
2275 AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
2276 fi
2278 if test "x$have_deprecated" = "xyes"; then
2279 AC_DEFINE(HAVE_DEPRECATED, 1, [Support for the deprecated attribute])
2280 fi
2282 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT (defaults to no)],[
2283 if test x$withval = xyes; then
2284 jit_wanted=true
2285 else
2286 jit_wanted=false
2287 fi
2288 ])
2290 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter (defaults to no)],[
2291 if test x$withval = xyes; then
2292 interp_wanted=true
2293 else
2294 interp_wanted=false
2295 fi
2296 ])
2298 USEJIT=false
2299 if test x$JIT_SUPPORTED = xyes; then
2300 if $jit_wanted; then
2301 USEJIT=true
2302 jit_status="Building and using the JIT"
2303 else
2304 if $interp_wanted; then
2305 jit_status="Building the JIT, defaulting to the interpreter"
2306 else
2307 AC_ERROR(No JIT or interpreter support available or selected.)
2308 fi
2309 fi
2310 else
2311 if test x$interp_wanted = xtrue; then
2312 jit_status="interpreter"
2313 else
2314 AC_ERROR(No JIT or interpreter support available or selected.)
2315 fi
2316 fi
2318 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
2320 libsuffix=".so"
2322 case "$host" in
2323 *-*-darwin*)
2324 libsuffix=".dylib"
2325 LIBC="libc.dylib"
2326 INTL="libintl.dylib"
2327 SQLITE="libsqlite.0.dylib"
2328 SQLITE3="libsqlite3.0.dylib"
2329 X11="libX11.dylib"
2330 ;;
2331 *-*-*netbsd*)
2332 LIBC="libc.so.12"
2333 INTL="libintl.so.0"
2334 ;;
2335 *-*-*freebsd*)
2336 LIBC="libc.so"
2337 INTL="libintl.so"
2338 ;;
2339 *-*-*openbsd*)
2340 LIBC="libc.so"
2341 INTL="libintl.so"
2342 ;;
2343 *-*-*linux*)
2344 AC_PATH_X
2345 AC_MSG_CHECKING(for the soname of libX11.so)
2346 for i in $x_libraries /usr/lib /usr/lib64; do
2347 for r in 4 5 6; do
2348 if test -f $i/libX11.so.$r; then
2349 X11=libX11.so.$r
2350 AC_MSG_RESULT($X11)
2351 fi
2352 done
2353 done
2355 if test "x$X11" = "xlibX11.so"; then
2356 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
2357 fi
2358 ;;
2359 esac
2362 AC_SUBST(libsuffix)
2364 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
2365 if test "x$with_tls" = "x__thread"; then
2366 #
2367 # On some linux distributions, TLS works in executables, but linking
2368 # against a shared library containing TLS fails with:
2369 # undefined reference to `__tls_get_addr'
2370 #
2371 rm -f conftest.c conftest.so conftest
2372 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
2373 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
2374 $CC -o conftest conftest.so > /dev/null 2>&1
2375 if test ! -f conftest; then
2376 AC_MSG_WARN([Disabling usage of __thread.]);
2377 with_tls=pthread
2378 fi
2379 rm -f conftest.c conftest.so conftest
2380 fi
2381 fi
2383 mono_debugger_supported=no
2384 AC_ARG_ENABLE(mono-debugger, [ --disable-mono-debugger disable support for the mdb debugger], try_mono_debugger=$enableval, try_mono_debugger=yes)
2385 if test "x$try_mono_debugger" = "xyes"; then
2386 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2387 if test x$use_included_gc = xyes; then
2388 case "$host" in
2389 *-*-*linux*)
2390 mono_debugger_supported=yes
2391 ;;
2392 *86-apple-darwin*)
2393 mono_debugger_supported=yes
2394 ;;
2395 esac
2396 fi
2397 fi
2398 fi
2400 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2401 if test "x$mono_debugger_supported" = "xyes"; then
2402 AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
2403 fi
2404 AC_MSG_RESULT($mono_debugger_supported)
2405 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2407 if test "x$with_tls" = "x__thread"; then
2408 AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2409 # Pass the information to libgc
2410 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2411 AC_MSG_CHECKING(if the tls_model attribute is supported)
2412 AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2413 ], [
2414 AC_MSG_RESULT(yes)
2415 AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2416 ], [
2417 AC_MSG_RESULT(no)
2418 ])
2419 fi
2421 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2422 dnl ******************************************
2423 dnl *** Check to see what FPU is available ***
2424 dnl ******************************************
2425 AC_MSG_CHECKING(which FPU to use)
2427 AC_TRY_COMPILE([], [
2428 __asm__ ("ldfd f0, [r0]");
2429 ], fpu=FPA, fpu=NONE)
2431 AC_MSG_RESULT($fpu)
2432 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2433 unset fpu
2434 fi
2436 if test ${TARGET} = unknown; then
2437 CPPFLAGS="$CPPFLAGS -DNO_PORT"
2438 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2439 fi
2441 if test ${ACCESS_UNALIGNED} = no; then
2442 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2443 fi
2445 case "x$gc" in
2446 xincluded)
2447 # Pass CPPFLAGS to libgc configure
2448 # We should use a separate variable for this to avoid passing useless and
2449 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2450 # This should be executed late so we pick up the final version of CPPFLAGS
2451 # The problem with this approach, is that during a reconfigure, the main
2452 # configure scripts gets invoked with these arguments, so we use separate
2453 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2454 LIBGC_CPPFLAGS=$CPPFLAGS
2455 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2456 LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2457 fi
2458 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2459 AC_CONFIG_SUBDIRS(libgc)
2460 ;;
2461 esac
2463 #AC_ARG_WITH(profile2, [ --with-profile2=yes,no If you want to install the 2.0 FX (defaults to yes)], [], [with_profile2=yes])
2464 AC_ARG_WITH(profile4, [ --with-profile4=yes,no If you want to install the 4.0 FX (defaults to yes)], [], [with_profile4=yes])
2465 AC_ARG_WITH(monotouch, [ --with-monotouch=yes,no If you want to build the raw MonoTouch 2.1 assemblies (defaults to no)], [], [with_monotouch=no])
2467 OPROFILE=no
2468 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<oprofile install dir> Enable oprofile support (defaults to no)],[
2469 if test x$with_oprofile != xno; then
2470 oprofile_include=$with_oprofile/include
2471 if test ! -f $oprofile_include/opagent.h; then
2472 AC_MSG_ERROR([oprofile include file not found at $oprofile_include/opagent.h])
2473 fi
2474 OPROFILE=yes
2475 OPROFILE_CFLAGS="-I$oprofile_include"
2476 OPROFILE_LIBS="-L$with_oprofile/lib/oprofile -lopagent"
2477 AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2478 fi
2479 ])
2481 MALLOC_MEMPOOLS=no
2482 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no Use malloc for each single mempool allocation (only for runtime debugging, defaults to no)],[
2483 if test x$with_malloc_mempools = xyes; then
2484 MALLOC_MEMPOOLS=yes
2485 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2486 fi
2487 ])
2490 DISABLE_MCS_DOCS=no
2491 AC_ARG_WITH(mcs_docs,[ --with-mcs-docs=yes,no If you want to build the documentation under mcs (defaults to yes)],[
2492 if test x$with_mcs_docs != xyes; then
2493 DISABLE_MCS_DOCS=yes
2494 fi
2495 ])
2497 AC_ARG_WITH(moonlight, [ --with-moonlight=yes|no|only If you want to build Mono for Moonlight (defaults to no)],[
2498 if test "x$with_moonlight" = "xyes"; then
2499 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2500 elif test "x$with_moonlight" = "xonly"; then
2501 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2502 fi
2503 ], [with_moonlight=no])
2507 dnl
2508 dnl Consistency settings
2509 dnl
2510 if test x$cross_compiling = xyes -o x$enable_mcs_build = xno; then
2511 DISABLE_MCS_DOCS=yes
2512 fi
2514 if test x$DISABLE_MCS_DOCS = xyes; then
2515 docs_dir=""
2516 else
2517 docs_dir=docs
2518 fi
2519 AC_SUBST(docs_dir)
2521 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2522 AC_SUBST(OPROFILE_CFLAGS)
2523 AC_SUBST(OPROFILE_LIBS)
2525 libmono_ldflags="$libmono_ldflags $LIBS"
2527 AM_CONDITIONAL(MOONLIGHT, [test "x$with_moonlight" != "xno"])
2528 AM_CONDITIONAL(ONLY_MOONLIGHT, [test "x$with_moonlight" = "xonly"])
2529 AM_CONDITIONAL(INSTALL_4_0, [test "x$with_profile4" = xyes])
2530 AM_CONDITIONAL(INSTALL_MONOTOUCH, [test "x$with_monotouch" = xyes])
2532 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2533 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2534 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2535 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2536 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2537 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2538 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2539 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2540 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2541 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2542 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2543 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2544 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2545 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2546 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2547 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2549 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2550 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2551 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2553 AC_SUBST(LIBC)
2554 AC_SUBST(INTL)
2555 AC_SUBST(SQLITE)
2556 AC_SUBST(SQLITE3)
2557 AC_SUBST(X11)
2558 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2559 AC_SUBST(arch_target)
2560 AC_SUBST(CFLAGS)
2561 AC_SUBST(CPPFLAGS)
2562 AC_SUBST(LDFLAGS)
2564 mono_build_root=`pwd`
2565 AC_SUBST(mono_build_root)
2567 if test x$USEJIT = xtrue; then
2568 mono_runtime=mono/mini/mono
2569 else
2570 mono_runtime=mono/interpreter/mint
2571 fi
2572 AC_SUBST(mono_runtime)
2574 mono_cfg_root=$mono_build_root/runtime
2575 if test x$host_win32 = xyes; then
2576 if test "x$cross_compiling" = "xno"; then
2577 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2578 else
2579 mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\'`\\etc
2580 fi
2581 else
2582 mono_cfg_dir=$mono_cfg_root/etc
2583 fi
2584 AC_SUBST(mono_cfg_dir)
2586 AC_CONFIG_FILES([po/mcs/Makefile.in])
2588 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2589 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2591 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2592 [ depth=../../../..
2593 case $srcdir in
2594 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2595 .) reldir=$depth ;;
2596 *) reldir=$depth/$srcdir ;;
2597 esac
2598 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2599 cd runtime/etc/mono/1.0
2600 rm -f machine.config
2601 $LN_S $reldir/data/net_1_1/machine.config machine.config
2602 cd $depth
2603 ],[LN_S='$LN_S'])
2605 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2606 [ depth=../../../..
2607 case $srcdir in
2608 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2609 .) reldir=$depth ;;
2610 *) reldir=$depth/$srcdir ;;
2611 esac
2612 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2613 cd runtime/etc/mono/2.0
2614 rm -f machine.config
2615 $LN_S $reldir/data/net_2_0/machine.config machine.config
2616 cd $depth
2617 ],[LN_S='$LN_S'])
2619 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2620 [ depth=../../../..
2621 case $srcdir in
2622 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2623 .) reldir=$depth ;;
2624 *) reldir=$depth/$srcdir ;;
2625 esac
2626 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2627 cd runtime/etc/mono/2.0
2628 rm -f web.config
2629 $LN_S $reldir/data/net_2_0/web.config web.config
2630 cd $depth
2631 ],[LN_S='$LN_S'])
2633 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2634 [ depth=../../..
2635 case $srcdir in
2636 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2637 .) reldir=$depth ;;
2638 *) reldir=$depth/$srcdir ;;
2639 esac
2640 $ac_aux_dir/install-sh -d runtime/etc/mono/
2641 cd runtime/etc/mono/
2642 rm -f browscap.ini
2643 $LN_S $reldir/data/browscap.ini browscap.ini
2644 cd $depth
2645 ],[LN_S='$LN_S'])
2647 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2648 [ depth=../../../../..
2649 case $srcdir in
2650 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2651 .) reldir=$depth ;;
2652 *) reldir=$depth/$srcdir ;;
2653 esac
2654 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2655 cd runtime/etc/mono/2.0/Browsers
2656 rm -f Compat.browser
2657 $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2658 cd $depth
2659 ],[LN_S='$LN_S'])
2661 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/machine.config],
2662 [ depth=../../../..
2663 case $srcdir in
2664 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2665 .) reldir=$depth ;;
2666 *) reldir=$depth/$srcdir ;;
2667 esac
2668 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2669 cd runtime/etc/mono/4.0
2670 rm -f machine.config
2671 $LN_S $reldir/data/net_4_0/machine.config machine.config
2672 cd $depth
2673 ],[LN_S='$LN_S'])
2675 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/web.config],
2676 [ depth=../../../..
2677 case $srcdir in
2678 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2679 .) reldir=$depth ;;
2680 *) reldir=$depth/$srcdir ;;
2681 esac
2682 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2683 cd runtime/etc/mono/4.0
2684 rm -f web.config
2685 $LN_S $reldir/data/net_4_0/web.config web.config
2686 cd $depth
2687 ],[LN_S='$LN_S'])
2689 if test x$enable_quiet_build = xyes; then
2690 AC_CONFIG_COMMANDS([quiet], [for i in `find mono libgc support -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
2691 AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2692 fi
2694 AC_OUTPUT([
2695 Makefile
2696 mono-core.spec
2697 mono-uninstalled.pc
2698 scripts/mono-find-provides
2699 scripts/mono-find-requires
2700 mono/Makefile
2701 mono/utils/Makefile
2702 mono/metadata/Makefile
2703 mono/dis/Makefile
2704 mono/cil/Makefile
2705 mono/arch/Makefile
2706 mono/arch/x86/Makefile
2707 mono/arch/amd64/Makefile
2708 mono/arch/hppa/Makefile
2709 mono/arch/ppc/Makefile
2710 mono/arch/sparc/Makefile
2711 mono/arch/s390/Makefile
2712 mono/arch/s390x/Makefile
2713 mono/arch/arm/Makefile
2714 mono/arch/alpha/Makefile
2715 mono/arch/ia64/Makefile
2716 mono/arch/mips/Makefile
2717 mono/interpreter/Makefile
2718 mono/tests/Makefile
2719 mono/tests/tests-config
2720 mono/tests/assemblyresolve/Makefile
2721 mono/tests/cas/Makefile
2722 mono/tests/cas/assembly/Makefile
2723 mono/tests/cas/demand/Makefile
2724 mono/tests/cas/inheritance/Makefile
2725 mono/tests/cas/linkdemand/Makefile
2726 mono/tests/cas/threads/Makefile
2727 mono/benchmark/Makefile
2728 mono/monograph/Makefile
2729 mono/io-layer/Makefile
2730 mono/mini/Makefile
2731 mono/profiler/Makefile
2732 ikvm-native/Makefile
2733 scripts/Makefile
2734 man/Makefile
2735 web/Makefile
2736 docs/Makefile
2737 data/Makefile
2738 data/net_2_0/Makefile
2739 data/net_4_0/Makefile
2740 data/net_2_0/Browsers/Makefile
2741 data/mint.pc
2742 data/mono-2.pc
2743 data/mono-cairo.pc
2744 data/mono-nunit.pc
2745 data/mono-options.pc
2746 data/mono-lineeditor.pc
2747 data/monodoc.pc
2748 data/mono.web.pc
2749 data/dotnet.pc
2750 data/dotnet35.pc
2751 data/wcf.pc
2752 data/cecil.pc
2753 data/system.web.extensions_1.0.pc
2754 data/system.web.extensions.design_1.0.pc
2755 data/system.web.mvc.pc
2756 data/system.web.mvc2.pc
2757 samples/Makefile
2758 support/Makefile
2759 data/config
2760 tools/Makefile
2761 tools/locale-builder/Makefile
2762 tools/sgen/Makefile
2763 runtime/Makefile
2764 msvc/Makefile
2765 po/Makefile
2766 ])
2768 if test x$host_win32 = xyes; then
2769 # Get rid of 'cyg' prefixes in library names
2770 sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2771 # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2772 # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2773 # executable doesn't work...
2774 sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2775 fi
2777 (
2778 case $prefix in
2779 NONE) prefix=$ac_default_prefix ;;
2780 esac
2781 case $exec_prefix in
2782 NONE) exec_prefix='${prefix}' ;;
2783 esac
2785 #
2786 # If we are cross compiling, we don't build in the mcs/ tree. Let us not clobber
2787 # any existing config.make. This allows people to share the same source tree
2788 # with different build directories, one native and one cross
2789 #
2790 if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2792 test -w $mcs_topdir/build || chmod +w $mcs_topdir/build
2794 echo "prefix=$prefix" > $mcs_topdir/build/config.make
2795 echo "exec_prefix=$exec_prefix" >> $mcs_topdir/build/config.make
2796 echo "sysconfdir=$sysconfdir" >> $mcs_topdir/build/config.make
2797 echo 'mono_libdir=${exec_prefix}/lib' >> $mcs_topdir/build/config.make
2798 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $mcs_topdir/build/config.make
2799 echo 'IL_FLAGS = /debug' >> $mcs_topdir/build/config.make
2800 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $mcs_topdir/build/config.make
2801 echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $mcs_topdir/build/config.make
2803 case $INSTALL in
2804 [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2805 *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2806 esac
2808 echo "INSTALL = $mcs_INSTALL" >> $mcs_topdir/build/config.make
2810 export VERSION
2811 [myver=$($AWK 'BEGIN {
2812 split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2813 if(length(vsplit [1]) > 4) {
2814 split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2815 }
2816 print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2817 }')]
2819 echo "MONO_VERSION = $myver" >> $mcs_topdir/build/config.make
2821 if test x$platform_darwin = xyes; then
2822 echo "PLATFORM = darwin" >> $mcs_topdir/build/config.make
2823 fi
2825 if test x$TARGET = xAMD64 -a x$host_win32 = xno -a "x$AOT_SUPPORTED" = "xyes" -a x$enable_system_aot = xyes; then
2826 echo "ENABLE_AOT = 1" >> $mcs_topdir/build/config.make
2827 fi
2829 if test x$DISABLE_MCS_DOCS = xyes; then
2830 echo "DISABLE_MCS_DOCS = yes" >> $mcs_topdir/build/config.make
2831 fi
2833 if test x$with_moonlight != xno; then
2834 echo "MOONLIGHT = 1" >> $srcdir/$mcsdir/build/config.make
2835 fi
2837 fi
2839 # if we have an olive folder, override the default settings
2840 if test -d $olivedir; then
2842 if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2844 test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2846 echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2847 echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2848 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2849 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2850 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2851 echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2852 fi
2853 fi
2855 )
2857 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2859 echo "
2860 mcs source: $mcsdir
2861 olive source: $olive_topdir
2863 Engine:
2864 GC: $gc
2865 GLIB: $with_glib
2866 TLS: $with_tls
2867 SIGALTSTACK: $with_sigaltstack
2868 Engine: $jit_status
2869 oprofile: $OPROFILE
2870 BigArrays: $enable_big_arrays
2871 DTrace: $enable_dtrace
2872 Parallel Mark: $enable_parallel_mark
2873 LLVM Back End: $enable_llvm
2875 Libraries:
2876 Moon Profile: $with_moonlight
2877 MonoTouch: $with_monotouch
2878 JNI support: $jdk_headers_found
2879 libgdiplus: $libgdiplus_msg
2880 zlib: $zlib_msg
2881 $disabled
2882 "
2883 if test x$with_static_mono = xno -a "x$host_win32" != "xyes"; then
2884 AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexpected bugs)
2885 fi
2887 if test x$gc = xsgen; then
2888 echo IMPORTANT:
2889 echo IMPORTANT: You have selected an experimental, work-in-progress
2890 echo IMPORTANT: GC engine. This GC engine is currently not supported
2891 echo IMPORTANT: and is not yet ready for use.
2892 echo IMPORTANT:
2893 echo IMPORTANT: There are known problems with it, use at your own risk.
2894 fi
2896 if test x$enable_llvm = xyes; then
2897 echo IMPORTANT:
2898 echo IMPORTANT: The LLVM Back End is experimental and has known problems.
2899 echo IMPORTANT:
2900 fi