mono/tests/tailcall-mrgctx.il

   1 /*
   2 Author:
   3     Jay Krell (jaykrell@microsoft.com)
   4
   5 Copyright 2018 Microsoft
   6 Licensed under the MIT license. See LICENSE file in the project root for full license information.
   7
   8 http://www.mono-project.com/docs/advanced/runtime/docs/generic-sharing/
   9 1. Non-generic non-static methods of reference types have access to the
  10    RGCTX via the “this” argument (this->vtable->rgctx).
  11 2. a. Non-generic static methods of reference types and b. non-generic methods
  12    of value types need to be passed a pointer to the caller’s class’s VTable in the MONO_ARCH_RGCTX_REG register.
  13 3. Generic methods need to be passed a pointer to the MRGCTX in the MONO_ARCH_RGCTX_REG register
  14
  15 Test case 3.
  16
  17 using System;
  18 using System.Runtime.CompilerServices;
  19 using static System.Runtime.CompilerServices.MethodImplOptions;
  20
  21 unsafe class A
  22 {
  23     [MethodImpl (NoInlining)]
  24     static int check (long stack1, long stack2)
  25     {
  26         return (stack1 == stack2) ? 0 : 1;
  27     }
  28
  29     [MethodImpl (NoInlining)]
  30     public int f1<T> (int counter, long initial_stack, long current_stack)
  31     {
  32         int local;
  33         if (counter > 0)
  34             return f2<T> (counter - 1, initial_stack, (long)&local);
  35         return check ((long)&local, current_stack);
  36     }
  37
  38     [MethodImpl (NoInlining)]
  39     public int f2<T> (int counter, long initial_stack, long current_stack)
  40     {
  41         int local;
  42         if (counter > 0)
  43             return f1<T> (counter - 1, initial_stack, (long)&local);
  44         return check ((long)&local, current_stack);
  45     }
  46 }
  47
  48 unsafe class B
  49 {
  50     [MethodImpl (NoInlining)]
  51     public static void Main()
  52     {
  53         int stack;
  54         Environment.Exit(new A().f1<object> (100, (long)&stack, 0));
  55     }
  56 }
  57 */
  58
  59 .assembly extern mscorlib { }
  60
  61 .assembly 'tailcall-mrgctx' { }
  62
  63 .class A
  64 {
  65 .method static int32 check (int64 stack1, int64 stack2) noinlining
  66 {
  67         ldarg.0
  68         ldarg.1
  69         beq.s IL_0006
  70
  71         ldc.i4.1
  72         ret
  73
  74 IL_0006:
  75         ldc.i4.0
  76         ret
  77 }
  78
  79 .method instance int32 f1<T> (int32 counter, int64 initial_stack, int64 current_stack) noinlining
  80 {
  81         .locals init (int32 V_0)
  82         ldarg.1         // counter
  83         ldc.i4.0        // 0
  84         ble.s IL_0013   // if (counter <= 0) goto 13.
  85
  86         ldarg.0         // this
  87         ldarg.1         // counter
  88         ldc.i4.1        // 1
  89         sub             // counter - 1
  90         ldarg.2         // initial_stack
  91         ldloca.s V_0    // &local
  92         conv.u          // (long)&local
  93         conv.u8         // (long)&local
  94         tail. call instance int32 A::f2<!!0> (int32, int64, int64)
  95         ret
  96
  97 IL_0013:
  98         ldloca.s V_0    // &local
  99         conv.u          // (long)&local
 100         conv.u8         // (long)&local
 101         ldarg.3         // current_stack
 102         tail. call int32 A::check (int64, int64)
 103         ret
 104 }
 105
 106 .method instance int32  f2<T> (int32 counter, int64 initial_stack, int64 current_stack) noinlining
 107 {
 108         .locals init (int32 V_0)
 109         ldarg.1
 110         ldc.i4.0
 111         ble.s IL_0013
 112
 113         ldarg.0
 114         ldarg.1
 115         ldc.i4.1
 116         sub
 117         ldarg.2
 118         ldloca.s V_0
 119         conv.u
 120         conv.u8
 121         tail. call instance int32 A::f1<!!0> (int32, int64, int64)
 122         ret
 123
 124 IL_0013:
 125         ldloca.s V_0
 126         conv.u
 127         conv.u8
 128         ldarg.3
 129         tail. call int32 A::check (int64, int64)
 130         ret
 131 }
 132
 133 .method instance void .ctor ()
 134 {
 135         ldarg.0
 136         tail. call instance void [mscorlib]System.Object::.ctor ()
 137         ret
 138 }
 139
 140 }
 141
 142 .class B
 143 {
 144 .method static int32 Main () noinlining
 145 {
 146         .entrypoint
 147         .locals init (int32 V_0)
 148         newobj instance void A::.ctor ()
 149         ldc.i4.s 100
 150         ldloca.s V_0
 151         conv.u
 152         conv.u8
 153         ldc.i4.0
 154         conv.i8
 155         tail. call instance int32 A::f1<object> (int32, int64, int64)
 156         ret
 157 }
 158
 159 .method instance void .ctor ()
 160 {
 161         ldarg.0
 162         tail. call instance void [mscorlib]System.Object::.ctor ()
 163         ret
 164 }
 165 }