| blob | acd77e2391c9996ea9e2f9a49b8f617d5c29fd48 |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,1.1.3)
10 AM_MAINTAINER_MODE
12 AC_PROG_LN_S
14 # In case of cygwin, override LN_S, irrespective of what it determines.
15 # The build uses cygwin, but the actual runtime doesn't.
16 case $host_os in
17 *cygwin* ) LN_S='cp -p';;
18 esac
21 dnl
22 dnl libgc checks
23 dnl
25 gc_headers=no
26 gc=included
27 use_included_gc=no
29 if test -d $srcdir/libgc ; then
30 gc_default=included
31 else
32 gc_default=boehm
33 fi
35 #
36 # These are the flags that need to be stored in the mono.pc file for
37 # compiling code that will embed Mono
38 #
39 libmono_cflags=""
40 libmono_ldflags=""
41 AC_SUBST(libmono_cflags)
42 AC_SUBST(libmono_ldflags)
44 dnl if linker handles the version script
45 no_version_script=no
47 # Set to yes if Unix sockets cannot be created in an anonymous namespace
48 need_link_unlink=no
50 # Thread configuration inspired by sleepycat's db
51 AC_MSG_CHECKING([host platform characteristics])
52 libgc_threads=no
53 case "$host" in
54 *-*-mingw*|*-*-cygwin*)
55 platform_win32=yes
56 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
57 CC="gcc -mno-cygwin -g"
58 HOST_CC="gcc"
59 # So libgc configure gets -mno-cygwin
60 export CC
61 # latest libgc already defines GC_WIN32_THREADS
62 # CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
63 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
64 libdl=
65 libgc_threads=win32
66 gc_default=included
67 with_nptl=default
68 with_sigaltstack=no
69 LN_S=cp
70 ;;
71 *-*-*netbsd*)
72 platform_win32=no
73 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
74 libmono_cflags="-D_REENTRANT"
75 LDFLAGS="$LDFLAGS -pthread"
76 libmono_ldflags="-pthread"
77 need_link_unlink=yes
78 libdl=
79 libgc_threads=no
80 ;;
81 # these flags will work for all versions of -STABLE
82 #
83 *-*-*freebsd4*)
84 platform_win32=no
85 if test "x$PTHREAD_CFLAGS" = "x"; then
86 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
87 libmono_cflags="-D_THREAD_SAFE"
88 else
89 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
90 libmono_cflags="$PTHREAD_CFLAGS"
91 fi
92 if test "x$PTHREAD_LIBS" = "x"; then
93 LDFLAGS="$LDFLAGS -pthread"
94 libmono_ldflags="-pthread"
95 else
96 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
97 libmono_ldflags="$PTHREAD_LIBS"
98 fi
99 need_link_unlink=yes
100 AC_DEFINE(PTHREAD_POINTER_ID)
101 libdl=
102 libgc_threads=pthreads
103 # TLS isn't implemented at all on -STABLE
104 with_nptl=no
105 with_tls=pthread
106 ;;
107 # older versions of -CURRENT will break with these flags but testing
108 # indicates these older versions won't run Mono anyway
109 #
110 *-*-*freebsd5*)
111 platform_win32=no
112 if test "x$PTHREAD_CFLAGS" = "x"; then
113 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
114 libmono_cflags=
115 else
116 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
117 libmono_cflags="$PTHREAD_CFLAGS"
118 fi
119 if test "x$PTHREAD_LIBS" = "x"; then
120 LDFLAGS="$LDFLAGS -lpthread"
121 libmono_ldflags="-lpthread"
122 else
123 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
124 libmono_ldflags="$PTHREAD_LIBS"
125 fi
126 need_link_unlink=yes
127 AC_DEFINE(PTHREAD_POINTER_ID)
128 libdl=
129 libgc_threads=pthreads
130 # TLS is only partially implemented on -CURRENT (compiler support
131 # but NOT library support)
132 #
133 with_nptl=no
134 with_tls=pthread
135 ;;
136 *-*-*openbsd*)
137 platform_win32=no
138 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
139 libmono_cflags="-D_THREAD_SAFE"
140 LDFLAGS="$LDFLAGS -pthread"
141 libmono_ldflags="-pthread"
142 need_link_unlink=yes
143 AC_DEFINE(PTHREAD_POINTER_ID)
144 libdl=
145 libgc_threads=pthreads
146 ;;
147 *-*-linux*)
148 platform_win32=no
149 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
150 libmono_cflags="-D_REENTRANT"
151 libmono_ldflags="-lpthread"
152 libdl="-ldl"
153 libgc_threads=pthreads
154 ;;
155 *-*-hpux*)
156 platform_win32=no
157 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
158 CFLAGS="$CFLAGS +ESdbgasm"
159 LDFLAGS="$LDFLAGS -z"
160 libmono_cflags="-D_REENTRANT"
161 libmono_ldflags="-lpthread"
162 libgc_threads=pthreads
163 need_link_unlink=yes
164 ;;
165 *-*-solaris*)
166 platform_win32=no
167 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
168 need_link_unlink=yes
169 libmono_cflags="-D_REENTRANT"
170 libgc_threads=pthreads
171 ;;
172 *-*-darwin*)
173 platform_win32=no
174 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
175 libmono_cflags="-D_THREAD_SAFE"
176 LDFLAGS="$LDFLAGS -pthread"
177 libmono_ldflags="-pthread"
178 need_link_unlink=yes
179 AC_DEFINE(PTHREAD_POINTER_ID)
180 AC_DEFINE(USE_MACH_SEMA)
181 no_version_script=yes
182 libdl=
183 libgc_threads=pthreads
184 ;;
185 *)
186 AC_MSG_WARN([*** Please add $host to configure.in checks!])
187 platform_win32=no
188 libdl="-ldl"
189 ;;
190 esac
191 AC_MSG_RESULT(ok)
193 if test x$need_link_unlink = xyes; then
194 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
195 fi
197 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
199 AC_CHECK_TOOL(CC, gcc, gcc)
200 AC_PROG_CC
201 AM_PROG_CC_STDC
202 AC_PROG_INSTALL
203 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
204 : ${CCAS='$(CC)'}
205 # Set ASFLAGS if not already set.
206 : ${CCASFLAGS='$(CFLAGS)'}
207 AC_SUBST(CCAS)
208 AC_SUBST(CCASFLAGS)
210 AC_CHECK_PROG(BISON, bison,yes,no)
211 if test "x$BISON" = "xno";
212 then
213 AC_MSG_ERROR([You need to install bison])
214 fi
216 dnl may require a specific autoconf version
217 dnl AC_PROG_CC_FOR_BUILD
218 dnl CC_FOR_BUILD not automatically detected
219 CC_FOR_BUILD=$CC
220 BUILD_EXEEXT=
221 if test "x$cross_compiling" = "xyes"; then
222 CC_FOR_BUILD=cc
223 BUILD_EXEEXT=""
224 fi
225 AC_SUBST(CC_FOR_BUILD)
226 AC_SUBST(HOST_CC)
227 AC_SUBST(BUILD_EXEEXT)
229 # Set STDC_HEADERS
230 AC_HEADER_STDC
231 AC_LIBTOOL_WIN32_DLL
232 AM_PROG_LIBTOOL
234 # Test whenever ld supports -version-script
235 AC_PROG_LD
236 AC_PROG_LD_GNU
237 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
238 no_version_script=yes
239 fi
241 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
243 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
245 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
247 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
249 # for mono/metadata/debug-symfile.c
250 AC_CHECK_HEADERS(elf.h)
252 # for mono/dis
253 AC_CHECK_HEADERS(wchar.h)
254 AC_CHECK_HEADERS(ieeefp.h)
255 AC_MSG_CHECKING(for isinf)
256 AC_TRY_COMPILE([#include <math.h>], [
257 int f = isinf (1);
258 ], [
259 AC_MSG_RESULT(yes)
260 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
261 ], [
262 # We'll have to use signals
263 AC_MSG_RESULT(no)
264 ])
267 # not 64 bit clean in cross-compile
268 AC_CHECK_SIZEOF(void *, 4)
270 WARN=''
271 if test x"$GCC" = xyes; then
272 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
273 # The runtime code does not respect ANSI C strict aliasing rules
274 CFLAGS="$CFLAGS -fno-strict-aliasing"
275 else
276 # The Sun Forte compiler complains about inline functions that access static variables
277 # so disable all inlining.
278 case "$host" in
279 *-*-solaris*)
280 CFLAGS="$CFLAGS -Dinline="
281 ;;
282 esac
283 fi
284 CFLAGS="$CFLAGS -g $WARN"
286 # Where's the 'mcs' source tree?
287 if test -d $srcdir/mcs; then
288 mcsdir=mcs
289 else
290 mcsdir=../mcs
291 fi
293 mcs_topdir='$(top_srcdir)/'$mcsdir
294 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
296 AC_SUBST([mcs_topdir])
297 AC_SUBST([mcs_topdir_from_srcdir])
299 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
300 if test "x$PKG_CONFIG" = "xno"; then
301 AC_MSG_ERROR([You need to install pkg-config])
302 fi
304 dnl for use on the build system
305 dnl pkg-config is stupid
306 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
307 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
308 AC_SUBST(BUILD_GLIB_CFLAGS)
309 AC_SUBST(BUILD_GLIB_LIBS)
311 PKG_PATH=
312 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir],
313 if test x$with_crosspkgdir = "x"; then
314 if test -s $PKG_CONFIG_PATH; then
315 PKG_PATH=$PKG_CONFIG_PATH
316 fi
317 else
318 PKG_PATH=$with_crosspkgdir
319 PKG_CONFIG_PATH=$PKG_PATH
320 export PKG_CONFIG_PATH
321 fi
322 )
324 ## Versions of dependencies
325 GLIB_REQUIRED_VERSION=1.3.11
327 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
329 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
330 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
331 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
332 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
334 AC_SUBST(GLIB_CFLAGS)
335 AC_SUBST(GLIB_LIBS)
336 AC_SUBST(GMODULE_CFLAGS)
337 AC_SUBST(GMODULE_LIBS)
339 if test x$platform_win32 = xyes; then
340 AC_MSG_CHECKING(for cygwin glib2-dev package)
341 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
342 AC_MSG_RESULT(found)
343 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
344 else
345 AC_MSG_RESULT(not found, ok)
346 fi
348 AC_MSG_CHECKING(for broken gwin32.h)
349 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
350 if test -f $glib_include/glib/gwin32.h; then
351 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
352 AC_MSG_RESULT(failed)
353 hashmark='#'
354 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
355 fi
356 fi
357 AC_MSG_RESULT(ok)
358 fi
360 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
362 # Enable support for fast thread-local storage
363 # Some systems have broken support, so we allow to disable it.
364 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation],[],[with_tls=__thread])
366 # Kept for compatibility
367 AC_ARG_WITH(nptl, [ --with-nptl=yes,no deprecated, use --with-tls instead],[],[with_nptl=default])
369 if test "x$with_nptl" != "xdefault"; then
370 if test "x$with_nptl" = "xyes"; then
371 AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
372 with_tls=__thread
373 fi
374 if test "x$with_nptl" = "xno"; then
375 AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
376 with_tls=pthread
377 fi
378 fi
380 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
381 # This does not work on some platforms (bug #55253)
382 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack],[],[with_sigaltstack=no])
384 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster)],[],[with_static_mono=yes])
386 if test "x$enable_static" = "xno"; then
387 with_static_mono=no
388 fi
390 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
392 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
393 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug, reflection_emit.],
394 [
395 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
396 eval "mono_feature_disable_$feature='yes'"
397 AC_MSG_NOTICE([Disabled support for feature: $feature])
398 done
399 disabled="Disabled: $enable_minimal"
400 ],[])
402 if test "x$mono_feature_disable_aot" = "xyes"; then
403 AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
404 fi
406 if test "x$mono_feature_disable_profiler" = "xyes"; then
407 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
408 fi
410 if test "x$mono_feature_disable_decimal" = "xyes"; then
411 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
412 fi
414 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
415 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
416 fi
418 if test "x$mono_feature_disable_debug" = "xyes"; then
419 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
420 fi
422 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
423 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
424 fi
426 LIBGC_CFLAGS=
427 LIBGC_LIBS=
428 LIBGC_STATIC_LIBS=
429 libgc_dir=
430 case "x$gc" in
431 xboehm|xbohem|xyes)
432 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
433 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
435 if test "x$found_boehm" != "xyes"; then
436 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
437 fi
438 if test "x$gc_headers" != "xyes"; then
439 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
440 fi
442 AC_DEFINE(HAVE_BOEHM_GC)
443 AC_SUBST(HAVE_BOEHM_GC)
444 LIBGC_LIBS="-lgc $libdl"
445 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
447 # AC_CHECK_FUNCS does not work for some reason...
448 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
449 if test "x$found_gcj_malloc" = "xyes"; then
450 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
451 fi
452 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
453 if test "x$found_gc_enable" = "xyes"; then
454 AC_DEFINE(HAVE_GC_ENABLE)
455 fi
456 ;;
458 xincluded)
459 AC_CONFIG_SUBDIRS(libgc)
461 found_boehm=yes
462 gc_headers=yes
463 use_included_gc=yes
464 libgc_dir=libgc
466 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
467 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
468 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
470 AC_DEFINE(HAVE_BOEHM_GC)
471 AC_SUBST(HAVE_BOEHM_GC)
473 AC_DEFINE(HAVE_GC_H)
474 AC_DEFINE(USE_INCLUDED_LIBGC)
476 # The included libgc contains GCJ support
477 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
478 AC_DEFINE(HAVE_GC_ENABLE)
479 ;;
481 xnone)
482 AC_MSG_WARN("Compiling mono without GC.")
483 ;;
484 *)
485 AC_MSG_ERROR([Invalid argument to --with-gc.])
486 ;;
487 esac
490 # tell libgc/configure about what we want
491 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
493 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
494 AC_SUBST(LIBGC_CFLAGS)
495 AC_SUBST(LIBGC_LIBS)
496 AC_SUBST(LIBGC_STATIC_LIBS)
497 AC_SUBST(libgc_dir)
499 dnl
500 dnl End of libgc checks
501 dnl
503 if test x$platform_win32 = xno; then
505 dnl ******************************************************************
506 dnl *** Checks for the IKVM JNI interface library ***
507 dnl ******************************************************************
508 AC_ARG_WITH(ikvm-jni, [ --with-ikvm-jni=yes,no build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
509 AC_ARG_WITH(jdk, [ --with-jdk=DIRECTORY Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
511 ikvm_jni_dir=
512 if test x$with_ikvm_jni = xyes; then
513 AC_MSG_CHECKING([JDK headers])
515 if test x$with_jdk_dir = x; then
516 # Try JAVA_HOME variable
517 if test x$JAVA_HOME != x; then
518 with_jdk_dir=$JAVA_HOME
519 fi
520 fi
522 jdk_platform=
523 if test -d $with_jdk_dir/include; then
524 jdk_headers_found=yes
526 if test -d $with_jdk_dir/include/linux; then
527 jdk_platform=linux
528 else
529 if test -d $with_jdk_dir/include/solaris; then
530 jdk_platform=solaris
531 else
532 if test -f $with_jdk_dir/include/jni_md.h; then
533 # GNU Classpath sources
534 jdk_platform=
535 else
536 jdk_headers_found=no
537 fi
538 fi
539 fi
540 else
541 jdk_headers_found=no
542 fi
544 if test x$jdk_headers_found = xyes; then
545 AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
546 else
547 AC_MSG_RESULT(not found)
548 fi
550 if test x$jdk_headers_found = xyes; then
551 ikvm_jni_dir=ikvm-jni
552 IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
553 fi
554 fi
556 AC_SUBST(ikvm_jni_dir)
557 AC_SUBST(IKVM_JNI_CFLAGS)
559 AC_CHECK_FUNCS(getgrgid_r)
560 AC_CHECK_FUNCS(getgrnam_r)
561 AC_CHECK_FUNCS(getpwnam_r)
562 AC_CHECK_FUNCS(getpwuid_r)
563 AC_CHECK_FUNCS(getresuid)
564 AC_CHECK_FUNCS(setresuid)
565 AC_CHECK_FUNCS(kqueue)
567 dnl ******************************************************************
568 dnl *** Check for large file support ***
569 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
570 dnl ******************************************************************
572 # Check that off_t can represent 2**63 - 1 correctly, working around
573 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
574 # CPPFLAGS and sets $large_offt to yes if the test succeeds
575 large_offt=no
576 AC_DEFUN(LARGE_FILES, [
577 large_CPPFLAGS=$CPPFLAGS
578 CPPFLAGS="$CPPFLAGS $1"
579 AC_TRY_RUN([
580 #include <sys/types.h>
582 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
584 int main(void) {
585 int big_off_t=((BIG_OFF_T%2147483629==721) &&
586 (BIG_OFF_T%2147483647==1));
587 if(big_off_t) {
588 exit(0);
589 } else {
590 exit(1);
591 }
592 }
593 ], [
594 AC_MSG_RESULT(ok)
595 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
596 large_CPPFLAGS="$large_CPPFLAGS $1"
597 large_offt=yes
598 ], [
599 AC_MSG_RESULT(no)
600 ], "")
601 CPPFLAGS=$large_CPPFLAGS
602 ])
604 AC_MSG_CHECKING(if off_t is 64 bits wide)
605 LARGE_FILES("")
606 if test $large_offt = no; then
607 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
608 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
609 fi
610 if test $large_offt = no; then
611 AC_MSG_WARN([No 64 bit file size support available])
612 fi
614 dnl *****************************
615 dnl *** Checks for libsocket ***
616 dnl *****************************
617 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
619 dnl *******************************
620 dnl *** Checks for MSG_NOSIGNAL ***
621 dnl *******************************
622 AC_MSG_CHECKING(for MSG_NOSIGNAL)
623 AC_TRY_COMPILE([#include <sys/socket.h>], [
624 int f = MSG_NOSIGNAL;
625 ], [
626 # Yes, we have it...
627 AC_MSG_RESULT(yes)
628 AC_DEFINE(HAVE_MSG_NOSIGNAL)
629 ], [
630 # We'll have to use signals
631 AC_MSG_RESULT(no)
632 ])
634 dnl *****************************
635 dnl *** Checks for SOL_IP ***
636 dnl *****************************
637 AC_MSG_CHECKING(for SOL_IP)
638 AC_TRY_COMPILE([#include <netdb.h>], [
639 int level = SOL_IP;
640 ], [
641 # Yes, we have it...
642 AC_MSG_RESULT(yes)
643 AC_DEFINE(HAVE_SOL_IP)
644 ], [
645 # We'll have to use getprotobyname
646 AC_MSG_RESULT(no)
647 ])
649 dnl *****************************
650 dnl *** Checks for SOL_IPV6 ***
651 dnl *****************************
652 AC_MSG_CHECKING(for SOL_IPV6)
653 AC_TRY_COMPILE([#include <netdb.h>], [
654 int level = SOL_IPV6;
655 ], [
656 # Yes, we have it...
657 AC_MSG_RESULT(yes)
658 AC_DEFINE(HAVE_SOL_IPV6)
659 ], [
660 # We'll have to use getprotobyname
661 AC_MSG_RESULT(no)
662 ])
664 dnl *****************************
665 dnl *** Checks for SOL_TCP ***
666 dnl *****************************
667 AC_MSG_CHECKING(for SOL_TCP)
668 AC_TRY_COMPILE([#include <netdb.h>], [
669 int level = SOL_TCP;
670 ], [
671 # Yes, we have it...
672 AC_MSG_RESULT(yes)
673 AC_DEFINE(HAVE_SOL_TCP)
674 ], [
675 # We'll have to use getprotobyname
676 AC_MSG_RESULT(no)
677 ])
679 dnl *****************************
680 dnl *** Checks for IP_PKTINFO ***
681 dnl *****************************
682 AC_MSG_CHECKING(for IP_PKTINFO)
683 AC_TRY_COMPILE([#include <netdb.h>], [
684 int level = IP_PKTINFO;
685 ], [
686 # Yes, we have it...
687 AC_MSG_RESULT(yes)
688 AC_DEFINE(HAVE_IP_PKTINFO)
689 ], [
690 AC_MSG_RESULT(no)
691 ])
693 dnl *********************************
694 dnl *** Check for struct ip_mreqn ***
695 dnl *********************************
696 AC_MSG_CHECKING(for struct ip_mreqn)
697 AC_TRY_COMPILE([#include <netinet/in.h>], [
698 struct ip_mreqn mreq;
699 mreq.imr_address.s_addr = 0;
700 ], [
701 # Yes, we have it...
702 AC_MSG_RESULT(yes)
703 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
704 ], [
705 # We'll just have to try and use struct ip_mreq
706 AC_MSG_RESULT(no)
707 AC_MSG_CHECKING(for struct ip_mreq)
708 AC_TRY_COMPILE([#include <netinet/in.h>], [
709 struct ip_mreq mreq;
710 mreq.imr_interface.s_addr = 0;
711 ], [
712 # Yes, we have it...
713 AC_MSG_RESULT(yes)
714 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
715 ], [
716 # No multicast support
717 AC_MSG_RESULT(no)
718 ])
719 ])
721 dnl **********************************
722 dnl *** Check for gethostbyname2_r ***
723 dnl **********************************
724 AC_MSG_CHECKING(for gethostbyname2_r)
725 AC_TRY_LINK([#include <netdb.h>], [
726 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
727 ], [
728 # Yes, we have it...
729 AC_MSG_RESULT(yes)
730 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
731 ], [
732 AC_MSG_RESULT(no)
733 ])
735 dnl *****************************
736 dnl *** Checks for libnsl ***
737 dnl *****************************
738 AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
740 AC_CHECK_FUNCS(inet_pton inet_aton)
742 dnl ***********************************************
743 dnl *** Checks for size of sockaddr_un.sun_path ***
744 dnl ***********************************************
745 # AC_CHECK_SIZEOF can't cope with struct members :-(
746 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
747 AC_CACHE_VAL(cv_mono_sizeof_sunpath,
748 [AC_TRY_RUN([
749 #include <sys/types.h>
750 #include <stdio.h>
751 #include <sys/un.h>
753 int main(void) {
754 struct sockaddr_un sock_un;
755 FILE *f=fopen("conftestval", "w");
756 if(!f) exit(1);
757 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
758 exit(0);
759 }
760 ], cv_mono_sizeof_sunpath=`cat conftestval`,
761 cv_mono_sizeof_sunpath=0,
762 cv_mono_sizeof_sunpath=0)])dnl
763 AC_MSG_RESULT($cv_mono_sizeof_sunpath)
764 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
766 dnl *************************************
767 dnl *** Checks for zero length arrays ***
768 dnl *************************************
769 AC_MSG_CHECKING(whether $CC supports zero length arrays)
770 AC_TRY_COMPILE([
771 struct s {
772 int length;
773 char data [0];
774 };
775 ], [], [
776 AC_MSG_RESULT(yes)
777 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
778 ], [
779 AC_MSG_RESULT(no)
780 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
781 ])
783 dnl *****************************
784 dnl *** Checks for libxnet ***
785 dnl *****************************
786 case "${host}" in
787 *solaris* )
788 AC_MSG_CHECKING(for Solaris XPG4 support)
789 if test -f /usr/lib/libxnet.so; then
790 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
791 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
792 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
793 LIBS="$LIBS -lxnet"
794 AC_MSG_RESULT(yes)
795 else
796 AC_MSG_RESULT(no)
797 fi
799 if test "$GCC" = "yes"; then
800 CFLAGS="$CFLAGS -Wno-char-subscripts"
801 fi
802 ;;
803 esac
805 dnl *****************************
806 dnl *** Checks for libpthread ***
807 dnl *****************************
808 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
809 # and libpthread does not exist
810 #
811 case "${host}" in
812 *-*-*freebsd4*)
813 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
814 ;;
815 *)
816 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
817 ;;
818 esac
819 AC_CHECK_HEADERS(pthread.h)
820 AC_CHECK_FUNCS(pthread_mutex_timedlock)
821 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
822 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
823 AC_TRY_COMPILE([ #include <pthread.h>], [
824 pthread_mutexattr_t attr;
825 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
826 ], [
827 AC_MSG_RESULT(ok)
828 ], [
829 AC_MSG_RESULT(no)
830 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
831 AC_DEFINE(USE_MONO_MUTEX)
832 ])
833 AC_CHECK_FUNCS(pthread_attr_setstacksize)
835 dnl ***********************************
836 dnl *** Checks for working __thread ***
837 dnl ***********************************
838 AC_MSG_CHECKING(for working __thread)
839 if test "x$with_tls" != "x__thread"; then
840 AC_MSG_RESULT(disabled)
841 else
842 AC_TRY_RUN([
843 #include <pthread.h>
845 __thread int i;
846 static int res1, res2;
848 void thread_main (void *arg)
849 {
850 i = arg;
851 sleep (1);
852 if (arg == 1)
853 res1 = (i == arg);
854 else
855 res2 = (i == arg);
856 }
858 int main () {
859 pthread_t t1, t2;
861 i = 5;
863 pthread_create (&t1, NULL, thread_main, 1);
864 pthread_create (&t2, NULL, thread_main, 2);
866 pthread_join (t1, NULL);
867 pthread_join (t2, NULL);
869 return !(res1 + res2 == 2);
870 }
871 ], [
872 AC_MSG_RESULT(yes)
873 ], [
874 AC_MSG_RESULT(no)
875 with_tls=pthread
876 ])
877 fi
879 dnl **************************************
880 dnl *** Checks for working sigaltstack ***
881 dnl **************************************
882 AC_MSG_CHECKING(for working sigaltstack)
883 if test "x$with_sigaltstack" != "xyes"; then
884 AC_MSG_RESULT(disabled)
885 else
886 AC_TRY_RUN([
887 #include <stdio.h>
888 #include <stdlib.h>
889 #include <unistd.h>
890 #include <signal.h>
891 #include <pthread.h>
892 #include <sys/wait.h>
894 static void
895 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
896 {
897 exit (0);
898 }
900 static void *
901 loop (void *ignored)
902 {
903 char *ptr = NULL;
905 *ptr = 0;
906 return NULL;
907 }
909 static void
910 child ()
911 {
912 struct sigaction sa;
913 struct sigaltstack sas;
914 pthread_t id;
915 pthread_attr_t attr;
917 sa.sa_sigaction = sigsegv_signal_handler;
918 sigemptyset (&sa.sa_mask);
919 sa.sa_flags = SA_SIGINFO | SA_STACK;
920 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
921 perror ("lala");
922 return;
923 }
925 sas.ss_sp = malloc (SIGSTKSZ);
926 sas.ss_size = SIGSTKSZ;
927 sas.ss_flags = SS_ONSTACK;
928 if (sigaltstack (&sas, NULL) == -1) {
929 perror ("lala");
930 return;
931 }
933 pthread_attr_init (&attr);
934 if (pthread_create(&id, &attr, loop, &attr) != 0) {
935 printf ("failed\n");
936 return;
937 }
939 sleep (100);
940 }
942 int
943 main ()
944 {
945 pid_t son;
946 int status;
947 int i;
949 son = fork ();
950 if (son == -1) {
951 return 1;
952 }
954 if (son == 0) {
955 child ();
956 return 0;
957 }
959 for (i = 0; i < 3; ++i) {
960 sleep (1);
961 waitpid (son, &status, WNOHANG);
962 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
963 return 0;
964 }
966 kill (son, SIGKILL);
967 return 1;
968 }
970 ], [
971 AC_MSG_RESULT(yes)
972 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
973 ], [
974 with_sigaltstack=no
975 AC_MSG_RESULT(no)
976 ])
977 fi
979 dnl ********************************
980 dnl *** Checks for semaphore lib ***
981 dnl ********************************
982 # 'Real Time' functions on Solaris
983 # posix4 on Solaris 2.6
984 # pthread (first!) on Linux
985 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
987 dnl ********************************
988 dnl *** Checks for timezone stuff **
989 dnl ********************************
990 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
991 AC_TRY_COMPILE([
992 #include <time.h>
993 ], [
994 struct tm tm;
995 tm.tm_gmtoff = 1;
996 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
997 if test $ac_cv_struct_tm_gmtoff = yes; then
998 AC_DEFINE(HAVE_TM_GMTOFF)
999 else
1000 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1001 AC_TRY_COMPILE([
1002 #include <time.h>
1003 ], [
1004 timezone = 1;
1005 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1006 if test $ac_cv_var_timezone = yes; then
1007 AC_DEFINE(HAVE_TIMEZONE)
1008 else
1009 AC_ERROR(unable to find a way to determine timezone)
1010 fi
1011 fi
1013 dnl *********************************
1014 dnl *** Checks for math functions ***
1015 dnl *********************************
1016 LIBS="$LIBS -lm";
1017 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1018 AC_TRY_LINK([#include <math.h>],
1019 [ finite(0.0); ],
1020 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1021 AC_MSG_RESULT(no)))
1022 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1023 AC_TRY_LINK([#include <math.h>],
1024 [ isfinite(0.0); ],
1025 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1026 AC_MSG_RESULT(no)))
1028 dnl ****************************************************************
1029 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1030 dnl *** have it in the library (duh)) ***
1031 dnl ****************************************************************
1032 AC_CHECK_FUNCS(poll)
1034 dnl *************************
1035 dnl *** Check for signbit ***
1036 dnl *************************
1037 AC_MSG_CHECKING(for signbit)
1038 AC_TRY_LINK([#include <math.h>], [
1039 int s = signbit(1.0);
1040 ], [
1041 AC_MSG_RESULT(yes)
1042 AC_DEFINE(HAVE_SIGNBIT)
1043 ], [
1044 AC_MSG_RESULT(no)
1045 ])
1047 dnl *********************
1048 dnl *** Check for AIO ***
1049 dnl *********************
1050 AC_MSG_CHECKING([for SIGEV_THREAD definition])
1051 dnl Some systems (FreeBSD at least) may have aio_read
1052 dnl but don't support/define SIGEV_THREAD.
1053 AC_TRY_COMPILE([
1054 #include <sys/signal.h>
1055 ],[
1056 int x = SIGEV_THREAD;
1057 ],[
1058 ac_cv_c_sigev_thread=yes
1059 AC_MSG_RESULT(yes)
1060 ],[
1061 AC_MSG_RESULT(no)
1062 ])
1064 if test "$ac_cv_c_sigev_thread" = "yes" ; then
1065 AC_CHECK_HEADERS(aio.h sys/aio.h)
1066 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
1067 SIGVAL_PTR="undefined"
1068 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
1069 AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
1070 #include <sys/signal.h>
1071 ])
1072 AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
1073 #include <sys/signal.h>
1074 ])
1075 if test "$SIGVAL_PTR" = "undefined" ; then
1076 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
1077 fi
1078 fi
1079 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
1080 fi
1082 dnl **********************************
1083 dnl *** Checks for MonoPosixHelper ***
1084 dnl **********************************
1085 AC_CHECK_FUNCS(posix_fadvise)
1086 AC_CHECK_FUNCS(posix_madvise)
1087 AC_CHECK_FUNCS(posix_fallocate)
1088 AC_CHECK_FUNCS(fgetgrent)
1089 AC_CHECK_FUNCS(fgetpwent)
1090 AC_CHECK_FUNCS(fgetpwent)
1091 AC_CHECK_HEADERS(sys/sendfile.h)
1092 AC_CHECK_FUNCS(sendfile)
1093 AC_CHECK_FUNCS(sethostid)
1094 AC_CHECK_FUNCS(stime)
1095 AC_CHECK_FUNCS(strerror_r)
1096 AC_CHECK_FUNCS(ttyname_r)
1097 AC_CHECK_SIZEOF(size_t)
1098 AC_CHECK_MEMBERS(
1099 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1100 [#include <sys/types.h>
1101 #include <dirent.h>])
1102 else
1103 jdk_headers_found=no
1104 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1105 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1106 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1108 dnl *********************************
1109 dnl *** Check for struct ip_mreqn ***
1110 dnl *********************************
1111 AC_MSG_CHECKING(for struct ip_mreqn)
1112 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1113 struct ip_mreqn mreq;
1114 mreq.imr_address.s_addr = 0;
1115 ], [
1116 # Yes, we have it...
1117 AC_MSG_RESULT(yes)
1118 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1119 ], [
1120 # We'll just have to try and use struct ip_mreq
1121 AC_MSG_RESULT(no)
1122 AC_MSG_CHECKING(for struct ip_mreq)
1123 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1124 struct ip_mreq mreq;
1125 mreq.imr_interface.s_addr = 0;
1126 ], [
1127 # Yes, we have it...
1128 AC_MSG_RESULT(yes)
1129 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1130 ], [
1131 # No multicast support
1132 AC_MSG_RESULT(no)
1133 ])
1134 ])
1135 fi
1137 dnl socklen_t check
1138 AC_MSG_CHECKING(for socklen_t)
1139 AC_TRY_COMPILE([
1140 #include <sys/types.h>
1141 #include <sys/socket.h>
1142 ],[
1143 socklen_t foo;
1144 ],[
1145 ac_cv_c_socklen_t=yes
1146 AC_DEFINE(HAVE_SOCKLEN_T)
1147 AC_MSG_RESULT(yes)
1148 ],[
1149 AC_MSG_RESULT(no)
1150 ])
1152 AC_MSG_CHECKING(for array element initalizer support)
1153 AC_TRY_COMPILE([#include <sys/socket.h>], [
1154 const int array[] = {[1] = 2,};
1155 ], [
1156 # Yes, we have it...
1157 AC_MSG_RESULT(yes)
1158 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1159 ], [
1160 # We'll have to use signals
1161 AC_MSG_RESULT(no)
1162 ])
1164 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1165 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1166 AC_TRY_LINK([#include <math.h>],
1167 [ static void *p = &trunc; ],
1168 [
1169 AC_DEFINE(HAVE_TRUNC)
1170 AC_MSG_RESULT(yes)
1171 ac_cv_trunc=yes
1172 ],
1173 AC_MSG_RESULT(no)))
1175 if test "x$ac_cv_truncl" != "xyes"; then
1176 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1177 fi
1179 dnl ****************************
1180 dnl *** Look for /dev/random ***
1181 dnl ****************************
1183 AC_MSG_CHECKING([if usage of random device is requested])
1184 AC_ARG_ENABLE(dev-random,
1185 [ --disable-dev-random disable the use of the random device],
1186 try_dev_random=$enableval, try_dev_random=yes)
1187 AC_MSG_RESULT($try_dev_random)
1189 case "{$target}" in
1190 *-openbsd*)
1191 NAME_DEV_RANDOM="/dev/srandom"
1192 ;;
1194 dnl Win32 does not have /dev/random, they have their own method...
1196 *-*-mingw*|*-*-cygwin*)
1197 ac_cv_have_dev_random=no
1198 ;;
1200 dnl Everywhere else, it's /dev/random
1202 *)
1203 NAME_DEV_RANDOM="/dev/random"
1204 ;;
1205 esac
1207 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1209 dnl Now check if the device actually exists
1211 if test "x$try_dev_random" = "xyes"; then
1212 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1213 [if test -r "$NAME_DEV_RANDOM" ; then
1214 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1215 if test "x$ac_cv_have_dev_random" = "xyes"; then
1216 AC_DEFINE(HAVE_CRYPT_RNG)
1217 fi
1218 else
1219 AC_MSG_CHECKING(for random device)
1220 ac_cv_have_dev_random=no
1221 AC_MSG_RESULT(has been disabled)
1222 fi
1224 if test "x$platform_win32" = "xyes"; then
1225 AC_DEFINE(HAVE_CRYPT_RNG)
1226 fi
1228 if test "x$ac_cv_have_dev_random" = "xno" \
1229 && test "x$platform_win32" = "xno"; then
1230 AC_MSG_WARN([[
1231 ***
1232 *** A system-provided entropy source was not found on this system.
1233 *** Because of this, the System.Security.Cryptography random number generator
1234 *** will throw a NotImplemented exception.
1235 ***
1236 *** If you are seeing this message, and you know your system DOES have an
1237 *** entropy collection in place, please contact <crichton@gimp.org> and
1238 *** provide information about the system and how to access the random device.
1239 ***
1240 *** Otherwise you can install either egd or prngd and set the environment
1241 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1242 ***]])
1243 fi
1245 AC_MSG_CHECKING([if inter-process shared handles are requested])
1246 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1247 AC_MSG_RESULT($try_shared_handles)
1248 if test "x$try_shared_handles" != "xyes"; then
1249 AC_DEFINE(DISABLE_SHARED_HANDLES)
1250 AC_SUBST(DISABLE_SHARED_HANDLES)
1251 fi
1253 #
1254 # ICU
1255 #
1256 ICU_CFLAGS=""
1257 ICU_LIBS=""
1258 enable_icu="no; default"
1260 probe_icu=false
1261 AC_ARG_WITH(icu, [ --with-icu=yes/no],
1262 if test x$with_icu = xno; then
1263 probe_icu=false;
1264 AC_MSG_RESULT(Will not probe for ICU)
1265 fi
1266 if test x$with_icu = xyes; then
1267 probe_icu=true;
1268 fi
1269 )
1271 if $probe_icu; then
1272 AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1273 if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1274 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1275 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1276 else
1277 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1278 AC_DEFINE(HAVE_ICU)
1279 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1280 ICU_LIBS=`$ICU_CONFIG --ldflags`
1281 fi
1282 fi
1283 AC_SUBST(ICU_CFLAGS)
1284 AC_SUBST(ICU_LIBS)
1286 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1287 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1289 TARGET="unknown"
1290 ACCESS_UNALIGNED="yes"
1292 JIT_SUPPORTED=no
1293 INTERP_SUPPORTED=no
1294 LIBC="libc.so.6"
1295 INTL="libc.so.6"
1297 jit_wanted=false
1298 interp_wanted=false
1299 case "$host" in
1300 # mips-sgi-irix5.* | mips-sgi-irix6.*)
1301 # TARGET=MIPS;
1302 # ACCESS_UNALIGNED="no"
1303 # ;;
1304 i*86-*-*)
1305 TARGET=X86;
1306 arch_target=x86;
1307 JIT_SUPPORTED=yes
1308 jit_wanted=true
1309 ;;
1310 x86_64-*-* | amd64-*-*)
1311 TARGET=AMD64;
1312 arch_target=amd64;
1313 JIT_SUPPORTED=yes
1314 jit_wanted=true
1315 ;;
1316 sparc*-*-*)
1317 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1318 TARGET=SPARC64
1319 else
1320 TARGET=SPARC
1321 fi
1322 arch_target=sparc;
1323 JIT_SUPPORTED=yes
1324 ACCESS_UNALIGNED="no"
1325 LIBC="libc.so"
1326 INTL="libintl.so"
1327 jit_wanted=true
1328 if test x"$GCC" = xyes; then
1329 CFLAGS="$CFLAGS -Wno-cast-align"
1330 fi
1331 ;;
1332 alpha*-*-linux* | alpha*-*-osf*)
1333 TARGET=ALPHA;
1334 ACCESS_UNALIGNED="no"
1335 JIT_SUPPORTED=no
1336 INTERP_SUPPORTED=yes
1337 interp_wanted=true
1338 arch_target=alpha;
1339 ;;
1340 # ia64-*-linux* | ia64-*-hpux*)
1341 # TARGET=IA64;
1342 # arch_target=ia64;
1343 # JIT_SUPPORTED=no;
1344 # ACCESS_UNALIGNED="no";
1345 # case "$host_os" in
1346 # linux*) LIBC="libc.so.6.1";;
1347 # hpux*) LIBC="libc.so.1";;
1348 # esac
1349 # ;;
1350 # m68k-*-linux*)
1351 # TARGET=M68K
1352 # ;;
1353 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1354 TARGET=HPPA;
1355 arch_target=hppa;
1356 LIBC="libc.sl"
1357 ACCESS_UNALIGNED="no"
1358 INTERP_SUPPORTED=yes
1359 interp_wanted=true
1360 ;;
1361 hppa*linux*)
1362 TARGET=HPPA;
1363 arch_target=hppa;
1364 ACCESS_UNALIGNED="no"
1365 INTERP_SUPPORTED=yes
1366 interp_wanted=true
1367 ;;
1368 macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1369 powerpc-*-sysv* | powerpc-*-darwin*)
1370 TARGET=POWERPC;
1371 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1372 arch_target=ppc;
1373 JIT_SUPPORTED=yes
1374 jit_wanted=true
1375 ;;
1376 arm-*-linux-* | armv4l-*-linux-*)
1377 TARGET=ARM;
1378 arch_target=arm;
1379 ACCESS_UNALIGNED="no"
1380 INTERP_SUPPORTED=yes
1381 interp_wanted=true
1382 ;;
1383 s390-*-linux*)
1384 TARGET=S390;
1385 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1386 arch_target=s390;
1387 ACCESS_UNALIGNED="no"
1388 JIT_SUPPORTED=yes
1389 ;;
1390 s390x-*-linux*)
1391 TARGET=S390x;
1392 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1393 arch_target=s390x;
1394 ACCESS_UNALIGNED="no"
1395 JIT_SUPPORTED=yes
1396 ;;
1397 esac
1399 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT],[
1400 if test x$withval = xyes; then
1401 jit_wanted=true
1402 else
1403 jit_wanted=false
1404 fi
1405 ])
1407 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter],[
1408 if test x$withval = xyes; then
1409 interp_wanted=true
1410 else
1411 interp_wanted=false
1412 fi
1413 ])
1415 USEJIT=false
1416 if test x$JIT_SUPPORTED = xyes; then
1417 if $jit_wanted; then
1418 USEJIT=true
1419 jit_status="Building and using the JIT"
1420 else
1421 if $interp_wanted; then
1422 jit_status="Building the JIT, defaulting to the interpreter"
1423 else
1424 AC_ERROR(No JIT or interpreter support available or selected.)
1425 fi
1426 fi
1427 else
1428 if $interp_wanted; then
1429 jit_status="interpreter"
1430 else
1431 AC_ERROR(No JIT or interpreter support available or selected.)
1432 fi
1433 fi
1435 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1437 libsuffix=".so"
1439 case "$host" in
1440 powerpc-*-darwin*)
1441 libsuffix=".dylib"
1442 LIBC="libc.dylib"
1443 INTL="libintl.dylib"
1444 ;;
1445 *-*-*netbsd*)
1446 LIBC="libc.so.12"
1447 INTL="libintl.so.0"
1448 ;;
1449 *-*-*freebsd*)
1450 LIBC="libc.so"
1451 INTL="libintl.so"
1452 ;;
1453 *-*-*openbsd*)
1454 LIBC="libc.so"
1455 INTL="libintl.so"
1456 ;;
1457 esac
1458 AC_SUBST(libsuffix)
1460 if test "x$TARGET" != "xAMD64"; then
1461 # valgrind headers don't compile under x86-64
1462 AC_CHECK_HEADERS(valgrind/memcheck.h)
1463 fi
1465 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1466 if test "x$with_tls" = "x__thread"; then
1467 #
1468 # On some linux distributions, TLS works in executables, but linking
1469 # against a shared library containing TLS fails with:
1470 # undefined reference to `__tls_get_addr'
1471 #
1472 rm -f conftest.c conftest.so conftest
1473 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1474 gcc -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1475 gcc -o conftest conftest.so > /dev/null 2>&1
1476 if test ! -f conftest; then
1477 AC_MSG_WARN([Disabling usage of __thread.]);
1478 with_tls=pthread
1479 fi
1480 rm -f conftest.c conftest.so conftest
1481 fi
1482 fi
1484 if test "x$with_tls" = "x__thread"; then
1485 AC_DEFINE(HAVE_KW_THREAD)
1486 # Pass the information to libgc
1487 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1488 export CPPFLAGS
1489 fi
1491 if test ${TARGET} = ARM; then
1492 dnl ******************************************
1493 dnl *** Check to see what FPU is available ***
1494 dnl ******************************************
1495 AC_MSG_CHECKING(which FPU to use)
1497 AC_TRY_COMPILE([], [
1498 __asm__ ("ldfd f0, [r0]");
1499 ], fpu=FPA, [
1500 AC_TRY_COMPILE([], [
1501 __asm__ ("fldd d0, [r0]");
1502 ], fpu=VFP, fpu=NONE)
1503 ])
1505 AC_MSG_RESULT($fpu)
1506 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1507 unset fpu
1508 fi
1510 if test ${TARGET} = unknown; then
1511 CPPFLAGS="$CPPFLAGS -DNO_PORT"
1512 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1513 fi
1515 if test ${ACCESS_UNALIGNED} = no; then
1516 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1517 fi
1519 PREVIEW=no
1520 AC_ARG_WITH(preview, [ --with-preview=yes,no If you want to install the 2.0 FX preview],[
1521 if test x$with_preview = xyes; then
1522 PREVIEW=yes
1523 fi
1524 ])
1526 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1528 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1529 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1530 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1531 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1532 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1533 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1534 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1535 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1536 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1537 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1538 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1539 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1540 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1541 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1543 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1544 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1545 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1547 AC_SUBST(LIBC)
1548 AC_SUBST(INTL)
1550 AC_SUBST(arch_target)
1551 AC_SUBST(CFLAGS)
1552 AC_SUBST(CPPFLAGS)
1553 AC_SUBST(LDFLAGS)
1555 mono_build_root=`pwd`
1556 AC_SUBST(mono_build_root)
1558 if test x$USEJIT = xtrue; then
1559 mono_runtime=mono/mini/mono
1560 else
1561 mono_runtime=mono/interpreter/mint
1562 fi
1563 AC_SUBST(mono_runtime)
1565 mono_cfg_root=$mono_build_root/runtime
1566 if test x$platform_win32 = xyes; then
1567 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1568 else
1569 mono_cfg_dir=$mono_cfg_root/etc
1570 fi
1571 AC_SUBST(mono_cfg_dir)
1573 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1575 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1576 [ depth=../../../..
1577 case $srcdir in
1578 [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1579 .) reldir=$depth ;;
1580 *) reldir=$depth/$srcdir ;;
1581 esac
1582 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1583 cd runtime/etc/mono/1.0
1584 rm -f machine.config
1585 $LN_S $reldir/data/net_1_1/machine.config machine.config
1586 cd $depth
1587 ],[LN_S='$LN_S'])
1589 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1590 [ depth=../../../..
1591 case $srcdir in
1592 [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1593 .) reldir=$depth ;;
1594 *) reldir=$depth/$srcdir ;;
1595 esac
1596 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1597 cd runtime/etc/mono/2.0
1598 rm -f machine.config
1599 $LN_S $reldir/data/net_2_0/machine.config machine.config
1600 cd $depth
1601 ],[LN_S='$LN_S'])
1603 AC_OUTPUT([
1604 Makefile
1605 mint.pc
1606 mono.pc
1607 mono/Makefile
1608 mono/utils/Makefile
1609 mono/metadata/Makefile
1610 mono/dis/Makefile
1611 mono/cil/Makefile
1612 mono/arch/Makefile
1613 mono/os/Makefile
1614 mono/os/win32/Makefile
1615 mono/os/unix/Makefile
1616 mono/arch/x86/Makefile
1617 mono/arch/amd64/Makefile
1618 mono/arch/hppa/Makefile
1619 mono/arch/ppc/Makefile
1620 mono/arch/sparc/Makefile
1621 mono/arch/s390/Makefile
1622 mono/arch/s390x/Makefile
1623 mono/arch/arm/Makefile
1624 mono/arch/alpha/Makefile
1625 mono/interpreter/Makefile
1626 mono/tests/Makefile
1627 mono/tests/tests-config
1628 mono/benchmark/Makefile
1629 mono/monoburg/Makefile
1630 mono/monograph/Makefile
1631 mono/io-layer/Makefile
1632 mono/handles/Makefile
1633 mono/mini/Makefile
1634 mono/profiler/Makefile
1635 ikvm-jni/Makefile
1636 scripts/Makefile
1637 man/Makefile
1638 web/Makefile
1639 docs/Makefile
1640 data/Makefile
1641 data/net_1_1/Makefile
1642 data/net_2_0/Makefile
1643 samples/Makefile
1644 support/Makefile
1645 data/config
1646 mono.spec
1647 tools/Makefile
1648 tools/locale-builder/Makefile
1649 runtime/Makefile
1650 ])
1652 (
1653 case $prefix in
1654 NONE) prefix=/usr/local ;;
1655 esac
1656 case $exec_prefix in
1657 NONE | '${prefix}') exec_prefix=$prefix ;;
1658 esac
1660 echo "prefix=$exec_prefix" > $srcdir/$mcsdir/build/config.make
1661 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1662 )
1664 echo "
1665 mcs source: $mcs_topdir
1666 GC: $gc
1667 ICU: $enable_icu
1668 TLS: $with_tls
1669 SIGALTSTACK: $with_sigaltstack
1670 Engine: $jit_status
1671 2.0 Alpha: $PREVIEW
1672 JNI support: $jdk_headers_found
1673 $disabled
1675 "