configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT(GNU Midnight Commander, 4.5.99a, mc-devel@gnome.org)
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.5.99a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_PROG_LN_S
  15 AC_CANONICAL_HOST
  16
  17 AC_AIX
  18 AC_MINIX
  19 AC_ISC_POSIX
  20
  21 AC_PROG_CC_STDC
  22
  23 AC_HEADER_MAJOR
  24 AC_C_CONST
  25
  26 AC_SYS_LARGEFILE
  27
  28 AC_CHECK_TOOL(AR, ar, ar)
  29
  30 dnl Only list browsers here that can be run in background (i.e. with `&')
  31 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  32
  33 dnl
  34 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  35 dnl We use only part of the functionality of mmap, so on AIX,
  36 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  37 dnl
  38 AC_ARG_WITH(mmap,
  39         [--with-mmap                To force using the mmap call (AIX)],
  40         [case $withval in
  41 yes)
  42         ac_cv_func_mmap_fixed_mapped=yes
  43         AC_MSG_NOTICE([forcing MMAP support])
  44         ;;
  45 no)
  46         ac_cv_func_mmap_fixed_mapped=no
  47         AC_MSG_NOTICE([disabling MMAP support])
  48         ;;
  49 esac])
  50 AC_FUNC_MMAP
  51
  52 if test "x$ALL_LINGUAS" = x; then
  53 ALL_LINGUAS="az bg ca cs da de el es es_ES eu fi fr hu it ja ko lv nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  54 fi
  55
  56 dnl
  57 dnl Internationalization
  58 dnl
  59 AM_GNU_GETTEXT
  60 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  61     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  62 fi
  63
  64 dnl
  65 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  66 dnl
  67 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  68
  69 dnl
  70 dnl Enforce coding standards
  71 dnl
  72 if test "x$GCC" = xyes; then
  73     CFLAGS="$CFLAGS -Wall"
  74 fi
  75
  76 dnl
  77 dnl We now use glib
  78 dnl
  79 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  80 LIBS="$LIBS $GLIB_LIBS"
  81
  82 dnl
  83 dnl OS specific flags.
  84 dnl
  85
  86 posix_libs=""
  87 case $host_os in
  88 aux*)
  89     # A/UX
  90     posix_libs="-lposix"
  91     AC_DEFINE(_POSIX_SOURCE)
  92     ;;
  93 sco*)
  94     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
  95     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
  96     ;;
  97 esac
  98
  99 AC_PROG_INSTALL
 100 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 101         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 102         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h])
 103
 104 AC_HEADER_TIME
 105 AC_HEADER_SYS_WAIT
 106 AC_HEADER_DIRENT
 107 AC_SHORT_D_NAME_LEN
 108 AC_HEADER_STDC
 109
 110 dnl Missing structure components
 111 AC_STRUCT_ST_BLKSIZE
 112 AC_STRUCT_ST_BLOCKS
 113 AC_STRUCT_ST_RDEV
 114
 115 dnl
 116 dnl Check availability of some functions
 117 dnl
 118
 119 AC_CHECK_FUNCS([strerror statfs strcasecmp strncasecmp strftime \
 120                 strdup memmove pwdauth truncate initgroups putenv \
 121                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 122                 sigaction sigemptyset sigprocmask sigaddset \
 123                 sysconf setuid setreuid telldir seekdir])
 124
 125 dnl
 126 dnl getpt is a GNU Extension (glibc 2.1.x)
 127 dnl
 128 AC_CHECK_FUNCS(getpt)
 129
 130 SHADOWLIB=
 131 case $host_os in
 132 linux*)
 133     AC_CHECK_LIB(shadow,pw_encrypt,
 134         [shadow_header=yes
 135         AC_CHECK_HEADERS(shadow.h,,
 136                 [AC_CHECK_HEADERS(shadow/shadow.h,,
 137                         [shadow_header=no])])
 138         if test $shadow_header = yes; then
 139             AC_DEFINE(LINUX_SHADOW, 1,
 140                       [Define to use shadow passwords on Linux])
 141             SHADOWLIB=-lshadow
 142         fi])
 143     ;;
 144 esac
 145 AC_SUBST(SHADOWLIB)
 146
 147 NEED_CRYPT_PROTOTYPE=yes
 148 if test x$ac_cv_header_crypt_h = xyes; then
 149 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 150 if (p)
 151 return 0;],[
 152 NEED_CRYPT_PROTOTYPE=no])
 153 else
 154     if test x$ac_cv_header_unistd_h = xyes; then
 155 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 156 if (p)
 157 return 0;],[
 158 NEED_CRYPT_PROTOTYPE=no])
 159     fi
 160 fi
 161 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 162 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 163           [Define if function `crypt' needs a prototype])
 164 fi
 165
 166 dnl
 167 dnl On SCO and some SVR4, crypt is on libcrypt.a
 168 dnl         grantpt in  libpt.a
 169 dnl
 170 LCRYPT=""
 171 AC_CHECK_FUNCS(crypt, , [
 172     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 173         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 174 AC_SUBST(LCRYPT)
 175
 176 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 177
 178 dnl replacing lstat with statlstat on sco makes it more portable between
 179 dnl sco clones
 180 AC_CHECK_FUNCS(statlstat)
 181
 182 dnl
 183 dnl If running under AIX, AC_AIX does not tell us that
 184 dnl
 185 AC_MSG_CHECKING([for AIX defines])
 186 AC_EGREP_CPP(yes,
 187 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 188 yes
 189 #endif
 190 ], [
 191 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 192 AC_MSG_RESULT(yes)
 193 ], [AC_MSG_RESULT(no)])
 194
 195 dnl
 196 dnl This is from GNU fileutils, check aclocal.m4 for more information
 197 dnl
 198 AC_GET_FS_INFO
 199
 200 dnl
 201 dnl Missing typedefs and replacements
 202 dnl
 203
 204 AC_TYPE_MODE_T
 205 AC_CHECK_TYPE(umode_t, int)
 206 AC_CHECK_TYPE(off_t, long)
 207 AC_TYPE_PID_T
 208 AC_TYPE_UID_T
 209 AC_CHECK_TYPE(nlink_t, unsigned int)
 210
 211 AC_FUNC_ALLOCA
 212 AC_FUNC_STRCOLL
 213
 214 dnl
 215 dnl X11 support.
 216 dnl
 217
 218 dnl These variables are only used when building the MC binary
 219 MCCFLAGS=""
 220 MCLIBS=""
 221 AC_SUBST(MCCFLAGS)
 222 AC_SUBST(MCLIBS)
 223
 224 textmode_x11_support="no"
 225 AC_ARG_WITH(tm-x-support,
 226         [--with-tm-x-support        Try getting events from X Window System],
 227         [if test x$withval = xyes; then
 228                 AC_PATH_XTRA
 229                 MCCFLAGS="$X_CFLAGS"
 230                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 231                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 232                           [Define to enable getting events from X Window System])
 233                 textmode_x11_support="yes"
 234         fi
 235 ])
 236
 237 dnl
 238 dnl Network related functions
 239 dnl
 240
 241 AC_CHECK_LIB(nsl, t_accept)
 242 AC_CHECK_LIB(socket, socket)
 243
 244 have_socket=no
 245 AC_CHECK_FUNCS(socket, have_socket=yes)
 246 if test $have_socket = no; then
 247   # socket is not in the default libraries.  See if it's in some other.
 248   for lib in bsd socket inet; do
 249     AC_CHECK_LIB($lib, socket, [
 250         LIBS="$LIBS -l$lib"
 251         have_socket=yes
 252         AC_DEFINE(HAVE_SOCKET)
 253         break])
 254   done
 255 fi
 256
 257 have_gethostbyname=no
 258 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 259 if test $have_gethostbyname = no; then
 260   # gethostbyname is not in the default libraries.  See if it's in some other.
 261   for lib in bsd socket inet; do
 262     AC_CHECK_LIB([$lib], [gethostbyname],
 263                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 264   done
 265 fi
 266
 267 AC_CHECK_FUNCS(socketpair)
 268
 269 dnl
 270 dnl Sequent wants getprocessstats
 271 dnl
 272 AC_CHECK_LIB(seq, get_process_stats, [
 273         LIBS="$LIBS -lseq"
 274         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 275                   [Define if you have function `get_process_stats' and
 276 have to use that instead of gettimeofday])])
 277
 278 MC_VFS_CHECKS
 279
 280 dnl
 281 dnl Install mcserv only if explicitly enabled
 282 dnl
 283 AC_ARG_ENABLE([mcserv-install],
 284               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 285
 286 NETFILES=
 287 if test $have_socket = yes; then
 288    NETFILES="\$(NETFILES)"
 289 fi
 290 AC_SUBST(NETFILES)
 291
 292 vfs_type="normal"
 293 if test $use_vfs = yes
 294 then
 295         AC_MSG_NOTICE([enabling VFS code])
 296         vfs_type="Midnight Commander Virtual File System"
 297 fi
 298
 299 dnl This should be unadorned "slang" or "ncurses"
 300 screen_type=""
 301
 302 dnl Screen manager name (for the output only)
 303 screen_manager=unknown
 304
 305 search_ncurses=false
 306
 307 mouse_lib="xterm only"
 308 case $host_os in
 309 linux*)
 310     AC_ARG_WITH(gpm-mouse,
 311         [--with-gpm-mouse[=base-dir]  Compile with gpm mouse support (Linux only)],
 312         [if test x$withval != xno
 313         then
 314                 if test x$withval != xyes
 315                 then
 316                         LIBS="$LIBS -L$withval/lib"
 317                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 318                 fi
 319                 AC_DEFINE(HAVE_LIBGPM, 1,
 320                           [Define to enable gpm mouse support on Linux])
 321                 mouse_lib="GPM and xterm"
 322                 MCLIBS="-lgpm $MCLIBS"
 323         fi],
 324         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 325                 [AC_DEFINE(HAVE_LIBGPM)
 326                 mouse_lib="GPM and xterm"
 327                 MCLIBS="-lgpm $MCLIBS"],
 328                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 329                 [$LIBS])
 330         ])
 331     ;;
 332 esac
 333
 334 AC_ARG_WITH(ncurses,
 335         [--with-ncurses[=base-dir]    Compile with ncurses/locate base dir],
 336         [force_ncurses=true
 337         if test x$withval = xyes
 338         then
 339                 search_ncurses=true
 340         else
 341                 MCLIBS="$MCLIBS -L$withval/lib -lncurses"
 342                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 343                 search_ncurses=false
 344                 screen_type="ncurses"
 345                 screen_manager="ncurses"
 346                 AC_DEFINE(USE_NCURSES)
 347         fi
 348 ])
 349
 350 AC_ARG_WITH(hsc,
 351         [--with-hsc                 Compile with support for the HSC firewall],
 352         [if test x$withval = xyes; then
 353                 AC_DEFINE(HSC_PROXY, 1,
 354                           [Define if you want to use the HSC firewall])
 355         fi
 356 ])
 357
 358 dnl
 359 dnl Check for the -mandoc package
 360 dnl
 361 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 362 if $HAVE_nroff; then
 363     AC_MSG_CHECKING([for manual formatting macros])
 364     AC_CACHE_VAL(ac_cv_mandoc, [
 365     nroff -mandoc < /dev/null > /dev/null 2>&1
 366     if test $? = 0
 367     then
 368         ac_cv_mandoc=-mandoc
 369     else
 370         ac_cv_mandoc=-man
 371     fi
 372     ])
 373     MANDOC=$ac_cv_mandoc
 374     AC_MSG_RESULT([$MANDOC])
 375 else
 376     MANDOC=-man
 377 fi
 378 AC_SUBST(MANDOC)
 379
 380 dnl
 381 dnl Check if nroff accepts -Tlatin1 or -Tascii
 382 dnl
 383 if $HAVE_nroff; then
 384     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 385     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 386     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 387     if test $? = 0
 388     then
 389         ac_cv_nroff_tascii=" -Tlatin1"
 390     else
 391         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 392         if test $? = 0
 393         then
 394             ac_cv_nroff_tascii=" -Tascii"
 395         else
 396             ac_cv_nroff_tascii=""
 397         fi
 398     fi
 399     ])
 400     if test "x$ac_cv_nroff_tascii" = x; then
 401         AC_MSG_RESULT([no])
 402     else
 403         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 404     fi
 405 fi
 406 TROFFASCII="$ac_cv_nroff_tascii"
 407 AC_SUBST(TROFFASCII)
 408
 409 dnl
 410 dnl Check for - option to file
 411 dnl
 412 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 413 if $HAVE_FILECMD; then
 414     AC_MSG_CHECKING([for - option to file command])
 415     AC_CACHE_VAL(ac_cv_filestdin, [[
 416     cat > conftest.c <<\EOF
 417 /* A comment */
 418 #if 0
 419 #endif
 420 void main(void)
 421 { return; }
 422 EOF
 423     cat > conftest.sed <<\EOF
 424 s/^[^:]*:[      ]*//
 425 s/[     ]*$//
 426 EOF
 427     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 428     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 429     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 430         ac_cv_filestdin=yes
 431     else
 432         ac_cv_filestdin=no
 433     fi
 434     rm conftest.c conftest.sed
 435     ]])
 436
 437     if test x$ac_cv_filestdin = xyes; then
 438         AC_DEFINE(FILE_STDIN, 1,
 439                   [Define if the file command accepts - for stdin])
 440     fi
 441     filestdin=$ac_cv_filestdin
 442     AC_MSG_RESULT([$filestdin])
 443
 444     dnl
 445     dnl Check for -L option to file
 446     dnl
 447
 448 AC_MSG_CHECKING([for -L option to file command])
 449 AC_CACHE_VAL(ac_cv_filel, [
 450 file -L . > /dev/null 2>&1
 451 if test $? = 0
 452 then
 453     ac_cv_filel=yes
 454 else
 455     ac_cv_filel=no
 456 fi
 457 ])
 458 if test x$ac_cv_filel = xyes; then
 459     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 460 fi
 461 filel=$ac_cv_filel
 462 AC_MSG_RESULT([$filel])
 463 fi
 464
 465 AC_MSG_CHECKING([for subshell support])
 466 AC_ARG_WITH(subshell,
 467         [--with-subshell=optional   To disable concurrent shell by default
 468 --without-subshell         To disable concurrent shell completely],
 469         [result=no
 470         if test x$withval = xoptional
 471         then
 472                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 473                           [Define to make subshell support optional])
 474                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 475                           [Define to enable subshell support])
 476                 result="optional"
 477         fi
 478         if test x$withval = xyes
 479         then
 480                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 481                 result="yes"
 482         fi],
 483         [dnl Default: provide the subshell support on non-ultrix machines
 484         case $host_os in
 485         ultrix*)
 486                 result=no
 487                 ;;
 488         *)
 489                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 490                 result=yes
 491                 ;;
 492         esac
 493 ])
 494 AC_MSG_RESULT([$result])
 495 subshell="$result"
 496
 497 dnl
 498 dnl Memory Allocation Debugger
 499 dnl
 500 mem_debug="none"
 501 AC_ARG_WITH(mad,
 502 [--with-mad                 Developers only: activates MAD (memory debugger)],
 503         [if test x$withval = xyes; then
 504         mem_debug="Janne's MAD library"
 505         AC_DEFINE(HAVE_MAD, 1,
 506                   [Define to use Memory Allocation Debugger (MAD)])
 507         AC_MSG_NOTICE([compiling with memory leak detector])
 508 fi])
 509
 510 dnl
 511 dnl Electric Fence - another memory debugger
 512 dnl
 513 AC_ARG_WITH(efence,
 514 [--with-efence              Developers only: activates Electric Fence],
 515         [if test x$withval = xyes; then
 516         LIBS="$LIBS -lefence"
 517         AC_MSG_NOTICE([compiling with Electric fence])
 518         mem_debug="Electric Fence"
 519 fi])
 520
 521 if test -z "$force_ncurses"; then
 522         slang_check_lib=true
 523         slang_term=""
 524         slang_use_system_installed_lib=false
 525         AC_CHECK_LIB(slang,SLang_init_tty,
 526                 [AC_CHECK_HEADERS(slang.h)
 527                 if test x$ac_cv_header_slang_h = xyes
 528                 then
 529                      slang_use_system_installed_lib=true
 530                      slang_check_lib=false
 531                 else
 532                      AC_CHECK_HEADERS(slang/slang.h)
 533                      if test x$ac_cv_header_slang_slang_h = xyes
 534                      then
 535                          slang_use_system_installed_lib=true
 536                          slang_check_lib=false
 537                      fi
 538                 fi
 539         ])
 540 fi
 541
 542 AC_ARG_WITH(terminfo,
 543         [--with-terminfo            SLANG: Force usage of terminfo],[
 544         if test x$withval = xyes; then
 545                 AC_USE_TERMINFO
 546                 slang_check_lib=false
 547                 slang_use_system_installed_lib=false
 548         fi]
 549 )
 550
 551 AC_ARG_WITH(termcap,
 552         [--with-termcap             SLANG: Force usage of termcap],[
 553         if test x$withval = xyes; then
 554                 AC_USE_TERMCAP
 555                 slang_check_lib=false
 556                 slang_use_system_installed_lib=false
 557         fi]
 558 )
 559
 560 AC_ARG_WITH(included-slang,
 561         [--with-included-slang      SLANG: use the SLang library included here],[
 562         if test x$withval = xyes; then
 563             slang_use_system_installed_lib=false
 564             slang_check_lib=true
 565         fi]
 566 )
 567
 568 AC_ARG_WITH(slang,
 569         [--with-slang              Compile with the slang screen manager],[
 570         if test x$withval = xyes; then
 571                 AC_WITH_SLANG
 572         fi
 573 ])
 574
 575 LIBEDIT_A=""
 576 MCEDIT=""
 577 LEDIT=""
 578 EDIT_msg=""
 579 AC_ARG_WITH(edit,
 580         [--with-edit                Enable internal editor],
 581         [if test x$withval = xyes
 582         then
 583                 AC_WITH_EDIT
 584         else
 585                 EDIT_msg="no"
 586         fi],
 587         [dnl Default: provide the internal editor
 588         AC_WITH_EDIT
 589 ])
 590 AC_SUBST(LIBEDIT_A)
 591 AC_SUBST(MCEDIT)
 592 AC_SUBST(LEDIT)
 593
 594 AC_ARG_WITH(netrc,
 595         [--with-netrc               Compile with ftp .netrc support],[
 596         if test x$withval = xyes; then
 597                 AC_DEFINE(USE_NETRC, 1,
 598                           [Define to use .netrc for FTP connections])
 599                 AC_MSG_NOTICE([ftpfs will use .netrc])
 600         fi
 601 ])
 602
 603 undelfs_o=""
 604
 605 if test $use_vfs = yes; then
 606     AC_ARG_WITH(ext2undel,
 607         [--with-ext2undel           Compile with ext2 undelete code],[
 608         if test x$withval != xno;
 609         then
 610                 if test x$withval != xyes
 611                 then
 612                         LIBS="$LIBS -L$withval/lib"
 613                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 614                 fi
 615                 AC_EXT2_UNDEL
 616         fi],[
 617         dnl Default: detect
 618         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 619     ])
 620 fi
 621
 622 AC_SUBST(undelfs_o)
 623
 624 if $search_ncurses
 625 then
 626     AC_MSG_NOTICE([checking location of ncurses.h file])
 627
 628     AC_NCURSES(/usr/include, ncurses.h, -lncurses,,
 629                [ncurses in /usr/include])
 630     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses,
 631                [ncurses in /usr/include/ncurses])
 632     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include,
 633                [ncurses in /usr/local])
 634     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses,
 635                [ncurses in /usr/local/include/ncurses])
 636     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES,
 637                [renamed ncurses in /usr/local/include/ncurses])
 638     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES,
 639                [renamed ncurses in /usr/include/ncurses])
 640 fi
 641
 642 if test "x$screen_type" != xncurses && test -n "$force_ncurses"; then
 643     AC_MSG_ERROR([Could not find ncurses])
 644 fi
 645
 646
 647 dnl Ncurses specific checks
 648 dnl
 649 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 650 dnl or you'll have to press Esc three times to dismiss a dialog box.
 651 dnl
 652 if test "x$screen_type" = xncurses; then
 653   save_LIBS="$LIBS"
 654   LIBS="$MCLIBS $LIBS"
 655   AC_CACHE_CHECK([for ESCDELAY variable],
 656                  [mc_cv_ncurses_escdelay],
 657                  [AC_TRY_COMPILE([], [
 658                         extern int ESCDELAY;
 659                         int main ()
 660                         {
 661                           ESCDELAY = 0;
 662                         }
 663                         ],
 664                         [mc_cv_ncurses_escdelay=yes],
 665                         [mc_cv_ncurses_escdelay=no]
 666                   )
 667   ])
 668   if test "$mc_cv_ncurses_escdelay" = yes; then
 669     AC_DEFINE(HAVE_ESCDELAY, 1,
 670               [Define if ncurses has ESCDELAY variable])
 671   fi
 672
 673   AC_CHECK_FUNCS(resizeterm)
 674   LIBS="$save_LIBS"
 675 fi
 676
 677 if test "x$screen_type" = "x"; then
 678     AC_WITH_SLANG
 679 fi
 680
 681 dnl
 682 dnl The variables used for expanding the auto saver.
 683 dnl
 684 cons_saver=""
 685 install_saver="no"
 686 PAMLIBS=""
 687 case $host_os in
 688 linux*)
 689     cons_saver="cons.saver"
 690     install_saver="yes"
 691
 692     dnl
 693     dnl On Linux, check for PAM authentication available
 694     dnl
 695     AC_CHECK_LIB(pam, pam_start, [
 696         AC_DEFINE(HAVE_PAM, 1,
 697                   [Define if PAM (Pluggable Authentication Modules) is available])
 698         PAMLIBS="-lpam -ldl"
 699     ],[],[-ldl])
 700     ;;
 701 esac
 702 AC_SUBST(cons_saver)
 703 AC_SUBST(PAMLIBS)
 704
 705 dnl
 706 dnl User visible support for charset conversion.
 707 dnl
 708 AC_ARG_ENABLE([charset],
 709               [--enable-charset           Support for charset selection and conversion])
 710 have_charset=
 711 if test "x$enable_charset" = xyes; then
 712   if test -z "$am_cv_func_iconv"; then
 713     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 714   else
 715     AC_DEFINE(HAVE_CHARSET, 1,
 716               [Define to enable charset selection and conversion])
 717     have_charset=yes
 718   fi
 719 fi
 720
 721 if test "$GLIBC21" != yes; then
 722     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 723 fi
 724
 725 dnl
 726 dnl This code should be moved to the ac_WITH_SLANG
 727 dnl
 728 dnl We check for the existance of setupterm on curses library
 729 dnl this is required to load certain definitions on some termcaps
 730 dnl editions (AIX and OSF/1 I seem to remember).
 731 dnl Note that we avoid using setupterm
 732 if test "x$screen_type" = xslang; then
 733         case $host_os in
 734         linux*)
 735                 ;;
 736         *)
 737                 AC_CHECK_LIB(curses,setupterm,
 738                         [AC_TRY_COMPILE([
 739 #include <curses.h>
 740 #include <term.h>],[
 741    if (key_end == parm_insert_line)
 742         return 1;
 743    return 0;
 744 ],
 745                         [MCLIBS="$MCLIBS -lcurses"
 746                         AC_DEFINE(USE_SETUPTERM, 1,
 747                                   [Define to use function `setupterm'
 748 from `curses' library in S-Lang])])
 749                 ])
 750         esac
 751 fi
 752
 753 LIBS="$LIBS $posix_libs"
 754
 755 AC_SUBST(CFLAGS)
 756 AC_SUBST(CPPFLAGS)
 757 AC_SUBST(LDFLAGS)
 758 AC_SUBST(LIBS)
 759
 760 if test "x$SAMBAFILES" != x; then
 761   AC_CONFIG_SUBDIRS([vfs/samba])
 762 fi
 763
 764 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 765 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 766 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 767 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 768 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 769 AM_CONDITIONAL(MCSERV_INSTALL,
 770                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 771 AM_CONDITIONAL(INCLUDED_SLANG,
 772                [test "x$slang_use_system_installed_lib" = xfalse])
 773 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 774 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 775
 776 AH_BOTTOM([#include <extraconf.h>])
 777
 778 AC_CONFIG_FILES([
 779 Makefile
 780 mc.spec
 781 doc/Makefile
 782 vfs/Makefile
 783 vfs/extfs/Makefile
 784 lib/Makefile
 785 src/Makefile
 786 slang/Makefile
 787 edit/Makefile
 788 syntax/Makefile
 789 pc/Makefile
 790
 791 lib/mc.ext
 792 lib/mc.sh
 793 lib/mc.csh
 794
 795 mcfn_install
 796
 797 vfs/extfs/deb
 798 vfs/extfs/ftplist
 799 vfs/extfs/lslR
 800 vfs/extfs/uar
 801 vfs/extfs/ucpio
 802 vfs/extfs/ulha
 803 vfs/extfs/uha
 804 vfs/extfs/urar
 805 vfs/extfs/uzoo
 806
 807 doc/mc.1 doc/mcedit.1 doc/mcserv.8 doc/ru/mc.1 doc/ru/Makefile
 808
 809
 810 intl/Makefile po/Makefile.in
 811 ])
 812
 813 AC_CONFIG_COMMANDS(potfiles,
 814     [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 815
 816 AC_OUTPUT
 817
 818 if test "x$screen_type" = xslang; then
 819     screen_manager="${screen_manager}${slang_term}"
 820 fi
 821
 822 echo "
 823 Configuration:
 824
 825   Source code location:       ${srcdir}
 826   Compiler:                   ${CC}
 827   Compiler flags:             ${CFLAGS}
 828   File system:                ${vfs_type}
 829                               ${vfs_flags}
 830   Screen manager:             ${screen_manager}
 831   Install console saver:      ${install_saver}
 832   Mouse support:              ${mouse_lib}
 833   X11 events support:         ${textmode_x11_support}
 834   Debugger code:              ${mem_debug}
 835   With subshell support:      ${subshell}
 836   Internal editor:            ${EDIT_msg}
 837   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 838 "