configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4 AC_INIT(src/main.c)
   5 AC_PREREQ(2.52)
   6 AC_CANONICAL_HOST
   7
   8 AM_INIT_AUTOMAKE(mc, 4.5.99a)
   9 AM_CONFIG_HEADER(config.h)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_CC
  13 AC_PROG_CPP
  14 AC_PROG_RANLIB
  15 AC_PROG_LN_S
  16 AC_PROG_AWK
  17
  18 AC_AIX
  19 AC_MINIX
  20 AC_ISC_POSIX
  21
  22 AC_PROG_CC_STDC
  23
  24 AC_HEADER_MAJOR
  25 AC_C_CONST
  26
  27 AC_SYS_LARGEFILE
  28
  29 AC_CHECK_TOOL(AR, ar, ar)
  30
  31 AC_CHECK_PROGS(X11_WWW,netscape arena Mosaic chimera)
  32 if test x"$X11_WWW" = x; then
  33     X11_WWW=lynx
  34 fi
  35
  36 ALL_LINGUAS="az ca cs da de el es es_ES fi fr hu it ja ko lv nl no pl pt_BR ro ru sk sl sv uk ta tr wa zh_TW zh_CN.GB2312"
  37
  38 dnl
  39 dnl Internationalization
  40 dnl
  41 AM_GNU_GETTEXT
  42 INTLDEPS=
  43 LINTL=
  44 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  45     CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
  46     LINTL='-L$(top_builddir)/intl -lintl'
  47     INTLDEPS='$(top_builddir)/intl/libintl.a'
  48 fi
  49 AC_SUBST(LINTL)
  50 AC_SUBST(INTLDEPS)
  51
  52 dnl
  53 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  54 dnl
  55 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  56
  57 dnl
  58 dnl Enforce coding standards
  59 dnl
  60 if test "x$GCC" = xyes; then
  61     CFLAGS="$CFLAGS -Wall"
  62 fi
  63
  64 dnl
  65 dnl We now use glib
  66 dnl
  67 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  68 LIBS="$LIBS $GLIB_LIBS"
  69
  70 dnl
  71 dnl OS specific flags.
  72 dnl
  73
  74 posix_libs=""
  75 case $host_os in
  76 aux*)
  77     # A/UX
  78     posix_libs="-lposix"
  79     AC_DEFINE(_POSIX_SOURCE)
  80     ;;
  81 sco*)
  82     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
  83     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
  84     ;;
  85 esac
  86
  87 AC_PROG_INSTALL
  88 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
  89         malloc.h stdlib.h termios.h utime.h fcntl.h sys/statfs.h \
  90         sys/time.h sys/timeb.h stropts.h])
  91
  92 AC_HEADER_TIME
  93 AC_HEADER_SYS_WAIT
  94 AC_HEADER_DIRENT
  95 AC_SHORT_D_NAME_LEN
  96 AC_HEADER_STDC
  97
  98 dnl Missing structure components
  99 AC_STRUCT_ST_BLKSIZE
 100 AC_STRUCT_ST_BLOCKS
 101 AC_STRUCT_ST_RDEV
 102
 103 dnl
 104 dnl Check availability of some functions
 105 dnl
 106
 107 AC_CHECK_FUNCS([strerror statfs strcasecmp strncasecmp strcoll strftime \
 108                 strdup memmove pwdauth truncate initgroups putenv \
 109                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 110                 sigaction sigemptyset sigprocmask sigaddset \
 111                 sysconf setuid setreuid \
 112                 telldir seekdir])
 113
 114 dnl
 115 dnl getpt is a GNU Extension (glibc 2.1.x)
 116 dnl
 117 AC_CHECK_FUNCS(getpt)
 118
 119 SHADOWLIB=
 120 case $host_os in
 121 linux*)
 122     AC_CHECK_LIB(shadow,pw_encrypt,
 123         [shadow_header=yes
 124         AC_CHECK_HEADERS(shadow.h,,
 125                 [AC_CHECK_HEADERS(shadow/shadow.h,,
 126                         [shadow_header=no])])
 127         if test $shadow_header = yes; then
 128             AC_DEFINE(LINUX_SHADOW)
 129             SHADOWLIB=-lshadow
 130         fi])
 131     ;;
 132 esac
 133 AC_SUBST(SHADOWLIB)
 134
 135 NEED_CRYPT_PROTOTYPE=yes
 136 if test x$ac_cv_header_crypt_h = xyes; then
 137 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 138 if (p)
 139 return 0;],[
 140 NEED_CRYPT_PROTOTYPE=no])
 141 else
 142     if test x$ac_cv_header_unistd_h = xyes; then
 143 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 144 if (p)
 145 return 0;],[
 146 NEED_CRYPT_PROTOTYPE=no])
 147     fi
 148 fi
 149 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 150 AC_DEFINE(NEED_CRYPT_PROTOTYPE)
 151 fi
 152
 153 dnl
 154 dnl AIX and Sequent need <sys/select.h> for fd_set
 155 dnl
 156 AC_CHECK_HEADERS(sys/select.h)
 157
 158 dnl
 159 dnl On SCO and some SVR4, crypt is on libcrypt.a
 160 dnl         grantpt in  libpt.a
 161 dnl
 162 LCRYPT=""
 163 AC_CHECK_FUNCS(crypt, , [
 164     AC_CHECK_LIB(crypt, crypt, LCRYPT="-lcrypt",[
 165         AC_CHECK_LIB(crypt_i, crypt, LCRYPT="-lcrypt_i")])])
 166 AC_SUBST(LCRYPT)
 167
 168 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 169
 170 dnl replacing lstat with statlstat on sco makes it more portable between
 171 dnl sco clones
 172 AC_CHECK_FUNCS(statlstat)
 173
 174 dnl
 175 dnl If running under AIX, AC_AIX does not tell us that
 176 dnl
 177 AC_MSG_CHECKING([for AIX defines])
 178 AC_EGREP_CPP(yes,
 179 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 180 yes
 181 #endif
 182 ], [
 183 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 184 AC_MSG_RESULT(yes)
 185 ], [AC_MSG_RESULT(no)])
 186
 187 dnl
 188 dnl This hack is here until autoconf adds it
 189 dnl Needed for Unixware: getmntent is on libgen.a
 190 dnl
 191 AC_CHECK_LIB(gen, getmntent, [LIBS="-lgen $LIBS"])
 192
 193 dnl
 194 dnl This is from GNU fileutils, check aclocal.m4 for more information
 195 dnl
 196 AC_GET_FS_INFO
 197
 198 dnl
 199 dnl Missing typedefs and replacements
 200 dnl
 201
 202 AC_TYPE_MODE_T
 203 AC_CHECK_TYPE(umode_t, int)
 204 AC_CHECK_TYPE(off_t, long)
 205 AC_TYPE_PID_T
 206 AC_TYPE_UID_T
 207 AC_CHECK_TYPE(nlink_t, unsigned int)
 208
 209 AC_FUNC_MMAP
 210 AC_FUNC_ALLOCA
 211
 212 AC_PATH_XTRA
 213
 214 dnl
 215 dnl X11 support.
 216 dnl
 217
 218 dnl These variables are only used when building the MC binary
 219 MCCFLAGS=""
 220 MCLIBS=""
 221 AC_SUBST(MCCFLAGS)
 222 AC_SUBST(MCLIBS)
 223
 224 textmode_x11_support="no"
 225 AC_ARG_WITH(tm-x-support,
 226         [--with-tm-x-support        Try getting events from X Window System],
 227         [if test x$withval = xyes; then
 228                 MCCFLAGS="$X_CFLAGS"
 229                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 230                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT)
 231                 textmode_x11_support="yes"
 232         fi
 233 ])
 234
 235 dnl
 236 dnl Network related functions
 237 dnl
 238
 239 AC_CHECK_LIB(nsl, t_accept)
 240 AC_CHECK_LIB(socket, socket)
 241
 242 have_socket=no
 243 AC_CHECK_FUNCS(socket, have_socket=yes)
 244 if test $have_socket = no; then
 245   # socket is not in the default libraries.  See if it's in some other.
 246   for lib in bsd socket inet; do
 247     AC_CHECK_LIB($lib, socket, [
 248         LIBS="$LIBS -l$lib"
 249         have_socket=yes
 250         AC_DEFINE(HAVE_SOCKET)
 251         break])
 252   done
 253 fi
 254
 255 have_gethostbyname=no
 256 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 257 if test $have_gethostbyname = no; then
 258   # gethostbyname is not in the default libraries.  See if it's in some other.
 259   for lib in bsd socket inet; do
 260     AC_CHECK_LIB($lib, gethostbyname, [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 261   done
 262 fi
 263
 264 AC_CHECK_FUNCS(socketpair)
 265
 266 dnl
 267 dnl Sequent wants getprocessstats
 268 dnl
 269 AC_CHECK_LIB(seq, get_process_stats, [
 270         LIBS="$LIBS -lseq"
 271         AC_DEFINE(HAVE_GET_PROCESS_STATS)])
 272
 273 MC_VFS_CHECKS
 274
 275 dnl
 276 dnl Install mcserv only if explicitly enabled
 277 dnl
 278 AC_ARG_ENABLE([mcserv-install],
 279               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 280
 281 NETFILES=
 282 if test $have_socket = yes; then
 283    NETFILES="\$(NETFILES)"
 284 fi
 285 AC_SUBST(NETFILES)
 286
 287 LIBVFS=""
 288 LVFS=""
 289 vfs_type="normal"
 290 if test $use_vfs = yes
 291 then
 292         LIBVFS="libvfs-mc.a"
 293         LVFS="-lvfs-mc"
 294         MCCPPFLAGS="$MCCPPFLAGS -I\$(vfsdir)"
 295         AC_MSG_RESULT([Using the VFS switch code])
 296         vfs_type="Midnight Commander Virtual File System"
 297 fi
 298 AC_SUBST(LIBVFS)
 299 AC_SUBST(LVFS)
 300
 301 screen_manager=unknown
 302 search_ncurses=false
 303
 304 mouse_lib="xterm only"
 305 LGPM=""
 306 case $host_os in
 307 linux*)
 308     AC_ARG_WITH(gpm-mouse,
 309         [--with-gpm-mouse[=base-dir]  Compile with gpm mouse support (Linux only)],
 310         [if test x$withval != xno
 311         then
 312                 if test x$withval != xyes
 313                 then
 314                         LIBS="$LIBS -L$withval/lib"
 315                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 316                 fi
 317                 AC_DEFINE(HAVE_LIBGPM)
 318                 mouse_lib="GPM and xterm"
 319                 LGPM="-lgpm"
 320         fi],
 321         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 322                 [AC_DEFINE(HAVE_LIBGPM)
 323                 mouse_lib="GPM and xterm"
 324                 LGPM="-lgpm"],
 325                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 326                 $LIBS)
 327         ])
 328     ;;
 329 esac
 330 AC_SUBST(LGPM)
 331
 332 AC_ARG_WITH(ncurses,
 333         [--with-ncurses[=base-dir]    Compile with ncurses/locate base dir],
 334         [if test x$withval = xyes
 335         then
 336                 search_ncurses=true
 337         else
 338                 LIBS="$LIBS -L$withval/lib -lncurses"
 339                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 340                 search_ncurses=false
 341                 screen_manager="ncurses"
 342                 AC_DEFINE(USE_NCURSES)
 343         fi
 344 ])
 345
 346 AC_ARG_WITH(hsc,
 347         [--with-hsc               Compile with support for the HSC firewall],
 348         [if test x$withval = xyes; then
 349                 AC_DEFINE(HSC_PROXY, 1,
 350                           [Define if you want to use the HSC firewall])
 351         fi
 352 ])
 353
 354 dnl
 355 dnl Check for the -mandoc package
 356 dnl
 357 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 358 if $HAVE_nroff; then
 359     AC_MSG_CHECKING([for manual formatting macros])
 360     AC_CACHE_VAL(ac_cv_mandoc, [
 361     nroff -mandoc < /dev/null > /dev/null 2>&1 /dev/null
 362     if test $? = 0
 363     then
 364         ac_cv_mandoc=-mandoc
 365     else
 366         ac_cv_mandoc=-man
 367     fi
 368     ])
 369     MANDOC=$ac_cv_mandoc
 370     AC_MSG_RESULT($MANDOC)
 371 else
 372     MANDOC=-man
 373 fi
 374 AC_SUBST(MANDOC)
 375
 376 dnl
 377 dnl Check if nroff accepts -Tlatin1 or -Tascii
 378 dnl
 379 if $HAVE_nroff; then
 380     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 381     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 382     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 383     if test $? = 0
 384     then
 385         ac_cv_nroff_tascii=" -Tlatin1"
 386     else
 387         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 388         if test $? = 0
 389         then
 390             ac_cv_nroff_tascii=" -Tascii"
 391         else
 392             ac_cv_nroff_tascii=""
 393         fi
 394     fi
 395     ])
 396     if test "x$ac_cv_nroff_tascii" = x; then
 397         AC_MSG_RESULT(no)
 398     else
 399         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 400     fi
 401 fi
 402 TROFFASCII="$ac_cv_nroff_tascii"
 403 AC_SUBST(TROFFASCII)
 404
 405 dnl
 406 dnl Check for - option to file
 407 dnl
 408 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 409 if $HAVE_FILECMD; then
 410     AC_MSG_CHECKING([for - option to file command])
 411     AC_CACHE_VAL(ac_cv_filestdin, [[
 412     cat > conftest.c <<\EOF
 413 /* A comment */
 414 #if 0
 415 #endif
 416 void main(void)
 417 { return; }
 418 EOF
 419     cat > conftest.sed <<\EOF
 420 s/^[^:]*:[      ]*//
 421 s/[     ]*$//
 422 EOF
 423     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 424     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 425     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 426         ac_cv_filestdin=yes
 427     else
 428         ac_cv_filestdin=no
 429     fi
 430     rm conftest.c conftest.sed
 431     ]])
 432
 433     if test x$ac_cv_filestdin = xyes; then
 434         AC_DEFINE(FILE_STDIN, 1,
 435                   [Define if the file command accepts - for stdin])
 436     fi
 437     filestdin=$ac_cv_filestdin
 438     AC_MSG_RESULT([$filestdin])
 439
 440     dnl
 441     dnl Check for -L option to file
 442     dnl
 443
 444 AC_MSG_CHECKING([for -L option to file command])
 445 AC_CACHE_VAL(ac_cv_filel, [
 446 file -L . > /dev/null 2>&1
 447 if test $? = 0
 448 then
 449     ac_cv_filel=yes
 450 else
 451     ac_cv_filel=no
 452 fi
 453 ])
 454 if test x$ac_cv_filel = xyes; then
 455     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 456 fi
 457 filel=$ac_cv_filel
 458 AC_MSG_RESULT([$filel])
 459 fi
 460
 461 dnl
 462 dnl Check to see if grep program allowes dash to denote stdin
 463 dnl
 464 AC_MSG_CHECKING([for - option to grep command])
 465 AC_CACHE_VAL(ac_cv_grep_stdin, [
 466     echo "grep_test" | grep grep_test - >/dev/null 2>&1
 467     if test $? = 0; then
 468         ac_cv_grep_stdin=yes
 469     else
 470         ac_cv_grep_stdin=no
 471     fi
 472 ])
 473 if test x$ac_cv_grep_stdin = xyes; then
 474     AC_DEFINE(GREP_STDIN, 1, [Define if the grep command accepts - for stdin])
 475 fi
 476 AC_MSG_RESULT([$ac_cv_grep_stdin])
 477
 478 dnl
 479 dnl The subshell support
 480 dnl
 481
 482 AC_MSG_CHECKING([for subshell support])
 483 AC_ARG_WITH(subshell,
 484         [--with-subshell            If you want to use a concurrent shell],
 485         [result=no
 486         if test x$withval = xoptional
 487         then
 488                 AC_DEFINE(SUBSHELL_OPTIONAL)
 489                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 490                 result="optional"
 491         fi
 492         if test x$withval = xyes
 493         then
 494                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 495                 result="yes"
 496         fi],
 497         [dnl Default: provide the subshell support on non-ultrix machines
 498         case $host_os in
 499         ultrix*)
 500                 result=no
 501                 ;;
 502         *)
 503                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 504                 result=yes
 505                 ;;
 506         esac
 507 ])
 508 AC_MSG_RESULT([$result])
 509 subshell="$result"
 510
 511 dnl
 512 dnl Memory Allocation Debugger
 513 dnl
 514 mem_debug="none"
 515 AC_ARG_WITH(mad,
 516 [--with-mad                 Developers only: activates MAD (memory debugger)],
 517         [if test x$withval = xyes; then
 518         mem_debug="Janne's MAD library"
 519         AC_DEFINE(HAVE_MAD)
 520         AC_MSG_RESULT([compiling with memory leak detector])
 521 fi])
 522
 523 dnl
 524 dnl Electric Fence - another memory debugger
 525 dnl
 526 AC_ARG_WITH(efence,
 527 [--with-efence              Developers only: activates Electric Fence],
 528         [if test x$withval = xyes; then
 529         LIBS="$LIBS -lefence"
 530         AC_MSG_RESULT([compiling with Electric fence])
 531         mem_debug="Electric Fence"
 532 fi])
 533
 534 dnl
 535 dnl To force mmap support
 536 dnl We use only part of the functionality of mmap, so on AIX,
 537 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 538 dnl
 539 AC_ARG_WITH(mmap,
 540         [--with-mmap                To force using the mmap call (AIX)],
 541         [if test x$withval = xyes; then
 542         AC_DEFINE(HAVE_MMAP)
 543         AC_MSG_RESULT([forcing MMAP support])
 544 fi])
 545
 546 slang_check_lib=true
 547 slang_term=""
 548 slang_use_system_installed_lib=false
 549 AC_CHECK_LIB(slang,SLang_init_tty,
 550         [AC_CHECK_HEADERS(slang.h)
 551         if test x$ac_cv_header_slang_h = xyes
 552         then
 553              slang_use_system_installed_lib=true
 554              slang_check_lib=false
 555         else
 556              AC_CHECK_HEADERS(slang/slang.h)
 557              if test x$ac_cv_header_slang_slang_h = xyes
 558              then
 559                  slang_use_system_installed_lib=true
 560                  slang_check_lib=false
 561              fi
 562         fi
 563 ])
 564
 565 AC_ARG_WITH(terminfo,
 566         [--with-terminfo            SLANG: Force usage of terminfo],[
 567         if test x$withval = xyes; then
 568                 AC_USE_TERMINFO
 569                 slang_check_lib=false
 570                 slang_use_system_installed_lib=false
 571         fi]
 572 )
 573
 574 AC_ARG_WITH(termcap,
 575         [--with-termcap             SLANG: Force usage of termcap],[
 576         if test x$withval = xyes; then
 577                 AC_USE_TERMCAP
 578                 slang_check_lib=false
 579                 slang_use_system_installed_lib=false
 580         fi]
 581 )
 582
 583 AC_ARG_WITH(included-slang,
 584         [--with-included-slang      SLANG: use the SLang library included here],[
 585         if test x$withval = xyes; then
 586             slang_use_system_installed_lib=false
 587             slang_check_lib=true
 588         fi]
 589 )
 590
 591 LIBSLANG=""
 592 LSLANG=""
 593 AC_ARG_WITH(slang,
 594         [--with-slang              Compile with the slang screen manager],[
 595         if test x$withval = xyes; then
 596                 AC_WITH_SLANG
 597         fi
 598 ])
 599
 600 AC_SUBST(LIBSLANG)
 601 AC_SUBST(LSLANG)
 602
 603 LIBEDIT_A=""
 604 MCEDIT=""
 605 LEDIT=""
 606 EDIT_msg=""
 607 AC_ARG_WITH(edit,
 608         [--with-edit                Define INTERNAL_EDIT],
 609         [if test x$withval = xyes
 610         then
 611                 AC_WITH_EDIT
 612         else
 613                 EDIT_msg="no"
 614         fi],
 615         [dnl Default: provide the internal editor
 616         AC_WITH_EDIT
 617 ])
 618 AC_SUBST(LIBEDIT_A)
 619 AC_SUBST(MCEDIT)
 620 AC_SUBST(LEDIT)
 621
 622 AC_ARG_WITH(netrc,
 623         [--with-netrc               Compile with ftp .netrc support],[
 624         if test x$withval = xyes; then
 625                 AC_DEFINE(USE_NETRC, 1,
 626                           [Define to use .netrc for FTP connections])
 627                 AC_MSG_RESULT([ftpfs will have .netrc parsing code])
 628         fi
 629 ])
 630
 631 undelfs_o=""
 632
 633 if test $use_vfs = yes; then
 634     AC_ARG_WITH(ext2undel,
 635         [--with-ext2undel           Compile with ext2 undelete code],[
 636         if test x$withval != xno;
 637         then
 638                 if test x$withval != xyes
 639                 then
 640                         LIBS="$LIBS -L$withval/lib"
 641                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 642                 fi
 643                 AC_EXT2_UNDEL
 644         fi],[
 645         dnl Default: detect
 646         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL],,-lcom_err)
 647     ])
 648 fi
 649
 650 AC_SUBST(undelfs_o)
 651
 652 if $search_ncurses
 653 then
 654     AC_CHECKING([location of ncurses.h file])
 655
 656     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 657     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 658     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 659     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 660
 661     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 662
 663     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 664
 665     if $search_ncurses
 666     then
 667         :
 668     else
 669         # check for ncurses version, to properly ifdef mouse-fix
 670         AC_MSG_CHECKING([for ncurses version])
 671         ncurses_version=unknown
 672 cat > conftest.$ac_ext <<EOF
 673 [#]line __oline__ "configure"
 674 #include "confdefs.h"
 675 #ifdef RENAMED_NCURSES
 676 #include <curses.h>
 677 #else
 678 #include <ncurses.h>
 679 #endif
 680 #undef VERSION
 681 VERSION:NCURSES_VERSION
 682 EOF
 683         if (eval "$ac_cpp conftest.$ac_ext") 2>&AC_FD_CC |
 684   egrep "VERSION:" >conftest.out 2>&1; then
 685             ncurses_version=`cat conftest.out|sed -e 's/^[[^"]]*"//' -e 's/".*//'`
 686         fi
 687         rm -rf conftest*
 688         AC_MSG_RESULT([$ncurses_version])
 689         case "$ncurses_version" in
 690         4.[[01]])
 691             AC_DEFINE(NCURSES_970530,2)
 692             ;;
 693         1.9.9g)
 694             AC_DEFINE(NCURSES_970530,1)
 695             ;;
 696         1*)
 697             AC_DEFINE(NCURSES_970530,0)
 698             ;;
 699         esac
 700     fi
 701 fi
 702
 703
 704 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 705 dnl or you'll have to press Esc three times to dismiss a dialog box.
 706 dnl
 707 if test -n "$ncurses_version"; then
 708   AC_CACHE_CHECK([for ESCDELAY variable],
 709                  [mc_cv_ncurses_escdelay],
 710                  [AC_TRY_COMPILE([], [
 711                         extern int ESCDELAY;
 712                         int main ()
 713                         {
 714                           ESCDELAY = 0;
 715                         }
 716                         ],
 717                         [mc_cv_ncurses_escdelay=yes],
 718                         [mc_cv_ncurses_escdelay=no]
 719                   )
 720   ])
 721   if test "$mc_cv_ncurses_escdelay" = yes; then
 722     AC_DEFINE(HAVE_ESCDELAY, 1,
 723               [Define if ncurses has ESCDELAY variable])
 724   fi
 725 fi
 726
 727
 728 dnl Ncurses may be linked against libgpm. Change LIBS temporary for
 729 dnl check for resizeterm and keyok.
 730 dnl
 731 SAVED_LIBS="$LIBS"
 732 LIBS="$LIBS $LGPM"
 733 AC_CHECK_FUNCS(resizeterm keyok)
 734 LIBS="$SAVED_LIBS"
 735
 736 if test "x$screen_manager" = "xunknown"; then
 737     AC_WITH_SLANG
 738 fi
 739
 740 dnl
 741 dnl The variables used for expanding the auto saver.
 742 dnl
 743 cons_saver=""
 744 install_saver="no"
 745 PAMLIBS=""
 746 case $host_os in
 747 linux*)
 748     cons_saver="cons.saver"
 749     install_saver="yes"
 750
 751     dnl
 752     dnl On Linux, check for PAM authentication available
 753     dnl
 754     AC_CHECK_LIB(pam, pam_start, [
 755         AC_DEFINE(HAVE_PAM)
 756         PAMLIBS="-lpam -ldl"
 757     ],[],[-ldl])
 758     ;;
 759 esac
 760 AC_SUBST(cons_saver)
 761 AC_SUBST(PAMLIBS)
 762
 763 dnl
 764 dnl User visible support for charset conversion.
 765 dnl
 766 AC_ARG_ENABLE([charset],
 767               [--enable-charset           Support for charset selection and conversion])
 768 have_charset=
 769 if test "x$enable_charset" = xyes; then
 770   if test -z "$am_cv_func_iconv"; then
 771     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 772   else
 773     AC_DEFINE(HAVE_CHARSET, 1,
 774               [Define to enable charset selection and conversion])
 775     have_charset=yes
 776   fi
 777 fi
 778
 779
 780 dnl
 781 dnl This code should be moved to the ac_WITH_SLANG
 782 dnl
 783 dnl We check for the existance of setupterm on curses library
 784 dnl this is required to load certain definitions on some termcaps
 785 dnl editions (AIX and OSF/1 I seem to remember).
 786 dnl Note that we avoid using setupterm
 787 case $screen_manager in
 788 SLang*)
 789         case $host_os in
 790         linux*)
 791                 ;;
 792         *)
 793                 AC_CHECK_LIB(curses,setupterm,
 794                         [AC_TRY_COMPILE([
 795 #include <curses.h>
 796 #include <term.h>],[
 797    if (key_end == parm_insert_line)
 798         return 1;
 799    return 0;
 800 ],
 801                         [LIBS="$LIBS -lcurses"
 802                         AC_DEFINE(USE_SETUPTERM)])
 803                 ])
 804         esac
 805         ;;
 806 esac
 807
 808 LIBS="$LIBS $posix_libs"
 809
 810 AC_SUBST(CFLAGS)
 811 AC_SUBST(CPPFLAGS)
 812 AC_SUBST(MCCPPFLAGS)
 813 AC_SUBST(LDFLAGS)
 814 AC_SUBST(LIBS)
 815
 816 MCF=./Make.common
 817 AC_SUBST_FILE(MCF)
 818
 819 if test "x$SAMBAFILES" != x; then
 820   AC_CONFIG_SUBDIRS([vfs/samba])
 821 fi
 822
 823 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 824 AM_CONDITIONAL(USE_VFS, [test -n "$LIBVFS"])
 825 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 826 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 827 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 828 AM_CONDITIONAL(MCSERV_INSTALL,
 829                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 830 AM_CONDITIONAL(INCLUDED_SLANG, [test -n "$LIBSLANG"])
 831 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 832 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 833
 834 AC_OUTPUT([
 835 Make.common
 836 Makefile
 837 mc.spec
 838 doc/Makefile
 839 vfs/Makefile:vfs/Make-mc.in
 840 vfs/extfs/Makefile
 841 lib/Makefile
 842 src/Makefile
 843 slang/Makefile
 844 edit/Makefile
 845 syntax/Makefile
 846 pc/Makefile
 847
 848 lib/mc.ext
 849 lib/mc.sh
 850 lib/mc.csh
 851
 852 mcfn_install
 853
 854 vfs/extfs/deb
 855 vfs/extfs/ftplist
 856 vfs/extfs/lslR
 857 vfs/extfs/uar
 858 vfs/extfs/ucpio
 859 vfs/extfs/ulha
 860 vfs/extfs/uha
 861 vfs/extfs/urar
 862 vfs/extfs/uzoo
 863
 864 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 865
 866 intl/Makefile po/Makefile.in
 867 ],[sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 868
 869 if echo "$screen_manager" | grep -q "SLang" ; then
 870     screen_manager="${screen_manager}${slang_term}"
 871 fi
 872
 873 echo "
 874 Configuration:
 875
 876   Source code location:       ${srcdir}
 877   Compiler:                   ${CC}
 878   Compiler flags:             ${CFLAGS}
 879   File system:                ${vfs_type}
 880                               ${vfs_flags}
 881   Screen manager:             ${screen_manager}
 882   Install console saver:      ${install_saver}
 883   Mouse support:              ${mouse_lib}
 884   X11 events support:         ${textmode_x11_support}
 885   Debugger code:              ${mem_debug}
 886   With subshell support:      ${subshell}
 887   Internal editor:            ${EDIT_msg}
 888   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 889 "