configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT(GNU Midnight Commander, 4.5.99a, mc-devel@gnome.org)
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.5.99a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_PROG_LN_S
  15 AC_CANONICAL_HOST
  16
  17 AC_AIX
  18 AC_MINIX
  19 AC_ISC_POSIX
  20
  21 AC_PROG_CC_STDC
  22
  23 AC_HEADER_MAJOR
  24 AC_C_CONST
  25
  26 AC_SYS_LARGEFILE
  27
  28 AC_CHECK_TOOL(AR, ar, ar)
  29
  30 dnl Only list browsers here that can be run in background (i.e. with `&')
  31 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  32
  33 dnl
  34 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  35 dnl We use only part of the functionality of mmap, so on AIX,
  36 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  37 dnl
  38 AC_ARG_WITH(mmap,
  39         [--with-mmap                To force using the mmap call (AIX)],
  40         [case $withval in
  41 yes)
  42         ac_cv_func_mmap_fixed_mapped=yes
  43         AC_MSG_NOTICE([forcing MMAP support])
  44         ;;
  45 no)
  46         ac_cv_func_mmap_fixed_mapped=no
  47         AC_MSG_NOTICE([disabling MMAP support])
  48         ;;
  49 esac])
  50 AC_FUNC_MMAP
  51
  52 if test "x$ALL_LINGUAS" = x; then
  53 ALL_LINGUAS="az ca cs da de el es es_ES fi fr hu it ja ko lv nl no pl pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  54 fi
  55
  56 dnl
  57 dnl Internationalization
  58 dnl
  59 AM_GNU_GETTEXT
  60 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  61     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  62 fi
  63
  64 dnl
  65 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  66 dnl
  67 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  68
  69 dnl
  70 dnl Enforce coding standards
  71 dnl
  72 if test "x$GCC" = xyes; then
  73     CFLAGS="$CFLAGS -Wall"
  74 fi
  75
  76 dnl
  77 dnl We now use glib
  78 dnl
  79 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  80 LIBS="$LIBS $GLIB_LIBS"
  81
  82 dnl
  83 dnl OS specific flags.
  84 dnl
  85
  86 posix_libs=""
  87 case $host_os in
  88 aux*)
  89     # A/UX
  90     posix_libs="-lposix"
  91     AC_DEFINE(_POSIX_SOURCE)
  92     ;;
  93 sco*)
  94     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
  95     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
  96     ;;
  97 esac
  98
  99 AC_PROG_INSTALL
 100 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 101         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 102         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h])
 103
 104 AC_HEADER_TIME
 105 AC_HEADER_SYS_WAIT
 106 AC_HEADER_DIRENT
 107 AC_SHORT_D_NAME_LEN
 108 AC_HEADER_STDC
 109
 110 dnl Missing structure components
 111 AC_STRUCT_ST_BLKSIZE
 112 AC_STRUCT_ST_BLOCKS
 113 AC_STRUCT_ST_RDEV
 114
 115 dnl
 116 dnl Check availability of some functions
 117 dnl
 118
 119 AC_CHECK_FUNCS([strerror statfs strcasecmp strncasecmp strftime \
 120                 strdup memmove pwdauth truncate initgroups putenv \
 121                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 122                 sigaction sigemptyset sigprocmask sigaddset \
 123                 sysconf setuid setreuid telldir seekdir])
 124
 125 dnl
 126 dnl getpt is a GNU Extension (glibc 2.1.x)
 127 dnl
 128 AC_CHECK_FUNCS(getpt)
 129
 130 SHADOWLIB=
 131 case $host_os in
 132 linux*)
 133     AC_CHECK_LIB(shadow,pw_encrypt,
 134         [shadow_header=yes
 135         AC_CHECK_HEADERS(shadow.h,,
 136                 [AC_CHECK_HEADERS(shadow/shadow.h,,
 137                         [shadow_header=no])])
 138         if test $shadow_header = yes; then
 139             AC_DEFINE(LINUX_SHADOW, 1,
 140                       [Define to use shadow passwords on Linux])
 141             SHADOWLIB=-lshadow
 142         fi])
 143     ;;
 144 esac
 145 AC_SUBST(SHADOWLIB)
 146
 147 NEED_CRYPT_PROTOTYPE=yes
 148 if test x$ac_cv_header_crypt_h = xyes; then
 149 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 150 if (p)
 151 return 0;],[
 152 NEED_CRYPT_PROTOTYPE=no])
 153 else
 154     if test x$ac_cv_header_unistd_h = xyes; then
 155 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 156 if (p)
 157 return 0;],[
 158 NEED_CRYPT_PROTOTYPE=no])
 159     fi
 160 fi
 161 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 162 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 163           [Define if function `crypt' needs a prototype])
 164 fi
 165
 166 dnl
 167 dnl On SCO and some SVR4, crypt is on libcrypt.a
 168 dnl         grantpt in  libpt.a
 169 dnl
 170 LCRYPT=""
 171 AC_CHECK_FUNCS(crypt, , [
 172     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 173         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 174 AC_SUBST(LCRYPT)
 175
 176 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 177
 178 dnl replacing lstat with statlstat on sco makes it more portable between
 179 dnl sco clones
 180 AC_CHECK_FUNCS(statlstat)
 181
 182 dnl
 183 dnl If running under AIX, AC_AIX does not tell us that
 184 dnl
 185 AC_MSG_CHECKING([for AIX defines])
 186 AC_EGREP_CPP(yes,
 187 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 188 yes
 189 #endif
 190 ], [
 191 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 192 AC_MSG_RESULT(yes)
 193 ], [AC_MSG_RESULT(no)])
 194
 195 dnl
 196 dnl This is from GNU fileutils, check aclocal.m4 for more information
 197 dnl
 198 AC_GET_FS_INFO
 199
 200 dnl
 201 dnl Missing typedefs and replacements
 202 dnl
 203
 204 AC_TYPE_MODE_T
 205 AC_CHECK_TYPE(umode_t, int)
 206 AC_CHECK_TYPE(off_t, long)
 207 AC_TYPE_PID_T
 208 AC_TYPE_UID_T
 209 AC_CHECK_TYPE(nlink_t, unsigned int)
 210
 211 AC_FUNC_ALLOCA
 212 AC_FUNC_STRCOLL
 213
 214 dnl
 215 dnl X11 support.
 216 dnl
 217
 218 dnl These variables are only used when building the MC binary
 219 MCCFLAGS=""
 220 MCLIBS=""
 221 AC_SUBST(MCCFLAGS)
 222 AC_SUBST(MCLIBS)
 223
 224 textmode_x11_support="no"
 225 AC_ARG_WITH(tm-x-support,
 226         [--with-tm-x-support        Try getting events from X Window System],
 227         [if test x$withval = xyes; then
 228                 AC_PATH_XTRA
 229                 MCCFLAGS="$X_CFLAGS"
 230                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 231                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 232                           [Define to enable getting events from X Window System])
 233                 textmode_x11_support="yes"
 234         fi
 235 ])
 236
 237 dnl
 238 dnl Network related functions
 239 dnl
 240
 241 AC_CHECK_LIB(nsl, t_accept)
 242 AC_CHECK_LIB(socket, socket)
 243
 244 have_socket=no
 245 AC_CHECK_FUNCS(socket, have_socket=yes)
 246 if test $have_socket = no; then
 247   # socket is not in the default libraries.  See if it's in some other.
 248   for lib in bsd socket inet; do
 249     AC_CHECK_LIB($lib, socket, [
 250         LIBS="$LIBS -l$lib"
 251         have_socket=yes
 252         AC_DEFINE(HAVE_SOCKET)
 253         break])
 254   done
 255 fi
 256
 257 have_gethostbyname=no
 258 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 259 if test $have_gethostbyname = no; then
 260   # gethostbyname is not in the default libraries.  See if it's in some other.
 261   for lib in bsd socket inet; do
 262     AC_CHECK_LIB([$lib], [gethostbyname],
 263                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 264   done
 265 fi
 266
 267 AC_CHECK_FUNCS(socketpair)
 268
 269 dnl
 270 dnl Sequent wants getprocessstats
 271 dnl
 272 AC_CHECK_LIB(seq, get_process_stats, [
 273         LIBS="$LIBS -lseq"
 274         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 275                   [Define if you have function `get_process_stats' and
 276 have to use that instead of gettimeofday])])
 277
 278 MC_VFS_CHECKS
 279
 280 dnl
 281 dnl Install mcserv only if explicitly enabled
 282 dnl
 283 AC_ARG_ENABLE([mcserv-install],
 284               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 285
 286 NETFILES=
 287 if test $have_socket = yes; then
 288    NETFILES="\$(NETFILES)"
 289 fi
 290 AC_SUBST(NETFILES)
 291
 292 vfs_type="normal"
 293 if test $use_vfs = yes
 294 then
 295         AC_MSG_NOTICE([enabling VFS code])
 296         vfs_type="Midnight Commander Virtual File System"
 297 fi
 298
 299 screen_manager=unknown
 300 search_ncurses=false
 301
 302 mouse_lib="xterm only"
 303 case $host_os in
 304 linux*)
 305     AC_ARG_WITH(gpm-mouse,
 306         [--with-gpm-mouse[=base-dir]  Compile with gpm mouse support (Linux only)],
 307         [if test x$withval != xno
 308         then
 309                 if test x$withval != xyes
 310                 then
 311                         LIBS="$LIBS -L$withval/lib"
 312                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 313                 fi
 314                 AC_DEFINE(HAVE_LIBGPM, 1,
 315                           [Define to enable gpm mouse support on Linux])
 316                 mouse_lib="GPM and xterm"
 317                 MCLIBS="-lgpm $MCLIBS"
 318         fi],
 319         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 320                 [AC_DEFINE(HAVE_LIBGPM)
 321                 mouse_lib="GPM and xterm"
 322                 MCLIBS="-lgpm $MCLIBS"],
 323                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 324                 [$LIBS])
 325         ])
 326     ;;
 327 esac
 328
 329 AC_ARG_WITH(ncurses,
 330         [--with-ncurses[=base-dir]    Compile with ncurses/locate base dir],
 331         [if test x$withval = xyes
 332         then
 333                 search_ncurses=true
 334         else
 335                 MCLIBS="$MCLIBS -L$withval/lib -lncurses"
 336                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 337                 search_ncurses=false
 338                 screen_manager="ncurses"
 339                 AC_DEFINE(USE_NCURSES)
 340         fi
 341 ])
 342
 343 AC_ARG_WITH(hsc,
 344         [--with-hsc               Compile with support for the HSC firewall],
 345         [if test x$withval = xyes; then
 346                 AC_DEFINE(HSC_PROXY, 1,
 347                           [Define if you want to use the HSC firewall])
 348         fi
 349 ])
 350
 351 dnl
 352 dnl Check for the -mandoc package
 353 dnl
 354 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 355 if $HAVE_nroff; then
 356     AC_MSG_CHECKING([for manual formatting macros])
 357     AC_CACHE_VAL(ac_cv_mandoc, [
 358     nroff -mandoc < /dev/null > /dev/null 2>&1
 359     if test $? = 0
 360     then
 361         ac_cv_mandoc=-mandoc
 362     else
 363         ac_cv_mandoc=-man
 364     fi
 365     ])
 366     MANDOC=$ac_cv_mandoc
 367     AC_MSG_RESULT([$MANDOC])
 368 else
 369     MANDOC=-man
 370 fi
 371 AC_SUBST(MANDOC)
 372
 373 dnl
 374 dnl Check if nroff accepts -Tlatin1 or -Tascii
 375 dnl
 376 if $HAVE_nroff; then
 377     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 378     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 379     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 380     if test $? = 0
 381     then
 382         ac_cv_nroff_tascii=" -Tlatin1"
 383     else
 384         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 385         if test $? = 0
 386         then
 387             ac_cv_nroff_tascii=" -Tascii"
 388         else
 389             ac_cv_nroff_tascii=""
 390         fi
 391     fi
 392     ])
 393     if test "x$ac_cv_nroff_tascii" = x; then
 394         AC_MSG_RESULT([no])
 395     else
 396         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 397     fi
 398 fi
 399 TROFFASCII="$ac_cv_nroff_tascii"
 400 AC_SUBST(TROFFASCII)
 401
 402 dnl
 403 dnl Check for - option to file
 404 dnl
 405 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 406 if $HAVE_FILECMD; then
 407     AC_MSG_CHECKING([for - option to file command])
 408     AC_CACHE_VAL(ac_cv_filestdin, [[
 409     cat > conftest.c <<\EOF
 410 /* A comment */
 411 #if 0
 412 #endif
 413 void main(void)
 414 { return; }
 415 EOF
 416     cat > conftest.sed <<\EOF
 417 s/^[^:]*:[      ]*//
 418 s/[     ]*$//
 419 EOF
 420     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 421     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 422     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 423         ac_cv_filestdin=yes
 424     else
 425         ac_cv_filestdin=no
 426     fi
 427     rm conftest.c conftest.sed
 428     ]])
 429
 430     if test x$ac_cv_filestdin = xyes; then
 431         AC_DEFINE(FILE_STDIN, 1,
 432                   [Define if the file command accepts - for stdin])
 433     fi
 434     filestdin=$ac_cv_filestdin
 435     AC_MSG_RESULT([$filestdin])
 436
 437     dnl
 438     dnl Check for -L option to file
 439     dnl
 440
 441 AC_MSG_CHECKING([for -L option to file command])
 442 AC_CACHE_VAL(ac_cv_filel, [
 443 file -L . > /dev/null 2>&1
 444 if test $? = 0
 445 then
 446     ac_cv_filel=yes
 447 else
 448     ac_cv_filel=no
 449 fi
 450 ])
 451 if test x$ac_cv_filel = xyes; then
 452     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 453 fi
 454 filel=$ac_cv_filel
 455 AC_MSG_RESULT([$filel])
 456 fi
 457
 458 AC_MSG_CHECKING([for subshell support])
 459 AC_ARG_WITH(subshell,
 460         [--with-subshell            If you want to use a concurrent shell],
 461         [result=no
 462         if test x$withval = xoptional
 463         then
 464                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 465                           [Define to make subshell support optional])
 466                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 467                           [Define to enable subshell support])
 468                 result="optional"
 469         fi
 470         if test x$withval = xyes
 471         then
 472                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 473                 result="yes"
 474         fi],
 475         [dnl Default: provide the subshell support on non-ultrix machines
 476         case $host_os in
 477         ultrix*)
 478                 result=no
 479                 ;;
 480         *)
 481                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 482                 result=yes
 483                 ;;
 484         esac
 485 ])
 486 AC_MSG_RESULT([$result])
 487 subshell="$result"
 488
 489 dnl
 490 dnl Memory Allocation Debugger
 491 dnl
 492 mem_debug="none"
 493 AC_ARG_WITH(mad,
 494 [--with-mad                 Developers only: activates MAD (memory debugger)],
 495         [if test x$withval = xyes; then
 496         mem_debug="Janne's MAD library"
 497         AC_DEFINE(HAVE_MAD, 1,
 498                   [Define to use Memory Allocation Debugger (MAD)])
 499         AC_MSG_NOTICE([compiling with memory leak detector])
 500 fi])
 501
 502 dnl
 503 dnl Electric Fence - another memory debugger
 504 dnl
 505 AC_ARG_WITH(efence,
 506 [--with-efence              Developers only: activates Electric Fence],
 507         [if test x$withval = xyes; then
 508         LIBS="$LIBS -lefence"
 509         AC_MSG_NOTICE([compiling with Electric fence])
 510         mem_debug="Electric Fence"
 511 fi])
 512
 513 slang_check_lib=true
 514 slang_term=""
 515 slang_use_system_installed_lib=false
 516 AC_CHECK_LIB(slang,SLang_init_tty,
 517         [AC_CHECK_HEADERS(slang.h)
 518         if test x$ac_cv_header_slang_h = xyes
 519         then
 520              slang_use_system_installed_lib=true
 521              slang_check_lib=false
 522         else
 523              AC_CHECK_HEADERS(slang/slang.h)
 524              if test x$ac_cv_header_slang_slang_h = xyes
 525              then
 526                  slang_use_system_installed_lib=true
 527                  slang_check_lib=false
 528              fi
 529         fi
 530 ])
 531
 532 AC_ARG_WITH(terminfo,
 533         [--with-terminfo            SLANG: Force usage of terminfo],[
 534         if test x$withval = xyes; then
 535                 AC_USE_TERMINFO
 536                 slang_check_lib=false
 537                 slang_use_system_installed_lib=false
 538         fi]
 539 )
 540
 541 AC_ARG_WITH(termcap,
 542         [--with-termcap             SLANG: Force usage of termcap],[
 543         if test x$withval = xyes; then
 544                 AC_USE_TERMCAP
 545                 slang_check_lib=false
 546                 slang_use_system_installed_lib=false
 547         fi]
 548 )
 549
 550 AC_ARG_WITH(included-slang,
 551         [--with-included-slang      SLANG: use the SLang library included here],[
 552         if test x$withval = xyes; then
 553             slang_use_system_installed_lib=false
 554             slang_check_lib=true
 555         fi]
 556 )
 557
 558 AC_ARG_WITH(slang,
 559         [--with-slang              Compile with the slang screen manager],[
 560         if test x$withval = xyes; then
 561                 AC_WITH_SLANG
 562         fi
 563 ])
 564
 565 LIBEDIT_A=""
 566 MCEDIT=""
 567 LEDIT=""
 568 EDIT_msg=""
 569 AC_ARG_WITH(edit,
 570         [--with-edit                Enable internal editpr],
 571         [if test x$withval = xyes
 572         then
 573                 AC_WITH_EDIT
 574         else
 575                 EDIT_msg="no"
 576         fi],
 577         [dnl Default: provide the internal editor
 578         AC_WITH_EDIT
 579 ])
 580 AC_SUBST(LIBEDIT_A)
 581 AC_SUBST(MCEDIT)
 582 AC_SUBST(LEDIT)
 583
 584 AC_ARG_WITH(netrc,
 585         [--with-netrc               Compile with ftp .netrc support],[
 586         if test x$withval = xyes; then
 587                 AC_DEFINE(USE_NETRC, 1,
 588                           [Define to use .netrc for FTP connections])
 589                 AC_MSG_NOTICE([ftpfs will use .netrc])
 590         fi
 591 ])
 592
 593 undelfs_o=""
 594
 595 if test $use_vfs = yes; then
 596     AC_ARG_WITH(ext2undel,
 597         [--with-ext2undel           Compile with ext2 undelete code],[
 598         if test x$withval != xno;
 599         then
 600                 if test x$withval != xyes
 601                 then
 602                         LIBS="$LIBS -L$withval/lib"
 603                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 604                 fi
 605                 AC_EXT2_UNDEL
 606         fi],[
 607         dnl Default: detect
 608         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 609     ])
 610 fi
 611
 612 AC_SUBST(undelfs_o)
 613
 614 if $search_ncurses
 615 then
 616     AC_MSG_NOTICE([checking location of ncurses.h file])
 617
 618     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 619     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 620     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 621     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 622
 623     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 624
 625     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 626 fi
 627
 628
 629 dnl Ncurses specific checks
 630 dnl
 631 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 632 dnl or you'll have to press Esc three times to dismiss a dialog box.
 633 dnl
 634 if test -n "$ncurses_version"; then
 635   save_LIBS="$LIBS"
 636   LIBS="$MCLIBS $LIBS"
 637   AC_CACHE_CHECK([for ESCDELAY variable],
 638                  [mc_cv_ncurses_escdelay],
 639                  [AC_TRY_COMPILE([], [
 640                         extern int ESCDELAY;
 641                         int main ()
 642                         {
 643                           ESCDELAY = 0;
 644                         }
 645                         ],
 646                         [mc_cv_ncurses_escdelay=yes],
 647                         [mc_cv_ncurses_escdelay=no]
 648                   )
 649   ])
 650   if test "$mc_cv_ncurses_escdelay" = yes; then
 651     AC_DEFINE(HAVE_ESCDELAY, 1,
 652               [Define if ncurses has ESCDELAY variable])
 653   fi
 654
 655   AC_CHECK_FUNCS(resizeterm)
 656   LIBS="$save_LIBS"
 657 fi
 658
 659 if test "x$screen_manager" = "xunknown"; then
 660     AC_WITH_SLANG
 661 fi
 662
 663 dnl
 664 dnl The variables used for expanding the auto saver.
 665 dnl
 666 cons_saver=""
 667 install_saver="no"
 668 PAMLIBS=""
 669 case $host_os in
 670 linux*)
 671     cons_saver="cons.saver"
 672     install_saver="yes"
 673
 674     dnl
 675     dnl On Linux, check for PAM authentication available
 676     dnl
 677     AC_CHECK_LIB(pam, pam_start, [
 678         AC_DEFINE(HAVE_PAM, 1,
 679                   [Define if PAM (Pluggable Authentication Modules) is available])
 680         PAMLIBS="-lpam -ldl"
 681     ],[],[-ldl])
 682     ;;
 683 esac
 684 AC_SUBST(cons_saver)
 685 AC_SUBST(PAMLIBS)
 686
 687 dnl
 688 dnl User visible support for charset conversion.
 689 dnl
 690 AC_ARG_ENABLE([charset],
 691               [--enable-charset           Support for charset selection and conversion])
 692 have_charset=
 693 if test "x$enable_charset" = xyes; then
 694   if test -z "$am_cv_func_iconv"; then
 695     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 696   else
 697     AC_DEFINE(HAVE_CHARSET, 1,
 698               [Define to enable charset selection and conversion])
 699     have_charset=yes
 700   fi
 701 fi
 702
 703
 704 dnl
 705 dnl This code should be moved to the ac_WITH_SLANG
 706 dnl
 707 dnl We check for the existance of setupterm on curses library
 708 dnl this is required to load certain definitions on some termcaps
 709 dnl editions (AIX and OSF/1 I seem to remember).
 710 dnl Note that we avoid using setupterm
 711 case $screen_manager in
 712 SLang*)
 713         case $host_os in
 714         linux*)
 715                 ;;
 716         *)
 717                 AC_CHECK_LIB(curses,setupterm,
 718                         [AC_TRY_COMPILE([
 719 #include <curses.h>
 720 #include <term.h>],[
 721    if (key_end == parm_insert_line)
 722         return 1;
 723    return 0;
 724 ],
 725                         [MCLIBS="$MCLIBS -lcurses"
 726                         AC_DEFINE(USE_SETUPTERM, 1,
 727                                   [Define to use function `setupterm'
 728 from `curses' library in S-Lang])])
 729                 ])
 730         esac
 731         ;;
 732 esac
 733
 734 LIBS="$LIBS $posix_libs"
 735
 736 AC_SUBST(CFLAGS)
 737 AC_SUBST(CPPFLAGS)
 738 AC_SUBST(LDFLAGS)
 739 AC_SUBST(LIBS)
 740
 741 if test "x$SAMBAFILES" != x; then
 742   AC_CONFIG_SUBDIRS([vfs/samba])
 743 fi
 744
 745 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 746 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 747 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 748 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 749 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 750 AM_CONDITIONAL(MCSERV_INSTALL,
 751                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 752 AM_CONDITIONAL(INCLUDED_SLANG,
 753                [test "x$slang_use_system_installed_lib" = xfalse])
 754 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 755 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 756
 757 AH_BOTTOM([#include <extraconf.h>])
 758
 759 AC_CONFIG_FILES([
 760 Makefile
 761 mc.spec
 762 doc/Makefile
 763 vfs/Makefile:vfs/Make-mc.in
 764 vfs/extfs/Makefile
 765 lib/Makefile
 766 src/Makefile
 767 slang/Makefile
 768 edit/Makefile
 769 syntax/Makefile
 770 pc/Makefile
 771
 772 lib/mc.ext
 773 lib/mc.sh
 774 lib/mc.csh
 775
 776 mcfn_install
 777
 778 vfs/extfs/deb
 779 vfs/extfs/ftplist
 780 vfs/extfs/lslR
 781 vfs/extfs/uar
 782 vfs/extfs/ucpio
 783 vfs/extfs/ulha
 784 vfs/extfs/uha
 785 vfs/extfs/urar
 786 vfs/extfs/uzoo
 787
 788 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 789
 790 intl/Makefile po/Makefile.in
 791 ])
 792
 793 AC_CONFIG_COMMANDS(potfiles,
 794     [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 795
 796 AC_OUTPUT
 797
 798 case $screen_manager in
 799 SLang*)
 800     screen_manager="${screen_manager}${slang_term}" ;;
 801 esac
 802
 803 echo "
 804 Configuration:
 805
 806   Source code location:       ${srcdir}
 807   Compiler:                   ${CC}
 808   Compiler flags:             ${CFLAGS}
 809   File system:                ${vfs_type}
 810                               ${vfs_flags}
 811   Screen manager:             ${screen_manager}
 812   Install console saver:      ${install_saver}
 813   Mouse support:              ${mouse_lib}
 814   X11 events support:         ${textmode_x11_support}
 815   Debugger code:              ${mem_debug}
 816   With subshell support:      ${subshell}
 817   Internal editor:            ${EDIT_msg}
 818   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 819 "