configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU mc], [4.6.0-pre1a], [mc-devel@gnome.org])
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([src/main.c])
   8 AC_CONFIG_AUX_DIR([config])
   9 AM_INIT_AUTOMAKE
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_PROG_LN_S
  15 AC_CANONICAL_HOST
  16
  17 AC_AIX
  18 AC_MINIX
  19 AC_ISC_POSIX
  20
  21 AC_PROG_CC_STDC
  22
  23 AC_HEADER_MAJOR
  24 AC_C_CONST
  25
  26 AC_SYS_LARGEFILE
  27
  28 AC_CHECK_TOOL(AR, ar, ar)
  29
  30 dnl Only list browsers here that can be run in background (i.e. with `&')
  31 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  32
  33 dnl
  34 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  35 dnl We use only part of the functionality of mmap, so on AIX,
  36 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  37 dnl
  38 AC_ARG_WITH(mmap,
  39         [--with-mmap                To force using the mmap call (AIX)],
  40         [case $withval in
  41 yes)
  42         ac_cv_func_mmap_fixed_mapped=yes
  43         AC_MSG_NOTICE([forcing MMAP support])
  44         ;;
  45 no)
  46         ac_cv_func_mmap_fixed_mapped=no
  47         AC_MSG_NOTICE([disabling MMAP support])
  48         ;;
  49 esac])
  50 AC_FUNC_MMAP
  51
  52 if test "x$ALL_LINGUAS" = x; then
  53 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  54 fi
  55
  56 dnl
  57 dnl Internationalization
  58 dnl
  59 AM_GNU_GETTEXT
  60 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  61     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  62 fi
  63
  64 dnl
  65 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  66 dnl
  67 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  68
  69 dnl
  70 dnl Enforce coding standards
  71 dnl
  72 if test "x$GCC" = xyes; then
  73     CFLAGS="$CFLAGS -Wall"
  74 fi
  75
  76 dnl
  77 dnl We now use glib
  78 dnl
  79 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  80 LIBS="$LIBS $GLIB_LIBS"
  81
  82 dnl
  83 dnl OS specific flags.
  84 dnl
  85
  86 posix_libs=""
  87 case $host_os in
  88 aux*)
  89     # A/UX
  90     posix_libs="-lposix"
  91     AC_DEFINE(_POSIX_SOURCE)
  92     ;;
  93 sco*)
  94     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
  95     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
  96     ;;
  97 esac
  98
  99 AC_PROG_INSTALL
 100 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 101         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 102         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h])
 103
 104 AC_HEADER_TIME
 105 AC_HEADER_SYS_WAIT
 106 AC_HEADER_DIRENT
 107 AC_HEADER_STDC
 108
 109 dnl Missing structure components
 110 AC_STRUCT_ST_BLKSIZE
 111 AC_STRUCT_ST_BLOCKS
 112 AC_STRUCT_ST_RDEV
 113
 114 dnl
 115 dnl Check availability of some functions
 116 dnl
 117
 118 AC_CHECK_FUNCS([strerror statfs strftime \
 119                 memmove pwdauth truncate initgroups putenv \
 120                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 121                 sigaction sigemptyset sigprocmask sigaddset \
 122                 sysconf setuid setreuid telldir seekdir])
 123
 124 dnl
 125 dnl getpt is a GNU Extension (glibc 2.1.x)
 126 dnl
 127 AC_CHECK_FUNCS(getpt)
 128
 129 SHADOWLIB=
 130 case $host_os in
 131 linux*)
 132     AC_CHECK_LIB(shadow,pw_encrypt,
 133         [shadow_header=
 134         AC_CHECK_HEADERS([shadow.h shadow/shadow.h],
 135                          [shadow_header=yes; break])
 136         if test -n "$shadow_header"; then
 137             AC_DEFINE(LINUX_SHADOW, 1,
 138                       [Define to use shadow passwords on Linux])
 139             SHADOWLIB=-lshadow
 140         fi])
 141     ;;
 142 esac
 143 AC_SUBST(SHADOWLIB)
 144
 145 NEED_CRYPT_PROTOTYPE=yes
 146 if test x$ac_cv_header_crypt_h = xyes; then
 147 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 148 if (p)
 149 return 0;],[
 150 NEED_CRYPT_PROTOTYPE=no])
 151 else
 152     if test x$ac_cv_header_unistd_h = xyes; then
 153 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 154 if (p)
 155 return 0;],[
 156 NEED_CRYPT_PROTOTYPE=no])
 157     fi
 158 fi
 159 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 160 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 161           [Define if function `crypt' needs a prototype])
 162 fi
 163
 164 dnl
 165 dnl On SCO and some SVR4, crypt is on libcrypt.a
 166 dnl         grantpt in  libpt.a
 167 dnl
 168 LCRYPT=""
 169 AC_CHECK_FUNCS(crypt, , [
 170     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 171         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 172 AC_SUBST(LCRYPT)
 173
 174 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 175
 176 dnl replacing lstat with statlstat on sco makes it more portable between
 177 dnl sco clones
 178 AC_CHECK_FUNCS(statlstat)
 179
 180 dnl
 181 dnl If running under AIX, AC_AIX does not tell us that
 182 dnl
 183 AC_MSG_CHECKING([for AIX defines])
 184 AC_EGREP_CPP(yes,
 185 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 186 yes
 187 #endif
 188 ], [
 189 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 190 AC_MSG_RESULT(yes)
 191 ], [AC_MSG_RESULT(no)])
 192
 193 dnl
 194 dnl This is from GNU fileutils, check aclocal.m4 for more information
 195 dnl
 196 AC_GET_FS_INFO
 197
 198 dnl
 199 dnl Missing typedefs and replacements
 200 dnl
 201
 202 AC_TYPE_MODE_T
 203 AC_CHECK_TYPE(umode_t, int)
 204 AC_CHECK_TYPE(off_t, long)
 205 AC_TYPE_PID_T
 206 AC_TYPE_UID_T
 207 AC_CHECK_TYPE(nlink_t, unsigned int)
 208
 209 AC_FUNC_ALLOCA
 210 AC_FUNC_STRCOLL
 211
 212 dnl
 213 dnl X11 support.
 214 dnl
 215
 216 dnl These variables are only used when building the MC binary
 217 MCCFLAGS=""
 218 MCLIBS=""
 219 AC_SUBST(MCCFLAGS)
 220 AC_SUBST(MCLIBS)
 221
 222 textmode_x11_support="no"
 223 AC_ARG_WITH(tm-x-support,
 224         [--with-tm-x-support        Try getting events from X Window System],
 225         [if test x$withval = xyes; then
 226                 AC_PATH_XTRA
 227                 MCCFLAGS="$X_CFLAGS"
 228                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 229                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 230                           [Define to enable getting events from X Window System])
 231                 textmode_x11_support="yes"
 232         fi
 233 ])
 234
 235 dnl
 236 dnl Network related functions
 237 dnl
 238
 239 AC_CHECK_LIB(nsl, t_accept)
 240 AC_CHECK_LIB(socket, socket)
 241
 242 have_socket=no
 243 AC_CHECK_FUNCS(socket, have_socket=yes)
 244 if test $have_socket = no; then
 245   # socket is not in the default libraries.  See if it's in some other.
 246   for lib in bsd socket inet; do
 247     AC_CHECK_LIB($lib, socket, [
 248         LIBS="$LIBS -l$lib"
 249         have_socket=yes
 250         AC_DEFINE(HAVE_SOCKET)
 251         break])
 252   done
 253 fi
 254
 255 have_gethostbyname=no
 256 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 257 if test $have_gethostbyname = no; then
 258   # gethostbyname is not in the default libraries.  See if it's in some other.
 259   for lib in bsd socket inet; do
 260     AC_CHECK_LIB([$lib], [gethostbyname],
 261                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 262   done
 263 fi
 264
 265 AC_CHECK_FUNCS(socketpair)
 266
 267 dnl
 268 dnl Sequent wants getprocessstats
 269 dnl
 270 AC_CHECK_LIB(seq, get_process_stats, [
 271         LIBS="$LIBS -lseq"
 272         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 273                   [Define if you have function `get_process_stats' and
 274 have to use that instead of gettimeofday])])
 275
 276 MC_VFS_CHECKS
 277
 278 dnl
 279 dnl Install mcserv only if explicitly enabled
 280 dnl
 281 AC_ARG_ENABLE([mcserv-install],
 282               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 283
 284 NETFILES=
 285 if test $have_socket = yes; then
 286    NETFILES="\$(NETFILES)"
 287 fi
 288 AC_SUBST(NETFILES)
 289
 290 vfs_type="normal"
 291 if test $use_vfs = yes
 292 then
 293         AC_MSG_NOTICE([enabling VFS code])
 294         vfs_type="Midnight Commander Virtual File System"
 295 fi
 296
 297 dnl This should be unadorned "slang" or "ncurses"
 298 screen_type=""
 299
 300 dnl Screen manager name (for the output only)
 301 screen_manager=unknown
 302
 303 mouse_lib="xterm only"
 304 case $host_os in
 305 linux*)
 306     AC_ARG_WITH(gpm-mouse,
 307         [--with-gpm-mouse[=base-dir]  Compile with gpm mouse support (Linux only)],
 308         [if test x$withval != xno
 309         then
 310                 if test x$withval != xyes
 311                 then
 312                         LIBS="$LIBS -L$withval/lib"
 313                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 314                 fi
 315                 AC_DEFINE(HAVE_LIBGPM, 1,
 316                           [Define to enable gpm mouse support on Linux])
 317                 mouse_lib="GPM and xterm"
 318                 MCLIBS="-lgpm $MCLIBS"
 319         fi],
 320         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 321                 [AC_DEFINE(HAVE_LIBGPM)
 322                 mouse_lib="GPM and xterm"
 323                 MCLIBS="-lgpm $MCLIBS"],
 324                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 325                 [$LIBS])
 326         ])
 327     ;;
 328 esac
 329
 330 AC_ARG_WITH(ncurses,
 331         [--with-ncurses[=base-dir]    Compile with ncurses/locate base dir],
 332         [if test x$withval != xyes; then
 333                 MCLIBS="$MCLIBS -L$withval/lib"
 334                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 335         fi
 336
 337         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 338                          [ncurses_h_found=yes; break])
 339         if test -z "$ncurses_h_found"; then
 340             AC_MSG_ERROR([Could not find ncurses header])
 341         fi
 342
 343         dnl curses_version is specific to ncurses, it's not in old curses
 344         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 345                      [AC_MSG_ERROR([Could not find ncurses library])])
 346
 347         screen_type="ncurses"
 348         screen_manager="ncurses"
 349         AC_DEFINE(USE_NCURSES, 1,
 350                   [Define to use ncurses for screen management])
 351 ])
 352
 353 AC_ARG_WITH(hsc,
 354         [--with-hsc                 Compile with support for the HSC firewall],
 355         [if test x$withval = xyes; then
 356                 AC_DEFINE(HSC_PROXY, 1,
 357                           [Define if you want to use the HSC firewall])
 358         fi
 359 ])
 360
 361 dnl
 362 dnl Check for the -mandoc package
 363 dnl
 364 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 365 if $HAVE_nroff; then
 366     AC_MSG_CHECKING([for manual formatting macros])
 367     AC_CACHE_VAL(ac_cv_mandoc, [
 368     nroff -mandoc < /dev/null > /dev/null 2>&1
 369     if test $? = 0
 370     then
 371         ac_cv_mandoc=-mandoc
 372     else
 373         ac_cv_mandoc=-man
 374     fi
 375     ])
 376     MANDOC=$ac_cv_mandoc
 377     AC_MSG_RESULT([$MANDOC])
 378 else
 379     MANDOC=-man
 380 fi
 381 AC_SUBST(MANDOC)
 382
 383 dnl
 384 dnl Check if nroff accepts -Tlatin1 or -Tascii
 385 dnl
 386 if $HAVE_nroff; then
 387     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 388     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 389     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 390     if test $? = 0
 391     then
 392         ac_cv_nroff_tascii=" -Tlatin1"
 393     else
 394         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 395         if test $? = 0
 396         then
 397             ac_cv_nroff_tascii=" -Tascii"
 398         else
 399             ac_cv_nroff_tascii=""
 400         fi
 401     fi
 402     ])
 403     if test "x$ac_cv_nroff_tascii" = x; then
 404         AC_MSG_RESULT([no])
 405     else
 406         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 407     fi
 408 fi
 409 TROFFASCII="$ac_cv_nroff_tascii"
 410 AC_SUBST(TROFFASCII)
 411
 412 dnl
 413 dnl Check for - option to file
 414 dnl
 415 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 416 if $HAVE_FILECMD; then
 417     AC_MSG_CHECKING([for - option to file command])
 418     AC_CACHE_VAL(ac_cv_filestdin, [[
 419     cat > conftest.c <<\EOF
 420 /* A comment */
 421 #if 0
 422 #endif
 423 void main(void)
 424 { return; }
 425 EOF
 426     cat > conftest.sed <<\EOF
 427 s/^[^:]*:[      ]*//
 428 s/[     ]*$//
 429 EOF
 430     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 431     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 432     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 433         ac_cv_filestdin=yes
 434     else
 435         ac_cv_filestdin=no
 436     fi
 437     rm conftest.c conftest.sed
 438     ]])
 439
 440     if test x$ac_cv_filestdin = xyes; then
 441         AC_DEFINE(FILE_STDIN, 1,
 442                   [Define if the file command accepts - for stdin])
 443     fi
 444     filestdin=$ac_cv_filestdin
 445     AC_MSG_RESULT([$filestdin])
 446
 447     dnl
 448     dnl Check for -L option to file
 449     dnl
 450
 451 AC_MSG_CHECKING([for -L option to file command])
 452 AC_CACHE_VAL(ac_cv_filel, [
 453 file -L . > /dev/null 2>&1
 454 if test $? = 0
 455 then
 456     ac_cv_filel=yes
 457 else
 458     ac_cv_filel=no
 459 fi
 460 ])
 461 if test x$ac_cv_filel = xyes; then
 462     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 463 fi
 464 filel=$ac_cv_filel
 465 AC_MSG_RESULT([$filel])
 466 fi
 467
 468
 469 AC_MSG_CHECKING([for subshell support])
 470 AC_ARG_WITH(subshell,
 471         [--with-subshell=optional   To disable concurrent shell by default
 472 --without-subshell         To disable concurrent shell completely],
 473         [result=no
 474         if test x$withval = xoptional
 475         then
 476                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 477                           [Define to make subshell support optional])
 478                 result="optional"
 479         fi
 480         if test x$withval = xyes
 481         then
 482                 result="yes"
 483         fi],
 484         [dnl Default: enable the subshell support
 485         result="yes"
 486 ])
 487 if test "x$result" != xno; then
 488         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 489                   [Define to enable subshell support])
 490 fi
 491 AC_MSG_RESULT([$result])
 492 subshell="$result"
 493
 494 if test "x$screen_type" != xncurses; then
 495         slang_check_lib=true
 496         slang_term=""
 497         slang_use_system_installed_lib=false
 498         AC_CHECK_LIB(slang,SLang_init_tty,
 499                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 500                                   [slang_h_found=yes; break])
 501                 if test "x$slang_h_found" = xyes; then
 502                      slang_use_system_installed_lib=true
 503                      slang_check_lib=false
 504                 fi
 505         ])
 506 fi
 507
 508 AC_ARG_WITH(terminfo,
 509         [--with-terminfo            SLANG: Force usage of terminfo],[
 510         if test x$withval = xyes; then
 511                 AC_USE_TERMINFO
 512                 slang_check_lib=false
 513                 slang_use_system_installed_lib=false
 514         fi]
 515 )
 516
 517 AC_ARG_WITH(termcap,
 518         [--with-termcap             SLANG: Force usage of termcap],[
 519         if test x$withval = xyes; then
 520                 AC_USE_TERMCAP
 521                 slang_check_lib=false
 522                 slang_use_system_installed_lib=false
 523         fi]
 524 )
 525
 526 AC_ARG_WITH(included-slang,
 527         [--with-included-slang      SLANG: use the SLang library included here],[
 528         if test x$withval = xyes; then
 529             slang_use_system_installed_lib=false
 530             slang_check_lib=true
 531         fi]
 532 )
 533
 534 AC_ARG_WITH(slang,
 535         [--with-slang              Compile with the slang screen manager],[
 536         if test x$withval = xyes; then
 537                 AC_WITH_SLANG
 538         fi
 539 ])
 540
 541 LIBEDIT_A=""
 542 MCEDIT=""
 543 LEDIT=""
 544 EDIT_msg=""
 545 AC_ARG_WITH(edit,
 546         [--with-edit                Enable internal editor],
 547         [if test x$withval = xyes
 548         then
 549                 AC_WITH_EDIT
 550         else
 551                 EDIT_msg="no"
 552         fi],
 553         [dnl Default: provide the internal editor
 554         AC_WITH_EDIT
 555 ])
 556 AC_SUBST(LIBEDIT_A)
 557 AC_SUBST(MCEDIT)
 558 AC_SUBST(LEDIT)
 559
 560 undelfs_o=""
 561
 562 if test $use_vfs = yes; then
 563     AC_ARG_WITH(ext2undel,
 564         [--with-ext2undel           Compile with ext2 undelete code],[
 565         if test x$withval != xno;
 566         then
 567                 if test x$withval != xyes
 568                 then
 569                         LIBS="$LIBS -L$withval/lib"
 570                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 571                 fi
 572                 AC_EXT2_UNDEL
 573         fi],[
 574         dnl Default: detect
 575         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 576     ])
 577 fi
 578
 579 AC_SUBST(undelfs_o)
 580
 581
 582 dnl Ncurses specific checks
 583 dnl
 584 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 585 dnl or you'll have to press Esc three times to dismiss a dialog box.
 586 dnl
 587 if test "x$screen_type" = xncurses; then
 588   save_LIBS="$LIBS"
 589   LIBS="$MCLIBS $LIBS"
 590   AC_CACHE_CHECK([for ESCDELAY variable],
 591                  [mc_cv_ncurses_escdelay],
 592                  [AC_TRY_COMPILE([], [
 593                         extern int ESCDELAY;
 594                         int main ()
 595                         {
 596                           ESCDELAY = 0;
 597                         }
 598                         ],
 599                         [mc_cv_ncurses_escdelay=yes],
 600                         [mc_cv_ncurses_escdelay=no]
 601                   )
 602   ])
 603   if test "$mc_cv_ncurses_escdelay" = yes; then
 604     AC_DEFINE(HAVE_ESCDELAY, 1,
 605               [Define if ncurses has ESCDELAY variable])
 606   fi
 607
 608   AC_CHECK_FUNCS(resizeterm)
 609   LIBS="$save_LIBS"
 610 fi
 611
 612 if test "x$screen_type" = "x"; then
 613     AC_WITH_SLANG
 614 fi
 615
 616 dnl
 617 dnl The variables used for expanding the auto saver.
 618 dnl
 619 cons_saver=""
 620 install_saver="no"
 621 PAMLIBS=""
 622 case $host_os in
 623 linux*)
 624     cons_saver="cons.saver"
 625     install_saver="yes"
 626
 627     dnl
 628     dnl On Linux, check for PAM authentication available
 629     dnl
 630     AC_CHECK_LIB(pam, pam_start, [
 631         AC_DEFINE(HAVE_PAM, 1,
 632                   [Define if PAM (Pluggable Authentication Modules) is available])
 633         PAMLIBS="-lpam -ldl"
 634     ],[],[-ldl])
 635     ;;
 636 esac
 637 AC_SUBST(cons_saver)
 638 AC_SUBST(PAMLIBS)
 639
 640 dnl
 641 dnl User visible support for charset conversion.
 642 dnl
 643 AC_ARG_ENABLE([charset],
 644               [--enable-charset           Support for charset selection and conversion])
 645 have_charset=
 646 if test "x$enable_charset" = xyes; then
 647   if test -z "$am_cv_func_iconv"; then
 648     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 649   else
 650     AC_DEFINE(HAVE_CHARSET, 1,
 651               [Define to enable charset selection and conversion])
 652     have_charset=yes
 653   fi
 654 fi
 655
 656 if test "$GLIBC21" != yes; then
 657     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 658 fi
 659
 660 dnl
 661 dnl This code should be moved to the ac_WITH_SLANG
 662 dnl
 663 dnl We check for the existance of setupterm on curses library
 664 dnl this is required to load certain definitions on some termcaps
 665 dnl editions (AIX and OSF/1 I seem to remember).
 666 dnl Note that we avoid using setupterm
 667 if test "x$screen_type" = xslang; then
 668         case $host_os in
 669         linux*)
 670                 ;;
 671         *)
 672                 AC_CHECK_LIB(curses,setupterm,
 673                         [AC_TRY_COMPILE([
 674 #include <curses.h>
 675 #include <term.h>],[
 676    if (key_end == parm_insert_line)
 677         return 1;
 678    return 0;
 679 ],
 680                         [MCLIBS="$MCLIBS -lcurses"
 681                         AC_DEFINE(USE_SETUPTERM, 1,
 682                                   [Define to use function `setupterm'
 683 from `curses' library in S-Lang])])
 684                 ])
 685         esac
 686 fi
 687
 688 LIBS="$LIBS $posix_libs"
 689
 690 AC_SUBST(CFLAGS)
 691 AC_SUBST(CPPFLAGS)
 692 AC_SUBST(LDFLAGS)
 693 AC_SUBST(LIBS)
 694
 695 if test "x$SAMBAFILES" != x; then
 696   AC_CONFIG_SUBDIRS([vfs/samba])
 697 fi
 698
 699 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 700 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 701 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 702 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 703 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 704 AM_CONDITIONAL(MCSERV_INSTALL,
 705                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 706 AM_CONDITIONAL(INCLUDED_SLANG,
 707                [test "x$slang_use_system_installed_lib" = xfalse])
 708 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 709 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 710
 711 AH_BOTTOM([#include <extraconf.h>])
 712
 713 AC_CONFIG_FILES([
 714 Makefile
 715 mc.spec
 716 doc/Makefile
 717 vfs/Makefile
 718 vfs/extfs/Makefile
 719 lib/Makefile
 720 src/Makefile
 721 slang/Makefile
 722 edit/Makefile
 723 syntax/Makefile
 724 pc/Makefile
 725
 726 lib/mc.ext
 727 lib/mc.sh
 728 lib/mc.csh
 729
 730 mcfn_install
 731
 732 vfs/extfs/deb
 733 vfs/extfs/ftplist
 734 vfs/extfs/lslR
 735 vfs/extfs/uar
 736 vfs/extfs/ucpio
 737 vfs/extfs/ulha
 738 vfs/extfs/uha
 739 vfs/extfs/urar
 740 vfs/extfs/uzoo
 741
 742 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 743 doc/es/mc.1 doc/es/Makefile
 744 doc/hu/Makefile
 745 doc/it/mc.1 doc/it/Makefile
 746 doc/ru/mc.1 doc/ru/Makefile
 747
 748 intl/Makefile po/Makefile.in
 749 ])
 750
 751 AC_CONFIG_COMMANDS(potfiles,
 752     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 753
 754 AC_OUTPUT
 755
 756 if test "x$screen_type" = xslang; then
 757     screen_manager="${screen_manager}${slang_term}"
 758 fi
 759
 760 echo "
 761 Configuration:
 762
 763   Source code location:       ${srcdir}
 764   Compiler:                   ${CC}
 765   Compiler flags:             ${CFLAGS}
 766   File system:                ${vfs_type}
 767                               ${vfs_flags}
 768   Screen manager:             ${screen_manager}
 769   Install console saver:      ${install_saver}
 770   Mouse support:              ${mouse_lib}
 771   X11 events support:         ${textmode_x11_support}
 772   Debugger code:              ${mem_debug}
 773   With subshell support:      ${subshell}
 774   Internal editor:            ${EDIT_msg}
 775   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 776 "