configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.60)
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_SRCDIR(src/main.c)
  10 AC_CONFIG_AUX_DIR(config)
  11 MC_VERSION
  12 AM_INIT_AUTOMAKE(mc, ${VERSION} )
  13
  14 LIBMC_VERSION="0.0.1"
  15 LIBMC_RELEASE="1"
  16 AC_SUBST(LIBMC_VERSION)
  17 AC_SUBST(LIBMC_RELEASE)
  18
  19 dnl Enable silent rules by default (if yes)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AM_CONFIG_HEADER(config.h)
  23 AM_MAINTAINER_MODE
  24 AC_CANONICAL_HOST
  25
  26 AC_USE_SYSTEM_EXTENSIONS
  27
  28 AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS],["$ac_configure_args"],[MC configure arguments])
  29
  30 AC_PROG_LIBTOOL
  31 PKG_PROG_PKG_CONFIG
  32 AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
  33
  34 AC_ISC_POSIX
  35
  36 AC_PROG_CC_STDC
  37 AM_PROG_CC_C_O
  38
  39 dnl Doxygen
  40
  41 DX_HTML_FEATURE(ON)
  42 DX_CHM_FEATURE(OFF)
  43 DX_CHI_FEATURE(OFF)
  44 DX_MAN_FEATURE(OFF)
  45 DX_RTF_FEATURE(OFF)
  46 DX_XML_FEATURE(OFF)
  47 DX_PDF_FEATURE(OFF)
  48 DX_PS_FEATURE(OFF)
  49 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
  50
  51 dnl PKG_CHECK_MODULES([CHECK], [check >= 0.9.4])
  52
  53 AC_CHECK_GLIB
  54
  55 AC_ARG_ENABLE([mclib],
  56         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
  57         [
  58             if test "x$enableval" = "xno" ; then
  59                 enable_mclib=no
  60             else
  61                 if test "x$enable_shared" = "xno" ; then
  62                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
  63                     enable_mclib=no
  64                 else
  65                     enable_mclib=yes
  66                 fi
  67             fi
  68         ],
  69         [enable_mclib=no])
  70
  71 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
  72
  73 AC_HEADER_MAJOR
  74 AC_C_CONST
  75 dnl Check this before type sizeof checks
  76 AC_SYS_LARGEFILE
  77
  78 AC_PROG_LN_S
  79 AC_CHECK_TOOL(AR, ar, ar)
  80
  81 dnl Only list browsers here that can be run in background (i.e. with `&')
  82 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
  83
  84 dnl
  85 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  86 dnl We use only part of the functionality of mmap, so on AIX,
  87 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  88 dnl
  89 AC_ARG_WITH(mmap,
  90         [  --with-mmap              Use the mmap call [[yes if found]]])
  91 if test x$with_mmap != xno; then
  92     if test x$with_mmap = x; then
  93         AC_FUNC_MMAP
  94     else
  95         AC_DEFINE(HAVE_MMAP, 1)
  96     fi
  97 fi
  98
  99 dnl
 100 dnl Internationalization
 101 dnl
 102 AM_GNU_GETTEXT(no-libtool, need-ngettext)
 103 AM_GNU_GETTEXT_VERSION(0.14.3)
 104
 105 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
 106     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
 107 fi
 108
 109 dnl Determine which help translations we want to install.
 110 ALL_DOC_LINGUAS="es hu it pl ru sr"
 111
 112 DOC_LINGUAS=
 113 if test "x$USE_NLS" = xyes; then
 114     if test -z "$LINGUAS"; then
 115         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 116     else
 117         langs="$LINGUAS"
 118     fi
 119 else
 120     langs=
 121 fi
 122
 123 for h_lang in $ALL_DOC_LINGUAS; do
 124     for lang in $langs; do
 125         if test "$lang" = "$h_lang"; then
 126             DOC_LINGUAS="$DOC_LINGUAS $lang"
 127             break
 128         fi
 129     done
 130 done
 131 AC_SUBST(DOC_LINGUAS)
 132
 133 dnl
 134 dnl OS specific flags.
 135 dnl
 136 case $host_os in
 137 aux*)
 138     # A/UX
 139     LIBS="$LIBS -lposix"
 140     AC_DEFINE(_POSIX_SOURCE)
 141     ;;
 142 esac
 143
 144 AC_PROG_INSTALL
 145 AC_CHECK_HEADERS([unistd.h string.h memory.h limits.h malloc.h \
 146         utime.h fcntl.h sys/statfs.h sys/vfs.h sys/time.h \
 147         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 148         sys/socket.h sys/sysmacros.h sys/types.h sys/mkdev.h])
 149
 150 AC_HEADER_TIME
 151 AC_HEADER_DIRENT
 152 AC_HEADER_ASSERT
 153
 154 dnl Missing structure components
 155 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev])
 156 AC_STRUCT_ST_BLOCKS
 157
 158 dnl
 159 dnl Check availability of some functions
 160 dnl
 161
 162 AC_CHECK_FUNCS([\
 163         atoll \
 164         isascii \
 165         statfs sysconf \
 166         tcgetattr tcsetattr \
 167         ftruncate \
 168         strverscmp \
 169         strncasecmp \
 170         realpath
 171 ])
 172
 173 dnl
 174 dnl getpt is a GNU Extension (glibc 2.1.x)
 175 dnl
 176 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 177 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 178
 179 dnl replacing lstat with statlstat on sco makes it more portable between
 180 dnl sco clones
 181 AC_CHECK_FUNCS(statlstat)
 182
 183 dnl
 184 dnl If running under AIX, AC_AIX does not tell us that
 185 dnl
 186 AC_MSG_CHECKING([for AIX defines])
 187 AC_EGREP_CPP(yes,
 188 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 189 yes
 190 #endif
 191 ], [
 192 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 193 AC_MSG_RESULT(yes)
 194 ], [AC_MSG_RESULT(no)])
 195
 196 dnl
 197 dnl Missing typedefs and replacements
 198 dnl
 199
 200 AC_CHECK_SIZEOF(long)
 201 AC_TYPE_UINTMAX_T
 202 AC_CHECK_SIZEOF(uintmax_t)
 203 AC_TYPE_OFF_T
 204 AC_CHECK_SIZEOF(off_t)
 205 AC_TYPE_MODE_T
 206 AC_TYPE_PID_T
 207 AC_TYPE_UID_T
 208
 209 AC_FUNC_STRCOLL
 210
 211 AC_MC_GET_FS_INFO
 212
 213 dnl
 214 dnl X11 support.
 215 dnl Used to read keyboard modifiers when running under X11.
 216 AC_PATH_XTRA
 217
 218 dnl
 219 dnl Check if the gmodule functionality supported on this system.
 220 AC_G_MODULE_SUPPORTED
 221
 222 dnl
 223 dnl Sequent wants getprocessstats
 224 dnl
 225 AC_CHECK_LIB(seq, get_process_stats, [
 226         LIBS="$LIBS -lseq"
 227         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 228                   [Define if you have function `get_process_stats' and
 229 have to use that instead of gettimeofday])])
 230
 231 AC_MC_VFS_CHECKS
 232
 233 dnl
 234 dnl Check for gpm mouse support (Linux only)
 235 dnl
 236 mouse_lib="xterm only"
 237 AC_ARG_WITH(gpm-mouse,
 238         [  --with-gpm-mouse         Compile with gpm mouse support (Linux only)
 239                            [[yes if found]]])
 240
 241 case $host_os in
 242 linux*)
 243     if test x$with_gpm_mouse != xno; then
 244         AC_CHECK_LIB(gpm, Gpm_Repeat,
 245             [AC_DEFINE(HAVE_LIBGPM, 1,
 246                        [Define to enable gpm mouse support on Linux])
 247             mouse_lib="gpm and xterm"
 248             MCLIBS="$MCLIBS -lgpm"],
 249             if test "x$with_gpm_mouse" = "xyes"; then
 250                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 251             else
 252                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 253             fi
 254         )
 255     fi
 256     ;;
 257 esac
 258
 259 MC_CHECK_SEARCH_TYPE
 260
 261 dnl
 262 dnl Check nroff and the options it supports
 263 dnl
 264 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 265
 266 dnl Default values
 267 MANDOC=-man
 268 MAN_FLAGS=
 269
 270 if $HAVE_nroff; then
 271     AC_MSG_CHECKING([for manual formatting macros])
 272     AC_CACHE_VAL(mc_cv_mandoc, [
 273     nroff -mandoc < /dev/null > /dev/null 2>&1
 274     if test $? = 0; then
 275         mc_cv_mandoc=-mandoc
 276     else
 277         mc_cv_mandoc=-man
 278     fi
 279     ])
 280     MANDOC=$mc_cv_mandoc
 281     AC_MSG_RESULT([$MANDOC])
 282
 283     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 284     AC_CACHE_VAL(mc_cv_man_nocolor, [
 285     nroff -c < /dev/null > /dev/null 2>&1
 286     if test $? = 0; then
 287         mc_cv_man_nocolor=-c
 288     else
 289         mc_cv_man_nocolor=
 290     fi
 291     ])
 292     MAN_FLAGS=$mc_cv_man_nocolor
 293     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 294
 295     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 296     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 297     mc_cv_nroff_tascii=
 298     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 299     if test $? = 0; then
 300         mc_cv_nroff_tascii=-Tlatin1
 301     else
 302         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 303         if test $? = 0; then
 304             mc_cv_nroff_tascii=-Tascii
 305         fi
 306     fi
 307     ])
 308     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 309     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 310 fi
 311
 312 AC_SUBST(MANDOC)
 313 AC_SUBST(MAN_FLAGS)
 314
 315
 316 dnl
 317 dnl Check for -L option to file
 318 dnl
 319 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 320 if $HAVE_FILECMD; then
 321     AC_MSG_CHECKING([for -L option to file command])
 322     AC_CACHE_VAL(mc_cv_filel, [
 323     file -L . > /dev/null 2>&1
 324     if test $? = 0; then
 325         mc_cv_filel=yes
 326     else
 327         mc_cv_filel=no
 328     fi
 329     ])
 330     if test x$mc_cv_filel = xyes; then
 331         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 332     fi
 333     filel=$mc_cv_filel
 334     AC_MSG_RESULT([$filel])
 335 fi
 336
 337
 338 AC_MSG_CHECKING([for subshell support])
 339 AC_ARG_WITH(subshell,
 340         [  --with-subshell          Compile in concurrent subshell [[yes]]
 341   --with-subshell=optional Don't run concurrent shell by default [[no]]],
 342         [result=no
 343         if test x$withval = xoptional
 344         then
 345                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 346                           [Define to make subshell support optional])
 347                 result="optional"
 348         fi
 349         if test x$withval = xyes
 350         then
 351                 result="yes"
 352         fi],
 353         [dnl Default: enable the subshell support
 354         result="yes"
 355 ])
 356 if test "x$result" != xno; then
 357         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 358                   [Define to enable subshell support])
 359 fi
 360 AC_MSG_RESULT([$result])
 361 subshell="$result"
 362
 363
 364 MC_WITH_SCREEN
 365
 366
 367 dnl
 368 dnl Internal editor support.
 369 dnl
 370 AC_ARG_WITH(edit,
 371         [  --with-edit              Enable internal editor [[yes]]])
 372
 373 if test x$with_edit != xno; then
 374         AC_DEFINE(USE_INTERNAL_EDIT, 1, [Define to enable internal editor])
 375         use_edit=yes
 376         edit_msg="yes"
 377         AC_MSG_NOTICE([using internal editor])
 378 else
 379         edit_msg="no"
 380 fi
 381
 382 dnl
 383 dnl Diff viewer support.
 384 dnl
 385 AC_ARG_WITH(diff_viewer,
 386         [  --with-diff-viewer       Compile with diff viewer [[yes]]])
 387
 388 if test x$with_diff_viewer != xno; then
 389         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 390         use_diff=yes
 391         diff_msg="yes"
 392         AC_MSG_NOTICE([using diff viewer])
 393 else
 394         diff_msg="no"
 395 fi
 396
 397
 398 dnl Check if the OS is supported by the console saver.
 399 cons_saver=""
 400 case $host_os in
 401 linux*)
 402     cons_saver=yes
 403 esac
 404
 405
 406 dnl
 407 dnl Where config files should be placed
 408 dnl
 409
 410 AC_ARG_WITH([homedir],
 411     AS_HELP_STRING([--with-homedir], [Choose any place of user settings relative to home dir, or XDG for respect XDG standards @<:@XDG@:>@]),
 412     [
 413         if test "x$withval" = "xXDG"; then
 414             with_homedir=XDG
 415         else
 416             with_homedir=$withval
 417         fi
 418     ],
 419     [with_homedir=XDG])
 420
 421
 422 if test x$with_homedir = xXDG; then
 423     AC_DEFINE(MC_HOMEDIR_XDG, 1,
 424         [Define to enable XDG standard support])
 425 else
 426     AC_DEFINE_UNQUOTED([MC_USERCONF_DIR], ["$with_homedir"], [Where configs will be placed relative to $HOME])
 427 fi
 428
 429
 430 MC_BACKGROUND
 431
 432
 433 dnl
 434 dnl User visible support for charset conversion.
 435 dnl
 436 AC_ARG_ENABLE([charset],
 437               [  --enable-charset        Support for charset selection and conversion [[yes]]])
 438 have_charset=
 439 charset_msg="no"
 440 if test "x$enable_charset" != "xno"; then
 441     AC_DEFINE(HAVE_CHARSET, 1,
 442               [Define to enable charset selection and conversion])
 443     have_charset=yes
 444     charset_msg="yes"
 445 fi
 446
 447 if test "$GLIBC21" != yes; then
 448     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 449 fi
 450
 451 MC_CHECK_CFLAGS
 452
 453 CFLAGS_OPTS=""
 454
 455 if test "x$CFLAGS" = "x"; then
 456     CFLAGS_OPTS=" -O2 "
 457 fi
 458
 459 if test x$USE_MAINTAINER_MODE = xyes; then
 460     CFLAGS_OPTS="-g3 -O -ggdb"
 461     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
 462 fi
 463
 464 AC_ARG_ENABLE(
 465     [werror],
 466     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors])
 467 )
 468
 469 if test "x$enable_werror" = xyes; then
 470     MC_CHECK_ONE_CFLAG([-Werror])
 471 fi
 472 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 473
 474 MC_UNIT_TESTS
 475
 476 AC_SUBST(CFLAGS)
 477 AC_SUBST(CPPFLAGS)
 478 AC_SUBST(LDFLAGS)
 479 AC_SUBST(LIBS)
 480
 481 dnl Libraries used only when building the mc binary
 482 AC_SUBST(MCLIBS)
 483
 484 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 485 AC_SUBST(MAN_DATE)
 486
 487 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 488 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 489 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 490 AM_CONDITIONAL(USE_EDIT, [test -n "$use_edit"])
 491 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 492 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 493 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 494
 495 AC_CONFIG_FILES(
 496 [
 497 src/man2hlp/man2hlp
 498 ],
 499 [
 500 chmod +x src/man2hlp/man2hlp
 501 ])
 502
 503 AC_CONFIG_FILES([
 504 Makefile
 505
 506 contrib/Makefile
 507 contrib/dist/Makefile
 508 contrib/dist/debian/Makefile
 509 contrib/dist/gentoo/Makefile
 510 contrib/dist/redhat/Makefile
 511 contrib/dist/redhat/mc.spec
 512 contrib/dist/pkginfo
 513 contrib/dist/prototype
 514
 515 misc/Makefile
 516 misc/skins/Makefile
 517 misc/macros.d/Makefile
 518 misc/mc.ext
 519
 520 src/Makefile
 521 src/consaver/Makefile
 522 src/editor/Makefile
 523 src/man2hlp/Makefile
 524 src/viewer/Makefile
 525 src/diffviewer/Makefile
 526 src/filemanager/Makefile
 527
 528 src/vfs/Makefile
 529
 530 src/vfs/cpio/Makefile
 531
 532 src/vfs/extfs/Makefile
 533 src/vfs/extfs/helpers/Makefile
 534 src/vfs/extfs/helpers/a+
 535 src/vfs/extfs/helpers/apt+
 536 src/vfs/extfs/helpers/audio
 537 src/vfs/extfs/helpers/deb
 538 src/vfs/extfs/helpers/deba
 539 src/vfs/extfs/helpers/debd
 540 src/vfs/extfs/helpers/dpkg+
 541 src/vfs/extfs/helpers/iso9660
 542 src/vfs/extfs/helpers/hp48+
 543 src/vfs/extfs/helpers/lslR
 544 src/vfs/extfs/helpers/mailfs
 545 src/vfs/extfs/helpers/patchfs
 546 src/vfs/extfs/helpers/rpms+
 547 src/vfs/extfs/helpers/s3+
 548 src/vfs/extfs/helpers/uace
 549 src/vfs/extfs/helpers/ualz
 550 src/vfs/extfs/helpers/uar
 551 src/vfs/extfs/helpers/uarc
 552 src/vfs/extfs/helpers/uarj
 553 src/vfs/extfs/helpers/uc1541
 554 src/vfs/extfs/helpers/ucab
 555 src/vfs/extfs/helpers/uha
 556 src/vfs/extfs/helpers/ulha
 557 src/vfs/extfs/helpers/urar
 558 src/vfs/extfs/helpers/uzip
 559 src/vfs/extfs/helpers/uzoo
 560
 561 src/vfs/fish/Makefile
 562 src/vfs/fish/helpers/Makefile
 563
 564 src/vfs/ftpfs/Makefile
 565
 566 src/vfs/local/Makefile
 567
 568 src/vfs/sfs/Makefile
 569
 570 src/vfs/smbfs/Makefile
 571
 572 src/vfs/tar/Makefile
 573
 574 src/vfs/undelfs/Makefile
 575
 576 lib/Makefile
 577 lib/event/Makefile
 578 lib/filehighlight/Makefile
 579 lib/mcconfig/Makefile
 580 lib/search/Makefile
 581 lib/skin/Makefile
 582 lib/strutil/Makefile
 583 lib/tty/Makefile
 584
 585 lib/vfs/Makefile
 586
 587 lib/widget/Makefile
 588
 589 misc/syntax/Makefile
 590
 591 doc/Makefile
 592 doc/hints/Makefile
 593 doc/man/mc.1 doc/man/mcedit.1 doc/man/mcview.1 doc/man/Makefile
 594 doc/man/es/mc.1 doc/man/es/Makefile
 595 doc/man/hu/mc.1 doc/man/hu/Makefile
 596 doc/man/it/mc.1 doc/man/it/Makefile
 597 doc/man/pl/mc.1 doc/man/pl/Makefile
 598 doc/man/ru/mc.1 doc/man/ru/Makefile
 599 doc/man/sr/mc.1 doc/man/sr/Makefile
 600
 601 doc/hlp/Makefile
 602 doc/hlp/es/Makefile
 603 doc/hlp/hu/Makefile
 604 doc/hlp/it/Makefile
 605 doc/hlp/pl/Makefile
 606 doc/hlp/ru/Makefile
 607 doc/hlp/sr/Makefile
 608
 609 intl/Makefile
 610 po/Makefile.in
 611 ])
 612
 613 if test x$enable_tests != xno; then
 614     AC_CONFIG_FILES([
 615 tests/Makefile
 616 tests/lib/Makefile
 617 tests/lib/mcconfig/Makefile
 618 tests/lib/search/Makefile
 619 tests/lib/vfs/Makefile
 620 tests/src/Makefile
 621 tests/src/filemanager/Makefile
 622 ])
 623
 624 fi
 625
 626
 627 AC_OUTPUT
 628
 629 echo "
 630 Configuration:
 631
 632   Source code location:       ${srcdir}
 633   Compiler:                   ${CC}
 634   Compiler flags:             ${CFLAGS}
 635   File system:                ${vfs_type}
 636                               ${vfs_flags}
 637   Screen library:             ${screen_msg}
 638   Mouse support:              ${mouse_lib}
 639   X11 events support:         ${textmode_x11_support}
 640   With subshell support:      ${subshell}
 641   With background operations: ${enable_background}
 642   Internal editor:            ${edit_msg}
 643   Diff viewer:                ${diff_msg}
 644   Support for charset:        ${charset_msg}
 645   Search type:                ${SEARCH_TYPE}
 646 "