configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.60)
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_SRCDIR(src/main.c)
   9 AC_CONFIG_AUX_DIR(config)
  10 AM_INIT_AUTOMAKE(mc, 4.6.2)
  11
  12 AM_CONFIG_HEADER(config.h)
  13 AM_MAINTAINER_MODE
  14
  15 AC_CANONICAL_HOST
  16
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 AC_PROG_LIBTOOL
  20
  21 AC_ISC_POSIX
  22
  23 AC_PROG_CC_STDC
  24
  25 dnl Doxygen
  26
  27 DX_HTML_FEATURE(ON)
  28 DX_CHM_FEATURE(OFF)
  29 DX_CHI_FEATURE(OFF)
  30 DX_MAN_FEATURE(OFF)
  31 DX_RTF_FEATURE(OFF)
  32 DX_XML_FEATURE(OFF)
  33 DX_PDF_FEATURE(OFF)
  34 DX_PS_FEATURE(OFF)
  35 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
  36
  37 dnl PKG_CHECK_MODULES([CHECK], [check >= 0.9.4])
  38
  39 dnl
  40 dnl First try glib 2.x.  If it's not found, use glib 1.2.x.
  41 dnl Keep this check close to the beginning, so that the users
  42 dnl without any glib won't have their time wasted by other checks.
  43 dnl
  44
  45 AC_ARG_WITH([glib_static],
  46             [  --with-glib-static       Link glib statically [[no]]])
  47
  48 glib_found=no
  49
  50 if test "x$with_glib12" != "xyes"; then
  51         PKG_CHECK_MODULES(GLIB, [glib-2.0], [glib_found=yes], [:])
  52 fi
  53
  54 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0], [gmodule_found=yes])
  55 GLIB_LIBDIR="`$PKG_CONFIG --variable=libdir glib-2.0`"
  56
  57 if test "x$gmodule_found" = "xyes" ; then
  58         dnl Check if the gmodule functionality supported on this system.
  59         AC_G_MODULE_SUPPORTED
  60 fi
  61
  62 AC_HEADER_MAJOR
  63 AC_C_CONST
  64 AC_SYS_LARGEFILE
  65
  66 AC_PROG_LN_S
  67 AC_CHECK_TOOL(AR, ar, ar)
  68
  69 dnl Only list browsers here that can be run in background (i.e. with `&')
  70 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  71
  72 dnl
  73 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  74 dnl We use only part of the functionality of mmap, so on AIX,
  75 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  76 dnl
  77 AC_ARG_WITH(mmap,
  78         [  --with-mmap              Use the mmap call [[yes if found]]])
  79 if test x$with_mmap != xno; then
  80     if test x$with_mmap = x; then
  81         AC_FUNC_MMAP
  82     else
  83         AC_DEFINE(HAVE_MMAP, 1)
  84     fi
  85 fi
  86
  87 dnl
  88 dnl Internationalization
  89 dnl
  90 AM_GNU_GETTEXT(no-libtool, need-ngettext)
  91 AM_GNU_GETTEXT_VERSION(0.14.3)
  92
  93 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  94     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  95 fi
  96
  97 dnl Determine which help translations we want to install.
  98 ALL_DOC_LINGUAS="es hu it pl ru sr"
  99
 100 DOC_LINGUAS=
 101 if test "x$USE_NLS" = xyes; then
 102     if test -z "$LINGUAS"; then
 103         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 104     else
 105         langs="$LINGUAS"
 106     fi
 107 else
 108     langs=
 109 fi
 110
 111 for h_lang in $ALL_DOC_LINGUAS; do
 112     for lang in $langs; do
 113         if test "$lang" = "$h_lang"; then
 114             DOC_LINGUAS="$DOC_LINGUAS $lang"
 115             break
 116         fi
 117     done
 118 done
 119 AC_SUBST(DOC_LINGUAS)
 120
 121 dnl
 122 dnl OS specific flags.
 123 dnl
 124 case $host_os in
 125 aux*)
 126     # A/UX
 127     LIBS="$LIBS -lposix"
 128     AC_DEFINE(_POSIX_SOURCE)
 129     ;;
 130 esac
 131
 132 dnl Extended Character Sets
 133 dnl
 134 AC_ARG_ENABLE([extcharset],
 135         AC_HELP_STRING([--enable-extcharset], [Enable extended character sets]))
 136 if test x"$enable_extcharset" = x"yes"; then
 137   AC_DEFINE([EXTCHARSET_ENABLED], 1, [Enable extended character sets?])
 138 fi
 139
 140 AC_PROG_INSTALL
 141 AC_CHECK_HEADERS([unistd.h string.h memory.h grp.h limits.h malloc.h \
 142         stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h sys/time.h \
 143         sys/timeb.h sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 144         security/pam_misc.h sys/socket.h sys/sysmacros.h sys/types.h \
 145         sys/mkdev.h wchar.h wctype.h])
 146
 147 AC_HEADER_TIME
 148 AC_HEADER_SYS_WAIT
 149 AC_HEADER_DIRENT
 150 AC_HEADER_STDC
 151
 152 dnl Missing structure components
 153 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev])
 154 AC_STRUCT_ST_BLOCKS
 155
 156 dnl
 157 dnl Check availability of some functions
 158 dnl
 159
 160 AC_CHECK_FUNCS([\
 161         atoll \
 162         cfgetospeed \
 163         getegid geteuid getgid getsid getuid \
 164         initgroups isascii \
 165         memcpy memset \
 166         putenv \
 167         setreuid setuid statfs strerror strftime sysconf \
 168         tcgetattr tcsetattr truncate \
 169 ])
 170
 171 dnl
 172 dnl getpt is a GNU Extension (glibc 2.1.x)
 173 dnl
 174 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 175 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 176
 177 dnl replacing lstat with statlstat on sco makes it more portable between
 178 dnl sco clones
 179 AC_CHECK_FUNCS(statlstat)
 180
 181 dnl
 182 dnl If running under AIX, AC_AIX does not tell us that
 183 dnl
 184 AC_MSG_CHECKING([for AIX defines])
 185 AC_EGREP_CPP(yes,
 186 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 187 yes
 188 #endif
 189 ], [
 190 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 191 AC_MSG_RESULT(yes)
 192 ], [AC_MSG_RESULT(no)])
 193
 194 dnl
 195 dnl This is from GNU fileutils, check aclocal.m4 for more information
 196 dnl
 197 AC_GET_FS_INFO
 198
 199 dnl
 200 dnl Missing typedefs and replacements
 201 dnl
 202
 203 AC_CHECK_SIZEOF(long)
 204 AC_CHECK_SIZEOF(long long)
 205 AC_TYPE_MODE_T
 206 AC_TYPE_OFF_T
 207 AC_CHECK_SIZEOF(off_t)
 208 AC_TYPE_PID_T
 209 AC_TYPE_UID_T
 210 AC_CHECK_TYPE(nlink_t, unsigned int)
 211 AC_CHECK_TYPES([socklen_t],,,
 212 [
 213 #include <sys/types.h>
 214 #include <sys/socket.h>
 215 ])
 216
 217 dnl This is needed for regex.c only
 218 AC_CHECK_TYPE(uintptr_t,
 219               [AC_DEFINE(HAVE_UINTPTR_T, 1,
 220                          [Define if you have the `uintptr_t' type.])
 221 ])
 222
 223 AC_FUNC_ALLOCA
 224 AC_FUNC_STRCOLL
 225
 226 dnl
 227 dnl X11 support.
 228 dnl Used to read keyboard modifiers when running under X11.
 229 dnl
 230
 231 AC_PATH_XTRA
 232 if test "x$no_x" = xyes; then
 233     textmode_x11_support="no"
 234 else
 235     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 236     if test "x$mc_cv_g_module_supported" = "xyes" ; then
 237         dnl Replace the contents of GLIB_CFLAGS and GLIB_LIBS with those of
 238         dnl GMODULE_CFLAGS and GMODULE_LIBS, only if X is available and gmodule
 239         dnl functionality is supported on the system.  This way, mc will be
 240         dnl linked against the gmodule library only when it's really required.
 241         GLIB_CFLAGS="$GMODULE_CFLAGS"
 242         GLIB_LIBS="$GMODULE_LIBS"
 243     else
 244         MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 245     fi
 246     AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 247               [Define to enable getting events from X Window System])
 248     textmode_x11_support="yes"
 249 fi
 250
 251 dnl
 252 dnl Try to find static libraries for glib and gmodule.
 253 dnl
 254 if test x$with_glib_static = xyes; then
 255     new_GLIB_LIBS=
 256     for i in $GLIB_LIBS; do
 257         case x$i in
 258         x-lglib*)
 259             lib=glib ;;
 260         x-lgmodule*)
 261             lib=gmodule ;;
 262         *)
 263             lib=
 264             add="$i" ;;
 265         esac
 266
 267         if test -n "$lib"; then
 268             lib1=`echo $i | sed 's/^-l//'`
 269             if test -f "$GLIB_LIBDIR/lib${lib1}.a"; then
 270                 add="$GLIB_LIBDIR/lib${lib1}.a"
 271             else
 272                 if test -f "$GLIB_LIBDIR/lib${lib}.a"; then
 273                     add="$GLIB_LIBDIR/lib${lib}.a"
 274                 else
 275                     AC_MSG_ERROR([Cannot find static $lib])
 276                 fi
 277             fi
 278         fi
 279         new_GLIB_LIBS="$new_GLIB_LIBS $add"
 280     done
 281     GLIB_LIBS="$new_GLIB_LIBS"
 282 fi
 283
 284
 285 dnl
 286 dnl Network related functions
 287 dnl
 288
 289 AC_SEARCH_LIBS([socket], [socket])
 290 AC_SEARCH_LIBS([gethostbyname], [nsl])
 291
 292 dnl
 293 dnl Sequent wants getprocessstats
 294 dnl
 295 AC_CHECK_LIB(seq, get_process_stats, [
 296         LIBS="$LIBS -lseq"
 297         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 298                   [Define if you have function `get_process_stats' and
 299 have to use that instead of gettimeofday])])
 300
 301 AC_MC_VFS_CHECKS
 302
 303 vfs_type="normal"
 304 if test x$use_vfs = xyes; then
 305         AC_MSG_NOTICE([enabling VFS code])
 306         vfs_type="Midnight Commander Virtual File System"
 307 fi
 308
 309 dnl
 310 dnl Check for gpm mouse support (Linux only)
 311 dnl
 312 mouse_lib="xterm only"
 313 AC_ARG_WITH(gpm-mouse,
 314         [  --with-gpm-mouse         Compile with gpm mouse support (Linux only)
 315                            [[yes if found]]])
 316
 317 case $host_os in
 318 linux*)
 319     if test x$with_gpm_mouse != xno; then
 320         AC_CHECK_LIB(gpm, Gpm_Repeat,
 321             [AC_DEFINE(HAVE_LIBGPM, 1,
 322                        [Define to enable gpm mouse support on Linux])
 323             mouse_lib="gpm and xterm"
 324             MCLIBS="$MCLIBS -lgpm"],
 325             [AC_MSG_WARN([libgpm is missing or older than 0.18])
 326         ])
 327     fi
 328     ;;
 329 esac
 330
 331 $PKG_CONFIG --max-version 2.14 glib-2.0
 332 if test $? -eq 0
 333 then
 334     AX_PATH_LIB_PCRE
 335 fi
 336
 337 dnl
 338 dnl Check nroff and the options it supports
 339 dnl
 340 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 341
 342 dnl Default values
 343 MANDOC=-man
 344 MAN_FLAGS=
 345
 346 if $HAVE_nroff; then
 347     AC_MSG_CHECKING([for manual formatting macros])
 348     AC_CACHE_VAL(mc_cv_mandoc, [
 349     nroff -mandoc < /dev/null > /dev/null 2>&1
 350     if test $? = 0; then
 351         mc_cv_mandoc=-mandoc
 352     else
 353         mc_cv_mandoc=-man
 354     fi
 355     ])
 356     MANDOC=$mc_cv_mandoc
 357     AC_MSG_RESULT([$MANDOC])
 358
 359     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 360     AC_CACHE_VAL(mc_cv_man_nocolor, [
 361     nroff -c < /dev/null > /dev/null 2>&1
 362     if test $? = 0; then
 363         mc_cv_man_nocolor=-c
 364     else
 365         mc_cv_man_nocolor=
 366     fi
 367     ])
 368     MAN_FLAGS=$mc_cv_man_nocolor
 369     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 370
 371     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 372     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 373     mc_cv_nroff_tascii=
 374     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 375     if test $? = 0; then
 376         mc_cv_nroff_tascii=-Tlatin1
 377     else
 378         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 379         if test $? = 0; then
 380             mc_cv_nroff_tascii=-Tascii
 381         fi
 382     fi
 383     ])
 384     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 385     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 386 fi
 387
 388 AC_SUBST(MANDOC)
 389 AC_SUBST(MAN_FLAGS)
 390
 391
 392 dnl
 393 dnl Check for -L option to file
 394 dnl
 395 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 396 if $HAVE_FILECMD; then
 397     AC_MSG_CHECKING([for -L option to file command])
 398     AC_CACHE_VAL(mc_cv_filel, [
 399     file -L . > /dev/null 2>&1
 400     if test $? = 0; then
 401         mc_cv_filel=yes
 402     else
 403         mc_cv_filel=no
 404     fi
 405     ])
 406     if test x$mc_cv_filel = xyes; then
 407         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 408     fi
 409     filel=$mc_cv_filel
 410     AC_MSG_RESULT([$filel])
 411 fi
 412
 413
 414 AC_MSG_CHECKING([for subshell support])
 415 AC_ARG_WITH(subshell,
 416         [  --with-subshell          Compile in concurrent subshell [[yes]]
 417   --with-subshell=optional Don't run concurrent shell by default [[no]]],
 418         [result=no
 419         if test x$withval = xoptional
 420         then
 421                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 422                           [Define to make subshell support optional])
 423                 result="optional"
 424         fi
 425         if test x$withval = xyes
 426         then
 427                 result="yes"
 428         fi],
 429         [dnl Default: enable the subshell support
 430         result="yes"
 431 ])
 432 if test "x$result" != xno; then
 433         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 434                   [Define to enable subshell support])
 435 fi
 436 AC_MSG_RESULT([$result])
 437 subshell="$result"
 438
 439
 440 dnl
 441 dnl Select the screen library.
 442 dnl
 443 AC_ARG_WITH(screen,
 444         [  --with-screen=LIB        Compile with screen library: slang or
 445                            ncurses [[slang if found]]])
 446
 447 case x$with_screen in
 448 xslang)
 449         MC_WITH_SLANG(strict)
 450         ;;
 451 xncurses)
 452         MC_WITH_NCURSES
 453         ;;
 454 xncursesw)
 455         MC_WITH_NCURSESW
 456         ;;
 457 x)
 458         MC_WITH_SLANG
 459         ;;
 460 *)
 461         AC_MSG_ERROR([Value of the screen library is incorrect])
 462         ;;
 463 esac
 464
 465
 466 dnl
 467 dnl Internal editor support.
 468 dnl
 469 AC_ARG_WITH(edit,
 470         [  --with-edit              Enable internal editor [[yes]]])
 471
 472 if test x$with_edit != xno; then
 473         AC_DEFINE(USE_INTERNAL_EDIT, 1, [Define to enable internal editor])
 474         use_edit=yes
 475         edit_msg="yes"
 476         AC_MSG_NOTICE([using internal editor])
 477 else
 478         edit_msg="no"
 479 fi
 480
 481
 482 dnl Check if the OS is supported by the console saver.
 483 cons_saver=""
 484 case $host_os in
 485 linux*)
 486     cons_saver=yes
 487 esac
 488
 489
 490 dnl Support for background operations
 491 AC_ARG_ENABLE([background],
 492               [  --enable-background      Support for background file operations [[yes]]])
 493 if test "x$enable_background" != xno; then
 494     AC_DEFINE(WITH_BACKGROUND, 1, [Define to enable background file operations])
 495 fi
 496
 497
 498 dnl
 499 dnl User visible support for charset conversion.
 500 dnl
 501 AC_ARG_ENABLE([charset],
 502               [  --enable-charset         Support for charset selection and conversion [[no]]])
 503 have_charset=
 504 charset_msg="no"
 505 if test "x$enable_charset" = xyes; then
 506   if test "x$am_cv_func_iconv" != xyes; then
 507     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 508   else
 509     AC_DEFINE(HAVE_CHARSET, 1,
 510               [Define to enable charset selection and conversion])
 511     have_charset=yes
 512     charset_msg="yes"
 513   fi
 514 fi
 515
 516 if test "$GLIBC21" != yes; then
 517     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 518 fi
 519
 520 dnl If default CFLAGS is used with gcc, add -Wall
 521 if test -z "$ac_env_CFLAGS_set"; then
 522     if test -n "$GCC"; then
 523         CFLAGS="$CFLAGS -Wall"
 524     fi
 525 fi
 526
 527 AC_SUBST(CFLAGS)
 528 AC_SUBST(CPPFLAGS)
 529 AC_SUBST(LDFLAGS)
 530 AC_SUBST(LIBS)
 531
 532 dnl Libraries used only when building the mc binary
 533 AC_SUBST(MCLIBS)
 534
 535 dnl Version for the RedHat package, without dashes
 536 RPM_VERSION=`echo $VERSION | sed 's/-//g'`
 537 AC_SUBST(RPM_VERSION)
 538
 539 if test -n "$use_smbfs"; then
 540   AC_CONFIG_SUBDIRS([vfs/samba])
 541 fi
 542
 543 AM_CONDITIONAL(USE_EDIT, [test -n "$use_edit"])
 544 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 545 AM_CONDITIONAL(USE_VFS_NET, [test x"$use_net_code" = xtrue])
 546 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$use_undelfs"])
 547 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$use_smbfs"])
 548 AM_CONDITIONAL(USE_MCFS, [test -n "$use_mcfs"])
 549 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 550 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 551
 552 AC_CONFIG_FILES([
 553 Makefile
 554
 555 contrib/Makefile
 556 contrib/dist/Makefile
 557 contrib/dist/debian/Makefile
 558 contrib/dist/gentoo/Makefile
 559 contrib/dist/redhat/Makefile
 560 contrib/dist/redhat/mc.spec
 561 contrib/dist/mc.qpg
 562 contrib/dist/pkginfo
 563 contrib/dist/prototype
 564 contrib/mc.ext
 565
 566 src/Makefile
 567 src/search/Makefile
 568
 569 edit/Makefile
 570 syntax/Makefile
 571
 572 vfs/Makefile
 573 vfs/extfs/Makefile
 574 vfs/extfs/a
 575 vfs/extfs/apt
 576 vfs/extfs/audio
 577 vfs/extfs/deb
 578 vfs/extfs/deba
 579 vfs/extfs/debd
 580 vfs/extfs/dpkg
 581 vfs/extfs/iso9660
 582 vfs/extfs/hp48
 583 vfs/extfs/lslR
 584 vfs/extfs/mailfs
 585 vfs/extfs/patchfs
 586 vfs/extfs/rpms
 587 vfs/extfs/uace
 588 vfs/extfs/ualz
 589 vfs/extfs/uar
 590 vfs/extfs/uarc
 591 vfs/extfs/uarj
 592 vfs/extfs/uc1541
 593 vfs/extfs/uha
 594 vfs/extfs/ulha
 595 vfs/extfs/urar
 596 vfs/extfs/uzip
 597 vfs/extfs/uzoo
 598
 599 doc/Makefile
 600 doc/hints/Makefile
 601 doc/man/mc.1 doc/man/mcedit.1 doc/man/mcview.1 doc/man/mcserv.8 doc/man/Makefile
 602 doc/man/es/mc.1 doc/man/es/Makefile
 603 doc/man/hu/mc.1 doc/man/hu/Makefile
 604 doc/man/it/mc.1 doc/man/it/Makefile
 605 doc/man/pl/mc.1 doc/man/pl/Makefile
 606 doc/man/ru/mc.1 doc/man/ru/Makefile
 607 doc/man/sr/mc.1 doc/man/sr/mcserv.8 doc/man/sr/Makefile
 608 doc/es/Makefile
 609 doc/hu/Makefile
 610 doc/it/Makefile
 611 doc/pl/Makefile
 612 doc/ru/Makefile
 613 doc/sr/Makefile
 614
 615 intl/Makefile
 616 po/Makefile.in
 617 ])
 618
 619 AC_OUTPUT
 620
 621 echo "
 622 Configuration:
 623
 624   Source code location:       ${srcdir}
 625   Compiler:                   ${CC}
 626   Compiler flags:             ${CFLAGS}
 627   File system:                ${vfs_type}
 628                               ${vfs_flags}
 629   Screen library:             ${screen_msg}
 630   Mouse support:              ${mouse_lib}
 631   X11 events support:         ${textmode_x11_support}
 632   With subshell support:      ${subshell}
 633   Internal editor:            ${edit_msg}
 634   Support for charset:        ${charset_msg}
 635 "