m4.include/ax_check_compile_flag.m4

   1 # ===========================================================================
   2 #  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check whether the given FLAG works with the current language's compiler
  12 #   or gives an error.  (Warnings, however, are ignored)
  13 #
  14 #   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
  15 #   success/failure.
  16 #
  17 #   If EXTRA-FLAGS is defined, it is added to the current language's default
  18 #   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
  19 #   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
  20 #   force the compiler to issue an error when a bad flag is given.
  21 #
  22 #   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
  23 #
  24 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
  25 #   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
  26 #
  27 # LICENSE
  28 #
  29 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  30 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  31 #
  32 #   Copying and distribution of this file, with or without modification, are
  33 #   permitted in any medium without royalty provided the copyright notice
  34 #   and this notice are preserved.  This file is offered as-is, without any
  35 #   warranty.
  36
  37 # Yury Zaytsev:
  38 # Toggle Werror since at some point clang started treating unknown -W
  39 # flags as warnings, succeeding with the build, yet issuing an annoying
  40 # warning.
  41
  42 #serial 6
  43
  44 AC_DEFUN([AX_CHECK_COMPILE_FLAG],
  45 [AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
  46 AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
  47 AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
  48   ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  49   _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1 -Werror"
  50   AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
  51     [AS_VAR_SET(CACHEVAR,[yes])],
  52     [AS_VAR_SET(CACHEVAR,[no])])
  53   _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
  54 AS_VAR_IF(CACHEVAR,yes,
  55   [m4_default([$2], :)],
  56   [m4_default([$3], :)])
  57 AS_VAR_POPDEF([CACHEVAR])dnl
  58 ])dnl AX_CHECK_COMPILE_FLAGS