configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.6.0-pre1a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_CANONICAL_HOST
  15
  16 AC_AIX
  17 AC_MINIX
  18 AC_ISC_POSIX
  19
  20 AC_PROG_CC_STDC
  21
  22
  23 dnl
  24 dnl Find glib 1.2.x.  This check should be kept close to the beginning,
  25 dnl as it tends to fail often.
  26 dnl
  27
  28 dnl This temporary variable is a workaround for a bug in Autoconf-2.53
  29 glib_path=$PATH:/usr/local/bin
  30
  31 dnl Klugde for FreeBSD, where glib-config is renamed to glib12-config.
  32 AC_PATH_PROGS([GLIB_CONFIG], [glib-config glib12-config],,[$glib_path])
  33
  34 AC_ARG_VAR([GLIB_CONFIG], [Path to glib-config])
  35 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  36 AC_SUBST(GLIB_LIBS)
  37
  38
  39 AC_HEADER_MAJOR
  40 AC_C_CONST
  41 AC_SYS_LARGEFILE
  42
  43 AC_PROG_LN_S
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 dnl Only list browsers here that can be run in background (i.e. with `&')
  47 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  48
  49 dnl
  50 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  51 dnl We use only part of the functionality of mmap, so on AIX,
  52 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  53 dnl
  54 AC_ARG_WITH(mmap,
  55         [--with-mmap                To force using the mmap call (AIX)],
  56         [case $withval in
  57 yes)
  58         ac_cv_func_mmap_fixed_mapped=yes
  59         AC_MSG_NOTICE([forcing MMAP support])
  60         ;;
  61 no)
  62         ac_cv_func_mmap_fixed_mapped=no
  63         AC_MSG_NOTICE([disabling MMAP support])
  64         ;;
  65 esac])
  66 AC_FUNC_MMAP
  67
  68 if test "x$ALL_LINGUAS" = x; then
  69 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  70 fi
  71
  72 dnl
  73 dnl Internationalization
  74 dnl
  75 AM_GNU_GETTEXT
  76 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  77     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  78 fi
  79
  80 dnl
  81 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  82 dnl
  83 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  84
  85 dnl
  86 dnl Enforce coding standards
  87 dnl
  88 if test "x$GCC" = xyes; then
  89     CFLAGS="$CFLAGS -Wall"
  90 fi
  91
  92 dnl
  93 dnl OS specific flags.
  94 dnl
  95
  96 posix_libs=""
  97 case $host_os in
  98 aux*)
  99     # A/UX
 100     posix_libs="-lposix"
 101     AC_DEFINE(_POSIX_SOURCE)
 102     ;;
 103 sco*)
 104     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
 105     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
 106     ;;
 107 esac
 108
 109 AC_PROG_INSTALL
 110 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 111         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 112         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h])
 113
 114 AC_HEADER_TIME
 115 AC_HEADER_SYS_WAIT
 116 AC_HEADER_DIRENT
 117 AC_HEADER_STDC
 118
 119 dnl Missing structure components
 120 AC_STRUCT_ST_BLKSIZE
 121 AC_STRUCT_ST_BLOCKS
 122 AC_STRUCT_ST_RDEV
 123
 124 dnl
 125 dnl Check availability of some functions
 126 dnl
 127
 128 AC_CHECK_FUNCS([strerror statfs strftime \
 129                 memmove pwdauth truncate initgroups putenv \
 130                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 131                 sigaction sigemptyset sigprocmask sigaddset \
 132                 sysconf setuid setreuid telldir seekdir])
 133
 134 dnl
 135 dnl getpt is a GNU Extension (glibc 2.1.x)
 136 dnl
 137 AC_CHECK_FUNCS(getpt)
 138
 139 dnl
 140 dnl Password encryption support for mcserv
 141 dnl Check if function crypt needs a prototype
 142 dnl
 143 NEED_CRYPT_PROTOTYPE=yes
 144 if test x$ac_cv_header_crypt_h = xyes; then
 145 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 146 if (p)
 147 return 0;],[
 148 NEED_CRYPT_PROTOTYPE=no])
 149 else
 150     if test x$ac_cv_header_unistd_h = xyes; then
 151 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 152 if (p)
 153 return 0;],[
 154 NEED_CRYPT_PROTOTYPE=no])
 155     fi
 156 fi
 157 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 158 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 159           [Define if function `crypt' needs a prototype])
 160 fi
 161
 162 dnl
 163 dnl On SCO and some SVR4, crypt is on libcrypt.a
 164 dnl         grantpt in  libpt.a
 165 dnl
 166 LCRYPT=""
 167 AC_CHECK_FUNCS(crypt, , [
 168     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 169         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 170 AC_SUBST(LCRYPT)
 171
 172 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 173
 174 dnl replacing lstat with statlstat on sco makes it more portable between
 175 dnl sco clones
 176 AC_CHECK_FUNCS(statlstat)
 177
 178 dnl
 179 dnl If running under AIX, AC_AIX does not tell us that
 180 dnl
 181 AC_MSG_CHECKING([for AIX defines])
 182 AC_EGREP_CPP(yes,
 183 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 184 yes
 185 #endif
 186 ], [
 187 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 188 AC_MSG_RESULT(yes)
 189 ], [AC_MSG_RESULT(no)])
 190
 191 dnl
 192 dnl This is from GNU fileutils, check aclocal.m4 for more information
 193 dnl
 194 AC_GET_FS_INFO
 195
 196 dnl
 197 dnl Missing typedefs and replacements
 198 dnl
 199
 200 AC_TYPE_MODE_T
 201 AC_CHECK_TYPE(umode_t, int)
 202 AC_CHECK_TYPE(off_t, long)
 203 AC_TYPE_PID_T
 204 AC_TYPE_UID_T
 205 AC_CHECK_TYPE(nlink_t, unsigned int)
 206
 207 AC_FUNC_ALLOCA
 208 AC_FUNC_STRCOLL
 209
 210 dnl
 211 dnl X11 support.
 212 dnl
 213
 214 dnl These variables are only used when building the MC binary
 215 MCCFLAGS=""
 216 MCLIBS=""
 217 AC_SUBST(MCCFLAGS)
 218 AC_SUBST(MCLIBS)
 219
 220 textmode_x11_support="no"
 221 AC_ARG_WITH(tm-x-support,
 222         [--with-tm-x-support        Try getting events from X Window System],
 223         [if test x$withval = xyes; then
 224                 AC_PATH_XTRA
 225                 MCCFLAGS="$X_CFLAGS"
 226                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 227                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 228                           [Define to enable getting events from X Window System])
 229                 textmode_x11_support="yes"
 230         fi
 231 ])
 232
 233 dnl
 234 dnl Network related functions
 235 dnl
 236
 237 AC_CHECK_LIB(nsl, t_accept)
 238 AC_CHECK_LIB(socket, socket)
 239
 240 have_socket=no
 241 AC_CHECK_FUNCS(socket, have_socket=yes)
 242 if test $have_socket = no; then
 243   # socket is not in the default libraries.  See if it's in some other.
 244   for lib in bsd socket inet; do
 245     AC_CHECK_LIB($lib, socket, [
 246         LIBS="$LIBS -l$lib"
 247         have_socket=yes
 248         AC_DEFINE(HAVE_SOCKET)
 249         break])
 250   done
 251 fi
 252
 253 have_gethostbyname=no
 254 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 255 if test $have_gethostbyname = no; then
 256   # gethostbyname is not in the default libraries.  See if it's in some other.
 257   for lib in bsd socket inet; do
 258     AC_CHECK_LIB([$lib], [gethostbyname],
 259                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 260   done
 261 fi
 262
 263 AC_CHECK_FUNCS(socketpair)
 264
 265 dnl
 266 dnl Sequent wants getprocessstats
 267 dnl
 268 AC_CHECK_LIB(seq, get_process_stats, [
 269         LIBS="$LIBS -lseq"
 270         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 271                   [Define if you have function `get_process_stats' and
 272 have to use that instead of gettimeofday])])
 273
 274 MC_VFS_CHECKS
 275
 276 dnl
 277 dnl Install mcserv only if explicitly enabled
 278 dnl
 279 AC_ARG_ENABLE([mcserv-install],
 280               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 281
 282 NETFILES=
 283 if test $have_socket = yes; then
 284    NETFILES="\$(NETFILES)"
 285 fi
 286 AC_SUBST(NETFILES)
 287
 288 vfs_type="normal"
 289 if test $use_vfs = yes
 290 then
 291         AC_MSG_NOTICE([enabling VFS code])
 292         vfs_type="Midnight Commander Virtual File System"
 293 fi
 294
 295 dnl This should be unadorned "slang" or "ncurses"
 296 screen_type=""
 297
 298 dnl Screen manager name (for the output only)
 299 screen_manager=unknown
 300
 301 mouse_lib="xterm only"
 302 case $host_os in
 303 linux*)
 304     AC_ARG_WITH(gpm-mouse,
 305         [--with-gpm-mouse[[=base-dir]]  Compile with gpm mouse support (Linux only)],
 306         [if test x$withval != xno
 307         then
 308                 if test x$withval != xyes
 309                 then
 310                         LIBS="$LIBS -L$withval/lib"
 311                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 312                 fi
 313                 AC_DEFINE(HAVE_LIBGPM, 1,
 314                           [Define to enable gpm mouse support on Linux])
 315                 mouse_lib="GPM and xterm"
 316                 MCLIBS="-lgpm $MCLIBS"
 317         fi],
 318         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 319                 [AC_DEFINE(HAVE_LIBGPM)
 320                 mouse_lib="GPM and xterm"
 321                 MCLIBS="-lgpm $MCLIBS"],
 322                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 323                 [$LIBS])
 324         ])
 325     ;;
 326 esac
 327
 328 AC_ARG_WITH(ncurses,
 329         [--with-ncurses[[=base-dir]]  Compile with ncurses/locate base dir],
 330 [if test x$withval != xno; then
 331         if test x$withval != xyes; then
 332                 MCLIBS="$MCLIBS -L$withval/lib"
 333                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 334         fi
 335
 336         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 337                          [ncurses_h_found=yes; break])
 338         if test -z "$ncurses_h_found"; then
 339             AC_MSG_ERROR([Could not find ncurses header])
 340         fi
 341
 342         dnl curses_version is specific to ncurses, it's not in old curses
 343         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 344                      [AC_MSG_ERROR([Could not find ncurses library])])
 345
 346         screen_type="ncurses"
 347         screen_manager="ncurses"
 348         AC_DEFINE(USE_NCURSES, 1,
 349                   [Define to use ncurses for screen management])
 350 fi
 351 ])
 352
 353 AC_ARG_WITH(hsc,
 354         [--with-hsc                 Compile with support for the HSC firewall],
 355         [if test x$withval = xyes; then
 356                 AC_DEFINE(HSC_PROXY, 1,
 357                           [Define if you want to use the HSC firewall])
 358         fi
 359 ])
 360
 361 dnl
 362 dnl Check for the -mandoc package
 363 dnl
 364 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 365 if $HAVE_nroff; then
 366     AC_MSG_CHECKING([for manual formatting macros])
 367     AC_CACHE_VAL(ac_cv_mandoc, [
 368     nroff -mandoc < /dev/null > /dev/null 2>&1
 369     if test $? = 0
 370     then
 371         ac_cv_mandoc=-mandoc
 372     else
 373         ac_cv_mandoc=-man
 374     fi
 375     ])
 376     MANDOC=$ac_cv_mandoc
 377     AC_MSG_RESULT([$MANDOC])
 378 else
 379     MANDOC=-man
 380 fi
 381 AC_SUBST(MANDOC)
 382
 383 dnl
 384 dnl Check if nroff accepts -Tlatin1 or -Tascii
 385 dnl
 386 if $HAVE_nroff; then
 387     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 388     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 389     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 390     if test $? = 0
 391     then
 392         ac_cv_nroff_tascii=" -Tlatin1"
 393     else
 394         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 395         if test $? = 0
 396         then
 397             ac_cv_nroff_tascii=" -Tascii"
 398         else
 399             ac_cv_nroff_tascii=""
 400         fi
 401     fi
 402     ])
 403     if test "x$ac_cv_nroff_tascii" = x; then
 404         AC_MSG_RESULT([no])
 405     else
 406         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 407     fi
 408 fi
 409 TROFFASCII="$ac_cv_nroff_tascii"
 410 AC_SUBST(TROFFASCII)
 411
 412 dnl
 413 dnl Check for - option to file
 414 dnl
 415 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 416 if $HAVE_FILECMD; then
 417     AC_MSG_CHECKING([for - option to file command])
 418     AC_CACHE_VAL(ac_cv_filestdin, [[
 419     cat > conftest.c <<\EOF
 420 /* A comment */
 421 #if 0
 422 #endif
 423 void main(void)
 424 { return; }
 425 EOF
 426     cat > conftest.sed <<\EOF
 427 s/^[^:]*:[      ]*//
 428 s/[     ]*$//
 429 EOF
 430     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 431     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 432     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 433         ac_cv_filestdin=yes
 434     else
 435         ac_cv_filestdin=no
 436     fi
 437     rm conftest.c conftest.sed
 438     ]])
 439
 440     if test x$ac_cv_filestdin = xyes; then
 441         AC_DEFINE(FILE_STDIN, 1,
 442                   [Define if the file command accepts - for stdin])
 443     fi
 444     filestdin=$ac_cv_filestdin
 445     AC_MSG_RESULT([$filestdin])
 446
 447     dnl
 448     dnl Check for -L option to file
 449     dnl
 450
 451 AC_MSG_CHECKING([for -L option to file command])
 452 AC_CACHE_VAL(ac_cv_filel, [
 453 file -L . > /dev/null 2>&1
 454 if test $? = 0
 455 then
 456     ac_cv_filel=yes
 457 else
 458     ac_cv_filel=no
 459 fi
 460 ])
 461 if test x$ac_cv_filel = xyes; then
 462     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 463 fi
 464 filel=$ac_cv_filel
 465 AC_MSG_RESULT([$filel])
 466 fi
 467
 468
 469 AC_MSG_CHECKING([for subshell support])
 470 AC_ARG_WITH(subshell,
 471         [--with-subshell=optional   To disable concurrent shell by default
 472 --without-subshell         To disable concurrent shell completely],
 473         [result=no
 474         if test x$withval = xoptional
 475         then
 476                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 477                           [Define to make subshell support optional])
 478                 result="optional"
 479         fi
 480         if test x$withval = xyes
 481         then
 482                 result="yes"
 483         fi],
 484         [dnl Default: enable the subshell support
 485         result="yes"
 486 ])
 487 if test "x$result" != xno; then
 488         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 489                   [Define to enable subshell support])
 490 fi
 491 AC_MSG_RESULT([$result])
 492 subshell="$result"
 493
 494 if test "x$screen_type" != xncurses; then
 495         slang_check_lib=true
 496         slang_term=""
 497         slang_use_system_installed_lib=false
 498         AC_CHECK_LIB(slang,SLang_init_tty,
 499                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 500                                   [slang_h_found=yes; break])
 501                 if test "x$slang_h_found" = xyes; then
 502                      slang_use_system_installed_lib=true
 503                      slang_check_lib=false
 504                 fi
 505         ])
 506 fi
 507
 508 AC_ARG_WITH(terminfo,
 509         [--with-terminfo            SLANG: Force usage of terminfo],[
 510         if test x$withval = xyes; then
 511                 AC_USE_TERMINFO
 512                 slang_check_lib=false
 513                 slang_use_system_installed_lib=false
 514         fi]
 515 )
 516
 517 AC_ARG_WITH(termcap,
 518         [--with-termcap             SLANG: Force usage of termcap],[
 519         if test x$withval = xyes; then
 520                 AC_USE_TERMCAP
 521                 slang_check_lib=false
 522                 slang_use_system_installed_lib=false
 523         fi]
 524 )
 525
 526 AC_ARG_WITH(included-slang,
 527         [--with-included-slang      SLANG: use the SLang library included here],[
 528         if test x$withval = xyes; then
 529             slang_use_system_installed_lib=false
 530             slang_check_lib=true
 531         fi]
 532 )
 533
 534 AC_ARG_WITH(slang,
 535         [--with-slang              Compile with the slang screen manager],[
 536         if test x$withval = xyes; then
 537                 AC_WITH_SLANG
 538         fi
 539 ])
 540
 541 LIBEDIT_A=""
 542 MCEDIT=""
 543 LEDIT=""
 544 EDIT_msg=""
 545 AC_ARG_WITH(edit,
 546         [--with-edit                Enable internal editor],
 547         [if test x$withval = xyes
 548         then
 549                 AC_WITH_EDIT
 550         else
 551                 EDIT_msg="no"
 552         fi],
 553         [dnl Default: provide the internal editor
 554         AC_WITH_EDIT
 555 ])
 556 AC_SUBST(LIBEDIT_A)
 557 AC_SUBST(MCEDIT)
 558 AC_SUBST(LEDIT)
 559
 560 undelfs_o=""
 561
 562 if test $use_vfs = yes; then
 563     AC_ARG_WITH(ext2undel,
 564         [--with-ext2undel           Compile with ext2 undelete code],[
 565         if test x$withval != xno;
 566         then
 567                 if test x$withval != xyes
 568                 then
 569                         LIBS="$LIBS -L$withval/lib"
 570                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 571                 fi
 572                 AC_EXT2_UNDEL
 573         fi],[
 574         dnl Default: detect
 575         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 576     ])
 577 fi
 578
 579 AC_SUBST(undelfs_o)
 580
 581
 582 dnl Ncurses specific checks
 583 dnl
 584 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 585 dnl or you'll have to press Esc three times to dismiss a dialog box.
 586 dnl
 587 if test "x$screen_type" = xncurses; then
 588   save_LIBS="$LIBS"
 589   LIBS="$MCLIBS $LIBS"
 590   AC_CACHE_CHECK([for ESCDELAY variable],
 591                  [mc_cv_ncurses_escdelay],
 592                  [AC_TRY_COMPILE([], [
 593                         extern int ESCDELAY;
 594                         int main ()
 595                         {
 596                           ESCDELAY = 0;
 597                         }
 598                         ],
 599                         [mc_cv_ncurses_escdelay=yes],
 600                         [mc_cv_ncurses_escdelay=no]
 601                   )
 602   ])
 603   if test "$mc_cv_ncurses_escdelay" = yes; then
 604     AC_DEFINE(HAVE_ESCDELAY, 1,
 605               [Define if ncurses has ESCDELAY variable])
 606   fi
 607
 608   AC_CHECK_FUNCS(resizeterm)
 609   LIBS="$save_LIBS"
 610 fi
 611
 612 if test "x$screen_type" = "x"; then
 613     AC_WITH_SLANG
 614 fi
 615
 616 dnl
 617 dnl The variables used for expanding the auto saver.
 618 dnl
 619 cons_saver=""
 620 install_saver="no"
 621 PAMLIBS=""
 622 case $host_os in
 623 linux*)
 624     cons_saver="cons.saver"
 625     install_saver="yes"
 626
 627     dnl
 628     dnl On Linux, check for PAM authentication available
 629     dnl
 630     AC_CHECK_LIB(pam, pam_start, [
 631         AC_DEFINE(HAVE_PAM, 1,
 632                   [Define if PAM (Pluggable Authentication Modules) is available])
 633         PAMLIBS="-lpam -ldl"
 634     ],[],[-ldl])
 635     ;;
 636 esac
 637 AC_SUBST(cons_saver)
 638 AC_SUBST(PAMLIBS)
 639
 640 dnl
 641 dnl User visible support for charset conversion.
 642 dnl
 643 AC_ARG_ENABLE([charset],
 644               [--enable-charset           Support for charset selection and conversion])
 645 have_charset=
 646 if test "x$enable_charset" = xyes; then
 647   if test "x$am_cv_func_iconv" != xyes; then
 648     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 649   else
 650     AC_DEFINE(HAVE_CHARSET, 1,
 651               [Define to enable charset selection and conversion])
 652     have_charset=yes
 653   fi
 654 fi
 655
 656 if test "$GLIBC21" != yes; then
 657     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 658 fi
 659
 660 dnl
 661 dnl This code should be moved to the ac_WITH_SLANG
 662 dnl
 663 dnl We check for the existance of setupterm on curses library
 664 dnl this is required to load certain definitions on some termcaps
 665 dnl editions (AIX and OSF/1 I seem to remember).
 666 dnl Note that we avoid using setupterm
 667 if test "x$screen_type" = xslang; then
 668         case $host_os in
 669         linux*)
 670                 ;;
 671         *)
 672                 AC_CHECK_LIB(curses,setupterm,
 673                         [AC_TRY_COMPILE([
 674 #include <curses.h>
 675 #include <term.h>],[
 676    if (key_end == parm_insert_line)
 677         return 1;
 678    return 0;
 679 ],
 680                         [MCLIBS="$MCLIBS -lcurses"
 681                         AC_DEFINE(USE_SETUPTERM, 1,
 682                                   [Define to use function `setupterm'
 683 from `curses' library in S-Lang])])
 684                 ])
 685         esac
 686 fi
 687
 688 LIBS="$LIBS $posix_libs"
 689
 690 AC_SUBST(CFLAGS)
 691 AC_SUBST(CPPFLAGS)
 692 AC_SUBST(LDFLAGS)
 693 AC_SUBST(LIBS)
 694
 695 dnl Version for the RedHat package, without dashes
 696 RH_VERSION=`echo $VERSION | sed 's/-//'`
 697 AC_SUBST(RH_VERSION)
 698
 699 if test "x$SAMBAFILES" != x; then
 700   AC_CONFIG_SUBDIRS([vfs/samba])
 701 fi
 702
 703 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 704 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 705 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 706 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 707 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 708 AM_CONDITIONAL(MCSERV_INSTALL,
 709                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 710 AM_CONDITIONAL(INCLUDED_SLANG,
 711                [test "x$slang_use_system_installed_lib" = xfalse])
 712 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 713 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 714
 715 AH_BOTTOM([#include <extraconf.h>])
 716
 717 AC_CONFIG_FILES([
 718 Makefile
 719 mc.spec
 720 doc/Makefile
 721 vfs/Makefile
 722 vfs/extfs/Makefile
 723 lib/Makefile
 724 src/Makefile
 725 slang/Makefile
 726 edit/Makefile
 727 syntax/Makefile
 728 pc/Makefile
 729
 730 lib/mc.ext
 731 lib/mc.sh
 732 lib/mc.csh
 733
 734 mcfn_install
 735
 736 vfs/extfs/deb
 737 vfs/extfs/ftplist
 738 vfs/extfs/lslR
 739 vfs/extfs/uar
 740 vfs/extfs/ucpio
 741 vfs/extfs/ulha
 742 vfs/extfs/uha
 743 vfs/extfs/urar
 744 vfs/extfs/uzoo
 745
 746 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 747 doc/es/mc.1 doc/es/Makefile
 748 doc/hu/Makefile
 749 doc/it/mc.1 doc/it/Makefile
 750 doc/pl/mc.1 doc/pl/Makefile
 751 doc/ru/mc.1 doc/ru/Makefile
 752
 753 intl/Makefile po/Makefile.in
 754 ])
 755
 756 AC_CONFIG_COMMANDS(potfiles,
 757     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 758
 759 AC_OUTPUT
 760
 761 if test "x$screen_type" = xslang; then
 762     screen_manager="${screen_manager}${slang_term}"
 763 fi
 764
 765 echo "
 766 Configuration:
 767
 768   Source code location:       ${srcdir}
 769   Compiler:                   ${CC}
 770   Compiler flags:             ${CFLAGS}
 771   File system:                ${vfs_type}
 772                               ${vfs_flags}
 773   Screen manager:             ${screen_manager}
 774   Install console saver:      ${install_saver}
 775   Mouse support:              ${mouse_lib}
 776   X11 events support:         ${textmode_x11_support}
 777   Debugger code:              ${mem_debug}
 778   With subshell support:      ${subshell}
 779   Internal editor:            ${EDIT_msg}
 780   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 781 "