vfs/samba/aclocal.m4

   1 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
   2 dnl if the cache file is inconsistent with the current host,
   3 dnl target and build system types, execute CMD or print a default
   4 dnl error message.
   5 AC_DEFUN([AC_VALIDATE_CACHE_SYSTEM_TYPE], [
   6     AC_REQUIRE([AC_CANONICAL_SYSTEM])
   7     AC_MSG_CHECKING([config.cache system type])
   8     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
   9          test x"$ac_cv_host_system_type" != x"$host"; } ||
  10        { test x"${ac_cv_build_system_type+set}" = x"set" &&
  11          test x"$ac_cv_build_system_type" != x"$build"; } ||
  12        { test x"${ac_cv_target_system_type+set}" = x"set" &&
  13          test x"$ac_cv_target_system_type" != x"$target"; }; then
  14         AC_MSG_RESULT([different])
  15         ifelse($#, 1, [$1],
  16                 [AC_MSG_ERROR([you must remove config.cache and restart configure])])
  17     else
  18         AC_MSG_RESULT([same])
  19     fi
  20     ac_cv_host_system_type="$host"
  21     ac_cv_build_system_type="$build"
  22     ac_cv_target_system_type="$target"
  23 ])
  24
  25 dnl based on Automake's maintainer mode
  26 AC_DEFUN([SAMBA_MAINTAINER_MODE],[
  27   AC_ARG_ENABLE(maintainer-mode,
  28         [  --enable-maintainer-mode enable some make rules for maintainers],
  29       maint_mode=$enableval, maint_mode=no)
  30   if test x"$maint_mode" = x"yes"; then MAINT=; else MAINT='#'; fi
  31   AC_SUBST(MAINT)
  32   AC_PATH_PROG(AUTOCONF, autoconf, autoconf)
  33   AC_SUBST(AUTOCONF)
  34   AC_PATH_PROG(AUTOHEADER, autoheader, autoheader)
  35   AC_SUBST(AUTOHEADER)
  36 ])
  37
  38
  39 dnl AC_PROG_CC_FLAG(flag)
  40 AC_DEFUN([AC_PROG_CC_FLAG],
  41 [AC_CACHE_CHECK([whether ${CC-cc} accepts -$1], ac_cv_prog_cc_$1,
  42 [echo 'void f(){}' > conftest.c
  43 if test -z "`${CC-cc} -$1 -c conftest.c 2>&1`"; then
  44   ac_cv_prog_cc_$1=yes
  45 else
  46   ac_cv_prog_cc_$1=no
  47 fi
  48 rm -f conftest*
  49 ])])
  50
  51 dnl check for a function in a library, but don't
  52 dnl keep adding the same library to the LIBS variable.
  53 dnl AC_LIBTESTFUNC(lib,func)
  54 AC_DEFUN([AC_LIBTESTFUNC],
  55 [case "$LIBS" in
  56   *-l$1*) AC_CHECK_FUNCS($2) ;;
  57   *) AC_CHECK_LIB($1, $2)
  58      AC_CHECK_FUNCS($2)
  59   ;;
  60   esac
  61 ])