m4.include/vfs/mc-vfs-extfs.m4

   1 dnl AC_MC_EXTFS_CHECKS
   2 dnl    Check for tools used in extfs scripts.
   3
   4 dnl FIXME: make this configurable
   5 AC_DEFUN([AC_MC_EXTFS_CHECKS], [
   6     AC_PATH_PROG([ZIP], [zip], [/usr/bin/zip])
   7     AC_PATH_PROG([UNZIP], [unzip], [/usr/bin/unzip])
   8     AC_CACHE_CHECK([for zipinfo code in unzip], [mc_cv_have_zipinfo],
   9         [mc_cv_have_zipinfo=no
  10         if $UNZIP -Z </dev/null >/dev/null 2>&1; then
  11             mc_cv_have_zipinfo=yes
  12         fi])
  13     if test x"$mc_cv_have_zipinfo" = xyes; then
  14         HAVE_ZIPINFO=1
  15     else
  16         HAVE_ZIPINFO=0
  17     fi
  18     AC_SUBST([HAVE_ZIPINFO])
  19 ])
  20
  21
  22 dnl Enable Extfs (classic)
  23 AC_DEFUN([AC_MC_VFS_EXTFS],
  24 [
  25     AC_ARG_ENABLE([vfs-extfs],
  26                     AS_HELP_STRING([--enable-vfs-extfs], [Support for extfs filesystem @<:@yes@:>@]))
  27     if test "$enable_vfs" = "yes" -a x"$enable_vfs_extfs" != x"no"; then
  28         AC_MC_EXTFS_CHECKS
  29         enable_vfs_extfs="yes"
  30         AC_MC_VFS_ADDNAME([extfs])
  31         AC_DEFINE([ENABLE_VFS_EXTFS], [1], [Support for extfs])
  32     fi
  33     AM_CONDITIONAL(ENABLE_VFS_EXTFS, [test "$enable_vfs" = "yes" -a x"$enable_vfs_extfs" = x"yes"])
  34 ])