configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT(GNU Midnight Commander, 4.5.99a, mc-devel@gnome.org)
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.5.99a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_PROG_LN_S
  15 AC_CANONICAL_HOST
  16
  17 AC_AIX
  18 AC_MINIX
  19 AC_ISC_POSIX
  20
  21 AC_PROG_CC_STDC
  22
  23 AC_HEADER_MAJOR
  24 AC_C_CONST
  25
  26 AC_SYS_LARGEFILE
  27
  28 AC_CHECK_TOOL(AR, ar, ar)
  29
  30 dnl Only list browsers here that can be run in background (i.e. with `&')
  31 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  32
  33 dnl
  34 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  35 dnl We use only part of the functionality of mmap, so on AIX,
  36 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  37 dnl
  38 AC_ARG_WITH(mmap,
  39         [--with-mmap                To force using the mmap call (AIX)],
  40         [case $withval in
  41 yes)
  42         ac_cv_func_mmap_fixed_mapped=yes
  43         AC_MSG_NOTICE([forcing MMAP support])
  44         ;;
  45 no)
  46         ac_cv_func_mmap_fixed_mapped=no
  47         AC_MSG_NOTICE([disabling MMAP support])
  48         ;;
  49 esac])
  50 AC_FUNC_MMAP
  51
  52 if test "x$ALL_LINGUAS" = x; then
  53 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  54 fi
  55
  56 dnl
  57 dnl Internationalization
  58 dnl
  59 AM_GNU_GETTEXT
  60 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  61     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  62 fi
  63
  64 dnl
  65 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  66 dnl
  67 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  68
  69 dnl
  70 dnl Enforce coding standards
  71 dnl
  72 if test "x$GCC" = xyes; then
  73     CFLAGS="$CFLAGS -Wall"
  74 fi
  75
  76 dnl
  77 dnl We now use glib
  78 dnl
  79 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  80 LIBS="$LIBS $GLIB_LIBS"
  81
  82 dnl
  83 dnl OS specific flags.
  84 dnl
  85
  86 posix_libs=""
  87 case $host_os in
  88 aux*)
  89     # A/UX
  90     posix_libs="-lposix"
  91     AC_DEFINE(_POSIX_SOURCE)
  92     ;;
  93 sco*)
  94     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
  95     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
  96     ;;
  97 esac
  98
  99 AC_PROG_INSTALL
 100 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 101         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 102         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h])
 103
 104 AC_HEADER_TIME
 105 AC_HEADER_SYS_WAIT
 106 AC_HEADER_DIRENT
 107 AC_SHORT_D_NAME_LEN
 108 AC_HEADER_STDC
 109
 110 dnl Missing structure components
 111 AC_STRUCT_ST_BLKSIZE
 112 AC_STRUCT_ST_BLOCKS
 113 AC_STRUCT_ST_RDEV
 114
 115 dnl
 116 dnl Check availability of some functions
 117 dnl
 118
 119 AC_CHECK_FUNCS([strerror statfs strftime \
 120                 memmove pwdauth truncate initgroups putenv \
 121                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 122                 sigaction sigemptyset sigprocmask sigaddset \
 123                 sysconf setuid setreuid telldir seekdir])
 124
 125 dnl
 126 dnl getpt is a GNU Extension (glibc 2.1.x)
 127 dnl
 128 AC_CHECK_FUNCS(getpt)
 129
 130 SHADOWLIB=
 131 case $host_os in
 132 linux*)
 133     AC_CHECK_LIB(shadow,pw_encrypt,
 134         [shadow_header=
 135         AC_CHECK_HEADERS([shadow.h shadow/shadow.h],
 136                          [shadow_header=yes; break])
 137         if test -n "$shadow_header"; then
 138             AC_DEFINE(LINUX_SHADOW, 1,
 139                       [Define to use shadow passwords on Linux])
 140             SHADOWLIB=-lshadow
 141         fi])
 142     ;;
 143 esac
 144 AC_SUBST(SHADOWLIB)
 145
 146 NEED_CRYPT_PROTOTYPE=yes
 147 if test x$ac_cv_header_crypt_h = xyes; then
 148 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 149 if (p)
 150 return 0;],[
 151 NEED_CRYPT_PROTOTYPE=no])
 152 else
 153     if test x$ac_cv_header_unistd_h = xyes; then
 154 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 155 if (p)
 156 return 0;],[
 157 NEED_CRYPT_PROTOTYPE=no])
 158     fi
 159 fi
 160 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 161 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 162           [Define if function `crypt' needs a prototype])
 163 fi
 164
 165 dnl
 166 dnl On SCO and some SVR4, crypt is on libcrypt.a
 167 dnl         grantpt in  libpt.a
 168 dnl
 169 LCRYPT=""
 170 AC_CHECK_FUNCS(crypt, , [
 171     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 172         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 173 AC_SUBST(LCRYPT)
 174
 175 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 176
 177 dnl replacing lstat with statlstat on sco makes it more portable between
 178 dnl sco clones
 179 AC_CHECK_FUNCS(statlstat)
 180
 181 dnl
 182 dnl If running under AIX, AC_AIX does not tell us that
 183 dnl
 184 AC_MSG_CHECKING([for AIX defines])
 185 AC_EGREP_CPP(yes,
 186 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 187 yes
 188 #endif
 189 ], [
 190 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 191 AC_MSG_RESULT(yes)
 192 ], [AC_MSG_RESULT(no)])
 193
 194 dnl
 195 dnl This is from GNU fileutils, check aclocal.m4 for more information
 196 dnl
 197 AC_GET_FS_INFO
 198
 199 dnl
 200 dnl Missing typedefs and replacements
 201 dnl
 202
 203 AC_TYPE_MODE_T
 204 AC_CHECK_TYPE(umode_t, int)
 205 AC_CHECK_TYPE(off_t, long)
 206 AC_TYPE_PID_T
 207 AC_TYPE_UID_T
 208 AC_CHECK_TYPE(nlink_t, unsigned int)
 209
 210 AC_FUNC_ALLOCA
 211 AC_FUNC_STRCOLL
 212
 213 dnl
 214 dnl X11 support.
 215 dnl
 216
 217 dnl These variables are only used when building the MC binary
 218 MCCFLAGS=""
 219 MCLIBS=""
 220 AC_SUBST(MCCFLAGS)
 221 AC_SUBST(MCLIBS)
 222
 223 textmode_x11_support="no"
 224 AC_ARG_WITH(tm-x-support,
 225         [--with-tm-x-support        Try getting events from X Window System],
 226         [if test x$withval = xyes; then
 227                 AC_PATH_XTRA
 228                 MCCFLAGS="$X_CFLAGS"
 229                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 230                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 231                           [Define to enable getting events from X Window System])
 232                 textmode_x11_support="yes"
 233         fi
 234 ])
 235
 236 dnl
 237 dnl Network related functions
 238 dnl
 239
 240 AC_CHECK_LIB(nsl, t_accept)
 241 AC_CHECK_LIB(socket, socket)
 242
 243 have_socket=no
 244 AC_CHECK_FUNCS(socket, have_socket=yes)
 245 if test $have_socket = no; then
 246   # socket is not in the default libraries.  See if it's in some other.
 247   for lib in bsd socket inet; do
 248     AC_CHECK_LIB($lib, socket, [
 249         LIBS="$LIBS -l$lib"
 250         have_socket=yes
 251         AC_DEFINE(HAVE_SOCKET)
 252         break])
 253   done
 254 fi
 255
 256 have_gethostbyname=no
 257 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 258 if test $have_gethostbyname = no; then
 259   # gethostbyname is not in the default libraries.  See if it's in some other.
 260   for lib in bsd socket inet; do
 261     AC_CHECK_LIB([$lib], [gethostbyname],
 262                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 263   done
 264 fi
 265
 266 AC_CHECK_FUNCS(socketpair)
 267
 268 dnl
 269 dnl Sequent wants getprocessstats
 270 dnl
 271 AC_CHECK_LIB(seq, get_process_stats, [
 272         LIBS="$LIBS -lseq"
 273         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 274                   [Define if you have function `get_process_stats' and
 275 have to use that instead of gettimeofday])])
 276
 277 MC_VFS_CHECKS
 278
 279 dnl
 280 dnl Install mcserv only if explicitly enabled
 281 dnl
 282 AC_ARG_ENABLE([mcserv-install],
 283               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 284
 285 NETFILES=
 286 if test $have_socket = yes; then
 287    NETFILES="\$(NETFILES)"
 288 fi
 289 AC_SUBST(NETFILES)
 290
 291 vfs_type="normal"
 292 if test $use_vfs = yes
 293 then
 294         AC_MSG_NOTICE([enabling VFS code])
 295         vfs_type="Midnight Commander Virtual File System"
 296 fi
 297
 298 dnl This should be unadorned "slang" or "ncurses"
 299 screen_type=""
 300
 301 dnl Screen manager name (for the output only)
 302 screen_manager=unknown
 303
 304 mouse_lib="xterm only"
 305 case $host_os in
 306 linux*)
 307     AC_ARG_WITH(gpm-mouse,
 308         [--with-gpm-mouse[=base-dir]  Compile with gpm mouse support (Linux only)],
 309         [if test x$withval != xno
 310         then
 311                 if test x$withval != xyes
 312                 then
 313                         LIBS="$LIBS -L$withval/lib"
 314                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 315                 fi
 316                 AC_DEFINE(HAVE_LIBGPM, 1,
 317                           [Define to enable gpm mouse support on Linux])
 318                 mouse_lib="GPM and xterm"
 319                 MCLIBS="-lgpm $MCLIBS"
 320         fi],
 321         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 322                 [AC_DEFINE(HAVE_LIBGPM)
 323                 mouse_lib="GPM and xterm"
 324                 MCLIBS="-lgpm $MCLIBS"],
 325                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 326                 [$LIBS])
 327         ])
 328     ;;
 329 esac
 330
 331 AC_ARG_WITH(ncurses,
 332         [--with-ncurses[=base-dir]    Compile with ncurses/locate base dir],
 333         [if test x$withval != xyes; then
 334                 MCLIBS="$MCLIBS -L$withval/lib"
 335                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 336         fi
 337
 338         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 339                          [ncurses_h_found=yes; break])
 340         if test -z "$ncurses_h_found"; then
 341             AC_MSG_ERROR([Could not find ncurses header])
 342         fi
 343
 344         dnl curses_version is specific to ncurses, it's not in old curses
 345         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 346                      [AC_MSG_ERROR([Could not find ncurses library])])
 347
 348         screen_type="ncurses"
 349         screen_manager="ncurses"
 350         AC_DEFINE(USE_NCURSES, 1,
 351                   [Define to use ncurses for screen management])
 352 ])
 353
 354 AC_ARG_WITH(hsc,
 355         [--with-hsc                 Compile with support for the HSC firewall],
 356         [if test x$withval = xyes; then
 357                 AC_DEFINE(HSC_PROXY, 1,
 358                           [Define if you want to use the HSC firewall])
 359         fi
 360 ])
 361
 362 dnl
 363 dnl Check for the -mandoc package
 364 dnl
 365 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 366 if $HAVE_nroff; then
 367     AC_MSG_CHECKING([for manual formatting macros])
 368     AC_CACHE_VAL(ac_cv_mandoc, [
 369     nroff -mandoc < /dev/null > /dev/null 2>&1
 370     if test $? = 0
 371     then
 372         ac_cv_mandoc=-mandoc
 373     else
 374         ac_cv_mandoc=-man
 375     fi
 376     ])
 377     MANDOC=$ac_cv_mandoc
 378     AC_MSG_RESULT([$MANDOC])
 379 else
 380     MANDOC=-man
 381 fi
 382 AC_SUBST(MANDOC)
 383
 384 dnl
 385 dnl Check if nroff accepts -Tlatin1 or -Tascii
 386 dnl
 387 if $HAVE_nroff; then
 388     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 389     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 390     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 391     if test $? = 0
 392     then
 393         ac_cv_nroff_tascii=" -Tlatin1"
 394     else
 395         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 396         if test $? = 0
 397         then
 398             ac_cv_nroff_tascii=" -Tascii"
 399         else
 400             ac_cv_nroff_tascii=""
 401         fi
 402     fi
 403     ])
 404     if test "x$ac_cv_nroff_tascii" = x; then
 405         AC_MSG_RESULT([no])
 406     else
 407         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 408     fi
 409 fi
 410 TROFFASCII="$ac_cv_nroff_tascii"
 411 AC_SUBST(TROFFASCII)
 412
 413 dnl
 414 dnl Check for - option to file
 415 dnl
 416 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 417 if $HAVE_FILECMD; then
 418     AC_MSG_CHECKING([for - option to file command])
 419     AC_CACHE_VAL(ac_cv_filestdin, [[
 420     cat > conftest.c <<\EOF
 421 /* A comment */
 422 #if 0
 423 #endif
 424 void main(void)
 425 { return; }
 426 EOF
 427     cat > conftest.sed <<\EOF
 428 s/^[^:]*:[      ]*//
 429 s/[     ]*$//
 430 EOF
 431     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 432     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 433     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 434         ac_cv_filestdin=yes
 435     else
 436         ac_cv_filestdin=no
 437     fi
 438     rm conftest.c conftest.sed
 439     ]])
 440
 441     if test x$ac_cv_filestdin = xyes; then
 442         AC_DEFINE(FILE_STDIN, 1,
 443                   [Define if the file command accepts - for stdin])
 444     fi
 445     filestdin=$ac_cv_filestdin
 446     AC_MSG_RESULT([$filestdin])
 447
 448     dnl
 449     dnl Check for -L option to file
 450     dnl
 451
 452 AC_MSG_CHECKING([for -L option to file command])
 453 AC_CACHE_VAL(ac_cv_filel, [
 454 file -L . > /dev/null 2>&1
 455 if test $? = 0
 456 then
 457     ac_cv_filel=yes
 458 else
 459     ac_cv_filel=no
 460 fi
 461 ])
 462 if test x$ac_cv_filel = xyes; then
 463     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 464 fi
 465 filel=$ac_cv_filel
 466 AC_MSG_RESULT([$filel])
 467 fi
 468
 469 AC_MSG_CHECKING([for subshell support])
 470 AC_ARG_WITH(subshell,
 471         [--with-subshell=optional   To disable concurrent shell by default
 472 --without-subshell         To disable concurrent shell completely],
 473         [result=no
 474         if test x$withval = xoptional
 475         then
 476                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 477                           [Define to make subshell support optional])
 478                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 479                           [Define to enable subshell support])
 480                 result="optional"
 481         fi
 482         if test x$withval = xyes
 483         then
 484                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 485                 result="yes"
 486         fi],
 487         [dnl Default: provide the subshell support on non-ultrix machines
 488         case $host_os in
 489         ultrix*)
 490                 result=no
 491                 ;;
 492         *)
 493                 AC_DEFINE(HAVE_SUBSHELL_SUPPORT)
 494                 result=yes
 495                 ;;
 496         esac
 497 ])
 498 AC_MSG_RESULT([$result])
 499 subshell="$result"
 500
 501 AC_DEFINE(REGEX_MALLOC, 1, [Define to make regex use malloc(), not alloca()])
 502
 503 dnl
 504 dnl Memory Allocation Debugger
 505 dnl
 506 mem_debug="none"
 507 AC_ARG_WITH(mad,
 508 [--with-mad                 Developers only: activates MAD (memory debugger)],
 509         [if test x$withval = xyes; then
 510         mem_debug="Janne's MAD library"
 511         AC_DEFINE(HAVE_MAD, 1,
 512                   [Define to use Memory Allocation Debugger (MAD)])
 513         AC_MSG_NOTICE([compiling with memory leak detector])
 514 fi])
 515
 516 dnl
 517 dnl Electric Fence - another memory debugger
 518 dnl
 519 AC_ARG_WITH(efence,
 520 [--with-efence              Developers only: activates Electric Fence],
 521         [if test x$withval = xyes; then
 522         LIBS="$LIBS -lefence"
 523         AC_MSG_NOTICE([compiling with Electric fence])
 524         mem_debug="Electric Fence"
 525 fi])
 526
 527 if test "x$screen_type" != xncurses; then
 528         slang_check_lib=true
 529         slang_term=""
 530         slang_use_system_installed_lib=false
 531         AC_CHECK_LIB(slang,SLang_init_tty,
 532                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 533                                   [slang_h_found=yes; break])
 534                 if test "x$slang_h_found" = xyes; then
 535                      slang_use_system_installed_lib=true
 536                      slang_check_lib=false
 537                 fi
 538         ])
 539 fi
 540
 541 AC_ARG_WITH(terminfo,
 542         [--with-terminfo            SLANG: Force usage of terminfo],[
 543         if test x$withval = xyes; then
 544                 AC_USE_TERMINFO
 545                 slang_check_lib=false
 546                 slang_use_system_installed_lib=false
 547         fi]
 548 )
 549
 550 AC_ARG_WITH(termcap,
 551         [--with-termcap             SLANG: Force usage of termcap],[
 552         if test x$withval = xyes; then
 553                 AC_USE_TERMCAP
 554                 slang_check_lib=false
 555                 slang_use_system_installed_lib=false
 556         fi]
 557 )
 558
 559 AC_ARG_WITH(included-slang,
 560         [--with-included-slang      SLANG: use the SLang library included here],[
 561         if test x$withval = xyes; then
 562             slang_use_system_installed_lib=false
 563             slang_check_lib=true
 564         fi]
 565 )
 566
 567 AC_ARG_WITH(slang,
 568         [--with-slang              Compile with the slang screen manager],[
 569         if test x$withval = xyes; then
 570                 AC_WITH_SLANG
 571         fi
 572 ])
 573
 574 LIBEDIT_A=""
 575 MCEDIT=""
 576 LEDIT=""
 577 EDIT_msg=""
 578 AC_ARG_WITH(edit,
 579         [--with-edit                Enable internal editor],
 580         [if test x$withval = xyes
 581         then
 582                 AC_WITH_EDIT
 583         else
 584                 EDIT_msg="no"
 585         fi],
 586         [dnl Default: provide the internal editor
 587         AC_WITH_EDIT
 588 ])
 589 AC_SUBST(LIBEDIT_A)
 590 AC_SUBST(MCEDIT)
 591 AC_SUBST(LEDIT)
 592
 593 undelfs_o=""
 594
 595 if test $use_vfs = yes; then
 596     AC_ARG_WITH(ext2undel,
 597         [--with-ext2undel           Compile with ext2 undelete code],[
 598         if test x$withval != xno;
 599         then
 600                 if test x$withval != xyes
 601                 then
 602                         LIBS="$LIBS -L$withval/lib"
 603                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 604                 fi
 605                 AC_EXT2_UNDEL
 606         fi],[
 607         dnl Default: detect
 608         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 609     ])
 610 fi
 611
 612 AC_SUBST(undelfs_o)
 613
 614
 615 dnl Ncurses specific checks
 616 dnl
 617 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 618 dnl or you'll have to press Esc three times to dismiss a dialog box.
 619 dnl
 620 if test "x$screen_type" = xncurses; then
 621   save_LIBS="$LIBS"
 622   LIBS="$MCLIBS $LIBS"
 623   AC_CACHE_CHECK([for ESCDELAY variable],
 624                  [mc_cv_ncurses_escdelay],
 625                  [AC_TRY_COMPILE([], [
 626                         extern int ESCDELAY;
 627                         int main ()
 628                         {
 629                           ESCDELAY = 0;
 630                         }
 631                         ],
 632                         [mc_cv_ncurses_escdelay=yes],
 633                         [mc_cv_ncurses_escdelay=no]
 634                   )
 635   ])
 636   if test "$mc_cv_ncurses_escdelay" = yes; then
 637     AC_DEFINE(HAVE_ESCDELAY, 1,
 638               [Define if ncurses has ESCDELAY variable])
 639   fi
 640
 641   AC_CHECK_FUNCS(resizeterm)
 642   LIBS="$save_LIBS"
 643 fi
 644
 645 if test "x$screen_type" = "x"; then
 646     AC_WITH_SLANG
 647 fi
 648
 649 dnl
 650 dnl The variables used for expanding the auto saver.
 651 dnl
 652 cons_saver=""
 653 install_saver="no"
 654 PAMLIBS=""
 655 case $host_os in
 656 linux*)
 657     cons_saver="cons.saver"
 658     install_saver="yes"
 659
 660     dnl
 661     dnl On Linux, check for PAM authentication available
 662     dnl
 663     AC_CHECK_LIB(pam, pam_start, [
 664         AC_DEFINE(HAVE_PAM, 1,
 665                   [Define if PAM (Pluggable Authentication Modules) is available])
 666         PAMLIBS="-lpam -ldl"
 667     ],[],[-ldl])
 668     ;;
 669 esac
 670 AC_SUBST(cons_saver)
 671 AC_SUBST(PAMLIBS)
 672
 673 dnl
 674 dnl User visible support for charset conversion.
 675 dnl
 676 AC_ARG_ENABLE([charset],
 677               [--enable-charset           Support for charset selection and conversion])
 678 have_charset=
 679 if test "x$enable_charset" = xyes; then
 680   if test -z "$am_cv_func_iconv"; then
 681     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 682   else
 683     AC_DEFINE(HAVE_CHARSET, 1,
 684               [Define to enable charset selection and conversion])
 685     have_charset=yes
 686   fi
 687 fi
 688
 689 if test "$GLIBC21" != yes; then
 690     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 691 fi
 692
 693 dnl
 694 dnl This code should be moved to the ac_WITH_SLANG
 695 dnl
 696 dnl We check for the existance of setupterm on curses library
 697 dnl this is required to load certain definitions on some termcaps
 698 dnl editions (AIX and OSF/1 I seem to remember).
 699 dnl Note that we avoid using setupterm
 700 if test "x$screen_type" = xslang; then
 701         case $host_os in
 702         linux*)
 703                 ;;
 704         *)
 705                 AC_CHECK_LIB(curses,setupterm,
 706                         [AC_TRY_COMPILE([
 707 #include <curses.h>
 708 #include <term.h>],[
 709    if (key_end == parm_insert_line)
 710         return 1;
 711    return 0;
 712 ],
 713                         [MCLIBS="$MCLIBS -lcurses"
 714                         AC_DEFINE(USE_SETUPTERM, 1,
 715                                   [Define to use function `setupterm'
 716 from `curses' library in S-Lang])])
 717                 ])
 718         esac
 719 fi
 720
 721 LIBS="$LIBS $posix_libs"
 722
 723 AC_SUBST(CFLAGS)
 724 AC_SUBST(CPPFLAGS)
 725 AC_SUBST(LDFLAGS)
 726 AC_SUBST(LIBS)
 727
 728 if test "x$SAMBAFILES" != x; then
 729   AC_CONFIG_SUBDIRS([vfs/samba])
 730 fi
 731
 732 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 733 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 734 AM_CONDITIONAL(USE_VFS_NET, [test -n "$NETFILES"])
 735 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 736 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 737 AM_CONDITIONAL(MCSERV_INSTALL,
 738                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 739 AM_CONDITIONAL(INCLUDED_SLANG,
 740                [test "x$slang_use_system_installed_lib" = xfalse])
 741 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 742 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 743
 744 AH_BOTTOM([#include <extraconf.h>])
 745
 746 AC_CONFIG_FILES([
 747 Makefile
 748 mc.spec
 749 doc/Makefile
 750 vfs/Makefile
 751 vfs/extfs/Makefile
 752 lib/Makefile
 753 src/Makefile
 754 slang/Makefile
 755 edit/Makefile
 756 syntax/Makefile
 757 pc/Makefile
 758
 759 lib/mc.ext
 760 lib/mc.sh
 761 lib/mc.csh
 762
 763 mcfn_install
 764
 765 vfs/extfs/deb
 766 vfs/extfs/ftplist
 767 vfs/extfs/lslR
 768 vfs/extfs/uar
 769 vfs/extfs/ucpio
 770 vfs/extfs/ulha
 771 vfs/extfs/uha
 772 vfs/extfs/urar
 773 vfs/extfs/uzoo
 774
 775 doc/mc.1 doc/mcedit.1 doc/mcserv.8 doc/ru/mc.1 doc/ru/Makefile
 776
 777
 778 intl/Makefile po/Makefile.in
 779 ])
 780
 781 AC_CONFIG_COMMANDS(potfiles,
 782     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 783
 784 AC_OUTPUT
 785
 786 if test "x$screen_type" = xslang; then
 787     screen_manager="${screen_manager}${slang_term}"
 788 fi
 789
 790 echo "
 791 Configuration:
 792
 793   Source code location:       ${srcdir}
 794   Compiler:                   ${CC}
 795   Compiler flags:             ${CFLAGS}
 796   File system:                ${vfs_type}
 797                               ${vfs_flags}
 798   Screen manager:             ${screen_manager}
 799   Install console saver:      ${install_saver}
 800   Mouse support:              ${mouse_lib}
 801   X11 events support:         ${textmode_x11_support}
 802   Debugger code:              ${mem_debug}
 803   With subshell support:      ${subshell}
 804   Internal editor:            ${EDIT_msg}
 805   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 806 "