configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.6.0-pre1a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_CANONICAL_HOST
  15
  16 AC_AIX
  17 AC_MINIX
  18 AC_ISC_POSIX
  19
  20 AC_PROG_CC_STDC
  21
  22
  23 dnl
  24 dnl Find glib 1.2.x.  This check should be kept close to the beginning,
  25 dnl as it tends to fail often.
  26 dnl
  27
  28 dnl This temporary variable is a workaround for a bug in Autoconf-2.53
  29 glib_path=$PATH:/usr/local/bin
  30
  31 dnl Klugde for FreeBSD, where glib-config is renamed to glib12-config.
  32 AC_PATH_PROGS([GLIB_CONFIG], [glib-config glib12-config],,[$glib_path])
  33
  34 AC_ARG_VAR([GLIB_CONFIG], [Path to glib-config])
  35 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  36 AC_SUBST(GLIB_LIBS)
  37
  38
  39 AC_HEADER_MAJOR
  40 AC_C_CONST
  41 AC_SYS_LARGEFILE
  42
  43 AC_PROG_LN_S
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 dnl Only list browsers here that can be run in background (i.e. with `&')
  47 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  48
  49 dnl
  50 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  51 dnl We use only part of the functionality of mmap, so on AIX,
  52 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  53 dnl
  54 AC_ARG_WITH(mmap,
  55         [  --with-mmap              Force using the mmap call (only useful on AIX)],
  56         [case $withval in
  57 yes)
  58         ac_cv_func_mmap_fixed_mapped=yes
  59         AC_MSG_NOTICE([forcing MMAP support])
  60         ;;
  61 no)
  62         ac_cv_func_mmap_fixed_mapped=no
  63         AC_MSG_NOTICE([disabling MMAP support])
  64         ;;
  65 esac])
  66 AC_FUNC_MMAP
  67
  68 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv \
  69 nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  70
  71 dnl
  72 dnl Internationalization
  73 dnl
  74 AM_GNU_GETTEXT
  75 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  76     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  77 fi
  78
  79 dnl
  80 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  81 dnl
  82 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  83
  84 dnl
  85 dnl Enforce coding standards
  86 dnl
  87 if test "x$GCC" = xyes; then
  88     CFLAGS="$CFLAGS -Wall"
  89 fi
  90
  91 dnl
  92 dnl OS specific flags.
  93 dnl
  94
  95 posix_libs=""
  96 case $host_os in
  97 aux*)
  98     # A/UX
  99     posix_libs="-lposix"
 100     AC_DEFINE(_POSIX_SOURCE)
 101     ;;
 102 sco*)
 103     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
 104     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
 105     ;;
 106 esac
 107
 108 AC_PROG_INSTALL
 109 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 110         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 111         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h \
 112         arpa/inet.h])
 113
 114 AC_HEADER_TIME
 115 AC_HEADER_SYS_WAIT
 116 AC_HEADER_DIRENT
 117 AC_HEADER_STDC
 118
 119 dnl Missing structure components
 120 AC_STRUCT_ST_BLKSIZE
 121 AC_STRUCT_ST_BLOCKS
 122 AC_STRUCT_ST_RDEV
 123
 124 dnl
 125 dnl Check availability of some functions
 126 dnl
 127
 128 AC_CHECK_FUNCS([strerror statfs strftime \
 129                 memmove pwdauth truncate initgroups putenv \
 130                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 131                 sigaction sigemptyset sigprocmask sigaddset \
 132                 sysconf setuid setreuid telldir seekdir])
 133
 134 dnl
 135 dnl getpt is a GNU Extension (glibc 2.1.x)
 136 dnl
 137 AC_CHECK_FUNCS(getpt)
 138
 139 dnl
 140 dnl Password encryption support for mcserv
 141 dnl Check if function crypt needs a prototype
 142 dnl
 143 NEED_CRYPT_PROTOTYPE=yes
 144 if test x$ac_cv_header_crypt_h = xyes; then
 145 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 146 if (p)
 147 return 0;],[
 148 NEED_CRYPT_PROTOTYPE=no])
 149 else
 150     if test x$ac_cv_header_unistd_h = xyes; then
 151 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 152 if (p)
 153 return 0;],[
 154 NEED_CRYPT_PROTOTYPE=no])
 155     fi
 156 fi
 157 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 158 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 159           [Define if function `crypt' needs a prototype])
 160 fi
 161
 162 dnl
 163 dnl On SCO and some SVR4, crypt is on libcrypt.a
 164 dnl         grantpt in  libpt.a
 165 dnl
 166 LCRYPT=""
 167 AC_CHECK_FUNCS(crypt, , [
 168     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 169         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 170 AC_SUBST(LCRYPT)
 171
 172 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 173
 174 dnl replacing lstat with statlstat on sco makes it more portable between
 175 dnl sco clones
 176 AC_CHECK_FUNCS(statlstat)
 177
 178 dnl
 179 dnl If running under AIX, AC_AIX does not tell us that
 180 dnl
 181 AC_MSG_CHECKING([for AIX defines])
 182 AC_EGREP_CPP(yes,
 183 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 184 yes
 185 #endif
 186 ], [
 187 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 188 AC_MSG_RESULT(yes)
 189 ], [AC_MSG_RESULT(no)])
 190
 191 dnl
 192 dnl This is from GNU fileutils, check aclocal.m4 for more information
 193 dnl
 194 AC_GET_FS_INFO
 195
 196 dnl
 197 dnl Missing typedefs and replacements
 198 dnl
 199
 200 AC_TYPE_MODE_T
 201 AC_CHECK_TYPE(umode_t, int)
 202 AC_CHECK_TYPE(off_t, long)
 203 AC_TYPE_PID_T
 204 AC_TYPE_UID_T
 205 AC_CHECK_TYPE(nlink_t, unsigned int)
 206
 207 AC_FUNC_ALLOCA
 208 AC_FUNC_STRCOLL
 209
 210 dnl
 211 dnl X11 support.
 212 dnl
 213
 214 textmode_x11_support="no"
 215 AC_ARG_WITH(tm-x-support,
 216         [  --with-tm-x-support      Get keyboard events from X Window System [[no]]],
 217         [if test x$withval = xyes; then
 218                 AC_PATH_XTRA
 219                 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 220                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 221                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 222                           [Define to enable getting events from X Window System])
 223                 textmode_x11_support="yes"
 224         fi
 225 ])
 226
 227 dnl
 228 dnl Network related functions
 229 dnl
 230
 231 AC_CHECK_LIB(nsl, t_accept)
 232 AC_CHECK_LIB(socket, socket)
 233
 234 have_socket=no
 235 AC_CHECK_FUNCS(socket, have_socket=yes)
 236 if test $have_socket = no; then
 237   # socket is not in the default libraries.  See if it's in some other.
 238   for lib in bsd socket inet; do
 239     AC_CHECK_LIB($lib, socket, [
 240         LIBS="$LIBS -l$lib"
 241         have_socket=yes
 242         AC_DEFINE(HAVE_SOCKET)
 243         break])
 244   done
 245 fi
 246
 247 have_gethostbyname=no
 248 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 249 if test $have_gethostbyname = no; then
 250   # gethostbyname is not in the default libraries.  See if it's in some other.
 251   for lib in bsd socket inet; do
 252     AC_CHECK_LIB([$lib], [gethostbyname],
 253                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 254   done
 255 fi
 256
 257 AC_CHECK_FUNCS(socketpair)
 258
 259 dnl
 260 dnl Sequent wants getprocessstats
 261 dnl
 262 AC_CHECK_LIB(seq, get_process_stats, [
 263         LIBS="$LIBS -lseq"
 264         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 265                   [Define if you have function `get_process_stats' and
 266 have to use that instead of gettimeofday])])
 267
 268 MC_VFS_CHECKS
 269
 270 dnl
 271 dnl Install mcserv only if explicitly enabled
 272 dnl
 273 AC_ARG_ENABLE([mcserv-install],
 274               [  --enable-mcserv-install  Install mcserv - Midnight Commander file server [[no]]])
 275
 276 vfs_type="normal"
 277 if test $use_vfs = yes
 278 then
 279         AC_MSG_NOTICE([enabling VFS code])
 280         vfs_type="Midnight Commander Virtual File System"
 281 fi
 282
 283 dnl This should be unadorned "slang" or "ncurses"
 284 screen_type=""
 285
 286 dnl Screen manager name (for the output only)
 287 screen_manager=unknown
 288
 289 mouse_lib="xterm only"
 290 case $host_os in
 291 linux*)
 292     AC_ARG_WITH(gpm-mouse,
 293         [  --with-gpm-mouse[[=base-dir]]  Compile with gpm mouse support (Linux only)
 294                                [[yes if found]]],
 295         [if test x$withval != xno
 296         then
 297                 if test x$withval != xyes
 298                 then
 299                         LDFLAGS="$LDFLAGS -L$withval/lib"
 300                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 301                 fi
 302                 AC_DEFINE(HAVE_LIBGPM, 1,
 303                           [Define to enable gpm mouse support on Linux])
 304                 mouse_lib="GPM and xterm"
 305                 MCLIBS="-lgpm $MCLIBS"
 306         fi],
 307         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 308                 [AC_DEFINE(HAVE_LIBGPM)
 309                 mouse_lib="GPM and xterm"
 310                 MCLIBS="-lgpm $MCLIBS"],
 311                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 312                 [$LIBS])
 313         ])
 314     ;;
 315 esac
 316
 317 AC_ARG_WITH(ncurses,
 318         [  --with-ncurses[[=base-dir]]    Compile with ncurses [[no]]],
 319 [if test x$withval != xno; then
 320         if test x$withval != xyes; then
 321                 LDFLAGS="$LDFLAGS -L$withval/lib"
 322                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 323         fi
 324
 325         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 326                          [ncurses_h_found=yes; break])
 327         if test -z "$ncurses_h_found"; then
 328             AC_MSG_ERROR([Could not find ncurses header])
 329         fi
 330
 331         dnl curses_version is specific to ncurses, it's not in old curses
 332         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 333                      [AC_MSG_ERROR([Could not find ncurses library])])
 334
 335         screen_type="ncurses"
 336         screen_manager="ncurses"
 337         AC_DEFINE(USE_NCURSES, 1,
 338                   [Define to use ncurses for screen management])
 339 fi
 340 ])
 341
 342 AC_ARG_WITH(hsc,
 343         [  --with-hsc               Compile with support for HSC firewall instead
 344                            of FTP proxy [[no]]],
 345         [if test x$withval = xyes; then
 346                 AC_DEFINE(HSC_PROXY, 1,
 347                           [Define if you want to use the HSC firewall])
 348         fi
 349 ])
 350
 351 dnl
 352 dnl Check for the -mandoc package
 353 dnl
 354 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 355 if $HAVE_nroff; then
 356     AC_MSG_CHECKING([for manual formatting macros])
 357     AC_CACHE_VAL(ac_cv_mandoc, [
 358     nroff -mandoc < /dev/null > /dev/null 2>&1
 359     if test $? = 0
 360     then
 361         ac_cv_mandoc=-mandoc
 362     else
 363         ac_cv_mandoc=-man
 364     fi
 365     ])
 366     MANDOC=$ac_cv_mandoc
 367     AC_MSG_RESULT([$MANDOC])
 368 else
 369     MANDOC=-man
 370 fi
 371 AC_SUBST(MANDOC)
 372
 373 dnl
 374 dnl Check if nroff accepts -Tlatin1 or -Tascii
 375 dnl
 376 if $HAVE_nroff; then
 377     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 378     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 379     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 380     if test $? = 0
 381     then
 382         ac_cv_nroff_tascii=" -Tlatin1"
 383     else
 384         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 385         if test $? = 0
 386         then
 387             ac_cv_nroff_tascii=" -Tascii"
 388         else
 389             ac_cv_nroff_tascii=""
 390         fi
 391     fi
 392     ])
 393     if test "x$ac_cv_nroff_tascii" = x; then
 394         AC_MSG_RESULT([no])
 395     else
 396         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 397     fi
 398 fi
 399 TROFFASCII="$ac_cv_nroff_tascii"
 400 AC_SUBST(TROFFASCII)
 401
 402 dnl
 403 dnl Check for - option to file
 404 dnl
 405 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 406 if $HAVE_FILECMD; then
 407     AC_MSG_CHECKING([for - option to file command])
 408     AC_CACHE_VAL(ac_cv_filestdin, [[
 409     cat > conftest.c <<\EOF
 410 /* A comment */
 411 #if 0
 412 #endif
 413 void main(void)
 414 { return; }
 415 EOF
 416     cat > conftest.sed <<\EOF
 417 s/^[^:]*:[      ]*//
 418 s/[     ]*$//
 419 EOF
 420     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 421     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 422     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 423         ac_cv_filestdin=yes
 424     else
 425         ac_cv_filestdin=no
 426     fi
 427     rm conftest.c conftest.sed
 428     ]])
 429
 430     if test x$ac_cv_filestdin = xyes; then
 431         AC_DEFINE(FILE_STDIN, 1,
 432                   [Define if the file command accepts - for stdin])
 433     fi
 434     filestdin=$ac_cv_filestdin
 435     AC_MSG_RESULT([$filestdin])
 436
 437     dnl
 438     dnl Check for -L option to file
 439     dnl
 440
 441 AC_MSG_CHECKING([for -L option to file command])
 442 AC_CACHE_VAL(ac_cv_filel, [
 443 file -L . > /dev/null 2>&1
 444 if test $? = 0
 445 then
 446     ac_cv_filel=yes
 447 else
 448     ac_cv_filel=no
 449 fi
 450 ])
 451 if test x$ac_cv_filel = xyes; then
 452     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 453 fi
 454 filel=$ac_cv_filel
 455 AC_MSG_RESULT([$filel])
 456 fi
 457
 458
 459 AC_MSG_CHECKING([for subshell support])
 460 AC_ARG_WITH(subshell,
 461         [  --with-subshell          Compile in concurrent subshell [[yes]]
 462   --with-subshell=optional Don't run concurrent shell by default [[no]]],
 463         [result=no
 464         if test x$withval = xoptional
 465         then
 466                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 467                           [Define to make subshell support optional])
 468                 result="optional"
 469         fi
 470         if test x$withval = xyes
 471         then
 472                 result="yes"
 473         fi],
 474         [dnl Default: enable the subshell support
 475         result="yes"
 476 ])
 477 if test "x$result" != xno; then
 478         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 479                   [Define to enable subshell support])
 480 fi
 481 AC_MSG_RESULT([$result])
 482 subshell="$result"
 483
 484 if test "x$screen_type" != xncurses; then
 485         slang_check_lib=true
 486         slang_term=""
 487         slang_use_system_installed_lib=false
 488         AC_CHECK_LIB(slang,SLang_init_tty,
 489                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 490                                   [slang_h_found=yes; break])
 491                 if test "x$slang_h_found" = xyes; then
 492                      slang_use_system_installed_lib=true
 493                      slang_check_lib=false
 494                 fi
 495         ])
 496 fi
 497
 498 AC_ARG_WITH(slang,
 499         [  --with-slang             Compile with S-Lang screen manager [[yes]]],
 500         [if test x$withval = xyes; then
 501                 AC_WITH_SLANG
 502         fi]
 503 )
 504
 505 AC_ARG_WITH(included-slang,
 506         [  --with-included-slang    Use S-Lang library included with mc sources
 507                            [[use installed library if found]]],
 508         [if test x$withval = xyes; then
 509             slang_use_system_installed_lib=false
 510             slang_check_lib=true
 511         fi]
 512 )
 513
 514 AC_ARG_WITH(termcap,
 515         [  --with-termcap           Same as above, and try using termcap database [[no]]],
 516         [if test x$withval = xyes; then
 517                 AC_USE_TERMCAP
 518                 slang_check_lib=false
 519                 slang_use_system_installed_lib=false
 520         fi]
 521 )
 522
 523 LIBEDIT_A=""
 524 MCEDIT=""
 525 LEDIT=""
 526 EDIT_msg=""
 527 AC_ARG_WITH(edit,
 528         [  --with-edit              Enable internal editor [[yes]]],
 529         [if test x$withval = xyes
 530         then
 531                 AC_WITH_EDIT
 532         else
 533                 EDIT_msg="no"
 534         fi],
 535         [dnl Default: provide the internal editor
 536         AC_WITH_EDIT
 537 ])
 538 AC_SUBST(LIBEDIT_A)
 539 AC_SUBST(MCEDIT)
 540 AC_SUBST(LEDIT)
 541
 542 undelfs_o=""
 543
 544 if test $use_vfs = yes; then
 545     AC_ARG_WITH(ext2undel,
 546         [  --with-ext2undel         Compile with ext2 undelete code [[yes if found]]],
 547         [if test x$withval != xno; then
 548                 if test x$withval != xyes; then
 549                         LDFLAGS="$LDFLAGS -L$withval/lib"
 550                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 551                 fi
 552                 AC_EXT2_UNDEL
 553         fi],[
 554         dnl Default: detect
 555         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 556     ])
 557 fi
 558
 559 AC_SUBST(undelfs_o)
 560
 561
 562 dnl Ncurses specific checks
 563 dnl
 564 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 565 dnl or you'll have to press Esc three times to dismiss a dialog box.
 566 dnl
 567 if test "x$screen_type" = xncurses; then
 568   save_LIBS="$LIBS"
 569   LIBS="$MCLIBS $LIBS"
 570   AC_CACHE_CHECK([for ESCDELAY variable],
 571                  [mc_cv_ncurses_escdelay],
 572                  [AC_TRY_COMPILE([], [
 573                         extern int ESCDELAY;
 574                         int main ()
 575                         {
 576                           ESCDELAY = 0;
 577                         }
 578                         ],
 579                         [mc_cv_ncurses_escdelay=yes],
 580                         [mc_cv_ncurses_escdelay=no]
 581                   )
 582   ])
 583   if test "$mc_cv_ncurses_escdelay" = yes; then
 584     AC_DEFINE(HAVE_ESCDELAY, 1,
 585               [Define if ncurses has ESCDELAY variable])
 586   fi
 587
 588   AC_CHECK_FUNCS(resizeterm)
 589   LIBS="$save_LIBS"
 590 fi
 591
 592 if test "x$screen_type" = "x"; then
 593     AC_WITH_SLANG
 594 fi
 595
 596 dnl
 597 dnl The variables used for expanding the auto saver.
 598 dnl
 599 cons_saver=""
 600 install_saver="no"
 601 PAMLIBS=""
 602 case $host_os in
 603 linux*)
 604     cons_saver="cons.saver"
 605     install_saver="yes"
 606
 607     dnl
 608     dnl On Linux, check for PAM authentication available
 609     dnl
 610     AC_CHECK_LIB(pam, pam_start, [
 611         AC_DEFINE(HAVE_PAM, 1,
 612                   [Define if PAM (Pluggable Authentication Modules) is available])
 613         PAMLIBS="-lpam -ldl"
 614     ],[],[-ldl])
 615     ;;
 616 esac
 617 AC_SUBST(cons_saver)
 618 AC_SUBST(PAMLIBS)
 619
 620 dnl
 621 dnl User visible support for charset conversion.
 622 dnl
 623 AC_ARG_ENABLE([charset],
 624               [  --enable-charset         Support for charset selection and conversion [[no]]])
 625 have_charset=
 626 if test "x$enable_charset" = xyes; then
 627   if test "x$am_cv_func_iconv" != xyes; then
 628     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 629   else
 630     AC_DEFINE(HAVE_CHARSET, 1,
 631               [Define to enable charset selection and conversion])
 632     have_charset=yes
 633   fi
 634 fi
 635
 636 if test "$GLIBC21" != yes; then
 637     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 638 fi
 639
 640 dnl
 641 dnl This code should be moved to the ac_WITH_SLANG
 642 dnl
 643 dnl We check for the existance of setupterm on curses library
 644 dnl this is required to load certain definitions on some termcaps
 645 dnl editions (AIX and OSF/1 I seem to remember).
 646 dnl Note that we avoid using setupterm
 647 if test "x$screen_type" = xslang; then
 648         case $host_os in
 649         linux*)
 650                 ;;
 651         *)
 652                 AC_CHECK_LIB(curses,setupterm,
 653                         [AC_TRY_COMPILE([
 654 #include <curses.h>
 655 #include <term.h>],[
 656    if (key_end == parm_insert_line)
 657         return 1;
 658    return 0;
 659 ],
 660                         [MCLIBS="$MCLIBS -lcurses"
 661                         AC_DEFINE(USE_SETUPTERM, 1,
 662                                   [Define to use function `setupterm'
 663 from `curses' library in S-Lang])])
 664                 ])
 665         esac
 666 fi
 667
 668 LIBS="$LIBS $posix_libs"
 669
 670 AC_SUBST(CFLAGS)
 671 AC_SUBST(CPPFLAGS)
 672 AC_SUBST(LDFLAGS)
 673 AC_SUBST(LIBS)
 674
 675 dnl Libraries used only when building the mc binary
 676 AC_SUBST(MCLIBS)
 677
 678 dnl Version for the RedHat package, without dashes
 679 RH_VERSION=`echo $VERSION | sed 's/-//'`
 680 AC_SUBST(RH_VERSION)
 681
 682 if test "x$SAMBAFILES" != x; then
 683   AC_CONFIG_SUBDIRS([vfs/samba])
 684 fi
 685
 686 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 687 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 688 AM_CONDITIONAL(USE_VFS_NET, [test x"$use_net_code" = xtrue])
 689 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 690 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 691 AM_CONDITIONAL(MCSERV_INSTALL,
 692                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 693 AM_CONDITIONAL(INCLUDED_SLANG,
 694                [test "x$slang_use_system_installed_lib" = xfalse])
 695 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 696 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 697
 698 AH_BOTTOM([#include <extraconf.h>])
 699
 700 AC_CONFIG_FILES([
 701 Makefile
 702 mc.spec
 703 doc/Makefile
 704 vfs/Makefile
 705 vfs/extfs/Makefile
 706 lib/Makefile
 707 src/Makefile
 708 slang/Makefile
 709 edit/Makefile
 710 syntax/Makefile
 711 pc/Makefile
 712
 713 lib/mc.ext
 714 lib/mc.sh
 715 lib/mc.csh
 716
 717 vfs/extfs/deb
 718 vfs/extfs/ftplist
 719 vfs/extfs/lslR
 720 vfs/extfs/uar
 721 vfs/extfs/ucpio
 722 vfs/extfs/ulha
 723 vfs/extfs/uha
 724 vfs/extfs/urar
 725 vfs/extfs/uzoo
 726
 727 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 728 doc/es/mc.1 doc/es/Makefile
 729 doc/hu/Makefile
 730 doc/it/mc.1 doc/it/Makefile
 731 doc/pl/mc.1 doc/pl/Makefile
 732 doc/ru/mc.1 doc/ru/Makefile
 733
 734 intl/Makefile po/Makefile.in
 735 ])
 736
 737 AC_CONFIG_COMMANDS(potfiles,
 738     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 739
 740 AC_OUTPUT
 741
 742 if test "x$screen_type" = xslang; then
 743     screen_manager="${screen_manager}${slang_term}"
 744 fi
 745
 746 echo "
 747 Configuration:
 748
 749   Source code location:       ${srcdir}
 750   Compiler:                   ${CC}
 751   Compiler flags:             ${CFLAGS}
 752   File system:                ${vfs_type}
 753                               ${vfs_flags}
 754   Screen manager:             ${screen_manager}
 755   Install console saver:      ${install_saver}
 756   Mouse support:              ${mouse_lib}
 757   X11 events support:         ${textmode_x11_support}
 758   Debugger code:              ${mem_debug}
 759   With subshell support:      ${subshell}
 760   Internal editor:            ${EDIT_msg}
 761   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 762 "