configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.6.0-pre1a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_CANONICAL_HOST
  15
  16 AC_AIX
  17 AC_MINIX
  18 AC_ISC_POSIX
  19
  20 AC_PROG_CC_STDC
  21
  22
  23 dnl
  24 dnl Find glib 1.2.x.  This check should be kept close to the beginning,
  25 dnl as it tends to fail often.
  26 dnl
  27
  28 dnl This temporary variable is a workaround for a bug in Autoconf-2.53
  29 glib_path=$PATH:/usr/local/bin
  30
  31 dnl Klugde for FreeBSD, where glib-config is renamed to glib12-config.
  32 AC_PATH_PROGS([GLIB_CONFIG], [glib-config glib12-config],,[$glib_path])
  33
  34 AC_ARG_VAR([GLIB_CONFIG], [Path to glib-config])
  35 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  36 AC_SUBST(GLIB_LIBS)
  37
  38
  39 AC_HEADER_MAJOR
  40 AC_C_CONST
  41 AC_SYS_LARGEFILE
  42
  43 AC_PROG_LN_S
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 dnl Only list browsers here that can be run in background (i.e. with `&')
  47 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  48
  49 dnl
  50 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  51 dnl We use only part of the functionality of mmap, so on AIX,
  52 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  53 dnl
  54 AC_ARG_WITH(mmap,
  55         [  --with-mmap              Force using the mmap call (only useful on AIX)],
  56         [case $withval in
  57 yes)
  58         ac_cv_func_mmap_fixed_mapped=yes
  59         AC_MSG_NOTICE([forcing MMAP support])
  60         ;;
  61 no)
  62         ac_cv_func_mmap_fixed_mapped=no
  63         AC_MSG_NOTICE([disabling MMAP support])
  64         ;;
  65 esac])
  66 AC_FUNC_MMAP
  67
  68 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv \
  69 nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  70
  71 dnl
  72 dnl Internationalization
  73 dnl
  74 AM_GNU_GETTEXT
  75 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  76     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  77 fi
  78
  79 dnl
  80 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  81 dnl
  82 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  83
  84 dnl
  85 dnl Enforce coding standards
  86 dnl
  87 if test "x$GCC" = xyes; then
  88     CFLAGS="$CFLAGS -Wall"
  89 fi
  90
  91 dnl
  92 dnl OS specific flags.
  93 dnl
  94
  95 posix_libs=""
  96 case $host_os in
  97 aux*)
  98     # A/UX
  99     posix_libs="-lposix"
 100     AC_DEFINE(_POSIX_SOURCE)
 101     ;;
 102 sco*)
 103     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
 104     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
 105     ;;
 106 esac
 107
 108 AC_PROG_INSTALL
 109 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 110         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 111         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h \
 112         arpa/inet.h])
 113
 114 AC_HEADER_TIME
 115 AC_HEADER_SYS_WAIT
 116 AC_HEADER_DIRENT
 117 AC_HEADER_STDC
 118
 119 dnl Missing structure components
 120 AC_STRUCT_ST_BLKSIZE
 121 AC_STRUCT_ST_BLOCKS
 122 AC_STRUCT_ST_RDEV
 123
 124 dnl
 125 dnl Check availability of some functions
 126 dnl
 127
 128 AC_CHECK_FUNCS([strerror statfs strftime \
 129                 memmove pwdauth truncate initgroups putenv \
 130                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 131                 sigaction sigemptyset sigprocmask sigaddset \
 132                 sysconf setuid setreuid telldir seekdir])
 133
 134 dnl
 135 dnl getpt is a GNU Extension (glibc 2.1.x)
 136 dnl
 137 AC_CHECK_FUNCS(getpt)
 138
 139
 140 dnl
 141 dnl On SCO and some SVR4, crypt is on libcrypt.a
 142 dnl         grantpt in  libpt.a
 143 dnl
 144 LCRYPT=""
 145 AC_CHECK_FUNCS(crypt, , [
 146     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 147         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 148 AC_SUBST(LCRYPT)
 149
 150 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 151
 152 dnl replacing lstat with statlstat on sco makes it more portable between
 153 dnl sco clones
 154 AC_CHECK_FUNCS(statlstat)
 155
 156 dnl
 157 dnl If running under AIX, AC_AIX does not tell us that
 158 dnl
 159 AC_MSG_CHECKING([for AIX defines])
 160 AC_EGREP_CPP(yes,
 161 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 162 yes
 163 #endif
 164 ], [
 165 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 166 AC_MSG_RESULT(yes)
 167 ], [AC_MSG_RESULT(no)])
 168
 169 dnl
 170 dnl This is from GNU fileutils, check aclocal.m4 for more information
 171 dnl
 172 AC_GET_FS_INFO
 173
 174 dnl
 175 dnl Missing typedefs and replacements
 176 dnl
 177
 178 AC_TYPE_MODE_T
 179 AC_CHECK_TYPE(umode_t, int)
 180 AC_CHECK_TYPE(off_t, long)
 181 AC_TYPE_PID_T
 182 AC_TYPE_UID_T
 183 AC_CHECK_TYPE(nlink_t, unsigned int)
 184
 185 AC_FUNC_ALLOCA
 186 AC_FUNC_STRCOLL
 187
 188 dnl
 189 dnl X11 support.
 190 dnl
 191
 192 textmode_x11_support="no"
 193 AC_ARG_WITH(tm-x-support,
 194         [  --with-tm-x-support      Get keyboard events from X Window System [[no]]],
 195         [if test x$withval = xyes; then
 196                 AC_PATH_XTRA
 197                 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 198                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 199                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 200                           [Define to enable getting events from X Window System])
 201                 textmode_x11_support="yes"
 202         fi
 203 ])
 204
 205 dnl
 206 dnl Network related functions
 207 dnl
 208
 209 AC_CHECK_LIB(nsl, t_accept)
 210 AC_CHECK_LIB(socket, socket)
 211
 212 have_socket=no
 213 AC_CHECK_FUNCS(socket, have_socket=yes)
 214 if test $have_socket = no; then
 215   # socket is not in the default libraries.  See if it's in some other.
 216   for lib in bsd socket inet; do
 217     AC_CHECK_LIB($lib, socket, [
 218         LIBS="$LIBS -l$lib"
 219         have_socket=yes
 220         AC_DEFINE(HAVE_SOCKET)
 221         break])
 222   done
 223 fi
 224
 225 have_gethostbyname=no
 226 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 227 if test $have_gethostbyname = no; then
 228   # gethostbyname is not in the default libraries.  See if it's in some other.
 229   for lib in bsd socket inet; do
 230     AC_CHECK_LIB([$lib], [gethostbyname],
 231                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 232   done
 233 fi
 234
 235 AC_CHECK_FUNCS(socketpair)
 236
 237 dnl
 238 dnl Sequent wants getprocessstats
 239 dnl
 240 AC_CHECK_LIB(seq, get_process_stats, [
 241         LIBS="$LIBS -lseq"
 242         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 243                   [Define if you have function `get_process_stats' and
 244 have to use that instead of gettimeofday])])
 245
 246 MC_VFS_CHECKS
 247
 248 vfs_type="normal"
 249 if test x$use_vfs = xyes; then
 250         AC_MSG_NOTICE([enabling VFS code])
 251         vfs_type="Midnight Commander Virtual File System"
 252 fi
 253
 254 dnl This should be unadorned "slang" or "ncurses"
 255 screen_type=""
 256
 257 dnl Screen manager name (for the output only)
 258 screen_manager=unknown
 259
 260 mouse_lib="xterm only"
 261 case $host_os in
 262 linux*)
 263     AC_ARG_WITH(gpm-mouse,
 264         [  --with-gpm-mouse[[=base-dir]]  Compile with gpm mouse support (Linux only)
 265                                [[yes if found]]],
 266         [if test x$withval != xno
 267         then
 268                 if test x$withval != xyes
 269                 then
 270                         LDFLAGS="$LDFLAGS -L$withval/lib"
 271                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 272                 fi
 273                 AC_DEFINE(HAVE_LIBGPM, 1,
 274                           [Define to enable gpm mouse support on Linux])
 275                 mouse_lib="GPM and xterm"
 276                 MCLIBS="-lgpm $MCLIBS"
 277         fi],
 278         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 279                 [AC_DEFINE(HAVE_LIBGPM)
 280                 mouse_lib="GPM and xterm"
 281                 MCLIBS="-lgpm $MCLIBS"],
 282                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 283                 [$LIBS])
 284         ])
 285     ;;
 286 esac
 287
 288 AC_ARG_WITH(ncurses,
 289         [  --with-ncurses[[=base-dir]]    Compile with ncurses [[no]]],
 290 [if test x$withval != xno; then
 291         if test x$withval != xyes; then
 292                 LDFLAGS="$LDFLAGS -L$withval/lib"
 293                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 294         fi
 295
 296         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 297                          [ncurses_h_found=yes; break])
 298         if test -z "$ncurses_h_found"; then
 299             AC_MSG_ERROR([Could not find ncurses header])
 300         fi
 301
 302         dnl curses_version is specific to ncurses, it's not in old curses
 303         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 304                      [AC_MSG_ERROR([Could not find ncurses library])])
 305
 306         screen_type="ncurses"
 307         screen_manager="ncurses"
 308         AC_DEFINE(USE_NCURSES, 1,
 309                   [Define to use ncurses for screen management])
 310 fi
 311 ])
 312
 313 AC_ARG_WITH(hsc,
 314         [  --with-hsc               Compile with support for HSC firewall instead
 315                            of FTP proxy [[no]]],
 316         [if test x$withval = xyes; then
 317                 AC_DEFINE(HSC_PROXY, 1,
 318                           [Define if you want to use the HSC firewall])
 319         fi
 320 ])
 321
 322 dnl
 323 dnl Check for the -mandoc package
 324 dnl
 325 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 326 if $HAVE_nroff; then
 327     AC_MSG_CHECKING([for manual formatting macros])
 328     AC_CACHE_VAL(ac_cv_mandoc, [
 329     nroff -mandoc < /dev/null > /dev/null 2>&1
 330     if test $? = 0
 331     then
 332         ac_cv_mandoc=-mandoc
 333     else
 334         ac_cv_mandoc=-man
 335     fi
 336     ])
 337     MANDOC=$ac_cv_mandoc
 338     AC_MSG_RESULT([$MANDOC])
 339 else
 340     MANDOC=-man
 341 fi
 342 AC_SUBST(MANDOC)
 343
 344 dnl
 345 dnl Check if nroff accepts -Tlatin1 or -Tascii
 346 dnl
 347 if $HAVE_nroff; then
 348     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 349     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 350     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 351     if test $? = 0
 352     then
 353         ac_cv_nroff_tascii=" -Tlatin1"
 354     else
 355         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 356         if test $? = 0
 357         then
 358             ac_cv_nroff_tascii=" -Tascii"
 359         else
 360             ac_cv_nroff_tascii=""
 361         fi
 362     fi
 363     ])
 364     if test "x$ac_cv_nroff_tascii" = x; then
 365         AC_MSG_RESULT([no])
 366     else
 367         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 368     fi
 369 fi
 370 TROFFASCII="$ac_cv_nroff_tascii"
 371 AC_SUBST(TROFFASCII)
 372
 373 dnl
 374 dnl Check for - option to file
 375 dnl
 376 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 377 if $HAVE_FILECMD; then
 378     AC_MSG_CHECKING([for - option to file command])
 379     AC_CACHE_VAL(ac_cv_filestdin, [[
 380     cat > conftest.c <<\EOF
 381 /* A comment */
 382 #if 0
 383 #endif
 384 void main(void)
 385 { return; }
 386 EOF
 387     cat > conftest.sed <<\EOF
 388 s/^[^:]*:[      ]*//
 389 s/[     ]*$//
 390 EOF
 391     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 392     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 393     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 394         ac_cv_filestdin=yes
 395     else
 396         ac_cv_filestdin=no
 397     fi
 398     rm conftest.c conftest.sed
 399     ]])
 400
 401     if test x$ac_cv_filestdin = xyes; then
 402         AC_DEFINE(FILE_STDIN, 1,
 403                   [Define if the file command accepts - for stdin])
 404     fi
 405     filestdin=$ac_cv_filestdin
 406     AC_MSG_RESULT([$filestdin])
 407
 408     dnl
 409     dnl Check for -L option to file
 410     dnl
 411
 412 AC_MSG_CHECKING([for -L option to file command])
 413 AC_CACHE_VAL(ac_cv_filel, [
 414 file -L . > /dev/null 2>&1
 415 if test $? = 0
 416 then
 417     ac_cv_filel=yes
 418 else
 419     ac_cv_filel=no
 420 fi
 421 ])
 422 if test x$ac_cv_filel = xyes; then
 423     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 424 fi
 425 filel=$ac_cv_filel
 426 AC_MSG_RESULT([$filel])
 427 fi
 428
 429
 430 AC_MSG_CHECKING([for subshell support])
 431 AC_ARG_WITH(subshell,
 432         [  --with-subshell          Compile in concurrent subshell [[yes]]
 433   --with-subshell=optional Don't run concurrent shell by default [[no]]],
 434         [result=no
 435         if test x$withval = xoptional
 436         then
 437                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 438                           [Define to make subshell support optional])
 439                 result="optional"
 440         fi
 441         if test x$withval = xyes
 442         then
 443                 result="yes"
 444         fi],
 445         [dnl Default: enable the subshell support
 446         result="yes"
 447 ])
 448 if test "x$result" != xno; then
 449         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 450                   [Define to enable subshell support])
 451 fi
 452 AC_MSG_RESULT([$result])
 453 subshell="$result"
 454
 455 if test "x$screen_type" != xncurses; then
 456         slang_check_lib=true
 457         slang_term=""
 458         slang_use_system_installed_lib=false
 459         AC_CHECK_LIB(slang,SLang_init_tty,
 460                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 461                                   [slang_h_found=yes; break])
 462                 if test "x$slang_h_found" = xyes; then
 463                      slang_use_system_installed_lib=true
 464                      slang_check_lib=false
 465                 fi
 466         ])
 467 fi
 468
 469 AC_ARG_WITH(slang,
 470         [  --with-slang             Compile with S-Lang screen manager [[yes]]],
 471         [if test x$withval = xyes; then
 472                 AC_WITH_SLANG
 473         fi]
 474 )
 475
 476 AC_ARG_WITH(included-slang,
 477         [  --with-included-slang    Use S-Lang library included with mc sources
 478                            [[use installed library if found]]],
 479         [if test x$withval = xyes; then
 480             slang_use_system_installed_lib=false
 481             slang_check_lib=true
 482         fi]
 483 )
 484
 485 AC_ARG_WITH(termcap,
 486         [  --with-termcap           Same as above, and try using termcap database [[no]]],
 487         [if test x$withval = xyes; then
 488                 AC_USE_TERMCAP
 489                 slang_check_lib=false
 490                 slang_use_system_installed_lib=false
 491         fi]
 492 )
 493
 494
 495 dnl
 496 dnl Internal editor support.
 497 dnl
 498 AC_ARG_WITH(edit,
 499         [  --with-edit              Enable internal editor [[yes]]])
 500
 501 if test x$with_edit != xno; then
 502         AC_DEFINE(USE_INTERNAL_EDIT, 1, [Define to enable internal editor])
 503         use_edit=yes
 504         EDIT_msg="yes"
 505         AC_MSG_NOTICE([using internal editor])
 506 else
 507         EDIT_msg="no"
 508 fi
 509
 510
 511 if test $use_vfs = yes; then
 512     AC_ARG_WITH(ext2undel,
 513         [  --with-ext2undel         Compile with ext2 undelete code [[yes if found]]],
 514         [if test x$withval != xno; then
 515                 if test x$withval != xyes; then
 516                         LDFLAGS="$LDFLAGS -L$withval/lib"
 517                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 518                 fi
 519                 AC_EXT2_UNDEL
 520         fi],[
 521         dnl Default: detect
 522         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 523     ])
 524 fi
 525
 526
 527 dnl Ncurses specific checks
 528 dnl
 529 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 530 dnl or you'll have to press Esc three times to dismiss a dialog box.
 531 dnl
 532 if test "x$screen_type" = xncurses; then
 533   save_LIBS="$LIBS"
 534   LIBS="$MCLIBS $LIBS"
 535   AC_CACHE_CHECK([for ESCDELAY variable],
 536                  [mc_cv_ncurses_escdelay],
 537                  [AC_TRY_COMPILE([], [
 538                         extern int ESCDELAY;
 539                         int main ()
 540                         {
 541                           ESCDELAY = 0;
 542                         }
 543                         ],
 544                         [mc_cv_ncurses_escdelay=yes],
 545                         [mc_cv_ncurses_escdelay=no]
 546                   )
 547   ])
 548   if test "$mc_cv_ncurses_escdelay" = yes; then
 549     AC_DEFINE(HAVE_ESCDELAY, 1,
 550               [Define if ncurses has ESCDELAY variable])
 551   fi
 552
 553   AC_CHECK_FUNCS(resizeterm)
 554   LIBS="$save_LIBS"
 555 fi
 556
 557 if test "x$screen_type" = "x"; then
 558     AC_WITH_SLANG
 559 fi
 560
 561 dnl
 562 dnl The variables used for expanding the auto saver.
 563 dnl
 564 cons_saver=""
 565 install_saver="no"
 566 PAMLIBS=""
 567 case $host_os in
 568 linux*)
 569     cons_saver="cons.saver"
 570     install_saver="yes"
 571
 572     dnl
 573     dnl On Linux, check for PAM authentication available
 574     dnl
 575     AC_CHECK_LIB(pam, pam_start, [
 576         AC_DEFINE(HAVE_PAM, 1,
 577                   [Define if PAM (Pluggable Authentication Modules) is available])
 578         PAMLIBS="-lpam -ldl"
 579     ],[],[-ldl])
 580     ;;
 581 esac
 582 AC_SUBST(cons_saver)
 583 AC_SUBST(PAMLIBS)
 584
 585 dnl
 586 dnl User visible support for charset conversion.
 587 dnl
 588 AC_ARG_ENABLE([charset],
 589               [  --enable-charset         Support for charset selection and conversion [[no]]])
 590 have_charset=
 591 if test "x$enable_charset" = xyes; then
 592   if test "x$am_cv_func_iconv" != xyes; then
 593     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 594   else
 595     AC_DEFINE(HAVE_CHARSET, 1,
 596               [Define to enable charset selection and conversion])
 597     have_charset=yes
 598   fi
 599 fi
 600
 601 if test "$GLIBC21" != yes; then
 602     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 603 fi
 604
 605 dnl
 606 dnl This code should be moved to the ac_WITH_SLANG
 607 dnl
 608 dnl We check for the existance of setupterm on curses library
 609 dnl this is required to load certain definitions on some termcaps
 610 dnl editions (AIX and OSF/1 I seem to remember).
 611 dnl Note that we avoid using setupterm
 612 if test "x$screen_type" = xslang; then
 613         case $host_os in
 614         linux*)
 615                 ;;
 616         *)
 617                 AC_CHECK_LIB(curses,setupterm,
 618                         [AC_TRY_COMPILE([
 619 #include <curses.h>
 620 #include <term.h>],[
 621    if (key_end == parm_insert_line)
 622         return 1;
 623    return 0;
 624 ],
 625                         [MCLIBS="$MCLIBS -lcurses"
 626                         AC_DEFINE(USE_SETUPTERM, 1,
 627                                   [Define to use function `setupterm'
 628 from `curses' library in S-Lang])])
 629                 ])
 630         esac
 631 fi
 632
 633 LIBS="$LIBS $posix_libs"
 634
 635 AC_SUBST(CFLAGS)
 636 AC_SUBST(CPPFLAGS)
 637 AC_SUBST(LDFLAGS)
 638 AC_SUBST(LIBS)
 639
 640 dnl Libraries used only when building the mc binary
 641 AC_SUBST(MCLIBS)
 642
 643 dnl Version for the RedHat package, without dashes
 644 RH_VERSION=`echo $VERSION | sed 's/-//'`
 645 AC_SUBST(RH_VERSION)
 646
 647 if test -n "$use_smbfs"; then
 648   AC_CONFIG_SUBDIRS([vfs/samba])
 649 fi
 650
 651 AM_CONDITIONAL(USE_EDIT, [test -n "$use_edit"])
 652 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 653 AM_CONDITIONAL(USE_VFS_NET, [test x"$use_net_code" = xtrue])
 654 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$use_undelfs"])
 655 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$use_smbfs"])
 656 AM_CONDITIONAL(USE_MCFS, [test -n "$use_mcfs"])
 657 AM_CONDITIONAL(INCLUDED_SLANG,
 658                [test "x$slang_use_system_installed_lib" = xfalse])
 659 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 660 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 661
 662 AH_BOTTOM([#include <extraconf.h>])
 663
 664 AC_CONFIG_FILES([
 665 Makefile
 666 mc.spec
 667 doc/Makefile
 668 vfs/Makefile
 669 vfs/extfs/Makefile
 670 lib/Makefile
 671 src/Makefile
 672 slang/Makefile
 673 edit/Makefile
 674 syntax/Makefile
 675 pc/Makefile
 676
 677 lib/mc.ext
 678 lib/mc.sh
 679 lib/mc.csh
 680
 681 vfs/extfs/deb
 682 vfs/extfs/ftplist
 683 vfs/extfs/lslR
 684 vfs/extfs/uar
 685 vfs/extfs/ucpio
 686 vfs/extfs/ulha
 687 vfs/extfs/uha
 688 vfs/extfs/urar
 689 vfs/extfs/uzoo
 690
 691 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 692 doc/es/mc.1 doc/es/Makefile
 693 doc/hu/Makefile
 694 doc/it/mc.1 doc/it/Makefile
 695 doc/pl/mc.1 doc/pl/Makefile
 696 doc/ru/mc.1 doc/ru/Makefile
 697
 698 intl/Makefile po/Makefile.in
 699 ])
 700
 701 AC_CONFIG_COMMANDS(potfiles,
 702     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 703
 704 AC_OUTPUT
 705
 706 if test "x$screen_type" = xslang; then
 707     screen_manager="${screen_manager}${slang_term}"
 708 fi
 709
 710 echo "
 711 Configuration:
 712
 713   Source code location:       ${srcdir}
 714   Compiler:                   ${CC}
 715   Compiler flags:             ${CFLAGS}
 716   File system:                ${vfs_type}
 717                               ${vfs_flags}
 718   Screen manager:             ${screen_manager}
 719   Install console saver:      ${install_saver}
 720   Mouse support:              ${mouse_lib}
 721   X11 events support:         ${textmode_x11_support}
 722   Debugger code:              ${mem_debug}
 723   With subshell support:      ${subshell}
 724   Internal editor:            ${EDIT_msg}
 725   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 726 "