configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_AUX_DIR(config)
  10 AC_CONFIG_SRCDIR(src/main.c)
  11 AC_CONFIG_HEADERS(config.h)
  12 mc_VERSION
  13 AM_INIT_AUTOMAKE(mc, ${VERSION} )
  14 dnl Enable silent rules by default (if yes)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23
  24 dnl ############################################################################
  25 dnl Check for compiler
  26 dnl ############################################################################
  27
  28 AC_PROG_CC_STDC
  29 AM_PROG_CC_C_O
  30
  31 mc_CHECK_CFLAGS
  32
  33 CFLAGS_OPTS=""
  34 if test "x$CFLAGS" = "x"; then
  35     CFLAGS_OPTS=" -O2 "
  36 fi
  37 if test x$USE_MAINTAINER_MODE = xyes; then
  38     CFLAGS_OPTS="-g3 -O -ggdb"
  39     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  40 fi
  41
  42 AC_ARG_ENABLE([werror],
  43     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  44 if test "x$enable_werror" = xyes; then
  45     mc_CHECK_ONE_CFLAG([-Werror])
  46 fi
  47
  48 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  49
  50 LT_INIT
  51
  52
  53 dnl ############################################################################
  54 dnl Check for programs
  55 dnl ############################################################################
  56
  57 PKG_PROG_PKG_CONFIG
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 dnl See also the "OS specific stuff" section below.
  61
  62 dnl Check nroff and the options it supports
  63 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  64 dnl Default values
  65 MANDOC=-man
  66 MAN_FLAGS=
  67 if $HAVE_nroff; then
  68     AC_MSG_CHECKING([for manual formatting macros])
  69     AC_CACHE_VAL(mc_cv_mandoc, [
  70     nroff -mandoc < /dev/null > /dev/null 2>&1
  71     if test $? = 0; then
  72         mc_cv_mandoc=-mandoc
  73     else
  74         mc_cv_mandoc=-man
  75     fi
  76     ])
  77     MANDOC=$mc_cv_mandoc
  78     AC_MSG_RESULT([$MANDOC])
  79
  80     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
  81     AC_CACHE_VAL(mc_cv_man_nocolor, [
  82     nroff -c < /dev/null > /dev/null 2>&1
  83     if test $? = 0; then
  84         mc_cv_man_nocolor=-c
  85     else
  86         mc_cv_man_nocolor=
  87     fi
  88     ])
  89     MAN_FLAGS=$mc_cv_man_nocolor
  90     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
  91
  92     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
  93     AC_CACHE_VAL(mc_cv_nroff_tascii, [
  94     mc_cv_nroff_tascii=
  95     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
  96     if test $? = 0; then
  97         mc_cv_nroff_tascii=-Tlatin1
  98     else
  99         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 100         if test $? = 0; then
 101             mc_cv_nroff_tascii=-Tascii
 102         fi
 103     fi
 104     ])
 105     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 106     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 107 fi
 108
 109 AC_SUBST(MANDOC)
 110 AC_SUBST(MAN_FLAGS)
 111
 112 dnl Check for -L option to file
 113 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 114 if $HAVE_FILECMD; then
 115     AC_MSG_CHECKING([for -L option to file command])
 116     AC_CACHE_VAL(mc_cv_filel, [
 117     file -L . > /dev/null 2>&1
 118     if test $? = 0; then
 119         mc_cv_filel=yes
 120     else
 121         mc_cv_filel=no
 122     fi
 123     ])
 124     if test x$mc_cv_filel = xyes; then
 125         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 126     fi
 127     filel=$mc_cv_filel
 128     AC_MSG_RESULT([$filel])
 129 fi
 130
 131 dnl Only list browsers here that can be run in background (i.e. with `&')
 132 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 133
 134
 135 dnl ############################################################################
 136 dnl Check for other tools
 137 dnl ############################################################################
 138
 139 AC_CHECK_TOOL(AR, ar, ar)
 140 mc_UNIT_TESTS
 141
 142
 143 dnl ############################################################################
 144 dnl Check for main libraies
 145 dnl ############################################################################
 146
 147 mc_CHECK_GLIB
 148 mc_G_MODULE_SUPPORTED
 149 mc_WITH_SCREEN
 150 mc_CHECK_SEARCH_TYPE
 151 dnl X11 support. Used to read keyboard modifiers when running under X11.
 152 mc_WITH_X
 153
 154
 155 dnl ############################################################################
 156 dnl Check for header files
 157 dnl ############################################################################
 158
 159 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 160         utime.h sys/statfs.h sys/vfs.h \
 161         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 162         sys/socket.h])
 163 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 164 dnl   to work around a buggy version in autoconf <= 2.69.
 165 AC_HEADER_MAJOR
 166
 167
 168 dnl ############################################################################
 169 dnl Check for types
 170 dnl ############################################################################
 171
 172 dnl Check largefile before type sizeof checks
 173 AC_SYS_LARGEFILE
 174
 175 AC_CHECK_SIZEOF(long)
 176 AC_TYPE_UINTMAX_T
 177 AC_CHECK_SIZEOF(uintmax_t)
 178 AC_TYPE_OFF_T
 179 AC_CHECK_SIZEOF(off_t)
 180 AC_TYPE_MODE_T
 181 gl_PROMOTED_TYPE_MODE_T
 182 AC_TYPE_PID_T
 183 AC_TYPE_UID_T
 184
 185 AC_STRUCT_ST_BLOCKS
 186 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim])
 187 gl_STAT_SIZE
 188
 189 AH_TEMPLATE([sig_atomic_t],
 190             [/* Define to `int' if <signal.h> doesn't define.])
 191 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 192             [Some systems declare sig_atomic_t as volatile, some others -- no.
 193              This define will have value `sig_atomic_t' or
 194              `volatile sig_atomic_t' accordingly.])
 195
 196 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 197 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 198   [
 199     ac_cv_type_sig_atomic_t=yes;
 200     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 201                     signal.h,
 202                     [
 203                         is_sig_atomic_t_volatile=yes;
 204                         AC_MSG_RESULT([yes, volatile])
 205                     ],
 206                     [
 207                         is_sig_atomic_t_volatile=no;
 208                         AC_MSG_RESULT([yes, non volatile])
 209                     ])
 210   ],
 211   [
 212     AC_MSG_RESULT(no)
 213     AC_CHECK_TYPE(sig_atomic_t, int)
 214     is_sig_atomic_t_volatile=no
 215   ])
 216 if test $is_sig_atomic_t_volatile = 'yes'
 217 then
 218     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 219 else
 220     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 221 fi
 222
 223
 224 dnl ############################################################################
 225 dnl Check for functions
 226 dnl ############################################################################
 227
 228 AC_CHECK_FUNCS([\
 229         strverscmp \
 230         strncasecmp \
 231         realpath
 232 ])
 233
 234 dnl getpt is a GNU Extension (glibc 2.1.x)
 235 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 236 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 237
 238 dnl replacing lstat with statlstat on sco makes it more portable between
 239 dnl sco clones
 240 AC_CHECK_FUNCS(statlstat)
 241
 242 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
 243 dnl We use only part of the functionality of mmap, so on AIX,
 244 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 245 AC_ARG_WITH([mmap],
 246         AS_HELP_STRING([--with-mmap], [Use the mmap call @<:@yes if found@:>@]))
 247 if test x$with_mmap != xno; then
 248     if test x$with_mmap = x; then
 249         AC_FUNC_MMAP
 250     else
 251         AC_DEFINE(HAVE_MMAP, 1)
 252     fi
 253 fi
 254
 255 dnl Sequent wants getprocessstats
 256 AC_CHECK_LIB(seq, get_process_stats, [
 257         LIBS="$LIBS -lseq"
 258         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 259                   [Define if you have function `get_process_stats' and
 260 have to use that instead of gettimeofday])])
 261
 262 mc_AC_GET_FS_INFO
 263
 264
 265 dnl ############################################################################
 266 dnl Internationalization
 267 dnl ############################################################################
 268
 269 AM_GNU_GETTEXT([no-libtool], [need-ngettext])
 270 AM_GNU_GETTEXT_VERSION([0.18.1])
 271
 272 mc_I18N
 273
 274 dnl ############################################################################
 275 dnl OS specific stuff
 276 dnl ############################################################################
 277
 278 case $host_os in
 279 *os400)
 280     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 281     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 282     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 283     ;;
 284 *)
 285     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 286     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 287     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 288 esac
 289
 290 case $host_os in
 291 aux*)
 292     # A/UX
 293     LIBS="$LIBS -lposix"
 294     AC_DEFINE(_POSIX_SOURCE)
 295     ;;
 296 esac
 297
 298 dnl If running under AIX, AC_AIX does not tell us that
 299 AC_MSG_CHECKING([for AIX defines])
 300 AC_EGREP_CPP([yes],
 301     [
 302         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 303         yes
 304         #endif
 305     ],
 306     [
 307         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 308         AC_MSG_RESULT(yes)
 309     ],
 310     [
 311         AC_MSG_RESULT(no)
 312     ])
 313
 314 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 315 dnl utimensat() causes different timespec structures to cause failures on IBM i and AIX
 316 case $host_os in
 317 *os400 | aix*)
 318     ;;
 319 *)
 320     AC_CHECK_FUNCS([utimensat])
 321     ;;
 322 esac
 323
 324 case $host_os in
 325 *os400)
 326     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 327 esac
 328
 329 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 330 case $host_os in
 331 linux*)
 332     AC_CHECK_HEADERS([linux/fs.h])
 333 esac
 334
 335 dnl Check if the OS is supported by the console saver.
 336 cons_saver=""
 337 case $host_os in
 338 linux*)
 339     cons_saver=yes
 340 esac
 341
 342 dnl Check for gpm mouse support (Linux only)
 343 mouse_lib="xterm only"
 344 AC_ARG_WITH([gpm-mouse],
 345     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 346
 347 case $host_os in
 348 linux*)
 349     if test x$with_gpm_mouse != xno; then
 350         AC_CHECK_LIB(gpm, Gpm_Repeat,
 351             [AC_DEFINE(HAVE_LIBGPM, 1,
 352                        [Define to enable gpm mouse support on Linux])
 353             mouse_lib="gpm and xterm"
 354             MCLIBS="$MCLIBS -lgpm"],
 355             if test "x$with_gpm_mouse" = "xyes"; then
 356                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 357             else
 358                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 359             fi
 360         )
 361     fi
 362     ;;
 363 esac
 364
 365
 366 dnl ############################################################################
 367 dnl libmc
 368 dnl ############################################################################
 369
 370 LIBMC_VERSION="0.0.1"
 371 LIBMC_RELEASE="1"
 372 AC_SUBST(LIBMC_VERSION)
 373 AC_SUBST(LIBMC_RELEASE)
 374
 375 AC_ARG_ENABLE([mclib],
 376         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 377         [
 378             if test "x$enableval" = "xno" ; then
 379                 enable_mclib=no
 380             else
 381                 if test "x$enable_shared" = "xno" ; then
 382                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 383                     enable_mclib=no
 384                 else
 385                     enable_mclib=yes
 386                 fi
 387             fi
 388         ],
 389         [enable_mclib=no])
 390
 391 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 392
 393
 394 dnl ############################################################################
 395 dnl Where config files should be placed
 396 dnl ############################################################################
 397
 398 AC_ARG_WITH([homedir],
 399     AS_HELP_STRING([--with-homedir],
 400                    [Choose any place of user settings relative to home dir, or XDG for respect XDG standards @<:@XDG@:>@]),
 401     [
 402         dnl Unfortunately, there is no way to tell AC_ARG_WITH that the
 403         dnl argument value is required, so we can't differentiate
 404         dnl between `--with-homedir` and `--with-homedir=yes`, because
 405         dnl `with_homedir` is set to `yes` in both cases.
 406         dnl
 407         dnl We opt to set `with_homedir` to `.mc` if the value is `yes`
 408         dnl in order to avoid the surprise for users using
 409         dnl `--with-homedir` w/o any value and then getting mc to store
 410         dnl settings in the `yes` directory.
 411
 412         if test "x$withval" = "xXDG"; then
 413             with_homedir=XDG
 414         elif test "x$withval" = "xyes"; then
 415             with_homedir=.mc
 416         else
 417             with_homedir=$withval
 418         fi
 419     ],
 420     [with_homedir=XDG])
 421
 422
 423 if test x$with_homedir = xXDG; then
 424     AC_DEFINE(MC_HOMEDIR_XDG, 1, [Define to enable XDG standard support])
 425 else
 426     AC_DEFINE(MC_HOMEDIR_XDG, 0, [Define to disable XDG standard support])
 427     AC_DEFINE_UNQUOTED([MC_USERCONF_DIR], ["$with_homedir"], [Where configs will be placed relative to $HOME])
 428 fi
 429
 430
 431 dnl ############################################################################
 432 dnl MC options
 433 dnl ############################################################################
 434
 435 mc_ASSERT
 436
 437 mc_WITH_INTERNAL_EDIT
 438
 439 dnl Diff viewer support.
 440 AC_ARG_WITH([diff_viewer],
 441     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 442
 443 if test x$with_diff_viewer != xno; then
 444         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 445         use_diff=yes
 446         diff_msg="yes"
 447         AC_MSG_NOTICE([using diff viewer])
 448 else
 449         diff_msg="no"
 450 fi
 451
 452 mc_SUBSHELL
 453 mc_BACKGROUND
 454 mc_VFS_CHECKS
 455
 456 dnl ############################################################################
 457 dnl Directories
 458 dnl ############################################################################
 459
 460 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 461 dnl Let define ${prefix} and ${exec_prefix}
 462 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 463 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 464
 465 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 466     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 467 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 468     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 469 else
 470     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 471 fi
 472 AC_SUBST(EXTHELPERSDIR)
 473
 474
 475 dnl ############################################################################
 476 dnl Documentation
 477 dnl ############################################################################
 478
 479 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 480 AC_SUBST(MAN_DATE)
 481
 482 dnl Determine which help translations we want to install.
 483 ALL_DOC_LINGUAS="es hu it pl ru sr"
 484
 485 DOC_LINGUAS=
 486 if test "x$USE_NLS" = xyes; then
 487     if test -z "$LINGUAS"; then
 488         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 489     else
 490         langs="$LINGUAS"
 491     fi
 492 else
 493     langs=
 494 fi
 495
 496 for h_lang in $ALL_DOC_LINGUAS; do
 497     for lang in $langs; do
 498         if test "$lang" = "$h_lang"; then
 499             DOC_LINGUAS="$DOC_LINGUAS $lang"
 500             break
 501         fi
 502     done
 503 done
 504 AC_SUBST(DOC_LINGUAS)
 505
 506 DX_HTML_FEATURE(ON)
 507 DX_CHM_FEATURE(OFF)
 508 DX_CHI_FEATURE(OFF)
 509 DX_MAN_FEATURE(OFF)
 510 DX_RTF_FEATURE(OFF)
 511 DX_XML_FEATURE(OFF)
 512 DX_PDF_FEATURE(OFF)
 513 DX_PS_FEATURE(OFF)
 514 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 515
 516
 517 dnl ############################################################################
 518 dnl Configure results
 519 dnl ############################################################################
 520
 521 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 522
 523 AC_SUBST(MCLIBS)
 524 AC_SUBST(CFLAGS)
 525 AC_SUBST(CPPFLAGS)
 526 AC_SUBST(LDFLAGS)
 527 AC_SUBST(LIBS)
 528
 529 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 530 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 531 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 532 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 533 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 534 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 535 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 536 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 537 dnl Clarify do we really need GModule
 538 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 539                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 540
 541 AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 542
 543 AC_CONFIG_FILES(
 544 [
 545 src/man2hlp/man2hlp
 546 ],
 547 [
 548 chmod +x src/man2hlp/man2hlp
 549 ])
 550
 551 AC_CONFIG_FILES([
 552 Makefile
 553
 554 contrib/Makefile
 555 contrib/dist/Makefile
 556 contrib/dist/gentoo/Makefile
 557 contrib/dist/redhat/Makefile
 558 contrib/dist/redhat/mc.spec
 559 contrib/dist/pkginfo
 560 contrib/dist/prototype
 561
 562 misc/Makefile
 563 misc/mc.menu
 564 misc/mcedit.menu
 565 misc/skins/Makefile
 566 misc/ext.d/Makefile
 567 misc/ext.d/doc.sh
 568 misc/ext.d/misc.sh
 569 misc/ext.d/text.sh
 570 misc/ext.d/web.sh
 571 misc/macros.d/Makefile
 572 misc/mc.ext
 573
 574 src/Makefile
 575 src/consaver/Makefile
 576 src/editor/Makefile
 577 src/man2hlp/Makefile
 578 src/subshell/Makefile
 579 src/viewer/Makefile
 580 src/diffviewer/Makefile
 581 src/filemanager/Makefile
 582
 583 src/vfs/Makefile
 584
 585 src/vfs/cpio/Makefile
 586
 587 src/vfs/extfs/Makefile
 588 src/vfs/extfs/helpers/Makefile
 589 src/vfs/extfs/helpers/a+
 590 src/vfs/extfs/helpers/apt+
 591 src/vfs/extfs/helpers/audio
 592 src/vfs/extfs/helpers/deb
 593 src/vfs/extfs/helpers/deba
 594 src/vfs/extfs/helpers/debd
 595 src/vfs/extfs/helpers/dpkg+
 596 src/vfs/extfs/helpers/iso9660
 597 src/vfs/extfs/helpers/hp48+
 598 src/vfs/extfs/helpers/lslR
 599 src/vfs/extfs/helpers/mailfs
 600 src/vfs/extfs/helpers/patchfs
 601 src/vfs/extfs/helpers/rpms+
 602 src/vfs/extfs/helpers/s3+
 603 src/vfs/extfs/helpers/uace
 604 src/vfs/extfs/helpers/ualz
 605 src/vfs/extfs/helpers/uar
 606 src/vfs/extfs/helpers/uarc
 607 src/vfs/extfs/helpers/uarj
 608 src/vfs/extfs/helpers/uc1541
 609 src/vfs/extfs/helpers/ucab
 610 src/vfs/extfs/helpers/uha
 611 src/vfs/extfs/helpers/ulha
 612 src/vfs/extfs/helpers/ulib
 613 src/vfs/extfs/helpers/urar
 614 src/vfs/extfs/helpers/uzip
 615 src/vfs/extfs/helpers/uzoo
 616
 617 src/vfs/fish/Makefile
 618 src/vfs/fish/helpers/Makefile
 619
 620 src/vfs/ftpfs/Makefile
 621
 622 src/vfs/sftpfs/Makefile
 623
 624 src/vfs/local/Makefile
 625
 626 src/vfs/sfs/Makefile
 627
 628 src/vfs/smbfs/Makefile
 629
 630 src/vfs/tar/Makefile
 631
 632 src/vfs/undelfs/Makefile
 633
 634 lib/Makefile
 635 lib/event/Makefile
 636 lib/filehighlight/Makefile
 637 lib/mcconfig/Makefile
 638 lib/search/Makefile
 639 lib/skin/Makefile
 640 lib/strutil/Makefile
 641 lib/tty/Makefile
 642
 643 lib/vfs/Makefile
 644
 645 lib/widget/Makefile
 646
 647 misc/syntax/Makefile
 648 misc/syntax/Syntax
 649
 650 doc/Makefile
 651
 652 doc/hints/Makefile
 653 doc/hints/l10n/Makefile
 654
 655 doc/man/Makefile
 656 doc/man/es/Makefile
 657 doc/man/hu/Makefile
 658 doc/man/it/Makefile
 659 doc/man/pl/Makefile
 660 doc/man/ru/Makefile
 661 doc/man/sr/Makefile
 662
 663 doc/hlp/Makefile
 664 doc/hlp/es/Makefile
 665 doc/hlp/hu/Makefile
 666 doc/hlp/it/Makefile
 667 doc/hlp/pl/Makefile
 668 doc/hlp/ru/Makefile
 669 doc/hlp/sr/Makefile
 670
 671 intl/Makefile
 672 po/Makefile.in
 673 ])
 674
 675 AC_CONFIG_FILES([
 676 tests/Makefile
 677 tests/lib/Makefile
 678 tests/lib/mcconfig/Makefile
 679 tests/lib/search/Makefile
 680 tests/lib/strutil/Makefile
 681 tests/lib/vfs/Makefile
 682 tests/lib/widget/Makefile
 683 tests/src/Makefile
 684 tests/src/filemanager/Makefile
 685 tests/src/editor/Makefile
 686 tests/src/editor/test-data.txt
 687 tests/src/vfs/Makefile
 688 tests/src/vfs/extfs/Makefile
 689 tests/src/vfs/extfs/helpers-list/Makefile
 690 tests/src/vfs/extfs/helpers-list/data/config.sh
 691 tests/src/vfs/extfs/helpers-list/misc/Makefile
 692 ])
 693
 694 AC_OUTPUT
 695
 696 AC_MSG_NOTICE([
 697
 698 Configuration:
 699
 700   Source code location:       ${srcdir}
 701   Compiler:                   ${CC}
 702   Compiler flags:             ${CFLAGS}
 703   Assertions:                 ${enable_assert}
 704   Unit tests:                 ${tests_msg}
 705   File system:                ${vfs_type}
 706                               ${vfs_flags}
 707   Screen library:             ${screen_msg}
 708   Mouse support:              ${mouse_lib}
 709   X11 events support:         ${textmode_x11_support}
 710   With subshell support:      ${subshell}
 711   With background operations: ${enable_background}
 712   Internal editor:            ${edit_msg}
 713   Diff viewer:                ${diff_msg}
 714   Support for charset:        ${charset_msg}
 715   Search type:                ${SEARCH_TYPE}
 716 ])
 717
 718 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 719 dnl we enable it back for top-level ./configure
 720 if test -n "$ac_unrecognized_opts"; then
 721   case $enable_option_checking in
 722     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 723     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 724   esac
 725 fi