configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_AUX_DIR(config)
  10 AC_CONFIG_SRCDIR(src/main.c)
  11 AC_CONFIG_HEADERS(config.h)
  12 mc_VERSION
  13 AM_INIT_AUTOMAKE(mc, ${VERSION} )
  14 dnl Enable silent rules by default (if yes)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23
  24 dnl ############################################################################
  25 dnl Check for compiler
  26 dnl ############################################################################
  27
  28 AC_PROG_CC_STDC
  29 AM_PROG_CC_C_O
  30
  31 mc_CHECK_CFLAGS
  32
  33 CFLAGS_OPTS=""
  34 if test "x$CFLAGS" = "x"; then
  35     CFLAGS_OPTS=" -O2 "
  36 fi
  37 if test x$USE_MAINTAINER_MODE = xyes; then
  38     CFLAGS_OPTS="-g3 -O -ggdb"
  39     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  40 fi
  41
  42 AC_ARG_ENABLE([werror],
  43     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  44 if test "x$enable_werror" = xyes; then
  45     mc_CHECK_ONE_CFLAG([-Werror])
  46 fi
  47
  48 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  49
  50 AC_PROG_LIBTOOL
  51
  52
  53 dnl ############################################################################
  54 dnl Check for programs
  55 dnl ############################################################################
  56
  57 PKG_PROG_PKG_CONFIG
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
  61 AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
  62 AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
  63
  64 dnl Check nroff and the options it supports
  65 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  66 dnl Default values
  67 MANDOC=-man
  68 MAN_FLAGS=
  69 if $HAVE_nroff; then
  70     AC_MSG_CHECKING([for manual formatting macros])
  71     AC_CACHE_VAL(mc_cv_mandoc, [
  72     nroff -mandoc < /dev/null > /dev/null 2>&1
  73     if test $? = 0; then
  74         mc_cv_mandoc=-mandoc
  75     else
  76         mc_cv_mandoc=-man
  77     fi
  78     ])
  79     MANDOC=$mc_cv_mandoc
  80     AC_MSG_RESULT([$MANDOC])
  81
  82     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
  83     AC_CACHE_VAL(mc_cv_man_nocolor, [
  84     nroff -c < /dev/null > /dev/null 2>&1
  85     if test $? = 0; then
  86         mc_cv_man_nocolor=-c
  87     else
  88         mc_cv_man_nocolor=
  89     fi
  90     ])
  91     MAN_FLAGS=$mc_cv_man_nocolor
  92     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
  93
  94     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
  95     AC_CACHE_VAL(mc_cv_nroff_tascii, [
  96     mc_cv_nroff_tascii=
  97     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
  98     if test $? = 0; then
  99         mc_cv_nroff_tascii=-Tlatin1
 100     else
 101         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 102         if test $? = 0; then
 103             mc_cv_nroff_tascii=-Tascii
 104         fi
 105     fi
 106     ])
 107     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 108     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 109 fi
 110
 111 AC_SUBST(MANDOC)
 112 AC_SUBST(MAN_FLAGS)
 113
 114 dnl Check for -L option to file
 115 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 116 if $HAVE_FILECMD; then
 117     AC_MSG_CHECKING([for -L option to file command])
 118     AC_CACHE_VAL(mc_cv_filel, [
 119     file -L . > /dev/null 2>&1
 120     if test $? = 0; then
 121         mc_cv_filel=yes
 122     else
 123         mc_cv_filel=no
 124     fi
 125     ])
 126     if test x$mc_cv_filel = xyes; then
 127         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 128     fi
 129     filel=$mc_cv_filel
 130     AC_MSG_RESULT([$filel])
 131 fi
 132
 133 dnl Only list browsers here that can be run in background (i.e. with `&')
 134 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 135
 136
 137 dnl ############################################################################
 138 dnl Check for other tools
 139 dnl ############################################################################
 140
 141 AC_CHECK_TOOL(AR, ar, ar)
 142 mc_UNIT_TESTS
 143
 144
 145 dnl ############################################################################
 146 dnl Check for main libraies
 147 dnl ############################################################################
 148
 149 mc_CHECK_GLIB
 150 mc_G_MODULE_SUPPORTED
 151 mc_WITH_SCREEN
 152 mc_CHECK_SEARCH_TYPE
 153 dnl X11 support. Used to read keyboard modifiers when running under X11.
 154 mc_WITH_X
 155
 156
 157 dnl ############################################################################
 158 dnl Check for header files
 159 dnl ############################################################################
 160
 161 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 162         utime.h sys/statfs.h sys/vfs.h \
 163         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 164         sys/socket.h])
 165 dnl This macro is redefined in m4.include/sys_types_h.m4
 166 dnl   to work around a buggy version in autoconf <= 2.69.
 167 AC_HEADER_MAJOR
 168
 169
 170 dnl ############################################################################
 171 dnl Check for types
 172 dnl ############################################################################
 173
 174 dnl Check largefile before type sizeof checks
 175 AC_SYS_LARGEFILE
 176
 177 AC_CHECK_SIZEOF(long)
 178 AC_TYPE_UINTMAX_T
 179 AC_CHECK_SIZEOF(uintmax_t)
 180 AC_TYPE_OFF_T
 181 AC_CHECK_SIZEOF(off_t)
 182 AC_TYPE_MODE_T
 183 gl_PROMOTED_TYPE_MODE_T
 184 AC_TYPE_PID_T
 185 AC_TYPE_UID_T
 186
 187 AC_STRUCT_ST_BLOCKS
 188 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim])
 189 gl_STAT_SIZE
 190
 191 AH_TEMPLATE([sig_atomic_t],
 192             [/* Define to `int' if <signal.h> doesn't define.])
 193 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 194             [Some systems declare sig_atomic_t as volatile, some others -- no.
 195              This define will have value `sig_atomic_t' or
 196              `volatile sig_atomic_t' accordingly.])
 197
 198 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 199 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 200   [
 201     ac_cv_type_sig_atomic_t=yes;
 202     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 203                     signal.h,
 204                     [
 205                         is_sig_atomic_t_volatile=yes;
 206                         AC_MSG_RESULT([yes, volatile])
 207                     ],
 208                     [
 209                         is_sig_atomic_t_volatile=no;
 210                         AC_MSG_RESULT([yes, non volatile])
 211                     ])
 212   ],
 213   [
 214     AC_MSG_RESULT(no)
 215     AC_CHECK_TYPE(sig_atomic_t, int)
 216     is_sig_atomic_t_volatile=no
 217   ])
 218 if test $is_sig_atomic_t_volatile = 'yes'
 219 then
 220     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 221 else
 222     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 223 fi
 224
 225
 226 dnl ############################################################################
 227 dnl Check for functions
 228 dnl ############################################################################
 229
 230 AC_CHECK_FUNCS([\
 231         strverscmp \
 232         strncasecmp \
 233         realpath
 234 ])
 235
 236 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 237 AC_CHECK_FUNCS([utimensat])
 238
 239 dnl getpt is a GNU Extension (glibc 2.1.x)
 240 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 241 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 242
 243 dnl replacing lstat with statlstat on sco makes it more portable between
 244 dnl sco clones
 245 AC_CHECK_FUNCS(statlstat)
 246
 247 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
 248 dnl We use only part of the functionality of mmap, so on AIX,
 249 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 250 AC_ARG_WITH([mmap],
 251         AS_HELP_STRING([--with-mmap], [Use the mmap call @<:@yes if found@:>@]))
 252 if test x$with_mmap != xno; then
 253     if test x$with_mmap = x; then
 254         AC_FUNC_MMAP
 255     else
 256         AC_DEFINE(HAVE_MMAP, 1)
 257     fi
 258 fi
 259
 260 dnl Sequent wants getprocessstats
 261 AC_CHECK_LIB(seq, get_process_stats, [
 262         LIBS="$LIBS -lseq"
 263         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 264                   [Define if you have function `get_process_stats' and
 265 have to use that instead of gettimeofday])])
 266
 267 mc_AC_GET_FS_INFO
 268
 269
 270 dnl ############################################################################
 271 dnl Internationalization
 272 dnl ############################################################################
 273
 274 AM_GNU_GETTEXT([no-libtool], [need-ngettext])
 275 AM_GNU_GETTEXT_VERSION([0.18.1])
 276
 277 mc_I18N
 278
 279 dnl ############################################################################
 280 dnl OS specific flags
 281 dnl ############################################################################
 282
 283 case $host_os in
 284 aux*)
 285     # A/UX
 286     LIBS="$LIBS -lposix"
 287     AC_DEFINE(_POSIX_SOURCE)
 288     ;;
 289 esac
 290
 291 dnl If running under AIX, AC_AIX does not tell us that
 292 AC_MSG_CHECKING([for AIX defines])
 293 AC_EGREP_CPP([yes],
 294     [
 295         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 296         yes
 297         #endif
 298     ],
 299     [
 300         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 301         AC_MSG_RESULT(yes)
 302     ],
 303     [
 304         AC_MSG_RESULT(no)
 305     ])
 306
 307 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 308 case $host_os in
 309 linux*)
 310     AC_CHECK_HEADERS([linux/fs.h])
 311 esac
 312
 313 dnl Check if the OS is supported by the console saver.
 314 cons_saver=""
 315 case $host_os in
 316 linux*)
 317     cons_saver=yes
 318 esac
 319
 320 dnl Check for gpm mouse support (Linux only)
 321 mouse_lib="xterm only"
 322 AC_ARG_WITH([gpm-mouse],
 323     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 324
 325 case $host_os in
 326 linux*)
 327     if test x$with_gpm_mouse != xno; then
 328         AC_CHECK_LIB(gpm, Gpm_Repeat,
 329             [AC_DEFINE(HAVE_LIBGPM, 1,
 330                        [Define to enable gpm mouse support on Linux])
 331             mouse_lib="gpm and xterm"
 332             MCLIBS="$MCLIBS -lgpm"],
 333             if test "x$with_gpm_mouse" = "xyes"; then
 334                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 335             else
 336                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 337             fi
 338         )
 339     fi
 340     ;;
 341 esac
 342
 343
 344 dnl ############################################################################
 345 dnl libmc
 346 dnl ############################################################################
 347
 348 LIBMC_VERSION="0.0.1"
 349 LIBMC_RELEASE="1"
 350 AC_SUBST(LIBMC_VERSION)
 351 AC_SUBST(LIBMC_RELEASE)
 352
 353 AC_ARG_ENABLE([mclib],
 354         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 355         [
 356             if test "x$enableval" = "xno" ; then
 357                 enable_mclib=no
 358             else
 359                 if test "x$enable_shared" = "xno" ; then
 360                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 361                     enable_mclib=no
 362                 else
 363                     enable_mclib=yes
 364                 fi
 365             fi
 366         ],
 367         [enable_mclib=no])
 368
 369 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 370
 371
 372 dnl ############################################################################
 373 dnl Where config files should be placed
 374 dnl ############################################################################
 375
 376 AC_ARG_WITH([homedir],
 377     AS_HELP_STRING([--with-homedir],
 378                    [Choose any place of user settings relative to home dir, or XDG for respect XDG standards @<:@XDG@:>@]),
 379     [
 380         dnl Unfortunately, there is no way to tell AC_ARG_WITH that the
 381         dnl argument value is required, so we can't differentiate
 382         dnl between `--with-homedir` and `--with-homedir=yes`, because
 383         dnl `with_homedir` is set to `yes` in both cases.
 384         dnl
 385         dnl We opt to set `with_homedir` to `.mc` if the value is `yes`
 386         dnl in order to avoid the surprise for users using
 387         dnl `--with-homedir` w/o any value and then getting mc to store
 388         dnl settings in the `yes` directory.
 389
 390         if test "x$withval" = "xXDG"; then
 391             with_homedir=XDG
 392         elif test "x$withval" = "xyes"; then
 393             with_homedir=.mc
 394         else
 395             with_homedir=$withval
 396         fi
 397     ],
 398     [with_homedir=XDG])
 399
 400
 401 if test x$with_homedir = xXDG; then
 402     AC_DEFINE(MC_HOMEDIR_XDG, 1, [Define to enable XDG standard support])
 403 else
 404     AC_DEFINE(MC_HOMEDIR_XDG, 0, [Define to disable XDG standard support])
 405     AC_DEFINE_UNQUOTED([MC_USERCONF_DIR], ["$with_homedir"], [Where configs will be placed relative to $HOME])
 406 fi
 407
 408
 409 dnl ############################################################################
 410 dnl MC options
 411 dnl ############################################################################
 412
 413 mc_ASSERT
 414
 415 mc_WITH_INTERNAL_EDIT
 416
 417 dnl Diff viewer support.
 418 AC_ARG_WITH([diff_viewer],
 419     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 420
 421 if test x$with_diff_viewer != xno; then
 422         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 423         use_diff=yes
 424         diff_msg="yes"
 425         AC_MSG_NOTICE([using diff viewer])
 426 else
 427         diff_msg="no"
 428 fi
 429
 430 mc_SUBSHELL
 431 mc_BACKGROUND
 432 mc_VFS_CHECKS
 433
 434 dnl ############################################################################
 435 dnl Directories
 436 dnl ############################################################################
 437
 438 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 439 dnl Let define ${prefix} and ${exec_prefix}
 440 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 441 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 442
 443 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 444     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 445 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 446     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 447 else
 448     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 449 fi
 450 AC_SUBST(EXTHELPERSDIR)
 451
 452
 453 dnl ############################################################################
 454 dnl Documentation
 455 dnl ############################################################################
 456
 457 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 458 AC_SUBST(MAN_DATE)
 459
 460 dnl Determine which help translations we want to install.
 461 ALL_DOC_LINGUAS="es hu it pl ru sr"
 462
 463 DOC_LINGUAS=
 464 if test "x$USE_NLS" = xyes; then
 465     if test -z "$LINGUAS"; then
 466         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 467     else
 468         langs="$LINGUAS"
 469     fi
 470 else
 471     langs=
 472 fi
 473
 474 for h_lang in $ALL_DOC_LINGUAS; do
 475     for lang in $langs; do
 476         if test "$lang" = "$h_lang"; then
 477             DOC_LINGUAS="$DOC_LINGUAS $lang"
 478             break
 479         fi
 480     done
 481 done
 482 AC_SUBST(DOC_LINGUAS)
 483
 484 DX_HTML_FEATURE(ON)
 485 DX_CHM_FEATURE(OFF)
 486 DX_CHI_FEATURE(OFF)
 487 DX_MAN_FEATURE(OFF)
 488 DX_RTF_FEATURE(OFF)
 489 DX_XML_FEATURE(OFF)
 490 DX_PDF_FEATURE(OFF)
 491 DX_PS_FEATURE(OFF)
 492 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 493
 494
 495 dnl ############################################################################
 496 dnl Configure results
 497 dnl ############################################################################
 498
 499 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 500
 501 AC_SUBST(MCLIBS)
 502 AC_SUBST(CFLAGS)
 503 AC_SUBST(CPPFLAGS)
 504 AC_SUBST(LDFLAGS)
 505 AC_SUBST(LIBS)
 506
 507 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 508 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 509 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 510 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 511 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 512 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 513 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 514 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 515 dnl Clarify do we really need GModule
 516 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 517                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 518
 519 AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 520
 521 AC_CONFIG_FILES(
 522 [
 523 src/man2hlp/man2hlp
 524 ],
 525 [
 526 chmod +x src/man2hlp/man2hlp
 527 ])
 528
 529 AC_CONFIG_FILES([
 530 Makefile
 531
 532 contrib/Makefile
 533 contrib/dist/Makefile
 534 contrib/dist/gentoo/Makefile
 535 contrib/dist/redhat/Makefile
 536 contrib/dist/redhat/mc.spec
 537 contrib/dist/pkginfo
 538 contrib/dist/prototype
 539
 540 misc/Makefile
 541 misc/mc.menu
 542 misc/mcedit.menu
 543 misc/skins/Makefile
 544 misc/ext.d/Makefile
 545 misc/ext.d/doc.sh
 546 misc/ext.d/misc.sh
 547 misc/ext.d/text.sh
 548 misc/ext.d/web.sh
 549 misc/macros.d/Makefile
 550 misc/mc.ext
 551
 552 src/Makefile
 553 src/consaver/Makefile
 554 src/editor/Makefile
 555 src/man2hlp/Makefile
 556 src/subshell/Makefile
 557 src/viewer/Makefile
 558 src/diffviewer/Makefile
 559 src/filemanager/Makefile
 560
 561 src/vfs/Makefile
 562
 563 src/vfs/cpio/Makefile
 564
 565 src/vfs/extfs/Makefile
 566 src/vfs/extfs/helpers/Makefile
 567 src/vfs/extfs/helpers/a+
 568 src/vfs/extfs/helpers/apt+
 569 src/vfs/extfs/helpers/audio
 570 src/vfs/extfs/helpers/deb
 571 src/vfs/extfs/helpers/deba
 572 src/vfs/extfs/helpers/debd
 573 src/vfs/extfs/helpers/dpkg+
 574 src/vfs/extfs/helpers/iso9660
 575 src/vfs/extfs/helpers/hp48+
 576 src/vfs/extfs/helpers/lslR
 577 src/vfs/extfs/helpers/mailfs
 578 src/vfs/extfs/helpers/patchfs
 579 src/vfs/extfs/helpers/rpms+
 580 src/vfs/extfs/helpers/s3+
 581 src/vfs/extfs/helpers/uace
 582 src/vfs/extfs/helpers/ualz
 583 src/vfs/extfs/helpers/uar
 584 src/vfs/extfs/helpers/uarc
 585 src/vfs/extfs/helpers/uarj
 586 src/vfs/extfs/helpers/uc1541
 587 src/vfs/extfs/helpers/ucab
 588 src/vfs/extfs/helpers/uha
 589 src/vfs/extfs/helpers/ulha
 590 src/vfs/extfs/helpers/ulib
 591 src/vfs/extfs/helpers/urar
 592 src/vfs/extfs/helpers/uzip
 593 src/vfs/extfs/helpers/uzoo
 594
 595 src/vfs/fish/Makefile
 596 src/vfs/fish/helpers/Makefile
 597
 598 src/vfs/ftpfs/Makefile
 599
 600 src/vfs/sftpfs/Makefile
 601
 602 src/vfs/local/Makefile
 603
 604 src/vfs/sfs/Makefile
 605
 606 src/vfs/smbfs/Makefile
 607
 608 src/vfs/tar/Makefile
 609
 610 src/vfs/undelfs/Makefile
 611
 612 lib/Makefile
 613 lib/event/Makefile
 614 lib/filehighlight/Makefile
 615 lib/mcconfig/Makefile
 616 lib/search/Makefile
 617 lib/skin/Makefile
 618 lib/strutil/Makefile
 619 lib/tty/Makefile
 620
 621 lib/vfs/Makefile
 622
 623 lib/widget/Makefile
 624
 625 misc/syntax/Makefile
 626 misc/syntax/Syntax
 627
 628 doc/Makefile
 629
 630 doc/hints/Makefile
 631 doc/hints/l10n/Makefile
 632
 633 doc/man/Makefile
 634 doc/man/es/Makefile
 635 doc/man/hu/Makefile
 636 doc/man/it/Makefile
 637 doc/man/pl/Makefile
 638 doc/man/ru/Makefile
 639 doc/man/sr/Makefile
 640
 641 doc/hlp/Makefile
 642 doc/hlp/es/Makefile
 643 doc/hlp/hu/Makefile
 644 doc/hlp/it/Makefile
 645 doc/hlp/pl/Makefile
 646 doc/hlp/ru/Makefile
 647 doc/hlp/sr/Makefile
 648
 649 intl/Makefile
 650 po/Makefile.in
 651 ])
 652
 653 AC_CONFIG_FILES([
 654 tests/Makefile
 655 tests/lib/Makefile
 656 tests/lib/mcconfig/Makefile
 657 tests/lib/search/Makefile
 658 tests/lib/strutil/Makefile
 659 tests/lib/vfs/Makefile
 660 tests/lib/widget/Makefile
 661 tests/src/Makefile
 662 tests/src/filemanager/Makefile
 663 tests/src/editor/Makefile
 664 tests/src/editor/test-data.txt
 665 tests/src/vfs/Makefile
 666 tests/src/vfs/extfs/Makefile
 667 tests/src/vfs/extfs/helpers-list/Makefile
 668 tests/src/vfs/extfs/helpers-list/data/config.sh
 669 tests/src/vfs/extfs/helpers-list/misc/Makefile
 670 ])
 671
 672 AC_OUTPUT
 673
 674 AC_MSG_NOTICE([
 675
 676 Configuration:
 677
 678   Source code location:       ${srcdir}
 679   Compiler:                   ${CC}
 680   Compiler flags:             ${CFLAGS}
 681   Assertions:                 ${enable_assert}
 682   Unit tests:                 ${tests_msg}
 683   File system:                ${vfs_type}
 684                               ${vfs_flags}
 685   Screen library:             ${screen_msg}
 686   Mouse support:              ${mouse_lib}
 687   X11 events support:         ${textmode_x11_support}
 688   With subshell support:      ${subshell}
 689   With background operations: ${enable_background}
 690   Internal editor:            ${edit_msg}
 691   Diff viewer:                ${diff_msg}
 692   Support for charset:        ${charset_msg}
 693   Search type:                ${SEARCH_TYPE}
 694 ])
 695
 696 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 697 dnl we enable it back for top-level ./configure
 698 if test -n "$ac_unrecognized_opts"; then
 699   case $enable_option_checking in
 700     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 701     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 702   esac
 703 fi