configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.6.0-pre1a)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_CANONICAL_HOST
  15
  16 AC_AIX
  17 AC_MINIX
  18 AC_ISC_POSIX
  19
  20 AC_PROG_CC_STDC
  21
  22
  23 dnl
  24 dnl Find glib 1.2.x.  This check should be kept close to the beginning,
  25 dnl as it tends to fail often.
  26 dnl
  27
  28 dnl This temporary variable is a workaround for a bug in Autoconf-2.53
  29 glib_path=$PATH:/usr/local/bin
  30
  31 dnl Klugde for FreeBSD, where glib-config is renamed to glib12-config.
  32 AC_PATH_PROGS([GLIB_CONFIG], [glib-config glib12-config],,[$glib_path])
  33
  34 AC_ARG_VAR([GLIB_CONFIG], [Path to glib-config])
  35 AM_PATH_GLIB(1.2.0,,[AC_MSG_ERROR([Test for GLIB failed.  MC requires GLIB.])])
  36 AC_SUBST(GLIB_LIBS)
  37
  38
  39 AC_HEADER_MAJOR
  40 AC_C_CONST
  41 AC_SYS_LARGEFILE
  42
  43 AC_PROG_LN_S
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 dnl Only list browsers here that can be run in background (i.e. with `&')
  47 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  48
  49 dnl
  50 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  51 dnl We use only part of the functionality of mmap, so on AIX,
  52 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  53 dnl
  54 AC_ARG_WITH(mmap,
  55         [--with-mmap                To force using the mmap call (AIX)],
  56         [case $withval in
  57 yes)
  58         ac_cv_func_mmap_fixed_mapped=yes
  59         AC_MSG_NOTICE([forcing MMAP support])
  60         ;;
  61 no)
  62         ac_cv_func_mmap_fixed_mapped=no
  63         AC_MSG_NOTICE([disabling MMAP support])
  64         ;;
  65 esac])
  66 AC_FUNC_MMAP
  67
  68 if test "x$ALL_LINGUAS" = x; then
  69 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  70 fi
  71
  72 dnl
  73 dnl Internationalization
  74 dnl
  75 AM_GNU_GETTEXT
  76 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  77     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  78 fi
  79
  80 dnl
  81 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  82 dnl
  83 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  84
  85 dnl
  86 dnl Enforce coding standards
  87 dnl
  88 if test "x$GCC" = xyes; then
  89     CFLAGS="$CFLAGS -Wall"
  90 fi
  91
  92 dnl
  93 dnl OS specific flags.
  94 dnl
  95
  96 posix_libs=""
  97 case $host_os in
  98 aux*)
  99     # A/UX
 100     posix_libs="-lposix"
 101     AC_DEFINE(_POSIX_SOURCE)
 102     ;;
 103 sco*)
 104     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
 105     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
 106     ;;
 107 esac
 108
 109 AC_PROG_INSTALL
 110 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 111         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 112         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h \
 113         arpa/inet.h])
 114
 115 AC_HEADER_TIME
 116 AC_HEADER_SYS_WAIT
 117 AC_HEADER_DIRENT
 118 AC_HEADER_STDC
 119
 120 dnl Missing structure components
 121 AC_STRUCT_ST_BLKSIZE
 122 AC_STRUCT_ST_BLOCKS
 123 AC_STRUCT_ST_RDEV
 124
 125 dnl
 126 dnl Check availability of some functions
 127 dnl
 128
 129 AC_CHECK_FUNCS([strerror statfs strftime \
 130                 memmove pwdauth truncate initgroups putenv \
 131                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 132                 sigaction sigemptyset sigprocmask sigaddset \
 133                 sysconf setuid setreuid telldir seekdir])
 134
 135 dnl
 136 dnl getpt is a GNU Extension (glibc 2.1.x)
 137 dnl
 138 AC_CHECK_FUNCS(getpt)
 139
 140 dnl
 141 dnl Password encryption support for mcserv
 142 dnl Check if function crypt needs a prototype
 143 dnl
 144 NEED_CRYPT_PROTOTYPE=yes
 145 if test x$ac_cv_header_crypt_h = xyes; then
 146 AC_TRY_WARNINGS([#include <crypt.h>], [char *p = crypt("xxx", "yyy");
 147 if (p)
 148 return 0;],[
 149 NEED_CRYPT_PROTOTYPE=no])
 150 else
 151     if test x$ac_cv_header_unistd_h = xyes; then
 152 AC_TRY_WARNINGS([#include <unistd.h>], [char *p = crypt("xxx", "yyy");
 153 if (p)
 154 return 0;],[
 155 NEED_CRYPT_PROTOTYPE=no])
 156     fi
 157 fi
 158 if test x$NEED_CRYPT_PROTOTYPE = xyes; then
 159 AC_DEFINE(NEED_CRYPT_PROTOTYPE, 1,
 160           [Define if function `crypt' needs a prototype])
 161 fi
 162
 163 dnl
 164 dnl On SCO and some SVR4, crypt is on libcrypt.a
 165 dnl         grantpt in  libpt.a
 166 dnl
 167 LCRYPT=""
 168 AC_CHECK_FUNCS(crypt, , [
 169     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 170         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 171 AC_SUBST(LCRYPT)
 172
 173 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 174
 175 dnl replacing lstat with statlstat on sco makes it more portable between
 176 dnl sco clones
 177 AC_CHECK_FUNCS(statlstat)
 178
 179 dnl
 180 dnl If running under AIX, AC_AIX does not tell us that
 181 dnl
 182 AC_MSG_CHECKING([for AIX defines])
 183 AC_EGREP_CPP(yes,
 184 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 185 yes
 186 #endif
 187 ], [
 188 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 189 AC_MSG_RESULT(yes)
 190 ], [AC_MSG_RESULT(no)])
 191
 192 dnl
 193 dnl This is from GNU fileutils, check aclocal.m4 for more information
 194 dnl
 195 AC_GET_FS_INFO
 196
 197 dnl
 198 dnl Missing typedefs and replacements
 199 dnl
 200
 201 AC_TYPE_MODE_T
 202 AC_CHECK_TYPE(umode_t, int)
 203 AC_CHECK_TYPE(off_t, long)
 204 AC_TYPE_PID_T
 205 AC_TYPE_UID_T
 206 AC_CHECK_TYPE(nlink_t, unsigned int)
 207
 208 AC_FUNC_ALLOCA
 209 AC_FUNC_STRCOLL
 210
 211 dnl
 212 dnl X11 support.
 213 dnl
 214
 215 textmode_x11_support="no"
 216 AC_ARG_WITH(tm-x-support,
 217         [--with-tm-x-support        Try getting events from X Window System],
 218         [if test x$withval = xyes; then
 219                 AC_PATH_XTRA
 220                 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 221                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 222                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 223                           [Define to enable getting events from X Window System])
 224                 textmode_x11_support="yes"
 225         fi
 226 ])
 227
 228 dnl
 229 dnl Network related functions
 230 dnl
 231
 232 AC_CHECK_LIB(nsl, t_accept)
 233 AC_CHECK_LIB(socket, socket)
 234
 235 have_socket=no
 236 AC_CHECK_FUNCS(socket, have_socket=yes)
 237 if test $have_socket = no; then
 238   # socket is not in the default libraries.  See if it's in some other.
 239   for lib in bsd socket inet; do
 240     AC_CHECK_LIB($lib, socket, [
 241         LIBS="$LIBS -l$lib"
 242         have_socket=yes
 243         AC_DEFINE(HAVE_SOCKET)
 244         break])
 245   done
 246 fi
 247
 248 have_gethostbyname=no
 249 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 250 if test $have_gethostbyname = no; then
 251   # gethostbyname is not in the default libraries.  See if it's in some other.
 252   for lib in bsd socket inet; do
 253     AC_CHECK_LIB([$lib], [gethostbyname],
 254                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 255   done
 256 fi
 257
 258 AC_CHECK_FUNCS(socketpair)
 259
 260 dnl
 261 dnl Sequent wants getprocessstats
 262 dnl
 263 AC_CHECK_LIB(seq, get_process_stats, [
 264         LIBS="$LIBS -lseq"
 265         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 266                   [Define if you have function `get_process_stats' and
 267 have to use that instead of gettimeofday])])
 268
 269 MC_VFS_CHECKS
 270
 271 dnl
 272 dnl Install mcserv only if explicitly enabled
 273 dnl
 274 AC_ARG_ENABLE([mcserv-install],
 275               [--enable-mcserv-install    Install mcserv - Midnight Commander file server])
 276
 277 vfs_type="normal"
 278 if test $use_vfs = yes
 279 then
 280         AC_MSG_NOTICE([enabling VFS code])
 281         vfs_type="Midnight Commander Virtual File System"
 282 fi
 283
 284 dnl This should be unadorned "slang" or "ncurses"
 285 screen_type=""
 286
 287 dnl Screen manager name (for the output only)
 288 screen_manager=unknown
 289
 290 mouse_lib="xterm only"
 291 case $host_os in
 292 linux*)
 293     AC_ARG_WITH(gpm-mouse,
 294         [--with-gpm-mouse[[=base-dir]]  Compile with gpm mouse support (Linux only)],
 295         [if test x$withval != xno
 296         then
 297                 if test x$withval != xyes
 298                 then
 299                         LDFLAGS="$LDFLAGS -L$withval/lib"
 300                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 301                 fi
 302                 AC_DEFINE(HAVE_LIBGPM, 1,
 303                           [Define to enable gpm mouse support on Linux])
 304                 mouse_lib="GPM and xterm"
 305                 MCLIBS="-lgpm $MCLIBS"
 306         fi],
 307         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 308                 [AC_DEFINE(HAVE_LIBGPM)
 309                 mouse_lib="GPM and xterm"
 310                 MCLIBS="-lgpm $MCLIBS"],
 311                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 312                 [$LIBS])
 313         ])
 314     ;;
 315 esac
 316
 317 AC_ARG_WITH(ncurses,
 318         [--with-ncurses[[=base-dir]]  Compile with ncurses/locate base dir],
 319 [if test x$withval != xno; then
 320         if test x$withval != xyes; then
 321                 LDFLAGS="$LDFLAGS -L$withval/lib"
 322                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 323         fi
 324
 325         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 326                          [ncurses_h_found=yes; break])
 327         if test -z "$ncurses_h_found"; then
 328             AC_MSG_ERROR([Could not find ncurses header])
 329         fi
 330
 331         dnl curses_version is specific to ncurses, it's not in old curses
 332         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 333                      [AC_MSG_ERROR([Could not find ncurses library])])
 334
 335         screen_type="ncurses"
 336         screen_manager="ncurses"
 337         AC_DEFINE(USE_NCURSES, 1,
 338                   [Define to use ncurses for screen management])
 339 fi
 340 ])
 341
 342 AC_ARG_WITH(hsc,
 343         [--with-hsc                 Compile with support for the HSC firewall],
 344         [if test x$withval = xyes; then
 345                 AC_DEFINE(HSC_PROXY, 1,
 346                           [Define if you want to use the HSC firewall])
 347         fi
 348 ])
 349
 350 dnl
 351 dnl Check for the -mandoc package
 352 dnl
 353 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 354 if $HAVE_nroff; then
 355     AC_MSG_CHECKING([for manual formatting macros])
 356     AC_CACHE_VAL(ac_cv_mandoc, [
 357     nroff -mandoc < /dev/null > /dev/null 2>&1
 358     if test $? = 0
 359     then
 360         ac_cv_mandoc=-mandoc
 361     else
 362         ac_cv_mandoc=-man
 363     fi
 364     ])
 365     MANDOC=$ac_cv_mandoc
 366     AC_MSG_RESULT([$MANDOC])
 367 else
 368     MANDOC=-man
 369 fi
 370 AC_SUBST(MANDOC)
 371
 372 dnl
 373 dnl Check if nroff accepts -Tlatin1 or -Tascii
 374 dnl
 375 if $HAVE_nroff; then
 376     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 377     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 378     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 379     if test $? = 0
 380     then
 381         ac_cv_nroff_tascii=" -Tlatin1"
 382     else
 383         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 384         if test $? = 0
 385         then
 386             ac_cv_nroff_tascii=" -Tascii"
 387         else
 388             ac_cv_nroff_tascii=""
 389         fi
 390     fi
 391     ])
 392     if test "x$ac_cv_nroff_tascii" = x; then
 393         AC_MSG_RESULT([no])
 394     else
 395         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 396     fi
 397 fi
 398 TROFFASCII="$ac_cv_nroff_tascii"
 399 AC_SUBST(TROFFASCII)
 400
 401 dnl
 402 dnl Check for - option to file
 403 dnl
 404 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 405 if $HAVE_FILECMD; then
 406     AC_MSG_CHECKING([for - option to file command])
 407     AC_CACHE_VAL(ac_cv_filestdin, [[
 408     cat > conftest.c <<\EOF
 409 /* A comment */
 410 #if 0
 411 #endif
 412 void main(void)
 413 { return; }
 414 EOF
 415     cat > conftest.sed <<\EOF
 416 s/^[^:]*:[      ]*//
 417 s/[     ]*$//
 418 EOF
 419     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 420     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 421     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 422         ac_cv_filestdin=yes
 423     else
 424         ac_cv_filestdin=no
 425     fi
 426     rm conftest.c conftest.sed
 427     ]])
 428
 429     if test x$ac_cv_filestdin = xyes; then
 430         AC_DEFINE(FILE_STDIN, 1,
 431                   [Define if the file command accepts - for stdin])
 432     fi
 433     filestdin=$ac_cv_filestdin
 434     AC_MSG_RESULT([$filestdin])
 435
 436     dnl
 437     dnl Check for -L option to file
 438     dnl
 439
 440 AC_MSG_CHECKING([for -L option to file command])
 441 AC_CACHE_VAL(ac_cv_filel, [
 442 file -L . > /dev/null 2>&1
 443 if test $? = 0
 444 then
 445     ac_cv_filel=yes
 446 else
 447     ac_cv_filel=no
 448 fi
 449 ])
 450 if test x$ac_cv_filel = xyes; then
 451     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 452 fi
 453 filel=$ac_cv_filel
 454 AC_MSG_RESULT([$filel])
 455 fi
 456
 457
 458 AC_MSG_CHECKING([for subshell support])
 459 AC_ARG_WITH(subshell,
 460         [--with-subshell=optional   To disable concurrent shell by default
 461 --without-subshell         To disable concurrent shell completely],
 462         [result=no
 463         if test x$withval = xoptional
 464         then
 465                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 466                           [Define to make subshell support optional])
 467                 result="optional"
 468         fi
 469         if test x$withval = xyes
 470         then
 471                 result="yes"
 472         fi],
 473         [dnl Default: enable the subshell support
 474         result="yes"
 475 ])
 476 if test "x$result" != xno; then
 477         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 478                   [Define to enable subshell support])
 479 fi
 480 AC_MSG_RESULT([$result])
 481 subshell="$result"
 482
 483 if test "x$screen_type" != xncurses; then
 484         slang_check_lib=true
 485         slang_term=""
 486         slang_use_system_installed_lib=false
 487         AC_CHECK_LIB(slang,SLang_init_tty,
 488                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 489                                   [slang_h_found=yes; break])
 490                 if test "x$slang_h_found" = xyes; then
 491                      slang_use_system_installed_lib=true
 492                      slang_check_lib=false
 493                 fi
 494         ])
 495 fi
 496
 497 AC_ARG_WITH(termcap,
 498         [--with-termcap             SLANG: Force usage of termcap],[
 499         if test x$withval = xyes; then
 500                 AC_USE_TERMCAP
 501                 slang_check_lib=false
 502                 slang_use_system_installed_lib=false
 503         fi]
 504 )
 505
 506 AC_ARG_WITH(included-slang,
 507         [--with-included-slang      SLANG: use the SLang library included here],[
 508         if test x$withval = xyes; then
 509             slang_use_system_installed_lib=false
 510             slang_check_lib=true
 511         fi]
 512 )
 513
 514 AC_ARG_WITH(slang,
 515         [--with-slang              Compile with the slang screen manager],[
 516         if test x$withval = xyes; then
 517                 AC_WITH_SLANG
 518         fi
 519 ])
 520
 521 LIBEDIT_A=""
 522 MCEDIT=""
 523 LEDIT=""
 524 EDIT_msg=""
 525 AC_ARG_WITH(edit,
 526         [--with-edit                Enable internal editor],
 527         [if test x$withval = xyes
 528         then
 529                 AC_WITH_EDIT
 530         else
 531                 EDIT_msg="no"
 532         fi],
 533         [dnl Default: provide the internal editor
 534         AC_WITH_EDIT
 535 ])
 536 AC_SUBST(LIBEDIT_A)
 537 AC_SUBST(MCEDIT)
 538 AC_SUBST(LEDIT)
 539
 540 undelfs_o=""
 541
 542 if test $use_vfs = yes; then
 543     AC_ARG_WITH(ext2undel,
 544         [--with-ext2undel           Compile with ext2 undelete code],[
 545         if test x$withval != xno;
 546         then
 547                 if test x$withval != xyes
 548                 then
 549                         LDFLAGS="$LDFLAGS -L$withval/lib"
 550                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 551                 fi
 552                 AC_EXT2_UNDEL
 553         fi],[
 554         dnl Default: detect
 555         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 556     ])
 557 fi
 558
 559 AC_SUBST(undelfs_o)
 560
 561
 562 dnl Ncurses specific checks
 563 dnl
 564 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 565 dnl or you'll have to press Esc three times to dismiss a dialog box.
 566 dnl
 567 if test "x$screen_type" = xncurses; then
 568   save_LIBS="$LIBS"
 569   LIBS="$MCLIBS $LIBS"
 570   AC_CACHE_CHECK([for ESCDELAY variable],
 571                  [mc_cv_ncurses_escdelay],
 572                  [AC_TRY_COMPILE([], [
 573                         extern int ESCDELAY;
 574                         int main ()
 575                         {
 576                           ESCDELAY = 0;
 577                         }
 578                         ],
 579                         [mc_cv_ncurses_escdelay=yes],
 580                         [mc_cv_ncurses_escdelay=no]
 581                   )
 582   ])
 583   if test "$mc_cv_ncurses_escdelay" = yes; then
 584     AC_DEFINE(HAVE_ESCDELAY, 1,
 585               [Define if ncurses has ESCDELAY variable])
 586   fi
 587
 588   AC_CHECK_FUNCS(resizeterm)
 589   LIBS="$save_LIBS"
 590 fi
 591
 592 if test "x$screen_type" = "x"; then
 593     AC_WITH_SLANG
 594 fi
 595
 596 dnl
 597 dnl The variables used for expanding the auto saver.
 598 dnl
 599 cons_saver=""
 600 install_saver="no"
 601 PAMLIBS=""
 602 case $host_os in
 603 linux*)
 604     cons_saver="cons.saver"
 605     install_saver="yes"
 606
 607     dnl
 608     dnl On Linux, check for PAM authentication available
 609     dnl
 610     AC_CHECK_LIB(pam, pam_start, [
 611         AC_DEFINE(HAVE_PAM, 1,
 612                   [Define if PAM (Pluggable Authentication Modules) is available])
 613         PAMLIBS="-lpam -ldl"
 614     ],[],[-ldl])
 615     ;;
 616 esac
 617 AC_SUBST(cons_saver)
 618 AC_SUBST(PAMLIBS)
 619
 620 dnl
 621 dnl User visible support for charset conversion.
 622 dnl
 623 AC_ARG_ENABLE([charset],
 624               [--enable-charset           Support for charset selection and conversion])
 625 have_charset=
 626 if test "x$enable_charset" = xyes; then
 627   if test "x$am_cv_func_iconv" != xyes; then
 628     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 629   else
 630     AC_DEFINE(HAVE_CHARSET, 1,
 631               [Define to enable charset selection and conversion])
 632     have_charset=yes
 633   fi
 634 fi
 635
 636 if test "$GLIBC21" != yes; then
 637     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 638 fi
 639
 640 dnl
 641 dnl This code should be moved to the ac_WITH_SLANG
 642 dnl
 643 dnl We check for the existance of setupterm on curses library
 644 dnl this is required to load certain definitions on some termcaps
 645 dnl editions (AIX and OSF/1 I seem to remember).
 646 dnl Note that we avoid using setupterm
 647 if test "x$screen_type" = xslang; then
 648         case $host_os in
 649         linux*)
 650                 ;;
 651         *)
 652                 AC_CHECK_LIB(curses,setupterm,
 653                         [AC_TRY_COMPILE([
 654 #include <curses.h>
 655 #include <term.h>],[
 656    if (key_end == parm_insert_line)
 657         return 1;
 658    return 0;
 659 ],
 660                         [MCLIBS="$MCLIBS -lcurses"
 661                         AC_DEFINE(USE_SETUPTERM, 1,
 662                                   [Define to use function `setupterm'
 663 from `curses' library in S-Lang])])
 664                 ])
 665         esac
 666 fi
 667
 668 LIBS="$LIBS $posix_libs"
 669
 670 AC_SUBST(CFLAGS)
 671 AC_SUBST(CPPFLAGS)
 672 AC_SUBST(LDFLAGS)
 673 AC_SUBST(LIBS)
 674
 675 dnl Libraries used only when building the mc binary
 676 AC_SUBST(MCLIBS)
 677
 678 dnl Version for the RedHat package, without dashes
 679 RH_VERSION=`echo $VERSION | sed 's/-//'`
 680 AC_SUBST(RH_VERSION)
 681
 682 if test "x$SAMBAFILES" != x; then
 683   AC_CONFIG_SUBDIRS([vfs/samba])
 684 fi
 685
 686 AM_CONDITIONAL(USE_EDIT, [test -n "$LIBEDIT_A"])
 687 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 688 AM_CONDITIONAL(USE_VFS_NET, [test x"$use_net_code" = xtrue])
 689 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$undelfs_o"])
 690 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$SAMBAFILES"])
 691 AM_CONDITIONAL(MCSERV_INSTALL,
 692                [test "x$enable_mcserv_install$mcserv" = xyesmcserv])
 693 AM_CONDITIONAL(INCLUDED_SLANG,
 694                [test "x$slang_use_system_installed_lib" = xfalse])
 695 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 696 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 697
 698 AH_BOTTOM([#include <extraconf.h>])
 699
 700 AC_CONFIG_FILES([
 701 Makefile
 702 mc.spec
 703 doc/Makefile
 704 vfs/Makefile
 705 vfs/extfs/Makefile
 706 lib/Makefile
 707 src/Makefile
 708 slang/Makefile
 709 edit/Makefile
 710 syntax/Makefile
 711 pc/Makefile
 712
 713 lib/mc.ext
 714 lib/mc.sh
 715 lib/mc.csh
 716
 717 vfs/extfs/deb
 718 vfs/extfs/ftplist
 719 vfs/extfs/lslR
 720 vfs/extfs/uar
 721 vfs/extfs/ucpio
 722 vfs/extfs/ulha
 723 vfs/extfs/uha
 724 vfs/extfs/urar
 725 vfs/extfs/uzoo
 726
 727 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 728 doc/es/mc.1 doc/es/Makefile
 729 doc/hu/Makefile
 730 doc/it/mc.1 doc/it/Makefile
 731 doc/pl/mc.1 doc/pl/Makefile
 732 doc/ru/mc.1 doc/ru/Makefile
 733
 734 intl/Makefile po/Makefile.in
 735 ])
 736
 737 AC_CONFIG_COMMANDS(potfiles,
 738     [grep ^top_builddir po/Makefile.in >/dev/null && sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 739
 740 AC_OUTPUT
 741
 742 if test "x$screen_type" = xslang; then
 743     screen_manager="${screen_manager}${slang_term}"
 744 fi
 745
 746 echo "
 747 Configuration:
 748
 749   Source code location:       ${srcdir}
 750   Compiler:                   ${CC}
 751   Compiler flags:             ${CFLAGS}
 752   File system:                ${vfs_type}
 753                               ${vfs_flags}
 754   Screen manager:             ${screen_manager}
 755   Install console saver:      ${install_saver}
 756   Mouse support:              ${mouse_lib}
 757   X11 events support:         ${textmode_x11_support}
 758   Debugger code:              ${mem_debug}
 759   With subshell support:      ${subshell}
 760   Internal editor:            ${EDIT_msg}
 761   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 762 "