configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ(2.64)
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 AC_PROG_CC
  40 AM_PROG_CC_C_O
  41
  42 mc_CHECK_CFLAGS
  43
  44 CFLAGS_OPTS=""
  45 if test "x$CFLAGS" = "x"; then
  46     CFLAGS_OPTS=" -O2 "
  47 fi
  48 if test x$USE_MAINTAINER_MODE = xyes; then
  49     CFLAGS_OPTS="-g3 -O -ggdb"
  50     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  51 fi
  52
  53 AC_ARG_ENABLE([werror],
  54     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  55 if test "x$enable_werror" = xyes; then
  56     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  57 fi
  58
  59 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  60 dnl which causes attribute checks to fail
  61 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  62 _AC_LANG_PREFIX[]FLAGS=
  63 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  64 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  65 unset ax_gcc_func_attribute_save_flags
  66
  67 LT_INIT
  68
  69
  70 dnl ############################################################################
  71 dnl Check for programs
  72 dnl ############################################################################
  73
  74 PKG_PROG_PKG_CONFIG
  75 AC_PROG_INSTALL
  76 AC_PROG_LN_S
  77 dnl See also the "OS specific stuff" section below.
  78
  79 dnl Check nroff and the options it supports
  80 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  81 dnl Default values
  82 MANDOC=-man
  83 MAN_FLAGS=
  84 if $HAVE_nroff; then
  85     AC_MSG_CHECKING([for manual formatting macros])
  86     AC_CACHE_VAL(mc_cv_mandoc, [
  87     nroff -mandoc < /dev/null > /dev/null 2>&1
  88     if test $? = 0; then
  89         mc_cv_mandoc=-mandoc
  90     else
  91         mc_cv_mandoc=-man
  92     fi
  93     ])
  94     MANDOC=$mc_cv_mandoc
  95     AC_MSG_RESULT([$MANDOC])
  96
  97     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
  98     AC_CACHE_VAL(mc_cv_man_nocolor, [
  99     nroff -c < /dev/null > /dev/null 2>&1
 100     if test $? = 0; then
 101         mc_cv_man_nocolor=-c
 102     else
 103         mc_cv_man_nocolor=
 104     fi
 105     ])
 106     MAN_FLAGS=$mc_cv_man_nocolor
 107     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 108
 109     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 110     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 111     mc_cv_nroff_tascii=
 112     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 113     if test $? = 0; then
 114         mc_cv_nroff_tascii=-Tlatin1
 115     else
 116         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 117         if test $? = 0; then
 118             mc_cv_nroff_tascii=-Tascii
 119         fi
 120     fi
 121     ])
 122     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 123     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 124 fi
 125
 126 AC_SUBST(MANDOC)
 127 AC_SUBST(MAN_FLAGS)
 128
 129 dnl Check for -z, -b, -L, and -S options to file
 130 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 131 if $HAVE_FILECMD; then
 132     dnl Don't use the file command if it doesn't accept the -z option
 133     AC_MSG_CHECKING([for -z option to file command])
 134     AC_CACHE_VAL(mc_cv_file_z, [
 135         file -z . > /dev/null 2>&1
 136         if test $? = 0; then
 137             mc_cv_file_z=yes
 138         else
 139             mc_cv_file_z=no
 140         fi
 141     ])
 142     AC_MSG_RESULT([$mc_cv_file_z])
 143
 144     if test x$mc_cv_file_z = xyes; then
 145         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 146     else
 147         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 148     fi
 149
 150     if test x$mc_cv_file_z = xyes; then
 151         dnl file is used; check -b, -L and -S options
 152
 153         AC_MSG_CHECKING([for -b option to file command])
 154         AC_CACHE_VAL(mc_cv_file_b, [
 155             file -b . > /dev/null 2>&1
 156             if test $? = 0; then
 157                 mc_cv_file_b=yes
 158             else
 159                 mc_cv_file_b=no
 160             fi
 161         ])
 162         AC_MSG_RESULT([$mc_cv_file_b])
 163
 164         if test x$mc_cv_file_b = xyes; then
 165             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 166         fi
 167
 168         AC_MSG_CHECKING([for -L option to file command])
 169         AC_CACHE_VAL(mc_cv_file_L, [
 170             file -L . > /dev/null 2>&1
 171             if test $? = 0; then
 172                 mc_cv_file_L=yes
 173             else
 174                 mc_cv_file_L=no
 175             fi
 176         ])
 177         AC_MSG_RESULT([$mc_cv_file_L])
 178
 179         if test x$mc_cv_file_L = xyes; then
 180             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 181         else
 182             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 183         fi
 184
 185         dnl The file command accepts the -S option since 5.33
 186         AC_MSG_CHECKING([for -S option to file command])
 187         AC_CACHE_VAL(mc_cv_file_S, [
 188             file -S . > /dev/null 2>&1
 189             if test $? = 0; then
 190                 mc_cv_file_S=yes
 191             else
 192                 mc_cv_file_S=no
 193             fi
 194         ])
 195         AC_MSG_RESULT([$mc_cv_file_S])
 196
 197         if test x$mc_cv_file_S = xyes; then
 198             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 199         else
 200             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 201         fi
 202     fi
 203 fi
 204
 205 dnl Only list browsers here that can be run in background (i.e. with `&')
 206 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 207
 208
 209 dnl ############################################################################
 210 dnl Check for other tools
 211 dnl ############################################################################
 212
 213 AC_CHECK_TOOL(AR, ar, ar)
 214 mc_UNIT_TESTS
 215
 216
 217 dnl ############################################################################
 218 dnl Check for main libraies
 219 dnl ############################################################################
 220
 221 mc_CHECK_GLIB
 222 mc_G_MODULE_SUPPORTED
 223 mc_WITH_SCREEN
 224 mc_CHECK_SEARCH_TYPE
 225 dnl X11 support. Used to read keyboard modifiers when running under X11.
 226 mc_WITH_X
 227
 228
 229 dnl ############################################################################
 230 dnl Check for header files
 231 dnl ############################################################################
 232
 233 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 234         utime.h sys/statfs.h sys/vfs.h \
 235         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 236         sys/socket.h])
 237 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 238 dnl   to work around a buggy version in autoconf <= 2.69.
 239 AC_HEADER_MAJOR
 240
 241
 242 dnl ############################################################################
 243 dnl Check for types
 244 dnl ############################################################################
 245
 246 dnl Check largefile before type sizeof checks
 247 AC_SYS_LARGEFILE
 248
 249 AC_CHECK_SIZEOF(long)
 250 AC_TYPE_UINTMAX_T
 251 AC_CHECK_SIZEOF(uintmax_t)
 252 AC_TYPE_OFF_T
 253 AC_CHECK_SIZEOF(off_t)
 254 AC_TYPE_MODE_T
 255 gl_PROMOTED_TYPE_MODE_T
 256 AC_TYPE_PID_T
 257 AC_TYPE_UID_T
 258
 259 AC_STRUCT_ST_BLOCKS
 260 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim])
 261 gl_STAT_SIZE
 262
 263 AH_TEMPLATE([sig_atomic_t],
 264             [/* Define to `int' if <signal.h> doesn't define.])
 265 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 266             [Some systems declare sig_atomic_t as volatile, some others -- no.
 267              This define will have value `sig_atomic_t' or
 268              `volatile sig_atomic_t' accordingly.])
 269
 270 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 271 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 272   [
 273     ac_cv_type_sig_atomic_t=yes;
 274     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 275                     signal.h,
 276                     [
 277                         is_sig_atomic_t_volatile=yes;
 278                         AC_MSG_RESULT([yes, volatile])
 279                     ],
 280                     [
 281                         is_sig_atomic_t_volatile=no;
 282                         AC_MSG_RESULT([yes, non volatile])
 283                     ])
 284   ],
 285   [
 286     AC_MSG_RESULT(no)
 287     AC_CHECK_TYPE(sig_atomic_t, int)
 288     is_sig_atomic_t_volatile=no
 289   ])
 290 if test $is_sig_atomic_t_volatile = 'yes'
 291 then
 292     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 293 else
 294     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 295 fi
 296
 297
 298 dnl ############################################################################
 299 dnl Check for functions
 300 dnl ############################################################################
 301
 302 AC_CHECK_FUNCS([\
 303         strverscmp \
 304         strncasecmp \
 305         realpath
 306 ])
 307
 308 dnl getpt is a GNU Extension (glibc 2.1.x)
 309 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 310 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 311
 312 dnl replacing lstat with statlstat on sco makes it more portable between
 313 dnl sco clones
 314 AC_CHECK_FUNCS(statlstat)
 315
 316 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
 317 dnl We use only part of the functionality of mmap, so on AIX,
 318 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 319 AC_ARG_WITH([mmap],
 320         AS_HELP_STRING([--with-mmap], [Use the mmap call @<:@yes if found@:>@]))
 321 if test x$with_mmap != xno; then
 322     if test x$with_mmap = x; then
 323         AC_FUNC_MMAP
 324     else
 325         AC_DEFINE(HAVE_MMAP, 1)
 326     fi
 327 fi
 328
 329 mc_GET_FS_INFO
 330
 331
 332 dnl ############################################################################
 333 dnl Internationalization
 334 dnl ############################################################################
 335
 336 AC_CHECK_FUNCS([setlocale])
 337
 338 AM_GNU_GETTEXT([external], [need-ngettext])
 339 AM_GNU_GETTEXT_VERSION([0.18.2])
 340
 341 mc_I18N
 342
 343 dnl ############################################################################
 344 dnl OS specific stuff
 345 dnl ############################################################################
 346
 347 case $host_os in
 348 *os400)
 349     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 350     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 351     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 352     ;;
 353 *)
 354     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 355     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 356     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 357 esac
 358
 359 case $host_os in
 360 aux*)
 361     # A/UX
 362     LIBS="$LIBS -lposix"
 363     AC_DEFINE(_POSIX_SOURCE)
 364     ;;
 365 esac
 366
 367 dnl If running under AIX, AC_AIX does not tell us that
 368 AC_MSG_CHECKING([for AIX defines])
 369 AC_EGREP_CPP([yes],
 370     [
 371         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 372         yes
 373         #endif
 374     ],
 375     [
 376         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 377         AC_MSG_RESULT(yes)
 378     ],
 379     [
 380         AC_MSG_RESULT(no)
 381     ])
 382
 383 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 384 dnl utimensat() causes different timespec structures to cause failures on IBM i and AIX
 385 case $host_os in
 386 *os400 | aix*)
 387     ;;
 388 *)
 389     AC_CHECK_FUNCS([utimensat])
 390     ;;
 391 esac
 392
 393 case $host_os in
 394 *os400)
 395     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 396 esac
 397
 398 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 399 case $host_os in
 400 linux*)
 401     AC_CHECK_HEADERS([linux/fs.h])
 402 esac
 403
 404 dnl Check if the OS is supported by the console saver.
 405 cons_saver=""
 406 case $host_os in
 407 linux*)
 408     cons_saver=yes
 409 esac
 410
 411 dnl Check for gpm mouse support (Linux only)
 412 mouse_lib="xterm only"
 413 AC_ARG_WITH([gpm-mouse],
 414     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 415
 416 case $host_os in
 417 linux*)
 418     if test x$with_gpm_mouse != xno; then
 419         AC_CHECK_LIB(gpm, Gpm_Repeat,
 420             [AC_DEFINE(HAVE_LIBGPM, 1,
 421                        [Define to enable gpm mouse support on Linux])
 422             mouse_lib="gpm and xterm"
 423             MCLIBS="$MCLIBS -lgpm"],
 424             if test "x$with_gpm_mouse" = "xyes"; then
 425                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 426             else
 427                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 428             fi
 429         )
 430     fi
 431     ;;
 432 esac
 433
 434
 435 dnl ############################################################################
 436 dnl libmc
 437 dnl ############################################################################
 438
 439 LIBMC_VERSION="0.0.1"
 440 LIBMC_RELEASE="1"
 441 AC_SUBST(LIBMC_VERSION)
 442 AC_SUBST(LIBMC_RELEASE)
 443
 444 AC_ARG_ENABLE([mclib],
 445         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 446         [
 447             if test "x$enableval" = "xno" ; then
 448                 enable_mclib=no
 449             else
 450                 if test "x$enable_shared" = "xno" ; then
 451                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 452                     enable_mclib=no
 453                 else
 454                     enable_mclib=yes
 455                 fi
 456             fi
 457         ],
 458         [enable_mclib=no])
 459
 460 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 461
 462
 463 dnl ############################################################################
 464 dnl MC options
 465 dnl ############################################################################
 466
 467 mc_ASSERT
 468
 469 mc_WITH_INTERNAL_EDIT
 470
 471 dnl Diff viewer support.
 472 AC_ARG_WITH([diff_viewer],
 473     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 474
 475 if test x$with_diff_viewer != xno; then
 476         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 477         use_diff=yes
 478         diff_msg="yes"
 479         AC_MSG_NOTICE([using diff viewer])
 480 else
 481         diff_msg="no"
 482 fi
 483
 484 mc_SUBSHELL
 485 mc_BACKGROUND
 486 mc_EXT2FS_ATTR
 487 mc_VFS_CHECKS
 488
 489 dnl ############################################################################
 490 dnl Directories
 491 dnl ############################################################################
 492
 493 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 494 dnl Let define ${prefix} and ${exec_prefix}
 495 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 496 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 497
 498 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 499     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 500 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 501     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 502 else
 503     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 504 fi
 505 AC_SUBST(EXTHELPERSDIR)
 506
 507
 508 dnl ############################################################################
 509 dnl Documentation
 510 dnl ############################################################################
 511
 512 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 513 AC_SUBST(MAN_DATE)
 514
 515 dnl Determine which help translations we want to install.
 516 ALL_DOC_LINGUAS="es hu it pl ru sr"
 517
 518 DOC_LINGUAS=
 519 if test "x$USE_NLS" = xyes; then
 520     if test -z "$LINGUAS"; then
 521         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 522     else
 523         langs="$LINGUAS"
 524     fi
 525 else
 526     langs=
 527 fi
 528
 529 for h_lang in $ALL_DOC_LINGUAS; do
 530     for lang in $langs; do
 531         if test "$lang" = "$h_lang"; then
 532             DOC_LINGUAS="$DOC_LINGUAS $lang"
 533             break
 534         fi
 535     done
 536 done
 537 AC_SUBST(DOC_LINGUAS)
 538
 539 DX_HTML_FEATURE(ON)
 540 DX_CHM_FEATURE(OFF)
 541 DX_CHI_FEATURE(OFF)
 542 DX_MAN_FEATURE(OFF)
 543 DX_RTF_FEATURE(OFF)
 544 DX_XML_FEATURE(OFF)
 545 DX_PDF_FEATURE(OFF)
 546 DX_PS_FEATURE(OFF)
 547 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 548
 549
 550 dnl ############################################################################
 551 dnl Configure results
 552 dnl ############################################################################
 553
 554 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 555
 556 AC_SUBST(MCLIBS)
 557 AC_SUBST(CFLAGS)
 558 AC_SUBST(CPPFLAGS)
 559 AC_SUBST(LDFLAGS)
 560 AC_SUBST(LIBS)
 561
 562 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 563 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 564 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 565 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 566 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 567 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 568 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 569 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 570 dnl Clarify do we really need GModule
 571 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 572                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 573
 574 AC_ARG_ENABLE([configure-args],
 575     AS_HELP_STRING([--enable-configure-args], [Handle all compiler warnings as errors]))
 576 if test "x$enable_configure_args" != xno; then
 577     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 578     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 579 fi
 580
 581
 582 AC_CONFIG_FILES(
 583 [
 584 src/man2hlp/man2hlp
 585 ],
 586 [
 587 chmod +x src/man2hlp/man2hlp
 588 ])
 589
 590 AC_CONFIG_FILES([
 591 Makefile
 592
 593 contrib/Makefile
 594
 595 misc/Makefile
 596 misc/mc.charsets
 597 misc/mc.menu
 598 misc/mcedit.menu
 599 misc/skins/Makefile
 600 misc/ext.d/Makefile
 601 misc/ext.d/doc.sh
 602 misc/ext.d/misc.sh
 603 misc/ext.d/text.sh
 604 misc/ext.d/web.sh
 605 misc/macros.d/Makefile
 606 misc/mc.ext
 607
 608 src/Makefile
 609 src/consaver/Makefile
 610 src/editor/Makefile
 611 src/man2hlp/Makefile
 612 src/subshell/Makefile
 613 src/viewer/Makefile
 614 src/diffviewer/Makefile
 615 src/filemanager/Makefile
 616
 617 src/vfs/Makefile
 618
 619 src/vfs/cpio/Makefile
 620
 621 src/vfs/extfs/Makefile
 622 src/vfs/extfs/helpers/Makefile
 623 src/vfs/extfs/helpers/a+
 624 src/vfs/extfs/helpers/apt+
 625 src/vfs/extfs/helpers/audio
 626 src/vfs/extfs/helpers/deb
 627 src/vfs/extfs/helpers/deba
 628 src/vfs/extfs/helpers/debd
 629 src/vfs/extfs/helpers/dpkg+
 630 src/vfs/extfs/helpers/iso9660
 631 src/vfs/extfs/helpers/hp48+
 632 src/vfs/extfs/helpers/lslR
 633 src/vfs/extfs/helpers/mailfs
 634 src/vfs/extfs/helpers/patchfs
 635 src/vfs/extfs/helpers/rpms+
 636 src/vfs/extfs/helpers/s3+
 637 src/vfs/extfs/helpers/uace
 638 src/vfs/extfs/helpers/ualz
 639 src/vfs/extfs/helpers/uar
 640 src/vfs/extfs/helpers/uarc
 641 src/vfs/extfs/helpers/uarj
 642 src/vfs/extfs/helpers/ucab
 643 src/vfs/extfs/helpers/uha
 644 src/vfs/extfs/helpers/ulha
 645 src/vfs/extfs/helpers/ulib
 646 src/vfs/extfs/helpers/unar
 647 src/vfs/extfs/helpers/urar
 648 src/vfs/extfs/helpers/uwim
 649 src/vfs/extfs/helpers/uzip
 650 src/vfs/extfs/helpers/uzoo
 651
 652 src/vfs/fish/Makefile
 653 src/vfs/fish/helpers/Makefile
 654
 655 src/vfs/ftpfs/Makefile
 656
 657 src/vfs/sftpfs/Makefile
 658
 659 src/vfs/local/Makefile
 660
 661 src/vfs/sfs/Makefile
 662
 663 src/vfs/tar/Makefile
 664
 665 src/vfs/undelfs/Makefile
 666
 667 lib/Makefile
 668 lib/event/Makefile
 669 lib/filehighlight/Makefile
 670 lib/mcconfig/Makefile
 671 lib/search/Makefile
 672 lib/skin/Makefile
 673 lib/strutil/Makefile
 674 lib/tty/Makefile
 675
 676 lib/vfs/Makefile
 677
 678 lib/widget/Makefile
 679
 680 misc/syntax/Makefile
 681 misc/syntax/Syntax
 682
 683 doc/Makefile
 684
 685 doc/hints/Makefile
 686 doc/hints/l10n/Makefile
 687
 688 doc/man/Makefile
 689 doc/man/es/Makefile
 690 doc/man/hu/Makefile
 691 doc/man/it/Makefile
 692 doc/man/pl/Makefile
 693 doc/man/ru/Makefile
 694 doc/man/sr/Makefile
 695
 696 doc/hlp/Makefile
 697 doc/hlp/es/Makefile
 698 doc/hlp/hu/Makefile
 699 doc/hlp/it/Makefile
 700 doc/hlp/pl/Makefile
 701 doc/hlp/ru/Makefile
 702 doc/hlp/sr/Makefile
 703
 704 po/Makefile.in
 705 ])
 706
 707 AC_CONFIG_FILES([
 708 tests/Makefile
 709 tests/lib/Makefile
 710 tests/lib/mcconfig/Makefile
 711 tests/lib/search/Makefile
 712 tests/lib/strutil/Makefile
 713 tests/lib/vfs/Makefile
 714 tests/lib/widget/Makefile
 715 tests/src/Makefile
 716 tests/src/filemanager/Makefile
 717 tests/src/editor/Makefile
 718 tests/src/editor/test-data.txt
 719 tests/src/vfs/Makefile
 720 tests/src/vfs/extfs/Makefile
 721 tests/src/vfs/extfs/helpers-list/Makefile
 722 tests/src/vfs/extfs/helpers-list/data/config.sh
 723 tests/src/vfs/extfs/helpers-list/misc/Makefile
 724 tests/src/vfs/ftpfs/Makefile
 725 ])
 726
 727 AC_OUTPUT
 728
 729 AC_MSG_NOTICE([
 730
 731 Configuration:
 732
 733   Source code location:           ${srcdir}
 734   Compiler:                       ${CC}
 735   Compiler flags:                 ${CFLAGS}
 736   Assertions:                     ${enable_assert}
 737   Unit tests:                     ${tests_msg}
 738   File system:                    ${vfs_type}
 739                                   ${vfs_flags}
 740   Screen library:                 ${screen_msg}
 741   Mouse support:                  ${mouse_lib}
 742   X11 events support:             ${textmode_x11_support}
 743   With subshell support:          ${subshell}
 744   With background operations:     ${enable_background}
 745   With ext2fs attributes support: ${ext2fs_attr_msg}
 746   Internal editor:                ${edit_msg}
 747   Diff viewer:                    ${diff_msg}
 748   Support for charset:            ${charset_msg}
 749   Search type:                    ${SEARCH_TYPE}
 750 ])
 751
 752 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 753 dnl we enable it back for top-level ./configure
 754 if test -n "$ac_unrecognized_opts"; then
 755   case $enable_option_checking in
 756     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 757     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 758   esac
 759 fi