configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$Id: configure.in,v 1.50 1995/12/14 07:18:09 roland Exp $])
   3 AC_PREREQ(2.1)dnl               dnl Minimum Autoconf version required.
   4 AC_INIT(vpath.c)dnl             dnl A distinctive file to look for in srcdir.
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_SUBDIRS(glob)         dnl Run configure in glob subdirectory.
   7
   8 AC_PROG_MAKE_SET
   9 AC_PROG_CC
  10 AC_PROG_INSTALL
  11 AC_PROG_CPP                     dnl Later checks need this.
  12 AC_AIX
  13 AC_ISC_POSIX
  14 AC_MINIX
  15 AC_HEADER_STDC
  16 AC_HEADER_DIRENT
  17 AC_TYPE_UID_T                   dnl Also does gid_t.
  18 AC_TYPE_PID_T
  19 AC_TYPE_SIGNAL
  20 AC_CHECK_HEADERS(unistd.h limits.h sys/param.h fcntl.h string.h memory.h \
  21                  sys/timeb.h)
  22 AC_PROG_CC_C_O
  23 AC_C_CONST                      dnl getopt needs this.
  24 AC_HEADER_STAT
  25
  26 AC_SUBST(LIBOBJS)
  27
  28 AC_DEFUN(AC_CHECK_SYMBOL, [dnl
  29 AC_MSG_CHECKING(for $1)
  30 AC_CACHE_VAL(ac_cv_check_symbol_$1, [dnl
  31 AC_TRY_LINK(, [extern char *sys_siglist[]; puts(*sys_siglist);],
  32             ac_cv_check_symbol_$1=yes, ac_cv_check_symbol_$1=no)])
  33 if test "$ac_cv_check_symbol_$1" = yes; then
  34 changequote(,)dnl
  35   ac_tr_symbol=`echo $1 | tr '[a-z]' '[A-Z]'`
  36 changequote([,])dnl
  37   AC_DEFINE_UNQUOTED(HAVE_${ac_tr_symbol})
  38 fi
  39 AC_MSG_RESULT($ac_cv_check_symbol_$1)])dnl
  40
  41 AC_CHECK_FUNCS(psignal mktemp \
  42                dup2 getcwd sigsetmask getgroups setlinebuf \
  43                seteuid setegid setreuid setregid strerror strsignal)
  44 AC_CHECK_SYMBOL(sys_siglist)
  45 AC_CHECK_SYMBOL(_sys_siglist)
  46 AC_FUNC_ALLOCA
  47 AC_FUNC_VFORK
  48 AC_FUNC_SETVBUF_REVERSED
  49 AC_FUNC_GETLOADAVG
  50 AC_FUNC_STRCOLL
  51
  52 # Check out the wait reality.
  53 AC_CHECK_HEADERS(sys/wait.h) AC_CHECK_FUNCS(waitpid wait3)
  54 AC_MSG_CHECKING(for union wait)
  55 AC_CACHE_VAL(make_cv_union_wait, [dnl
  56 AC_TRY_LINK([#include <sys/types.h>
  57 #include <sys/wait.h>],
  58             [union wait status; int pid; pid = wait (&status);
  59 #ifdef WEXITSTATUS
  60 /* Some POSIXoid systems have both the new-style macros and the old
  61    union wait type, and they do not work together.  If union wait
  62    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  63 if (WEXITSTATUS (status) != 0) pid = -1;
  64 #ifdef WTERMSIG
  65 /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
  66 -- blow chunks here --
  67 #endif
  68 #endif
  69 #ifdef HAVE_WAITPID
  70 /* Make sure union wait works with waitpid.  */
  71 pid = waitpid (-1, &status, 0);
  72 #endif
  73 ],
  74             [make_cv_union_wait=yes], [make_cv_union_wait=no])])
  75 if test "$make_cv_union_wait" = yes; then
  76   AC_DEFINE(HAVE_UNION_WAIT)
  77 fi
  78 AC_MSG_RESULT($make_cv_union_wait)
  79
  80 AC_DECL_SYS_SIGLIST
  81
  82 # The presence of the following is not meant to imply
  83 # that make necessarily works on those systems.
  84 AC_CHECK_LIB(sun, getpwnam)
  85
  86 AC_SUBST(REMOTE) REMOTE=stub
  87 AC_ARG_WITH(customs, [export jobs with the Customs daemon (NOT SUPPORTED)],
  88 [REMOTE=cstms LIBS="$LIBS libcustoms.a"])
  89
  90 echo checking for location of SCCS get command
  91 if test -f /usr/sccs/get; then
  92   SCCS_GET=/usr/sccs/get
  93   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  94 else
  95   SCCS_GET=get
  96   AC_DEFINE(SCCS_GET, "get")
  97 fi
  98 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
  99 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 100    test -f s.conftest; then
 101   # We successfully created an SCCS file.
 102   echo checking if SCCS get command understands -G
 103   if $SCCS_GET -Gconftoast s.conftest >/dev/null 2>&1 &&
 104      test -f conftoast; then
 105     AC_DEFINE(SCCS_GET_MINUS_G)
 106   fi
 107 fi
 108 rm -f s.conftest conftoast
 109
 110 AC_OUTPUT(Makefile build.sh, [
 111 # Makefile uses this timestamp file to know when to remake Makefile,
 112 # build.sh, and glob/Makefile.
 113 touch stamp-config])
 114
 115 dnl Local Variables:
 116 dnl comment-start: "dnl "
 117 dnl comment-end: ""
 118 dnl comment-start-skip: "\\bdnl\\b\\s *"
 119 dnl compile-command: "make configure config.h.in"
 120 dnl End: