configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$Id: configure.in,v 1.43 1995/01/15 13:23:03 roland Alpha $])
   3 AC_PREREQ(2.1)dnl               dnl Minimum Autoconf version required.
   4 AC_INIT(vpath.c)dnl             dnl A distinctive file to look for in srcdir.
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_SUBDIRS(glob)         dnl Run configure in glob subdirectory.
   7
   8 # We want these before the checks, so the checks can modify their values.
   9 test -z "$CFLAGS" && CFLAGS=-g AC_SUBST(CFLAGS)
  10 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
  11
  12 AC_PROG_MAKE_SET
  13 AC_PROG_CC
  14 AC_PROG_INSTALL
  15 AC_PROG_CPP                     dnl Later checks need this.
  16 AC_AIX
  17 AC_ISC_POSIX
  18 AC_MINIX
  19 AC_HEADER_STDC
  20 AC_HEADER_DIRENT
  21 AC_TYPE_UID_T                   dnl Also does gid_t.
  22 AC_TYPE_GETGROUPS
  23 AC_TYPE_PID_T
  24 AC_TYPE_SIGNAL
  25 AC_CHECK_HEADERS(unistd.h limits.h sys/param.h fcntl.h string.h memory.h \
  26                  sys/timeb.h)
  27 AC_PROG_CC_C_O
  28 AC_C_CONST                      dnl getopt needs this.
  29 AC_HEADER_STAT
  30
  31 AC_SUBST(LIBOBJS)
  32
  33 AC_DEFUN(AC_CHECK_SYMBOL, [dnl
  34 AC_MSG_CHECKING(for $1)
  35 AC_CACHE_VAL(ac_cv_check_symbol_$1, [dnl
  36 AC_TRY_LINK(, [extern char *sys_siglist[]; puts(*sys_siglist);],
  37             ac_cv_check_symbol_$1=yes, ac_cv_check_symbol_$1=no)])
  38 if test "$ac_cv_check_symbol_$1" = yes; then
  39 changequote(,)dnl
  40   ac_tr_symbol=`echo $1 | tr '[a-z]' '[A-Z]'`
  41 changequote([,])dnl
  42   AC_DEFINE_UNQUOTED(HAVE_${ac_tr_symbol})
  43 fi
  44 AC_MSG_RESULT($ac_cv_check_symbol_$1)])dnl
  45
  46 AC_CHECK_FUNCS(getdtablesize psignal \
  47                dup2 getcwd sigsetmask getgroups setlinebuf \
  48                seteuid setegid setreuid setregid strerror)
  49 AC_CHECK_SYMBOL(sys_siglist)
  50 AC_CHECK_SYMBOL(_sys_siglist)
  51 AC_FUNC_ALLOCA
  52 AC_FUNC_VFORK
  53 AC_FUNC_SETVBUF_REVERSED
  54 AC_FUNC_GETLOADAVG
  55 AC_FUNC_STRCOLL
  56
  57 # Check out the wait reality.
  58 AC_CHECK_HEADERS(sys/wait.h) AC_CHECK_FUNCS(waitpid wait3)
  59 AC_MSG_CHECKING(for union wait)
  60 AC_CACHE_VAL(make_cv_union_wait, [dnl
  61 AC_TRY_LINK([#include <sys/types.h>
  62 #include <sys/wait.h>],
  63             [union wait status; int pid; pid = wait (&status);
  64 #ifdef WEXITSTATUS
  65 /* Some POSIXoid systems have both the new-style macros and the old
  66    union wait type, and they do not work together.  If union wait
  67    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  68 if (WEXITSTATUS (status) != 0) pid = -1;
  69 #ifdef WTERMSIG
  70 /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
  71 -- blow chunks here --
  72 #endif
  73 #endif
  74 #ifdef HAVE_WAITPID
  75 /* Make sure union wait works with waitpid.  */
  76 pid = waitpid (-1, &status, 0);
  77 #endif
  78 ],
  79             [make_cv_union_wait=yes], [make_cv_union_wait=no])])
  80 if test "$make_cv_union_wait" = yes; then
  81   AC_DEFINE(HAVE_UNION_WAIT)
  82 fi
  83 AC_MSG_RESULT($make_cv_union_wait)
  84
  85 AC_DECL_SYS_SIGLIST
  86
  87 # The presence of the following is not meant to imply
  88 # that make necessarily works on those systems.
  89 AC_CHECK_LIB(sun, getpwnam)
  90
  91 AC_SUBST(REMOTE) REMOTE=stub
  92 AC_ARG_WITH(customs, [export jobs with the Customs daemon (NOT SUPPORTED)],
  93 [REMOTE=cstms LIBS="$LIBS libcustoms.a"])
  94
  95 echo checking for location of SCCS get command
  96 if test -f /usr/sccs/get; then
  97   SCCS_GET=/usr/sccs/get
  98   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  99 else
 100   SCCS_GET=get
 101   AC_DEFINE(SCCS_GET, "get")
 102 fi
 103 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 104 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 105    test -f s.conftest; then
 106   # We successfully created an SCCS file.
 107   echo checking if SCCS get command understands -G
 108   if $SCCS_GET -Gconftoast s.conftest >/dev/null 2>&1 &&
 109      test -f conftoast; then
 110     AC_DEFINE(SCCS_GET_MINUS_G)
 111   fi
 112 fi
 113 rm -f s.conftest conftoast
 114
 115 AC_OUTPUT(Makefile build.sh, [
 116 # Makefile uses this timestamp file to know when to remake Makefile,
 117 # build.sh, and glob/Makefile.
 118 touch stamp-config])
 119
 120 dnl Local Variables:
 121 dnl comment-start: "dnl "
 122 dnl comment-end: ""
 123 dnl comment-start-skip: "\\bdnl\\b\\s *"
 124 dnl compile-command: "make configure config.h.in"
 125 dnl End: