configure.in

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([GNU make],[3.81rc1],[bug-make@gnu.org])
   4
   5 AC_PREREQ(2.58)
   6 AC_REVISION([[$Id: configure.in,v 1.121 2004/01/21 06:33:00 psmith Exp $]])
   7
   8 # Autoconf setup
   9 AC_CONFIG_AUX_DIR(config)
  10 AC_CONFIG_SRCDIR(vpath.c)
  11 AC_CONFIG_HEADERS(config.h)
  12
  13 # Automake setup
  14 AM_INIT_AUTOMAKE([1.7.6])
  15
  16 # Checks for programs.
  17 AC_PROG_CC
  18 AC_PROG_INSTALL
  19 AC_PROG_RANLIB
  20 AC_PROG_CPP
  21 AC_CHECK_PROG(AR, ar, ar, ar)
  22 # Perl is needed for the test suite (only)
  23 AC_CHECK_PROG(PERL, perl, perl, perl)
  24
  25 # Specialized system macros
  26 AC_CANONICAL_HOST
  27 AC_AIX
  28 AC_ISC_POSIX
  29 AC_MINIX
  30
  31 # Needed for ansi2knr
  32 AM_C_PROTOTYPES
  33
  34 # Enable gettext, in "external" mode.
  35
  36 AM_GNU_GETTEXT_VERSION(0.12.1)
  37 AM_GNU_GETTEXT([external])
  38
  39 # This test must come as early as possible after the compiler configuration
  40 # tests, because the choice of the file model can (in principle) affect
  41 # whether functions and headers are available, whether they work, etc.
  42 AC_SYS_LARGEFILE
  43
  44 # Checks for libraries.
  45 AC_SEARCH_LIBS(getpwnam, [sun])
  46
  47 # Checks for header files.
  48 AC_HEADER_STDC
  49 AC_HEADER_DIRENT
  50 AC_HEADER_STAT
  51 AC_HEADER_TIME
  52 AC_CHECK_HEADERS(stdlib.h locale.h unistd.h limits.h fcntl.h string.h \
  53                  memory.h sys/param.h sys/time.h sys/timeb.h)
  54
  55 AM_PROG_CC_C_O
  56 AM_PROG_CC_STDC
  57 AC_C_CONST
  58 AC_TYPE_SIGNAL
  59 AC_TYPE_UID_T
  60 AC_TYPE_PID_T
  61
  62 # Find some definition for uintmax_t
  63
  64 AC_CHECK_TYPE(uintmax_t,,[
  65   uintmax_t="unsigned long"
  66   AC_CHECK_TYPE(unsigned long long,[uintmax_t="unsigned long long"])
  67   AC_DEFINE_UNQUOTED(uintmax_t,$uintmax_t,
  68     [Define uintmax_t if not defined in <stdint.h> or <inttypes.h>.])])
  69
  70 # Find out whether our struct stat returns nanosecond resolution timestamps.
  71
  72 AC_STRUCT_ST_MTIM_NSEC
  73 AC_MSG_CHECKING([whether to use high resolution file timestamps])
  74 AC_CACHE_VAL(make_cv_file_timestamp_hi_res, [
  75   make_cv_file_timestamp_hi_res=no
  76   if test "$ac_cv_struct_st_mtim_nsec" != no; then
  77     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  78 #       if HAVE_INTTYPES_H
  79 #        include <inttypes.h>
  80 #       endif]],
  81                       [[char a[0x7fffffff < (uintmax_t)-1 >> 30 ? 1 : -1];]])],
  82       [make_cv_file_timestamp_hi_res=yes],
  83       [])
  84   fi])
  85 AC_MSG_RESULT($make_cv_file_timestamp_hi_res)
  86 if test "$make_cv_file_timestamp_hi_res" = yes; then
  87   val=1
  88 else
  89   val=0
  90 fi
  91 AC_DEFINE_UNQUOTED(FILE_TIMESTAMP_HI_RES, $val,
  92                    [Use high resolution file timestamps if nonzero.])
  93
  94 if test "$make_cv_file_timestamp_hi_res" = yes; then
  95   # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
  96   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
  97   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
  98   if test "$ac_cv_search_clock_gettime" != no; then
  99     AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 100               [Define if you have the clock_gettime function.])
 101   fi
 102 fi
 103
 104 # Check for DOS-style pathnames.
 105 pds_AC_DOS_PATHS
 106
 107 # See if we have a standard version of gettimeofday().  Since actual
 108 # implementations can differ, just make sure we have the most common
 109 # one.
 110 AC_CACHE_CHECK([for standard gettimeofday], ac_cv_func_gettimeofday,
 111   [ac_cv_func_gettimeofday=no
 112    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/time.h>
 113                   int main ()
 114                   {
 115                     struct timeval t; t.tv_sec = -1; t.tv_usec = -1;
 116                     exit (gettimeofday (&t, 0) != 0
 117                           || t.tv_sec < 0 || t.tv_usec < 0);
 118                   }]])],
 119                   [ac_cv_func_gettimeofday=yes],
 120                   [ac_cv_func_gettimeofday=no],
 121                   [ac_cv_func_gettimeofday="no (cross-compiling)"])])
 122 if test "$ac_cv_func_gettimeofday" = yes; then
 123   AC_DEFINE(HAVE_GETTIMEOFDAY, 1,
 124             [Define if you have a standard gettimeofday function])
 125 fi
 126
 127 AC_CHECK_FUNCS( memcpy memmove strchr strdup mkstemp mktemp fdopen \
 128                 bsd_signal dup2 getcwd sigsetmask sigaction getgroups \
 129                 seteuid setegid setlinebuf setreuid setregid setvbuf pipe \
 130                 strerror strsignal)
 131
 132 AC_FUNC_SETVBUF_REVERSED
 133
 134 # strcoll() is used by the GNU glob library
 135 AC_FUNC_STRCOLL
 136
 137 AC_FUNC_ALLOCA
 138 AC_FUNC_FORK([])
 139 AC_FUNC_VPRINTF
 140 AC_FUNC_CLOSEDIR_VOID
 141
 142 AC_FUNC_GETLOADAVG
 143
 144 # AC_FUNC_GETLOADAVG is documented to set the NLIST_STRUCT value, but it
 145 # doesn't.  So, we will.
 146
 147 if test "$ac_cv_header_nlist_h" = yes; then
 148   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
 149         [[struct nlist nl;
 150           nl.n_name = "string";
 151           return 0;]])],
 152         [make_cv_nlist_struct=yes],
 153         [make_cv_nlist_struct=no])
 154   if test "$make_cv_nlist_struct" = yes; then
 155     AC_DEFINE(NLIST_STRUCT, 1,
 156        [Define if struct nlist.n_name is a pointer rather than an array.])
 157   fi
 158 fi
 159
 160 AC_CHECK_DECLS([sys_siglist])
 161
 162
 163 # Check out the wait reality.
 164 AC_CHECK_HEADERS(sys/wait.h)
 165 AC_CHECK_FUNCS(waitpid wait3)
 166 AC_MSG_CHECKING(for union wait)
 167 AC_CACHE_VAL(make_cv_union_wait, [dnl
 168     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 169 #include <sys/wait.h>]],
 170      [[union wait status; int pid; pid = wait (&status);
 171 #ifdef WEXITSTATUS
 172 /* Some POSIXoid systems have both the new-style macros and the old
 173    union wait type, and they do not work together.  If union wait
 174    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 175         if (WEXITSTATUS (status) != 0) pid = -1;
 176 #ifdef WTERMSIG
 177         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 178         -- blow chunks here --
 179 #endif
 180 #endif
 181 #ifdef HAVE_WAITPID
 182         /* Make sure union wait works with waitpid.  */
 183         pid = waitpid (-1, &status, 0);
 184 #endif
 185       ]])],
 186     [make_cv_union_wait=yes],
 187     [make_cv_union_wait=no])])
 188 if test "$make_cv_union_wait" = yes; then
 189   AC_DEFINE(HAVE_UNION_WAIT, 1,
 190             [Define this if you have the \`union wait' type in <sys/wait.h>.])
 191 fi
 192 AC_MSG_RESULT($make_cv_union_wait)
 193
 194
 195 # If we're building on Windows/DOS/OS/2, add some support for DOS drive specs.
 196 if test "$PATH_SEPARATOR" = ';'; then
 197   AC_DEFINE(HAVE_DOS_PATHS, 1,
 198             [Define this if your system requires backslashes or drive specs in pathnames.])
 199 fi
 200
 201
 202 # See if the user wants to use pmake's "customs" distributed build capability
 203
 204 AC_SUBST(REMOTE) REMOTE=stub
 205 use_customs=false
 206 AC_ARG_WITH(customs,
 207   AC_HELP_STRING([--with-customs=DIR],
 208                  [enable remote jobs via Customs--see README.customs]),
 209   [case $withval in
 210     n|no) : ;;
 211     *) make_cppflags="$CPPFLAGS"
 212        case $withval in
 213          y|ye|yes) : ;;
 214          *) CPPFLAGS="$CPPFLAGS -I$with_customs/include/customs"
 215             make_ldflags="$LDFLAGS -L$with_customs/lib" ;;
 216        esac
 217        CF_NETLIBS
 218        AC_CHECK_HEADER(customs.h,
 219                        [use_customs=true
 220                          REMOTE=cstms
 221                          LIBS="$LIBS -lcustoms" LDFLAGS="$make_ldflags"],
 222                        [with_customs=no
 223                          CPPFLAGS="$make_cppflags" make_badcust=yes])
 224        ;;
 225   esac])
 226 # Tell automake about this, so it can include the right .c files.
 227 AM_CONDITIONAL(USE_CUSTOMS, test "$use_customs" = true)
 228
 229 # See if we can handle the job server feature, and if the user wants it.
 230
 231 AC_ARG_ENABLE(job-server,
 232   AC_HELP_STRING([--disable-job-server],
 233                  [disallow recursive make communication during -jN]),
 234   [make_cv_job_server="$enableval" user_job_server="$enableval"],
 235   [make_cv_job_server="yes"])
 236
 237 has_wait_nohang=yes
 238 case "$ac_cv_func_waitpid/$ac_cv_func_wait3" in
 239   no/no) has_wait_nohang=no ;;
 240 esac
 241
 242 AC_CACHE_CHECK(for SA_RESTART, make_cv_sa_restart, [
 243   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]],
 244       [[return SA_RESTART;]])],
 245     [make_cv_sa_restart=yes],
 246     [make_cv_sa_restart=no])])
 247 if test "$make_cv_sa_restart" != no; then
 248   AC_DEFINE(HAVE_SA_RESTART, 1,
 249      [Define if <signal.h> defines the SA_RESTART constant.])
 250 fi
 251
 252 case "$ac_cv_func_pipe/$ac_cv_func_sigaction/$make_cv_sa_restart/$has_wait_nohang/$make_cv_job_server" in
 253   yes/yes/yes/yes/yes)
 254     AC_DEFINE(MAKE_JOBSERVER, 1,
 255               [Define this to enable job server support in GNU make.]);;
 256 esac
 257
 258 # Find the SCCS commands, so we can include them in our default rules.
 259
 260 AC_CACHE_CHECK(for location of SCCS get command, make_cv_path_sccs_get, [
 261 if test -f /usr/sccs/get; then
 262   make_cv_path_sccs_get=/usr/sccs/get
 263 else
 264   make_cv_path_sccs_get=get
 265 fi])
 266 AC_DEFINE_UNQUOTED(SCCS_GET, ["$make_cv_path_sccs_get"],
 267                    [Define to the name of the SCCS 'get' command.])
 268
 269 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 270 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 271    test -f s.conftest; then
 272   # We successfully created an SCCS file.
 273   AC_CACHE_CHECK(if SCCS get command understands -G, make_cv_sys_get_minus_G, [
 274     if $make_cv_path_sccs_get -Gconftoast s.conftest >/dev/null 2>&1 &&
 275        test -f conftoast; then
 276        make_cv_sys_get_minus_G=yes
 277     else
 278        make_cv_sys_get_minus_G=no
 279     fi])
 280   case "$make_cv_sys_get_minus_G" in
 281     yes) AC_DEFINE(SCCS_GET_MINUS_G, 1,
 282            [Define this if the SCCS 'get' command understands the '-G<file>' option.]);;
 283   esac
 284 fi
 285 rm -f s.conftest conftoast
 286
 287 # Check the system to see if it provides GNU glob.  If not, use our
 288 # local version.
 289
 290 AC_MSG_CHECKING(if system libc has GNU glob)
 291 AC_CACHE_VAL(make_cv_sys_gnu_glob, [
 292  AC_EGREP_CPP(gnu glob,[
 293 #include <features.h>
 294 #include <glob.h>
 295 #include <fnmatch.h>
 296
 297 #define GLOB_INTERFACE_VERSION 1
 298 #if !defined _LIBC && defined __GNU_LIBRARY__ && __GNU_LIBRARY__ > 1
 299 # include <gnu-versions.h>
 300 # if _GNU_GLOB_INTERFACE_VERSION == GLOB_INTERFACE_VERSION
 301    gnu glob
 302 # endif
 303 #endif
 304  ], [AC_MSG_RESULT(yes)
 305 make_cv_sys_gnu_glob=yes], [AC_MSG_RESULT([no; using local copy])
 306 AC_SUBST(GLOBINC) GLOBINC='-I$(srcdir)/glob'
 307 AC_SUBST(GLOBLIB) GLOBLIB=glob/libglob.a
 308 make_cv_sys_gnu_glob=no])])
 309 # Tell automake about this, so it can build the right .c files.
 310 AM_CONDITIONAL(USE_LOCAL_GLOB, test "$make_cv_sys_gnu_glob" = no)
 311
 312 # Let the makefile know what our build host is
 313
 314 AC_DEFINE_UNQUOTED(MAKE_HOST,"$host",[Build host information.])
 315 MAKE_HOST="$host"
 316 AC_SUBST(MAKE_HOST)
 317
 318 # Include the Maintainer's Makefile section, if it's here.
 319
 320 MAINT_MAKEFILE=/dev/null
 321 if test -r "$srcdir/maintMakefile"; then
 322   MAINT_MAKEFILE="$srcdir/maintMakefile"
 323 fi
 324 AC_SUBST_FILE(MAINT_MAKEFILE)
 325
 326 # Allow building with dmalloc
 327 AM_WITH_DMALLOC
 328
 329
 330 # Sanity check and inform the user of what we found
 331
 332 case "$make_badcust" in
 333   yes) echo
 334        echo "WARNING: --with-customs specified but no customs.h could be found;"
 335        echo "         disabling Customs support."
 336        echo ;;
 337 esac
 338
 339 case "$with_customs" in
 340   ""|n|no|y|ye|yes) ;;
 341   *) if test -f "$with_customs/lib/libcustoms.a"; then
 342        :
 343      else
 344        echo
 345        echo "WARNING: '$with_customs/lib' does not appear to contain the"
 346        echo "         Customs library.  You must build and install Customs"
 347        echo "         before compiling GNU make."
 348        echo
 349      fi ;;
 350 esac
 351
 352 case "$has_wait_nohang" in
 353   no) echo
 354       echo "WARNING: Your system has neither waitpid() nor wait3()."
 355       echo "         Without one of these, signal handling is unreliable."
 356       echo "         You should be aware that running GNU make with -j"
 357       echo "         could result in erratic behavior."
 358       echo ;;
 359 esac
 360
 361 case "$make_cv_job_server/$user_job_server" in
 362   no/yes) echo
 363           echo "WARNING: Make job server requires a POSIX-ish system that"
 364           echo "         supports the pipe(), sigaction(), and either"
 365           echo "         waitpid() or wait3() functions.  Your system doesn't"
 366           echo "         appear to provide one or more of those."
 367           echo "         Disabling job server support."
 368           echo ;;
 369 esac
 370
 371
 372 # Specify what files are to be created.
 373 # We only generate the build.sh if we have a build.sh.in; we won't have
 374 # one before we've created a distribution.
 375
 376 AC_CONFIG_FILES(Makefile glob/Makefile po/Makefile.in config/Makefile doc/Makefile)
 377
 378 if test -f $srcdir/build.sh.in; then
 379   AC_CONFIG_FILES(build.sh)
 380 fi
 381
 382
 383 # OK, do it!
 384
 385 AC_OUTPUT
 386
 387
 388 dnl Local Variables:
 389 dnl comment-start: "dnl "
 390 dnl comment-end: ""
 391 dnl comment-start-skip: "\\bdnl\\b\\s *"
 392 dnl compile-command: "make configure config.h.in"
 393 dnl End: