configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(vpath.c)                dnl A distinctive file to look for in srcdir.
   3 AC_CONFIG_HEADER(config.h)
   4
   5 # We want these before the checks, so the checks can modify their values.
   6 test -z "$CFLAGS" && CFLAGS=-g AC_SUBST(CFLAGS)
   7 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
   8
   9 AC_PROG_CC
  10 AC_PROG_INSTALL
  11 AC_PROG_RANLIB
  12 AC_PROG_CPP                     dnl Later checks need this.
  13 AC_AIX
  14 AC_ISC_POSIX
  15 AC_MINIX
  16 AC_STDC_HEADERS
  17 AC_UNISTD_H
  18 AC_DIR_HEADER
  19 AC_UID_T                        dnl Also does gid_t.
  20 AC_GETGROUPS_T
  21 AC_PID_T
  22 AC_RETSIGTYPE
  23 AC_HAVE_HEADERS(limits.h sys/param.h fcntl.h string.h memory.h)
  24 AC_MINUS_C_MINUS_O
  25 AC_CONST                        dnl getopt needs this.
  26 AC_USG
  27 AC_STAT_MACROS_BROKEN
  28
  29 AC_SUBST(LIBOBJS)
  30
  31 AC_HAVE_FUNCS(getdtablesize sys_siglist _sys_siglist psignal \
  32               dup2 getcwd sigsetmask getgroups setlinebuf \
  33               setreuid setregid)
  34 AC_ALLOCA
  35 AC_VFORK
  36 AC_SETVBUF_REVERSED
  37 AC_GETLOADAVG
  38 AC_STRCOLL
  39
  40 dnl Check out the wait reality.
  41 AC_HAVE_HEADERS(sys/wait.h) AC_HAVE_FUNCS(waitpid wait3)
  42 AC_COMPILE_CHECK(union wait, [#include <sys/types.h>
  43 #include <sys/wait.h>],
  44                  [union wait status; int pid; pid = wait (&status);
  45 #ifdef WEXITSTATUS
  46 /* Some POSIXoid systems have both the new-style macros and the old
  47    union wait type, and they do not work together.  If union wait
  48    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  49 if (WEXITSTATUS (status) != 0) pid = -1;
  50 #endif
  51 #ifdef HAVE_WAITPID
  52 /* Make sure union wait works with waitpid.  */
  53 pid = waitpid (-1, &status, 0);
  54 #endif
  55 ],
  56                  AC_DEFINE(HAVE_UNION_WAIT))
  57
  58 AC_COMPILE_CHECK(sys_siglist declaration in signal.h or unistd.h,
  59                  [#include <signal.h>
  60 /* NetBSD declares sys_siglist in <unistd.h>.  */
  61 #ifdef HAVE_UNISTD_H
  62 #include <unistd.h>
  63 #endif], [char *msg = *(sys_siglist + 1);],
  64                  AC_DEFINE(SYS_SIGLIST_DECLARED))
  65
  66 # The presence of the following is not meant to imply
  67 # that make necessarily works on those systems.
  68 AC_DYNIX_SEQ
  69 AC_XENIX_DIR
  70 AC_IRIX_SUN
  71
  72 AC_SUBST(REMOTE) REMOTE=stub
  73 AC_WITH(customs, [REMOTE=cstms
  74 LIBS="$LIBS libcustoms.a"])
  75
  76 echo checking for location of SCCS get command
  77 if test -f /usr/sccs/get; then
  78   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  79 else
  80   AC_DEFINE(SCCS_GET, "get")
  81 fi
  82
  83 AC_OUTPUT(Makefile build.sh glob/Makefile)
  84
  85 dnl Local Variables:
  86 dnl comment-start: "dnl "
  87 dnl comment-end: ""
  88 dnl comment-start-skip: "\\bdnl\\b\\s *"
  89 dnl compile-command: "make configure config.h.in"
  90 dnl End: