configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 # 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5 # This file is part of GNU Make.
   6 #
   7 # GNU Make is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2, or (at your option) any later version.
  10 #
  11 # GNU Make is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # GNU Make; see the file COPYING.  If not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 AC_INIT([GNU make],[3.81.90],[bug-make@gnu.org])
  20
  21 AC_PREREQ(2.59)
  22 AC_REVISION([[$Id: configure.in,v 1.146 2007/03/21 13:49:34 psmith Exp $]])
  23
  24 # Autoconf setup
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_CONFIG_SRCDIR(vpath.c)
  27 AC_CONFIG_HEADERS(config.h)
  28
  29 # Automake setup
  30 AM_INIT_AUTOMAKE([1.9])
  31
  32 # Checks for programs.
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 AC_PROG_RANLIB
  36 AC_PROG_CPP
  37 AC_CHECK_PROG(AR, ar, ar, ar)
  38 # Perl is needed for the test suite (only)
  39 AC_CHECK_PROG(PERL, perl, perl, perl)
  40
  41 # Specialized system macros
  42 AC_CANONICAL_HOST
  43 AC_AIX
  44 AC_ISC_POSIX
  45 AC_MINIX
  46
  47 # Enable gettext, in "external" mode.
  48
  49 AM_GNU_GETTEXT_VERSION(0.14.1)
  50 AM_GNU_GETTEXT([external])
  51
  52 # This test must come as early as possible after the compiler configuration
  53 # tests, because the choice of the file model can (in principle) affect
  54 # whether functions and headers are available, whether they work, etc.
  55 AC_SYS_LARGEFILE
  56
  57 # Checks for libraries.
  58 AC_SEARCH_LIBS(getpwnam, [sun])
  59
  60 # Checks for header files.
  61 AC_HEADER_STDC
  62 AC_HEADER_DIRENT
  63 AC_HEADER_STAT
  64 AC_HEADER_TIME
  65 AC_CHECK_HEADERS(stdlib.h locale.h unistd.h limits.h fcntl.h string.h \
  66                  memory.h sys/param.h sys/resource.h sys/time.h sys/timeb.h)
  67
  68 # Set a flag if we have an ANSI C compiler
  69 if test "$ac_cv_prog_cc_stdc" != no; then
  70   AC_DEFINE(HAVE_ANSI_COMPILER, 1,
  71               [Define if your compiler conforms to the ANSI C standard.])
  72 fi
  73
  74
  75 # Determine what kind of variadic function calls we support
  76 AC_CHECK_HEADERS(stdarg.h varargs.h, break)
  77
  78 AM_PROG_CC_C_O
  79 AC_C_CONST
  80 AC_TYPE_SIGNAL
  81 AC_TYPE_UID_T
  82 AC_TYPE_PID_T
  83
  84 # Find some definition for uintmax_t
  85
  86 AC_CHECK_TYPE(uintmax_t,,[
  87   uintmax_t="unsigned long"
  88   AC_CHECK_TYPE(unsigned long long,[uintmax_t="unsigned long long"])
  89   AC_DEFINE_UNQUOTED(uintmax_t,$uintmax_t,
  90     [Define uintmax_t if not defined in <stdint.h> or <inttypes.h>.])])
  91
  92 # Find out whether our struct stat returns nanosecond resolution timestamps.
  93
  94 AC_STRUCT_ST_MTIM_NSEC
  95 AC_MSG_CHECKING([whether to use high resolution file timestamps])
  96 AC_CACHE_VAL(make_cv_file_timestamp_hi_res, [
  97   make_cv_file_timestamp_hi_res=no
  98   if test "$ac_cv_struct_st_mtim_nsec" != no; then
  99     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 100 #       if HAVE_INTTYPES_H
 101 #        include <inttypes.h>
 102 #       endif]],
 103                       [[char a[0x7fffffff < (uintmax_t)-1 >> 30 ? 1 : -1];]])],
 104       [make_cv_file_timestamp_hi_res=yes],
 105       [])
 106   fi])
 107 AC_MSG_RESULT($make_cv_file_timestamp_hi_res)
 108 if test "$make_cv_file_timestamp_hi_res" = yes; then
 109   val=1
 110 else
 111   val=0
 112 fi
 113 AC_DEFINE_UNQUOTED(FILE_TIMESTAMP_HI_RES, $val,
 114                    [Use high resolution file timestamps if nonzero.])
 115
 116 if test "$make_cv_file_timestamp_hi_res" = yes; then
 117   # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 118   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 119   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 120   if test "$ac_cv_search_clock_gettime" != no; then
 121     AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 122               [Define if you have the clock_gettime function.])
 123   fi
 124 fi
 125
 126 # Check for DOS-style pathnames.
 127 pds_AC_DOS_PATHS
 128
 129 # See if we have a standard version of gettimeofday().  Since actual
 130 # implementations can differ, just make sure we have the most common
 131 # one.
 132 AC_CACHE_CHECK([for standard gettimeofday], ac_cv_func_gettimeofday,
 133   [ac_cv_func_gettimeofday=no
 134    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/time.h>
 135                   int main ()
 136                   {
 137                     struct timeval t; t.tv_sec = -1; t.tv_usec = -1;
 138                     exit (gettimeofday (&t, 0) != 0
 139                           || t.tv_sec < 0 || t.tv_usec < 0);
 140                   }]])],
 141                   [ac_cv_func_gettimeofday=yes],
 142                   [ac_cv_func_gettimeofday=no],
 143                   [ac_cv_func_gettimeofday="no (cross-compiling)"])])
 144 if test "$ac_cv_func_gettimeofday" = yes; then
 145   AC_DEFINE(HAVE_GETTIMEOFDAY, 1,
 146             [Define if you have a standard gettimeofday function])
 147 fi
 148
 149 AC_CHECK_FUNCS( strdup mkstemp mktemp fdopen \
 150                 bsd_signal dup2 getcwd realpath sigsetmask sigaction \
 151                 getgroups seteuid setegid setlinebuf setreuid setregid \
 152                 getrlimit setrlimit setvbuf pipe strerror strsignal \
 153                 lstat readlink atexit)
 154
 155 AC_FUNC_SETVBUF_REVERSED
 156
 157 # strcoll() is used by the GNU glob library
 158 AC_FUNC_STRCOLL
 159
 160 AC_FUNC_ALLOCA
 161 AC_FUNC_FORK([])
 162 AC_FUNC_VPRINTF
 163 AC_FUNC_CLOSEDIR_VOID
 164
 165 AC_FUNC_GETLOADAVG
 166
 167 # AC_FUNC_GETLOADAVG is documented to set the NLIST_STRUCT value, but it
 168 # doesn't.  So, we will.
 169
 170 if test "$ac_cv_header_nlist_h" = yes; then
 171   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
 172         [[struct nlist nl;
 173           nl.n_name = "string";
 174           return 0;]])],
 175         [make_cv_nlist_struct=yes],
 176         [make_cv_nlist_struct=no])
 177   if test "$make_cv_nlist_struct" = yes; then
 178     AC_DEFINE(NLIST_STRUCT, 1,
 179        [Define if struct nlist.n_name is a pointer rather than an array.])
 180   fi
 181 fi
 182
 183 AC_CHECK_DECLS([sys_siglist, _sys_siglist, __sys_siglist], , ,
 184   [AC_INCLUDES_DEFAULT
 185 #include <signal.h>
 186 /* NetBSD declares sys_siglist in unistd.h.  */
 187 #if HAVE_UNISTD_H
 188 # include <unistd.h>
 189 #endif
 190 ])
 191
 192
 193 # Check out the wait reality.
 194 AC_CHECK_HEADERS(sys/wait.h,,,[[#include <sys/types.h>]])
 195 AC_CHECK_FUNCS(waitpid wait3)
 196 AC_MSG_CHECKING(for union wait)
 197 AC_CACHE_VAL(make_cv_union_wait, [dnl
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 199 #include <sys/wait.h>]],
 200      [[union wait status; int pid; pid = wait (&status);
 201 #ifdef WEXITSTATUS
 202 /* Some POSIXoid systems have both the new-style macros and the old
 203    union wait type, and they do not work together.  If union wait
 204    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 205         if (WEXITSTATUS (status) != 0) pid = -1;
 206 #ifdef WTERMSIG
 207         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 208         -- blow chunks here --
 209 #endif
 210 #endif
 211 #ifdef HAVE_WAITPID
 212         /* Make sure union wait works with waitpid.  */
 213         pid = waitpid (-1, &status, 0);
 214 #endif
 215       ]])],
 216     [make_cv_union_wait=yes],
 217     [make_cv_union_wait=no])])
 218 if test "$make_cv_union_wait" = yes; then
 219   AC_DEFINE(HAVE_UNION_WAIT, 1,
 220             [Define this if you have the \`union wait' type in <sys/wait.h>.])
 221 fi
 222 AC_MSG_RESULT($make_cv_union_wait)
 223
 224
 225 # If we're building on Windows/DOS/OS/2, add some support for DOS drive specs.
 226 if test "$PATH_SEPARATOR" = ';'; then
 227   AC_DEFINE(HAVE_DOS_PATHS, 1,
 228             [Define this if your system requires backslashes or drive specs in pathnames.])
 229 fi
 230
 231
 232 # See if the user wants to use pmake's "customs" distributed build capability
 233
 234 AC_SUBST(REMOTE) REMOTE=stub
 235 use_customs=false
 236 AC_ARG_WITH(customs,
 237   AC_HELP_STRING([--with-customs=DIR],
 238                  [enable remote jobs via Customs--see README.customs]),
 239   [case $withval in
 240     n|no) : ;;
 241     *) make_cppflags="$CPPFLAGS"
 242        case $withval in
 243          y|ye|yes) : ;;
 244          *) CPPFLAGS="$CPPFLAGS -I$with_customs/include/customs"
 245             make_ldflags="$LDFLAGS -L$with_customs/lib" ;;
 246        esac
 247        CF_NETLIBS
 248        AC_CHECK_HEADER(customs.h,
 249                        [use_customs=true
 250                          REMOTE=cstms
 251                          LIBS="$LIBS -lcustoms" LDFLAGS="$make_ldflags"],
 252                        [with_customs=no
 253                          CPPFLAGS="$make_cppflags" make_badcust=yes])
 254        ;;
 255   esac])
 256 # Tell automake about this, so it can include the right .c files.
 257 AM_CONDITIONAL(USE_CUSTOMS, test "$use_customs" = true)
 258
 259 # See if the user asked to handle case insensitive file systems.
 260
 261 AH_TEMPLATE(HAVE_CASE_INSENSITIVE_FS, [Use case insensitive file names])
 262 AC_ARG_ENABLE(case-insensitive-file-system,
 263   AC_HELP_STRING([--enable-case-insensitive-file-system],
 264                  [assume file systems are case insensitive]),
 265   [case $enableval in
 266      yes) AC_DEFINE(HAVE_CASE_INSENSITIVE_FS) ;;
 267    esac])
 268
 269 # See if we can handle the job server feature, and if the user wants it.
 270
 271 AC_ARG_ENABLE(job-server,
 272   AC_HELP_STRING([--disable-job-server],
 273                  [disallow recursive make communication during -jN]),
 274   [make_cv_job_server="$enableval" user_job_server="$enableval"],
 275   [make_cv_job_server="yes"])
 276
 277 has_wait_nohang=yes
 278 case "$ac_cv_func_waitpid/$ac_cv_func_wait3" in
 279   no/no) has_wait_nohang=no ;;
 280 esac
 281
 282 AC_CACHE_CHECK(for SA_RESTART, make_cv_sa_restart, [
 283   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]],
 284       [[return SA_RESTART;]])],
 285     [make_cv_sa_restart=yes],
 286     [make_cv_sa_restart=no])])
 287
 288 if test "$make_cv_sa_restart" != no; then
 289   AC_DEFINE(HAVE_SA_RESTART, 1,
 290      [Define if <signal.h> defines the SA_RESTART constant.])
 291 fi
 292
 293 # enable make_cv_sa_restart for OS/2 so that the jobserver will be enabled,
 294 # but do it after HAVE_SA_RESTART has been defined.
 295 case "$host_os" in
 296   os2*) make_cv_sa_restart=yes ;;
 297 esac
 298
 299 case "$ac_cv_func_pipe/$ac_cv_func_sigaction/$make_cv_sa_restart/$has_wait_nohang/$make_cv_job_server" in
 300   yes/yes/yes/yes/yes)
 301     AC_DEFINE(MAKE_JOBSERVER, 1,
 302               [Define this to enable job server support in GNU make.]);;
 303 esac
 304
 305 # if we have both lstat() and readlink() then we can support symlink
 306 # timechecks.
 307 case "$ac_cv_func_lstat/$ac_cv_func_readlink" in
 308   yes/yes)
 309     AC_DEFINE(MAKE_SYMLINKS, 1,
 310               [Define this to enable symbolic link timestamp checking.]);;
 311 esac
 312
 313 # Find the SCCS commands, so we can include them in our default rules.
 314
 315 AC_CACHE_CHECK(for location of SCCS get command, make_cv_path_sccs_get, [
 316 if test -f /usr/sccs/get; then
 317   make_cv_path_sccs_get=/usr/sccs/get
 318 else
 319   make_cv_path_sccs_get=get
 320 fi])
 321 AC_DEFINE_UNQUOTED(SCCS_GET, ["$make_cv_path_sccs_get"],
 322                    [Define to the name of the SCCS 'get' command.])
 323
 324 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 325 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 326    test -f s.conftest; then
 327   # We successfully created an SCCS file.
 328   AC_CACHE_CHECK(if SCCS get command understands -G, make_cv_sys_get_minus_G, [
 329     if $make_cv_path_sccs_get -Gconftoast s.conftest >/dev/null 2>&1 &&
 330        test -f conftoast; then
 331        make_cv_sys_get_minus_G=yes
 332     else
 333        make_cv_sys_get_minus_G=no
 334     fi])
 335   case "$make_cv_sys_get_minus_G" in
 336     yes) AC_DEFINE(SCCS_GET_MINUS_G, 1,
 337            [Define this if the SCCS 'get' command understands the '-G<file>' option.]);;
 338   esac
 339 fi
 340 rm -f s.conftest conftoast
 341
 342 # Check the system to see if it provides GNU glob.  If not, use our
 343 # local version.
 344
 345 AC_MSG_CHECKING(if system libc has GNU glob)
 346 AC_CACHE_VAL(make_cv_sys_gnu_glob, [
 347  AC_EGREP_CPP(gnu glob,[
 348 #include <features.h>
 349 #include <glob.h>
 350 #include <fnmatch.h>
 351
 352 #define GLOB_INTERFACE_VERSION 1
 353 #if !defined _LIBC && defined __GNU_LIBRARY__ && __GNU_LIBRARY__ > 1
 354 # include <gnu-versions.h>
 355 # if _GNU_GLOB_INTERFACE_VERSION == GLOB_INTERFACE_VERSION
 356    gnu glob
 357 # endif
 358 #endif
 359  ], [AC_MSG_RESULT(yes)
 360 make_cv_sys_gnu_glob=yes], [AC_MSG_RESULT([no; using local copy])
 361 AC_SUBST(GLOBINC) GLOBINC='-I$(srcdir)/glob'
 362 AC_SUBST(GLOBLIB) GLOBLIB=glob/libglob.a
 363 make_cv_sys_gnu_glob=no])])
 364 # Tell automake about this, so it can build the right .c files.
 365 AM_CONDITIONAL(USE_LOCAL_GLOB, test "$make_cv_sys_gnu_glob" = no)
 366
 367 # Let the makefile know what our build host is
 368
 369 AC_DEFINE_UNQUOTED(MAKE_HOST,"$host",[Build host information.])
 370 MAKE_HOST="$host"
 371 AC_SUBST(MAKE_HOST)
 372
 373 w32_target_env=no
 374 AM_CONDITIONAL([WINDOWSENV], false)
 375
 376 case "$host" in
 377   *-*-mingw32)
 378     AM_CONDITIONAL(WINDOWSENV, true)
 379     w32_target_env=yes
 380     AC_DEFINE([WINDOWS32], [1], [Use platform specific coding])
 381     AC_DEFINE([HAVE_DOS_PATHS], [1], [Use platform specific coding])
 382     ;;
 383 esac
 384
 385 AC_DEFINE_UNQUOTED(PATH_SEPARATOR_CHAR,'$PATH_SEPARATOR',[Define to the character that separates directories in PATH.])
 386
 387 # Include the Maintainer's Makefile section, if it's here.
 388
 389 MAINT_MAKEFILE=/dev/null
 390 if test -r "$srcdir/maintMakefile"; then
 391   MAINT_MAKEFILE="$srcdir/maintMakefile"
 392 fi
 393 AC_SUBST_FILE(MAINT_MAKEFILE)
 394
 395 # Allow building with dmalloc
 396 AM_WITH_DMALLOC
 397
 398 # Forcibly disable SET_MAKE.  If it's set it breaks things like the test
 399 # scripts, etc.
 400 SET_MAKE=
 401
 402 # Sanity check and inform the user of what we found
 403
 404 case "$make_badcust" in
 405   yes) echo
 406        echo "WARNING: --with-customs specified but no customs.h could be found;"
 407        echo "         disabling Customs support."
 408        echo ;;
 409 esac
 410
 411 case "$with_customs" in
 412   ""|n|no|y|ye|yes) ;;
 413   *) if test -f "$with_customs/lib/libcustoms.a"; then
 414        :
 415      else
 416        echo
 417        echo "WARNING: '$with_customs/lib' does not appear to contain the"
 418        echo "         Customs library.  You must build and install Customs"
 419        echo "         before compiling GNU make."
 420        echo
 421      fi ;;
 422 esac
 423
 424 case "$has_wait_nohang" in
 425   no) echo
 426       echo "WARNING: Your system has neither waitpid() nor wait3()."
 427       echo "         Without one of these, signal handling is unreliable."
 428       echo "         You should be aware that running GNU make with -j"
 429       echo "         could result in erratic behavior."
 430       echo ;;
 431 esac
 432
 433 case "$make_cv_job_server/$user_job_server" in
 434   no/yes) echo
 435           echo "WARNING: Make job server requires a POSIX-ish system that"
 436           echo "         supports the pipe(), sigaction(), and either"
 437           echo "         waitpid() or wait3() functions.  Your system doesn't"
 438           echo "         appear to provide one or more of those."
 439           echo "         Disabling job server support."
 440           echo ;;
 441 esac
 442
 443
 444 # Specify what files are to be created.
 445 AC_CONFIG_FILES(Makefile glob/Makefile po/Makefile.in config/Makefile doc/Makefile w32/Makefile)
 446
 447 # OK, do it!
 448
 449 AC_OUTPUT
 450
 451 # We only generate the build.sh if we have a build.sh.in; we won't have
 452 # one before we've created a distribution.
 453 if test -f "$srcdir/build.sh.in"; then
 454   ./config.status --file build.sh
 455   chmod +x build.sh
 456 fi
 457
 458 dnl Local Variables:
 459 dnl comment-start: "dnl "
 460 dnl comment-end: ""
 461 dnl comment-start-skip: "\\bdnl\\b\\s *"
 462 dnl compile-command: "make configure config.h.in"
 463 dnl End: