configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 # This file is part of GNU Make.
   6 #
   7 # GNU Make is free software; you can redistribute it and/or modify it under
   8 # the terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # GNU Make is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License along with
  18 # this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU make],[3.82.90],[bug-make@gnu.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_REVISION([[$Id: configure.in,v 1.158 2011/11/15 21:12:54 psmith Exp $]])
  24
  25 # Autoconf setup
  26 AC_CONFIG_AUX_DIR(config)
  27 AC_CONFIG_SRCDIR(vpath.c)
  28 AC_CONFIG_HEADERS(config.h)
  29
  30 # Automake setup
  31 AM_INIT_AUTOMAKE([1.9])
  32
  33 # Checks for programs.
  34 AC_PROG_CC
  35 AC_PROG_INSTALL
  36 AC_PROG_RANLIB
  37 AC_PROG_CPP
  38 AC_CHECK_PROG(AR, ar, ar, ar)
  39 # Perl is needed for the test suite (only)
  40 AC_CHECK_PROG(PERL, perl, perl, perl)
  41
  42 # Specialized system macros
  43 AC_CANONICAL_HOST
  44 AC_AIX
  45 AC_ISC_POSIX
  46 AC_MINIX
  47
  48 # Enable gettext, in "external" mode.
  49
  50 AM_GNU_GETTEXT_VERSION(0.14.1)
  51 AM_GNU_GETTEXT([external])
  52
  53 # This test must come as early as possible after the compiler configuration
  54 # tests, because the choice of the file model can (in principle) affect
  55 # whether functions and headers are available, whether they work, etc.
  56 AC_SYS_LARGEFILE
  57
  58 # Checks for libraries.
  59 AC_SEARCH_LIBS(getpwnam, [sun])
  60
  61 # Checks for header files.
  62 AC_HEADER_STDC
  63 AC_HEADER_DIRENT
  64 AC_HEADER_STAT
  65 AC_HEADER_TIME
  66 AC_CHECK_HEADERS(stdlib.h locale.h unistd.h limits.h fcntl.h string.h \
  67                  memory.h sys/param.h sys/resource.h sys/time.h sys/timeb.h)
  68
  69 # Set a flag if we have an ANSI C compiler
  70 if test "$ac_cv_prog_cc_stdc" != no; then
  71   AC_DEFINE(HAVE_ANSI_COMPILER, 1,
  72               [Define to 1 if your compiler conforms to the ANSI C standard.])
  73 fi
  74
  75
  76 # Determine what kind of variadic function calls we support
  77 AC_CHECK_HEADERS(stdarg.h varargs.h, break)
  78
  79 AM_PROG_CC_C_O
  80 AC_C_CONST
  81 AC_TYPE_SIGNAL
  82 AC_TYPE_UID_T
  83 AC_TYPE_PID_T
  84
  85 # Find some definition for uintmax_t
  86
  87 AC_CHECK_TYPE(uintmax_t,,[
  88   uintmax_t="unsigned long"
  89   AC_CHECK_TYPE(unsigned long long,[uintmax_t="unsigned long long"])
  90   AC_DEFINE_UNQUOTED(uintmax_t,$uintmax_t,
  91     [Define uintmax_t if not defined in <stdint.h> or <inttypes.h>.])])
  92
  93 # Find out whether our struct stat returns nanosecond resolution timestamps.
  94
  95 AC_STRUCT_ST_MTIM_NSEC
  96 AC_MSG_CHECKING([whether to use high resolution file timestamps])
  97 AC_CACHE_VAL(make_cv_file_timestamp_hi_res, [
  98   make_cv_file_timestamp_hi_res=no
  99   if test "$ac_cv_struct_st_mtim_nsec" != no; then
 100     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 101 #       if HAVE_INTTYPES_H
 102 #        include <inttypes.h>
 103 #       endif]],
 104                       [[char a[0x7fffffff < (uintmax_t)-1 >> 30 ? 1 : -1];]])],
 105       [make_cv_file_timestamp_hi_res=yes],
 106       [])
 107   fi])
 108 AC_MSG_RESULT($make_cv_file_timestamp_hi_res)
 109 if test "$make_cv_file_timestamp_hi_res" = yes; then
 110   val=1
 111 else
 112   val=0
 113 fi
 114 AC_DEFINE_UNQUOTED(FILE_TIMESTAMP_HI_RES, $val,
 115                    [Use high resolution file timestamps if nonzero.])
 116
 117 if test "$make_cv_file_timestamp_hi_res" = yes; then
 118   # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 119   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 120   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 121   if test "$ac_cv_search_clock_gettime" != no; then
 122     AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 123               [Define to 1 if you have the clock_gettime function.])
 124   fi
 125 fi
 126
 127 # Check for DOS-style pathnames.
 128 pds_AC_DOS_PATHS
 129
 130 # See if we have a standard version of gettimeofday().  Since actual
 131 # implementations can differ, just make sure we have the most common
 132 # one.
 133 AC_CACHE_CHECK([for standard gettimeofday], ac_cv_func_gettimeofday,
 134   [ac_cv_func_gettimeofday=no
 135    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/time.h>
 136                   int main ()
 137                   {
 138                     struct timeval t; t.tv_sec = -1; t.tv_usec = -1;
 139                     exit (gettimeofday (&t, 0) != 0
 140                           || t.tv_sec < 0 || t.tv_usec < 0);
 141                   }]])],
 142                   [ac_cv_func_gettimeofday=yes],
 143                   [ac_cv_func_gettimeofday=no],
 144                   [ac_cv_func_gettimeofday="no (cross-compiling)"])])
 145 if test "$ac_cv_func_gettimeofday" = yes; then
 146   AC_DEFINE(HAVE_GETTIMEOFDAY, 1,
 147             [Define to 1 if you have a standard gettimeofday function])
 148 fi
 149
 150 AC_CHECK_FUNCS( strdup strndup mkstemp mktemp fdopen fileno \
 151                 dup2 getcwd realpath sigsetmask sigaction \
 152                 getgroups seteuid setegid setlinebuf setreuid setregid \
 153                 getrlimit setrlimit setvbuf pipe strerror strsignal \
 154                 lstat readlink atexit)
 155
 156 # We need to check declarations, not just existence, because on Tru64 this
 157 # function is not declared without special flags, which themselves cause
 158 # other problems.  We'll just use our own.
 159 AC_CHECK_DECLS([bsd_signal], [], [], [[#include <signal.h>]])
 160
 161 AC_FUNC_SETVBUF_REVERSED
 162
 163 # Rumor has it that strcasecmp lives in -lresolv on some odd systems.
 164 # It doesn't hurt much to use our own if we can't find it so I don't
 165 # make the effort here.
 166 AC_CHECK_FUNCS(strcasecmp strncasecmp strcmpi strncmpi stricmp strnicmp)
 167
 168 # strcoll() is used by the GNU glob library
 169 AC_FUNC_STRCOLL
 170
 171 AC_FUNC_ALLOCA
 172 AC_FUNC_FORK([])
 173 AC_FUNC_VPRINTF
 174 AC_FUNC_CLOSEDIR_VOID
 175
 176 AC_FUNC_GETLOADAVG
 177
 178 # AC_FUNC_GETLOADAVG is documented to set the NLIST_STRUCT value, but it
 179 # doesn't.  So, we will.
 180
 181 if test "$ac_cv_header_nlist_h" = yes; then
 182   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
 183         [[struct nlist nl;
 184           nl.n_name = "string";
 185           return 0;]])],
 186         [make_cv_nlist_struct=yes],
 187         [make_cv_nlist_struct=no])
 188   if test "$make_cv_nlist_struct" = yes; then
 189     AC_DEFINE(NLIST_STRUCT, 1,
 190        [Define to 1 if struct nlist.n_name is a pointer rather than an array.])
 191   fi
 192 fi
 193
 194 AC_CHECK_DECLS([sys_siglist, _sys_siglist, __sys_siglist], , ,
 195   [AC_INCLUDES_DEFAULT
 196 #include <signal.h>
 197 /* NetBSD declares sys_siglist in unistd.h.  */
 198 #if HAVE_UNISTD_H
 199 # include <unistd.h>
 200 #endif
 201 ])
 202
 203
 204 # Check out the wait reality.
 205 AC_CHECK_HEADERS(sys/wait.h,,,[[#include <sys/types.h>]])
 206 AC_CHECK_FUNCS(waitpid wait3)
 207 AC_MSG_CHECKING(for union wait)
 208 AC_CACHE_VAL(make_cv_union_wait, [dnl
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 210 #include <sys/wait.h>]],
 211      [[union wait status; int pid; pid = wait (&status);
 212 #ifdef WEXITSTATUS
 213 /* Some POSIXoid systems have both the new-style macros and the old
 214    union wait type, and they do not work together.  If union wait
 215    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 216         if (WEXITSTATUS (status) != 0) pid = -1;
 217 #ifdef WTERMSIG
 218         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 219         -- blow chunks here --
 220 #endif
 221 #endif
 222 #ifdef HAVE_WAITPID
 223         /* Make sure union wait works with waitpid.  */
 224         pid = waitpid (-1, &status, 0);
 225 #endif
 226       ]])],
 227     [make_cv_union_wait=yes],
 228     [make_cv_union_wait=no])])
 229 if test "$make_cv_union_wait" = yes; then
 230   AC_DEFINE(HAVE_UNION_WAIT, 1,
 231             [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 232 fi
 233 AC_MSG_RESULT($make_cv_union_wait)
 234
 235
 236 # If we're building on Windows/DOS/OS/2, add some support for DOS drive specs.
 237 if test "$PATH_SEPARATOR" = ';'; then
 238   AC_DEFINE(HAVE_DOS_PATHS, 1,
 239             [Define to 1 if your system requires backslashes or drive specs in pathnames.])
 240 fi
 241
 242
 243 # See if the user wants to use pmake's "customs" distributed build capability
 244
 245 AC_SUBST(REMOTE) REMOTE=stub
 246 use_customs=false
 247 AC_ARG_WITH(customs,
 248   AC_HELP_STRING([--with-customs=DIR],
 249                  [enable remote jobs via Customs--see README.customs]),
 250   [case $withval in
 251     n|no) : ;;
 252     *) make_cppflags="$CPPFLAGS"
 253        case $withval in
 254          y|ye|yes) : ;;
 255          *) CPPFLAGS="$CPPFLAGS -I$with_customs/include/customs"
 256             make_ldflags="$LDFLAGS -L$with_customs/lib" ;;
 257        esac
 258        CF_NETLIBS
 259        AC_CHECK_HEADER(customs.h,
 260                        [use_customs=true
 261                          REMOTE=cstms
 262                          LIBS="$LIBS -lcustoms" LDFLAGS="$make_ldflags"],
 263                        [with_customs=no
 264                          CPPFLAGS="$make_cppflags" make_badcust=yes])
 265        ;;
 266   esac])
 267 # Tell automake about this, so it can include the right .c files.
 268 AM_CONDITIONAL(USE_CUSTOMS, test "$use_customs" = true)
 269
 270 # See if the user asked to handle case insensitive file systems.
 271
 272 AH_TEMPLATE(HAVE_CASE_INSENSITIVE_FS, [Use case insensitive file names])
 273 AC_ARG_ENABLE(case-insensitive-file-system,
 274   AC_HELP_STRING([--enable-case-insensitive-file-system],
 275                  [assume file systems are case insensitive]),
 276   [case $enableval in
 277      yes) AC_DEFINE(HAVE_CASE_INSENSITIVE_FS) ;;
 278    esac])
 279
 280 # See if we can handle the job server feature, and if the user wants it.
 281
 282 AC_ARG_ENABLE(job-server,
 283   AC_HELP_STRING([--disable-job-server],
 284                  [disallow recursive make communication during -jN]),
 285   [make_cv_job_server="$enableval" user_job_server="$enableval"],
 286   [make_cv_job_server="yes"])
 287
 288 has_wait_nohang=yes
 289 case "$ac_cv_func_waitpid/$ac_cv_func_wait3" in
 290   no/no) has_wait_nohang=no ;;
 291 esac
 292
 293 AC_CACHE_CHECK(for SA_RESTART, make_cv_sa_restart, [
 294   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]],
 295       [[return SA_RESTART;]])],
 296     [make_cv_sa_restart=yes],
 297     [make_cv_sa_restart=no])])
 298
 299 if test "$make_cv_sa_restart" != no; then
 300   AC_DEFINE(HAVE_SA_RESTART, 1,
 301      [Define to 1 if <signal.h> defines the SA_RESTART constant.])
 302 fi
 303
 304 # Only allow jobserver on systems that support it
 305 case "/$ac_cv_func_pipe/$ac_cv_func_sigaction/$make_cv_sa_restart/$has_wait_nohang/" in
 306   */no/*) make_cv_job_server=no ;;
 307 esac
 308
 309 # Also supported on OS2 and W32
 310 case "$host_os" in
 311   os2*|mingw32) make_cv_sa_restart=yes ;;
 312 esac
 313
 314 if test "$make_cv_job_server" != no; then
 315   AC_DEFINE(MAKE_JOBSERVER, 1,
 316             [Define to 1 to enable job server support in GNU make.])
 317 fi
 318
 319 # if we have both lstat() and readlink() then we can support symlink
 320 # timechecks.
 321 case "$ac_cv_func_lstat/$ac_cv_func_readlink" in
 322   yes/yes)
 323     AC_DEFINE(MAKE_SYMLINKS, 1,
 324               [Define to 1 to enable symbolic link timestamp checking.]);;
 325 esac
 326
 327 # Find the SCCS commands, so we can include them in our default rules.
 328
 329 AC_CACHE_CHECK(for location of SCCS get command, make_cv_path_sccs_get, [
 330 if test -f /usr/sccs/get; then
 331   make_cv_path_sccs_get=/usr/sccs/get
 332 else
 333   make_cv_path_sccs_get=get
 334 fi])
 335 AC_DEFINE_UNQUOTED(SCCS_GET, ["$make_cv_path_sccs_get"],
 336                    [Define to the name of the SCCS 'get' command.])
 337
 338 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 339 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 340    test -f s.conftest; then
 341   # We successfully created an SCCS file.
 342   AC_CACHE_CHECK(if SCCS get command understands -G, make_cv_sys_get_minus_G, [
 343     if $make_cv_path_sccs_get -Gconftoast s.conftest >/dev/null 2>&1 &&
 344        test -f conftoast; then
 345        make_cv_sys_get_minus_G=yes
 346     else
 347        make_cv_sys_get_minus_G=no
 348     fi])
 349   case "$make_cv_sys_get_minus_G" in
 350     yes) AC_DEFINE(SCCS_GET_MINUS_G, 1,
 351            [Define to 1 if the SCCS 'get' command understands the '-G<file>' option.]);;
 352   esac
 353 fi
 354 rm -f s.conftest conftoast
 355
 356 # Check the system to see if it provides GNU glob.  If not, use our
 357 # local version.
 358 AC_MSG_CHECKING(if system libc has GNU glob)
 359 AC_CACHE_VAL(make_cv_sys_gnu_glob, [
 360  AC_EGREP_CPP(gnu glob,[
 361 #include <features.h>
 362 #include <glob.h>
 363 #include <fnmatch.h>
 364
 365 #define GLOB_INTERFACE_VERSION 1
 366 #if !defined _LIBC && defined __GNU_LIBRARY__ && __GNU_LIBRARY__ > 1
 367 # include <gnu-versions.h>
 368 # if _GNU_GLOB_INTERFACE_VERSION == GLOB_INTERFACE_VERSION
 369    gnu glob
 370 # endif
 371 #endif
 372  ], [AC_MSG_RESULT(yes)
 373 make_cv_sys_gnu_glob=yes], [AC_MSG_RESULT([no; using local copy])
 374 make_cv_sys_gnu_glob=no])])
 375 if test "$make_cv_sys_gnu_glob" = no; then
 376   GLOBINC='-I$(srcdir)/glob'
 377   GLOBLIB=glob/libglob.a
 378 fi
 379 AC_SUBST(GLOBINC)
 380 AC_SUBST(GLOBLIB)
 381
 382 # Tell automake about this, so it can build the right .c files.
 383 AM_CONDITIONAL(USE_LOCAL_GLOB, test "$make_cv_sys_gnu_glob" = no)
 384
 385 # Let the makefile know what our build host is
 386
 387 AC_DEFINE_UNQUOTED(MAKE_HOST,"$host",[Build host information.])
 388 MAKE_HOST="$host"
 389 AC_SUBST(MAKE_HOST)
 390
 391 w32_target_env=no
 392 AM_CONDITIONAL([WINDOWSENV], false)
 393
 394 case "$host" in
 395   *-*-mingw32)
 396     AM_CONDITIONAL(WINDOWSENV, true)
 397     w32_target_env=yes
 398     AC_DEFINE([WINDOWS32], [1], [Use platform specific coding])
 399     AC_DEFINE([HAVE_DOS_PATHS], [1], [Use platform specific coding])
 400     ;;
 401 esac
 402
 403 AC_DEFINE_UNQUOTED(PATH_SEPARATOR_CHAR,'$PATH_SEPARATOR',[Define to the character that separates directories in PATH.])
 404
 405 # Include the Maintainer's Makefile section, if it's here.
 406
 407 MAINT_MAKEFILE=/dev/null
 408 if test -r "$srcdir/maintMakefile"; then
 409   MAINT_MAKEFILE="$srcdir/maintMakefile"
 410 fi
 411 AC_SUBST_FILE(MAINT_MAKEFILE)
 412
 413 # Allow building with dmalloc
 414 AM_WITH_DMALLOC
 415
 416 # Forcibly disable SET_MAKE.  If it's set it breaks things like the test
 417 # scripts, etc.
 418 SET_MAKE=
 419
 420 # Sanity check and inform the user of what we found
 421
 422 case "$make_badcust" in
 423   yes) echo
 424        echo "WARNING: --with-customs specified but no customs.h could be found;"
 425        echo "         disabling Customs support."
 426        echo ;;
 427 esac
 428
 429 case "$with_customs" in
 430   ""|n|no|y|ye|yes) ;;
 431   *) if test -f "$with_customs/lib/libcustoms.a"; then
 432        :
 433      else
 434        echo
 435        echo "WARNING: '$with_customs/lib' does not appear to contain the"
 436        echo "         Customs library.  You must build and install Customs"
 437        echo "         before compiling GNU make."
 438        echo
 439      fi ;;
 440 esac
 441
 442 case "$has_wait_nohang" in
 443   no) echo
 444       echo "WARNING: Your system has neither waitpid() nor wait3()."
 445       echo "         Without one of these, signal handling is unreliable."
 446       echo "         You should be aware that running GNU make with -j"
 447       echo "         could result in erratic behavior."
 448       echo ;;
 449 esac
 450
 451 case "$make_cv_job_server/$user_job_server" in
 452   no/yes) echo
 453           echo "WARNING: Make job server requires a POSIX-ish system that"
 454           echo "         supports the pipe(), sigaction(), and either"
 455           echo "         waitpid() or wait3() functions.  Your system doesn't"
 456           echo "         appear to provide one or more of those."
 457           echo "         Disabling job server support."
 458           echo ;;
 459 esac
 460
 461
 462 # Specify what files are to be created.
 463 AC_CONFIG_FILES(Makefile glob/Makefile po/Makefile.in config/Makefile doc/Makefile w32/Makefile)
 464
 465 # OK, do it!
 466
 467 AC_OUTPUT
 468
 469 # We only generate the build.sh if we have a build.sh.in; we won't have
 470 # one before we've created a distribution.
 471 if test -f "$srcdir/build.sh.in"; then
 472   ./config.status --file build.sh
 473   chmod +x build.sh
 474 fi
 475
 476 dnl Local Variables:
 477 dnl comment-start: "dnl "
 478 dnl comment-end: ""
 479 dnl comment-start-skip: "\\bdnl\\b\\s *"
 480 dnl compile-command: "make configure config.h.in"
 481 dnl End: