configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$Id: configure.in,v 1.34 1994/03/29 00:23:41 roland Exp $])
   3 AC_INIT(vpath.c)                dnl A distinctive file to look for in srcdir.
   4 AC_CONFIG_HEADER(config.h)
   5
   6 # We want these before the checks, so the checks can modify their values.
   7 test -z "$CFLAGS" && CFLAGS=-g AC_SUBST(CFLAGS)
   8 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
   9
  10 AC_SET_MAKE
  11 AC_PROG_CC
  12 AC_PROG_INSTALL
  13 AC_PROG_RANLIB
  14 AC_PROG_CPP                     dnl Later checks need this.
  15 AC_AIX
  16 AC_ISC_POSIX
  17 AC_MINIX
  18 AC_STDC_HEADERS
  19 AC_DIR_HEADER
  20 AC_UID_T                        dnl Also does gid_t.
  21 AC_GETGROUPS_T
  22 AC_PID_T
  23 AC_RETSIGTYPE
  24 AC_HAVE_HEADERS(unistd.h limits.h sys/param.h fcntl.h string.h memory.h \
  25                 sys/timeb.h)
  26 AC_MINUS_C_MINUS_O
  27 AC_CONST                        dnl getopt needs this.
  28 AC_STAT_MACROS_BROKEN
  29
  30 AC_SUBST(LIBOBJS)
  31
  32 AC_HAVE_FUNCS(getdtablesize sys_siglist _sys_siglist psignal \
  33               dup2 getcwd sigsetmask getgroups setlinebuf \
  34               setreuid setregid strerror)
  35 AC_ALLOCA
  36 AC_VFORK
  37 AC_SETVBUF_REVERSED
  38 AC_GETLOADAVG
  39 AC_STRCOLL
  40
  41 dnl Check out the wait reality.
  42 AC_HAVE_HEADERS(sys/wait.h) AC_HAVE_FUNCS(waitpid wait3)
  43 AC_COMPILE_CHECK(union wait, [#include <sys/types.h>
  44 #include <sys/wait.h>],
  45                  [union wait status; int pid; pid = wait (&status);
  46 #ifdef WEXITSTATUS
  47 /* Some POSIXoid systems have both the new-style macros and the old
  48    union wait type, and they do not work together.  If union wait
  49    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  50 if (WEXITSTATUS (status) != 0) pid = -1;
  51 #endif
  52 #ifdef HAVE_WAITPID
  53 /* Make sure union wait works with waitpid.  */
  54 pid = waitpid (-1, &status, 0);
  55 #endif
  56 ],
  57                  AC_DEFINE(HAVE_UNION_WAIT))
  58
  59 AC_SYS_SIGLIST_DECLARED
  60
  61 # The presence of the following is not meant to imply
  62 # that make necessarily works on those systems.
  63 AC_DYNIX_SEQ
  64 AC_XENIX_DIR
  65 AC_IRIX_SUN
  66
  67 AC_SUBST(REMOTE) REMOTE=stub
  68 AC_WITH(customs, [REMOTE=cstms
  69 LIBS="$LIBS libcustoms.a"])
  70
  71 echo checking for location of SCCS get command
  72 if test -f /usr/sccs/get; then
  73   SCCS_GET=/usr/sccs/get
  74   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  75 else
  76   SCCS_GET=get
  77   AC_DEFINE(SCCS_GET, "get")
  78 fi
  79 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
  80 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
  81    test -f s.conftest; then
  82   # We successfully created an SCCS file.
  83   echo checking if SCCS get command understands -G
  84   if $SCCS_GET s.conftest -Gconftoast >/dev/null 2>&1 &&
  85      test -f conftoast; then
  86     AC_DEFINE(SCCS_GET_MINUS_G)
  87   fi
  88 fi
  89 rm -f s.conftest conftoast
  90
  91 AC_OUTPUT(Makefile build.sh glob/Makefile, [
  92 # Makefile uses this timestamp file to know when to remake Makefile,
  93 # build.sh, and glob/Makefile.
  94 touch stamp-config])
  95
  96 dnl Local Variables:
  97 dnl comment-start: "dnl "
  98 dnl comment-end: ""
  99 dnl comment-start-skip: "\\bdnl\\b\\s *"
 100 dnl compile-command: "make configure config.h.in"
 101 dnl End: