configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Id: configure.in,v 1.32 1994/03/28 22:58:08 roland Exp $)
   3 AC_INIT(vpath.c)                dnl A distinctive file to look for in srcdir.
   4 AC_CONFIG_HEADER(config.h)
   5
   6 # We want these before the checks, so the checks can modify their values.
   7 test -z "$CFLAGS" && CFLAGS=-g AC_SUBST(CFLAGS)
   8 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
   9
  10 AC_PROG_CC
  11 AC_PROG_INSTALL
  12 AC_PROG_RANLIB
  13 AC_PROG_CPP                     dnl Later checks need this.
  14 AC_AIX
  15 AC_ISC_POSIX
  16 AC_MINIX
  17 AC_STDC_HEADERS
  18 AC_DIR_HEADER
  19 AC_UID_T                        dnl Also does gid_t.
  20 AC_GETGROUPS_T
  21 AC_PID_T
  22 AC_RETSIGTYPE
  23 AC_HAVE_HEADERS(unistd.h limits.h sys/param.h fcntl.h string.h memory.h \
  24                 sys/timeb.h)
  25 AC_MINUS_C_MINUS_O
  26 AC_CONST                        dnl getopt needs this.
  27 AC_STAT_MACROS_BROKEN
  28
  29 AC_SUBST(LIBOBJS)
  30
  31 AC_HAVE_FUNCS(getdtablesize sys_siglist _sys_siglist psignal \
  32               dup2 getcwd sigsetmask getgroups setlinebuf \
  33               setreuid setregid strerror)
  34 AC_ALLOCA
  35 AC_VFORK
  36 AC_SETVBUF_REVERSED
  37 AC_GETLOADAVG
  38 AC_STRCOLL
  39
  40 dnl Check out the wait reality.
  41 AC_HAVE_HEADERS(sys/wait.h) AC_HAVE_FUNCS(waitpid wait3)
  42 AC_COMPILE_CHECK(union wait, [#include <sys/types.h>
  43 #include <sys/wait.h>],
  44                  [union wait status; int pid; pid = wait (&status);
  45 #ifdef WEXITSTATUS
  46 /* Some POSIXoid systems have both the new-style macros and the old
  47    union wait type, and they do not work together.  If union wait
  48    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  49 if (WEXITSTATUS (status) != 0) pid = -1;
  50 #endif
  51 #ifdef HAVE_WAITPID
  52 /* Make sure union wait works with waitpid.  */
  53 pid = waitpid (-1, &status, 0);
  54 #endif
  55 ],
  56                  AC_DEFINE(HAVE_UNION_WAIT))
  57
  58 AC_SYS_SIGLIST_DECLARED
  59
  60 # The presence of the following is not meant to imply
  61 # that make necessarily works on those systems.
  62 AC_DYNIX_SEQ
  63 AC_XENIX_DIR
  64 AC_IRIX_SUN
  65
  66 AC_SUBST(REMOTE) REMOTE=stub
  67 AC_WITH(customs, [REMOTE=cstms
  68 LIBS="$LIBS libcustoms.a"])
  69
  70 echo checking for location of SCCS get command
  71 if test -f /usr/sccs/get; then
  72   SCCS_GET=/usr/sccs/get
  73   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  74 else
  75   SCCS_GET=get
  76   AC_DEFINE(SCCS_GET, "get")
  77 fi
  78 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
  79 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
  80    test -f s.conftest; then
  81   # We successfully created an SCCS file.
  82   echo checking if SCCS get command understands -G
  83   if $SCCS_GET s.conftest -Gconftoast >/dev/null 2>&1 &&
  84      test -f conftoast; then
  85     AC_DEFINE(SCCS_GET_MINUS_G)
  86   fi
  87 fi
  88 rm -f s.conftest conftoast
  89
  90 AC_OUTPUT(Makefile build.sh glob/Makefile, [
  91 # Makefile uses this timestamp file to know when to remake Makefile,
  92 # build.sh, and glob/Makefile.
  93 touch stamp-config])
  94
  95 dnl Local Variables:
  96 dnl comment-start: "dnl "
  97 dnl comment-end: ""
  98 dnl comment-start-skip: "\\bdnl\\b\\s *"
  99 dnl compile-command: "make configure config.h.in"
 100 dnl End: