utils/themeeditor/themeeditor.pro

   1 # Setting the binary name
   2 TARGET = rbthemeeditor
   3 VERSION = 0.5
   4 CONFIG(debug) {
   5     REVISION = $$system(svnversion)
   6     VERSION = $$join(VERSION,,,r)
   7     VERSION = $$join(VERSION,,,$$REVISION)
   8 }
   9
  10 # Adding network support
  11 QT += network
  12
  13 # Enabling profiling
  14 QMAKE_CXXFLAGS_DEBUG += -pg
  15 QMAKE_LFLAGS_DEBUG += -pg
  16
  17 # Adding zlib dependency for QuaZip
  18 LIBS += -lz
  19 INCLUDEPATH += zlib
  20
  21 # build in a separate folder.
  22 MYBUILDDIR = $$OUT_PWD/build/
  23 OBJECTS_DIR = $$MYBUILDDIR/o
  24 UI_DIR = $$MYBUILDDIR/ui
  25 MOC_DIR = $$MYBUILDDIR/moc
  26 RCC_DIR = $$MYBUILDDIR/rcc
  27 RBBASE_DIR = $$_PRO_FILE_PWD_
  28 RBBASE_DIR = $$replace(RBBASE_DIR,/utils/themeeditor,)
  29
  30 # Include directories
  31 INCLUDEPATH += gui
  32 INCLUDEPATH += models
  33 INCLUDEPATH += graphics
  34 INCLUDEPATH += quazip
  35 INCLUDEPATH += qtfindreplacedialog
  36 DEFINES += FINDREPLACE_NOLIB
  37 cross {
  38     message("Crossbuilding for W32 binary")
  39
  40     # retrieve ar binary for w32 cross compile. This might be specific to
  41     # Fedora mingw32 packages of Qt. Using member() here is needed because at
  42     # least the F13 packages add ar options to the variable.
  43     CROSSOPTIONS += AR=$$member(QMAKE_LIB) TARGETPLATFORM=\"MinGW\"
  44
  45     # make sure we use the correct subsystem to prevent a console window coming up.
  46     LIBS += -Wl,-subsystem,windows
  47 }
  48
  49 # Stuff for the parse lib
  50 libskin_parser.commands = @$(MAKE) \
  51     TARGET_DIR=$$MYBUILDDIR \
  52     CC=\"$$QMAKE_CC\" \
  53     $$CROSSOPTIONS \
  54     BUILDDIR=$$OBJECTS_DIR \
  55     -C \
  56     $$RBBASE_DIR/lib/skin_parser \
  57     libskin_parser.a
  58 QMAKE_EXTRA_TARGETS += libskin_parser
  59 PRE_TARGETDEPS += libskin_parser
  60 INCLUDEPATH += $$RBBASE_DIR/lib/skin_parser
  61 LIBS += -L$$MYBUILDDIR \
  62     -lskin_parser
  63 DEPENDPATH = $$INCLUDEPATH
  64 HEADERS += models/parsetreemodel.h \
  65     models/parsetreenode.h \
  66     gui/editorwindow.h \
  67     gui/skinhighlighter.h \
  68     gui/skindocument.h \
  69     gui/preferencesdialog.h \
  70     gui/codeeditor.h \
  71     models/projectmodel.h \
  72     gui/tabcontent.h \
  73     gui/configdocument.h \
  74     gui/skinviewer.h \
  75     graphics/rbscreen.h \
  76     graphics/rbviewport.h \
  77     graphics/rbrenderinfo.h \
  78     graphics/rbimage.h \
  79     graphics/rbfont.h \
  80     gui/devicestate.h \
  81     graphics/rbalbumart.h \
  82     graphics/rbprogressbar.h \
  83     graphics/rbtext.h \
  84     graphics/rbfontcache.h \
  85     graphics/rbtextcache.h \
  86     gui/skintimer.h \
  87     graphics/rbtoucharea.h \
  88     gui/newprojectdialog.h \
  89     models/targetdata.h \
  90     quazip/zip.h \
  91     quazip/unzip.h \
  92     quazip/quazipnewinfo.h \
  93     quazip/quazipfileinfo.h \
  94     quazip/quazipfile.h \
  95     quazip/quazip.h \
  96     quazip/ioapi.h \
  97     quazip/crypt.h \
  98     zlib/zlib.h \
  99     zlib/zconf.h \
 100     gui/fontdownloader.h \
 101     qtfindreplacedialog/varianteditor.h \
 102     qtfindreplacedialog/findreplace_global.h \
 103     qtfindreplacedialog/findreplaceform.h \
 104     qtfindreplacedialog/findreplacedialog.h \
 105     qtfindreplacedialog/findform.h \
 106     qtfindreplacedialog/finddialog.h \
 107     gui/projectexporter.h \
 108     gui/targetdownloader.h \
 109     gui/syntaxcompleter.h \
 110     graphics/rbmovable.h \
 111     graphics/rbscene.h \
 112     gui/rbconsole.h
 113 SOURCES += main.cpp \
 114     models/parsetreemodel.cpp \
 115     models/parsetreenode.cpp \
 116     gui/editorwindow.cpp \
 117     gui/skinhighlighter.cpp \
 118     gui/skindocument.cpp \
 119     gui/preferencesdialog.cpp \
 120     gui/codeeditor.cpp \
 121     models/projectmodel.cpp \
 122     gui/configdocument.cpp \
 123     gui/skinviewer.cpp \
 124     graphics/rbscreen.cpp \
 125     graphics/rbviewport.cpp \
 126     graphics/rbrenderinfo.cpp \
 127     graphics/rbimage.cpp \
 128     graphics/rbfont.cpp \
 129     gui/devicestate.cpp \
 130     graphics/rbalbumart.cpp \
 131     graphics/rbprogressbar.cpp \
 132     graphics/rbtext.cpp \
 133     graphics/rbfontcache.cpp \
 134     graphics/rbtextcache.cpp \
 135     gui/skintimer.cpp \
 136     graphics/rbtoucharea.cpp \
 137     gui/newprojectdialog.cpp \
 138     models/targetdata.cpp \
 139     quazip/zip.c \
 140     quazip/unzip.c \
 141     quazip/quazipnewinfo.cpp \
 142     quazip/quazipfile.cpp \
 143     quazip/quazip.cpp \
 144     quazip/ioapi.c \
 145     gui/fontdownloader.cpp \
 146     qtfindreplacedialog/varianteditor.cpp \
 147     qtfindreplacedialog/findreplaceform.cpp \
 148     qtfindreplacedialog/findreplacedialog.cpp \
 149     qtfindreplacedialog/findform.cpp \
 150     qtfindreplacedialog/finddialog.cpp \
 151     gui/projectexporter.cpp \
 152     gui/targetdownloader.cpp \
 153     gui/syntaxcompleter.cpp \
 154     graphics/rbmovable.cpp \
 155     graphics/rbscene.cpp \
 156     gui/rbconsole.cpp
 157 OTHER_FILES += README \
 158     resources/windowicon.png \
 159     resources/appicon.xcf \
 160     resources/COPYING \
 161     resources/document-save.png \
 162     resources/document-open.png \
 163     resources/document-new.png \
 164     resources/deviceoptions \
 165     resources/render/statusbar.png \
 166     resources/render/scenebg.png \
 167     resources/play.xcf \
 168     resources/play.png \
 169     resources/rwnd.png \
 170     resources/pause.xcf \
 171     resources/pause.png \
 172     resources/ffwd.xcf \
 173     resources/ffwd.png \
 174     resources/lines.xcf \
 175     resources/lines.png \
 176     resources/cursor.xcf \
 177     resources/cursor.png \
 178     resources/targetdb \
 179     quazip/README.ROCKBOX \
 180     quazip/LICENSE.GPL \
 181     qtfindreplacedialog/dialogs.pro \
 182     resources/tagdb \
 183     resources/document-save-as.png \
 184     resources/edit-undo.png \
 185     resources/edit-redo.png \
 186     resources/edit-paste.png \
 187     resources/edit-cut.png \
 188     resources/edit-copy.png \
 189     resources/edit-find-replace.png \
 190     resources/applications-system.png
 191 FORMS += gui/editorwindow.ui \
 192     gui/preferencesdialog.ui \
 193     gui/configdocument.ui \
 194     gui/skinviewer.ui \
 195     gui/skintimer.ui \
 196     gui/newprojectdialog.ui \
 197     gui/fontdownloader.ui \
 198     qtfindreplacedialog/findreplaceform.ui \
 199     qtfindreplacedialog/findreplacedialog.ui \
 200     gui/projectexporter.ui \
 201     gui/targetdownloader.ui \
 202     gui/rbconsole.ui
 203 RESOURCES += resources.qrc
 204 win32:RC_FILE = themeeditor.rc
 205 macx {
 206     QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
 207     QMAKE_LFLAGS_PPC = -mmacosx-version-min=10.4 \
 208         -arch \
 209         ppc
 210     QMAKE_LFLAGS_X86 = -mmacosx-version-min=10.4 \
 211         -arch \
 212         i386
 213     CONFIG += x86 \
 214         ppc
 215     QMAKE_INFO_PLIST = Info.plist
 216     RC_FILE = resources/windowicon.icns
 217 }
 218
 219 # add any external lib build into build/ to clean target, as well as objects
 220 # created during that in the objects build folder.
 221 QMAKE_CLEAN += build/*.a $$OBJECTS_DIR/*.o