rbutil/rbutilqt/rbutilqt.pro

   1 #
   2 #             __________               __   ___.
   3 #   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
   4 #   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
   5 #   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
   6 #   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
   7 #                     \/            \/     \/    \/            \/
   8 # $Id$
   9 #
  10 # All files in this archive are subject to the GNU General Public License.
  11 # See the file COPYING in the source tree root for full license agreement.
  12 #
  13 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  14 # KIND, either express or implied.
  15 #
  16
  17 # ccache
  18 unix:!mac:!noccache {
  19     CCACHE = $$system(which ccache)
  20     !isEmpty(CCACHE) {
  21         message("using ccache")
  22         QMAKE_CXX = ccache g++
  23         QMAKE_CC = ccache gcc
  24     }
  25 }
  26
  27 MYBUILDDIR = $$OUT_PWD/build/
  28 MYLIBBUILDDIR = $$MYBUILDDIR/libs/
  29 OBJECTS_DIR = $$MYBUILDDIR/o
  30 UI_DIR = $$MYBUILDDIR/ui
  31 MOC_DIR = $$MYBUILDDIR/moc
  32 RCC_DIR = $$MYBUILDDIR/rcc
  33
  34 !silent {
  35     ADDENV = "V=1"
  36 } else {
  37     ADDENV = "@"
  38 }
  39
  40 # check version of Qt installation
  41 VER = $$find(QT_VERSION, ^4\\.[5-9]+.*)
  42 isEmpty(VER) {
  43     message("Qt >= 4.5 required!")
  44     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  45 }
  46 message("Qt version used:" $$VER)
  47
  48 MACHINEFLAGS = $$find(QMAKE_CFLAGS, -m[63][42])
  49
  50 RBBASE_DIR = $$_PRO_FILE_PWD_
  51 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  52
  53 message("Rockbox Base dir: "$$RBBASE_DIR)
  54
  55 # check for system speex. Add a custom rule for pre-building librbspeex if not
  56 # found. Newer versions of speex are split up into libspeex and libspeexdsp,
  57 # and some distributions package them separately. Check for both and fall back
  58 # to librbspeex if not found.
  59 # NOTE: keep adding the linker option after -lrbspeex, otherwise linker errors
  60 # occur if the linker defaults to --as-needed
  61 # (see http://www.gentoo.org/proj/en/qa/asneeded.xml)
  62 #
  63 # Always use our own copy when building statically. Don't search for libspeex
  64 # on Mac, since we don't deploy statically there.
  65 !static:unix:!mac {
  66     LIBSPEEX = $$system(pkg-config --silence-errors --libs speex speexdsp)
  67 }
  68 # The external Makefiles use ar to create libs. To allow cross-compiling pass
  69 # the ar that matches the current gcc. Since qmake doesn't provide a variable
  70 # holding the correct ar without any additions we need to figure it ourselves
  71 # here. This assumes that QMAKE_CC will always be "gcc", maybe with a postfix.
  72 MYAR = $$replace(QMAKE_CC,gcc.*,ar)
  73
  74 librbspeex.commands = $$ADDENV \
  75         BUILD_DIR=$$MYLIBBUILDDIR/rbspeex/ \
  76         TARGET_DIR=$$MYLIBBUILDDIR \
  77         SYS_SPEEX=\"$$LIBSPEEX\" \
  78         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
  79         $(MAKE) -C $$RBBASE_DIR/tools/rbspeex librbspeex.a
  80 libucl.commands = $$ADDENV \
  81         BUILD_DIR=$$MYLIBBUILDDIR/ucl/ \
  82         TARGET_DIR=$$MYLIBBUILDDIR \
  83         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
  84         $(MAKE) -C $$RBBASE_DIR/tools/ucl/src libucl.a
  85 libipodpatcher.commands = $$ADDENV \
  86         BUILD_DIR=$$MYLIBBUILDDIR/ipodpatcher/ \
  87         TARGET_DIR=$$MYLIBBUILDDIR \
  88         APPVERSION=\"rbutil\" \
  89         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
  90         $(MAKE) -C $$RBBASE_DIR/rbutil/ipodpatcher libipodpatcher.a
  91 libsansapatcher.commands = $$ADDENV \
  92         BUILD_DIR=$$MYLIBBUILDDIR/sansapatcher/ \
  93         TARGET_DIR=$$MYLIBBUILDDIR \
  94         APPVERSION=\"rbutil\" \
  95         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
  96         $(MAKE) -C $$RBBASE_DIR/rbutil/sansapatcher libsansapatcher.a
  97 libmkamsboot.commands = $$ADDENV \
  98         BUILD_DIR=$$MYLIBBUILDDIR/mkamsboot/ \
  99         TARGET_DIR=$$MYLIBBUILDDIR \
 100         APPVERSION=\"rbutil\" \
 101         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
 102         $(MAKE) -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot.a
 103 libmktccboot.commands = $$ADDENV \
 104         BUILD_DIR=$$MYLIBBUILDDIR/mktccboot/ \
 105         TARGET_DIR=$$MYLIBBUILDDIR \
 106         APPVERSION=\"rbutil\" \
 107         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
 108         $(MAKE) -C $$RBBASE_DIR/rbutil/mktccboot libmktccboot.a
 109 libmkmpioboot.commands = $$ADDENV \
 110         BUILD_DIR=$$MYLIBBUILDDIR/mkmpioboot/ \
 111         TARGET_DIR=$$MYLIBBUILDDIR \
 112         APPVERSION=\"rbutil\" \
 113         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
 114         $(MAKE) -C $$RBBASE_DIR/rbutil/mkmpioboot libmkmpioboot.a
 115 libchinachippatcher.commands = $$ADDENV \
 116         BUILD_DIR=$$MYLIBBUILDDIR/chinachippatcher/ \
 117         TARGET_DIR=$$MYLIBBUILDDIR \
 118         APPVERSION=\"rbutil\" \
 119         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
 120         $(MAKE) -C $$RBBASE_DIR/rbutil/chinachippatcher libchinachippatcher.a
 121 libmkimxboot.commands = $$ADDENV \
 122         BUILD_DIR=$$MYLIBBUILDDIR/mkimxboot/ \
 123         TARGET_DIR=$$MYLIBBUILDDIR \
 124         APPVERSION=\"rbutil\" \
 125         CC=\"$$QMAKE_CC\" CFLAGS=\"$$MACHINEFLAGS\" AR=\"$$MYAR\" \
 126         $(MAKE) -C $$RBBASE_DIR/rbutil/mkimxboot libmkimxboot.a
 127 # Note: order is important for RBLIBS! The libs are appended to the linker
 128 # flags in this order, put libucl at the end.
 129 RBLIBS = librbspeex libipodpatcher libsansapatcher libmkamsboot libmktccboot \
 130          libmkmpioboot libchinachippatcher libmkimxboot libucl
 131 QMAKE_EXTRA_TARGETS += $$RBLIBS
 132 PRE_TARGETDEPS += $$RBLIBS
 133
 134 # rule for creating ctags file
 135 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
 136 tags.depends = $(SOURCES)
 137 QMAKE_EXTRA_TARGETS += tags
 138
 139 # add a custom rule for making the translations
 140 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
 141 QMAKE_EXTRA_TARGETS += lrelease
 142 !dbg {
 143     PRE_TARGETDEPS += lrelease
 144 }
 145
 146 # Needed by QT on Win
 147 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools \
 148             $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base \
 149             $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/gui
 150 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher \
 151             $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
 152
 153 DEPENDPATH = $$INCLUDEPATH
 154
 155 LIBS += -L$$OUT_PWD -L$$MYLIBBUILDDIR
 156 # append all RBLIBS to LIBS
 157 for(rblib, RBLIBS) {
 158     LIBS += -l$$replace(rblib, lib,)
 159 }
 160
 161 # on win32 libz is linked implicitly.
 162 !win32 {
 163     LIBS += -lz
 164 }
 165
 166 # Add a (possibly found) libspeex now, don't do this before -lrbspeex!
 167 !static:!isEmpty(LIBSPEEX) {
 168     LIBS += $$LIBSPEEX
 169 }
 170
 171 TEMPLATE = app
 172 TARGET = RockboxUtility
 173 QT += network
 174 dbg {
 175     CONFIG += debug thread qt warn_on
 176     DEFINES -= QT_NO_DEBUG_OUTPUT
 177     DEFINES += DBG
 178     message("debug")
 179 }
 180 !dbg {
 181     CONFIG += release thread qt
 182     DEFINES -= QT_NO_DEBUG_OUTPUT
 183     DEFINES += NODEBUG
 184     message("release")
 185 }
 186
 187 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 188
 189 # platform specific
 190 win32 {
 191     # use MinGW's implementation of stdio functions for extended format string
 192     # support.
 193     DEFINES += __USE_MINGW_ANSI_STDIO=1
 194     DEFINES += _CRT_SECURE_NO_WARNINGS
 195     LIBS += -lsetupapi -lnetapi32
 196 }
 197 win32:static {
 198     QMAKE_LFLAGS += -static-libgcc -static-libstdc++
 199 }
 200 unix:!static:!libusb0:!macx {
 201     DEFINES += LIBUSB1
 202     LIBS += -lusb-1.0
 203 }
 204 unix:!static:libusb0:!macx {
 205     LIBS += -lusb
 206 }
 207
 208 unix:!macx:static {
 209     # force statically linking of libusb. Libraries that are appended
 210     # later will get linked dynamically again.
 211     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 212 }
 213
 214 # if -config intel is specified use 10.5 SDK and don't build for PPC
 215 macx:!intel {
 216     CONFIG += ppc
 217     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 218     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 219     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 220 }
 221 macx:intel {
 222     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.5 -arch i386
 223     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.5.sdk
 224     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.5
 225 }
 226 macx {
 227     CONFIG += x86
 228     LIBS += -L/usr/local/lib \
 229             -framework IOKit -framework CoreFoundation -framework Carbon \
 230             -framework SystemConfiguration -framework CoreServices
 231     INCLUDEPATH += /usr/local/include
 232
 233     # rule for creating a dmg file
 234     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 235     QMAKE_EXTRA_TARGETS += dmg
 236 }
 237
 238 static {
 239     QTPLUGIN += qtaccessiblewidgets
 240     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 241     LIBS += -L.
 242     DEFINES += STATIC
 243     message("using static plugin")
 244 }
 245
 246 unix {
 247     target.path = /usr/local/bin
 248     INSTALLS += target
 249 }
 250
 251 # source files are separate.
 252 include(rbutilqt.pri)
 253