tests/macros.at

   1 # Hand crafted tests for GNU M4.                               -*- Autotest -*-
   2 # Copyright (C) 2001, 2006, 2007, 2008 Free Software Foundation, Inc.
   3
   4 # This file is part of GNU M4.
   5 #
   6 # GNU M4 is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # GNU M4 is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AT_BANNER([Macro definitions.])
  20
  21 # Checking everything related to macro definitions: the expansion of
  22 # user macros, the propagation of various bits (tracing, number of
  23 # arguments and so on).
  24
  25 ## ---------------- ##
  26 ## Arity and defn.  ##
  27 ## ---------------- ##
  28
  29 AT_SETUP([Arity and defn])
  30
  31 # Check that the arity checking of define is correctly propagated.
  32
  33 AT_DATA([[input.m4]],
  34 [[define(`defun', defn(`define'))
  35 define
  36 define(`foo')
  37 define(`foo', `bar')
  38 define(`foo', `bar', `baz')
  39
  40 defun
  41 defun(`foo')
  42 defun(`foo', `bar')
  43 defun(`foo', `bar', `baz')
  44 ]])
  45
  46 AT_DATA([[expout]],
  47 [[
  48 define
  49
  50
  51
  52
  53 defun
  54
  55
  56
  57 ]])
  58
  59 AT_CHECK_M4([input.m4], 0, [expout],
  60 [[m4:input.m4:5: Warning: define: extra arguments ignored: 3 > 2
  61 m4:input.m4:10: Warning: defun: extra arguments ignored: 3 > 2
  62 ]])
  63
  64 AT_CLEANUP
  65
  66
  67 ## ------------------------- ##
  68 ## Arity, defn, and freeze.  ##
  69 ## ------------------------- ##
  70
  71 AT_SETUP([Arity, defn, and freeze])
  72 AT_KEYWORDS([frozen])
  73
  74 AT_DATA([[freezeme.m4]],
  75 [[define(`defun', defn(`define'))dnl
  76 undefine(`define')dnl
  77 ]])
  78
  79 AT_CHECK_M4([--freeze-state=frozen.m4f freezeme.m4], 0)
  80
  81 AT_DATA([[input.m4]],
  82 [[defun
  83 defun(`foo')
  84 defun(`foo', `bar')
  85 defun(`foo', `bar', `baz')
  86 ]])
  87
  88 AT_DATA([[expout]],
  89 [[defun
  90
  91
  92
  93 ]])
  94
  95 AT_CHECK_M4([--reload-state=frozen.m4f input.m4], 0, expout,
  96 [[m4:input.m4:4: Warning: defun: extra arguments ignored: 3 > 2
  97 ]])
  98
  99 AT_CLEANUP(freezeme.m4 frozen.m4f)
 100
 101
 102 ## ------------------- ##
 103 ## Command line define ##
 104 ## ------------------- ##
 105
 106 AT_SETUP([Command line define])
 107
 108 dnl Test that -D after last file still affects m4wrap'd text.
 109 AT_DATA([in1], [[m4wrap(`foo
 110 ')foo
 111 ]])
 112 AT_DATA([in2], [[foo
 113 ]])
 114 AT_CHECK_M4([-Dfoo=1 in1 -Dfoo=2 in2 -Dfoo=3], [0],
 115 [[1
 116 2
 117 3
 118 ]])
 119
 120 dnl Test that -D only affects top-most definition.
 121 AT_DATA([in1], [[define(`foo', `1')pushdef(`foo', `2')dnl
 122 ]])
 123 AT_DATA([in2], [[foo
 124 popdef(`foo')foo
 125 popdef(`foo')foo
 126 ]])
 127 AT_CHECK_M4([in1 -Dfoo=3 in2], [0],
 128 [[3
 129 1
 130 foo
 131 ]])
 132
 133 dnl Test that -D and -U interact in correct order
 134 AT_DATA([in], [[foo
 135 ]])
 136 AT_CHECK_M4([-Dfoo=bar in -Ufoo in], [0], [[bar
 137 foo
 138 ]])
 139 AT_CHECK_M4([-Ufoo in -Dfoo=bar in], [0], [[foo
 140 bar
 141 ]])
 142
 143 dnl Test macro arguments defined via -D
 144 AT_DATA([in], [[-foo-foo(1)-foo(1,2)-
 145 -bar-bar(1)-bar(1,2)-
 146 ]])
 147 AT_CHECK_M4([-Dfoo -Dbar='$@' in], [0],
 148 [[----
 149 --1-1,2-
 150 ]])
 151
 152 AT_CLEANUP
 153
 154
 155
 156 ## -------------------- ##
 157 ## Command line pushdef ##
 158 ## -------------------- ##
 159
 160 AT_SETUP([Command line pushdef])
 161
 162 dnl Test that -p after last file still affects m4wrap'd text.
 163 AT_DATA([in1], [[m4wrap(`foo
 164 ')foo
 165 ]])
 166 AT_DATA([in2], [[foo
 167 ]])
 168 AT_CHECK_M4([-pfoo=1 in1 -pfoo=2 in2 -pfoo=3], [0],
 169 [[1
 170 2
 171 3
 172 ]])
 173
 174 dnl Test that -p adds a definition.
 175 AT_DATA([in1], [[define(`foo', `1')pushdef(`foo', `2')dnl
 176 ]])
 177 AT_DATA([in2], [[foo
 178 popdef(`foo')foo
 179 popdef(`foo')foo
 180 ]])
 181 AT_CHECK_M4([in1 -pfoo=3 in2], [0],
 182 [[3
 183 2
 184 1
 185 ]])
 186
 187 dnl Test that --pushdef and --popdef interact in correct order
 188 AT_DATA([in], [[foo
 189 ]])
 190 AT_CHECK_M4([-Dfoo=1 --pushdef=foo=2 in --popdef=foo in], [0],
 191 [[2
 192 1
 193 ]])
 194 AT_CHECK_M4([--popdef=foo in --pushdef=foo=1 in], [0],
 195 [[foo
 196 1
 197 ]])
 198
 199 AT_CLEANUP
 200
 201
 202
 203 ## ---------------- ##
 204 ## pushdef/popdef.  ##
 205 ## ---------------- ##
 206
 207 AT_SETUP([pushdef/popdef])
 208
 209 AT_DATA([[pushpop.m4]],
 210 [[divert(-1)
 211 pushdef(`hej', `def 1.')
 212 dumpdef(`hej')
 213 pushdef(`hej', `def 2.')
 214 dumpdef(`hej')
 215 pushdef(`hej', `def 3.')
 216 dumpdef(`hej')
 217 pushdef(`hej', `def 4.')
 218 dumpdef(`hej')
 219
 220 popdef(`hej')
 221 dumpdef(`hej')
 222 popdef(`hej')
 223 dumpdef(`hej')
 224 popdef(`hej')
 225 dumpdef(`hej')
 226 popdef(`hej')
 227 dumpdef(`hej')
 228
 229 dumpdef(`mac2')
 230 popdef(`mac2')
 231 ]])
 232
 233 AT_CHECK_M4([pushpop.m4], 0, [],
 234 [[hej:  `def 1.'
 235 hej:    `def 2.'
 236 hej:    `def 3.'
 237 hej:    `def 4.'
 238 hej:    `def 3.'
 239 hej:    `def 2.'
 240 hej:    `def 1.'
 241 m4:pushpop.m4:18: Warning: dumpdef: undefined macro `hej'
 242 m4:pushpop.m4:20: Warning: dumpdef: undefined macro `mac2'
 243 m4:pushpop.m4:21: Warning: popdef: undefined macro `mac2'
 244 ]])
 245
 246 AT_CLEANUP
 247
 248
 249
 250 ## ---------------------- ##
 251 ## Tracing Hanoi Towers.  ##
 252 ## ---------------------- ##
 253
 254 AT_SETUP([Tracing Hanoi Towers])
 255
 256 AT_DATA([[trace.m4]],
 257 [[divert(-1)
 258
 259 # move(from, to)
 260 define(`move', `Move one disk from `$1' to `$2'.
 261 ')
 262
 263 # _hanoi (cnt, from, to, aux)
 264 define(`_hanoi', `ifelse(eval(`$1'<=1), 1, `move($2, $3)',
 265 `_hanoi(decr($1), $2, $4, $3)move($2, $3)_hanoi(decr($1), $4, $3, $2)')')
 266
 267 # hanoi (cnt)
 268 define(`hanoi', `_hanoi(`$1', source, destination, auxilliary)')
 269 divert`'dnl
 270
 271 # Debugmode t
 272 debugmode(`t')
 273 hanoi(2)
 274
 275 # Debugmode taeq
 276 debugmode(`taeq')
 277 hanoi(2)
 278
 279 # Debugmode OFF
 280 debugmode
 281 hanoi(2)
 282
 283 # Debugmode ae
 284 debugmode(`ae')
 285 traceon(`move', `_hanoi')
 286 hanoi(2)
 287 ]])
 288
 289 AT_DATA([[expout]],
 290 [[
 291 # Debugmode t
 292
 293 Move one disk from source to auxilliary.
 294 Move one disk from source to destination.
 295 Move one disk from auxilliary to destination.
 296
 297
 298 # Debugmode taeq
 299
 300 Move one disk from source to auxilliary.
 301 Move one disk from source to destination.
 302 Move one disk from auxilliary to destination.
 303
 304
 305 # Debugmode OFF
 306
 307 Move one disk from source to auxilliary.
 308 Move one disk from source to destination.
 309 Move one disk from auxilliary to destination.
 310
 311
 312 # Debugmode ae
 313
 314
 315 Move one disk from source to auxilliary.
 316 Move one disk from source to destination.
 317 Move one disk from auxilliary to destination.
 318
 319 ]])
 320
 321 AT_DATA([[experr]],
 322 [[m4trace: -1- hanoi
 323 m4trace: -1- _hanoi
 324 m4trace: -2- eval
 325 m4trace: -1- ifelse
 326 m4trace: -2- decr
 327 m4trace: -1- _hanoi
 328 m4trace: -2- eval
 329 m4trace: -1- ifelse
 330 m4trace: -1- move
 331 m4trace: -1- move
 332 m4trace: -2- decr
 333 m4trace: -1- _hanoi
 334 m4trace: -2- eval
 335 m4trace: -1- ifelse
 336 m4trace: -1- move
 337 m4trace: -1- debugmode
 338 m4trace: -1- hanoi(`2') -> `_hanoi(`2', source, destination, auxilliary)'
 339 m4trace: -1- _hanoi(`2', `source', `destination', `auxilliary') -> `ifelse(eval(`2'<=1), 1, `move(source, destination)',
 340 `_hanoi(decr(2), source, auxilliary, destination)move(source, destination)_hanoi(decr(2), auxilliary, destination, source)')'
 341 m4trace: -2- eval(`2<=1') -> `0'
 342 m4trace: -1- ifelse(`0', `1', `move(source, destination)', `_hanoi(decr(2), source, auxilliary, destination)move(source, destination)_hanoi(decr(2), auxilliary, destination, source)') -> `_hanoi(decr(2), source, auxilliary, destination)move(source, destination)_hanoi(decr(2), auxilliary, destination, source)'
 343 m4trace: -2- decr(`2') -> `1'
 344 m4trace: -1- _hanoi(`1', `source', `auxilliary', `destination') -> `ifelse(eval(`1'<=1), 1, `move(source, auxilliary)',
 345 `_hanoi(decr(1), source, destination, auxilliary)move(source, auxilliary)_hanoi(decr(1), destination, auxilliary, source)')'
 346 m4trace: -2- eval(`1<=1') -> `1'
 347 m4trace: -1- ifelse(`1', `1', `move(source, auxilliary)', `_hanoi(decr(1), source, destination, auxilliary)move(source, auxilliary)_hanoi(decr(1), destination, auxilliary, source)') -> `move(source, auxilliary)'
 348 m4trace: -1- move(`source', `auxilliary') -> `Move one disk from `source' to `auxilliary'.
 349 '
 350 m4trace: -1- move(`source', `destination') -> `Move one disk from `source' to `destination'.
 351 '
 352 m4trace: -2- decr(`2') -> `1'
 353 m4trace: -1- _hanoi(`1', `auxilliary', `destination', `source') -> `ifelse(eval(`1'<=1), 1, `move(auxilliary, destination)',
 354 `_hanoi(decr(1), auxilliary, source, destination)move(auxilliary, destination)_hanoi(decr(1), source, destination, auxilliary)')'
 355 m4trace: -2- eval(`1<=1') -> `1'
 356 m4trace: -1- ifelse(`1', `1', `move(auxilliary, destination)', `_hanoi(decr(1), auxilliary, source, destination)move(auxilliary, destination)_hanoi(decr(1), source, destination, auxilliary)') -> `move(auxilliary, destination)'
 357 m4trace: -1- move(`auxilliary', `destination') -> `Move one disk from `auxilliary' to `destination'.
 358 '
 359 m4trace: -1- debugmode -> `'
 360 m4trace: -1- _hanoi(2, source, destination, auxilliary) -> ifelse(eval(`2'<=1), 1, `move(source, destination)',
 361 `_hanoi(decr(2), source, auxilliary, destination)move(source, destination)_hanoi(decr(2), auxilliary, destination, source)')
 362 m4trace: -1- _hanoi(1, source, auxilliary, destination) -> ifelse(eval(`1'<=1), 1, `move(source, auxilliary)',
 363 `_hanoi(decr(1), source, destination, auxilliary)move(source, auxilliary)_hanoi(decr(1), destination, auxilliary, source)')
 364 m4trace: -1- move(source, auxilliary) -> Move one disk from `source' to `auxilliary'.
 365
 366 m4trace: -1- move(source, destination) -> Move one disk from `source' to `destination'.
 367
 368 m4trace: -1- _hanoi(1, auxilliary, destination, source) -> ifelse(eval(`1'<=1), 1, `move(auxilliary, destination)',
 369 `_hanoi(decr(1), auxilliary, source, destination)move(auxilliary, destination)_hanoi(decr(1), source, destination, auxilliary)')
 370 m4trace: -1- move(auxilliary, destination) -> Move one disk from `auxilliary' to `destination'.
 371
 372 ]])
 373
 374 AT_CHECK_M4([trace.m4], 0, expout, experr)
 375
 376 AT_CLEANUP
 377
 378
 379
 380 ## ------------------------------- ##
 381 ## Propagation of trace requests.  ##
 382 ## ------------------------------- ##
 383
 384 AT_SETUP([Propagation of traceon])
 385
 386 AT_DATA([[trace2.m4]],
 387 [[traceon(`define')
 388 debugmode(`aeq')
 389
 390 # copy the `define' builtin definition to another symbol
 391 define(`my_define', defn(`define'))
 392
 393 # delete the original
 394 undefine(`define')
 395
 396 # Does it work?
 397 my_define(`foo', `bar')
 398
 399 # Use the new definition to redefine the original symbol
 400 my_define(`define', defn(`my_define'))
 401
 402 # Torture the flag propogation
 403 undefine(`my_define')
 404 define(`my_define', defn(`define'))
 405
 406 # There are now 2 symbols pointing to the same builtin function
 407 my_define(`foo', `bar')
 408 define(`foo', `bar')
 409 ]])
 410
 411 AT_DATA([[expout]],
 412 [[
 413
 414
 415 # copy the `define' builtin definition to another symbol
 416
 417
 418 # delete the original
 419
 420
 421 # Does it work?
 422
 423
 424 # Use the new definition to redefine the original symbol
 425
 426
 427 # Torture the flag propogation
 428
 429
 430
 431 # There are now 2 symbols pointing to the same builtin function
 432
 433
 434 ]])
 435
 436 AT_DATA([[experr]],
 437 [[m4trace: -1- define(`my_define', <define>) -> `'
 438 m4trace: -1- define(`my_define', <define>) -> `'
 439 m4trace: -1- define(`foo', `bar') -> `'
 440 ]])
 441
 442 AT_CHECK_M4([trace2.m4], 0, expout, experr)
 443
 444 AT_CLEANUP
 445
 446
 447
 448 ## ------------------------ ##
 449 ## Propagation of --trace.  ##
 450 ## ------------------------ ##
 451
 452 AT_SETUP([Propagation of --trace])
 453
 454 AT_DATA([[trace3.m4]],
 455 [[# copy the `define' builtin definition to another symbol
 456 define(`my_define', defn(`define'))
 457
 458 # delete the original
 459 undefine(`define')
 460
 461 # Does it work?
 462 my_define(`foo', `bar')
 463
 464 # Use the new definition to redefine the original symbol
 465 my_define(`define', defn(`my_define'))
 466
 467 # Torture the flag propogation
 468 undefine(`my_define')
 469 define(`my_define', defn(`define'))
 470
 471 # There are now 2 symbols pointing to the same builtin function
 472 my_define(`foo', `bar')
 473 define(`foo', `bar')
 474 ]])
 475
 476 AT_DATA([[expout]],
 477 [[# copy the `define' builtin definition to another symbol
 478
 479
 480 # delete the original
 481
 482
 483 # Does it work?
 484
 485
 486 # Use the new definition to redefine the original symbol
 487
 488
 489 # Torture the flag propogation
 490
 491
 492
 493 # There are now 2 symbols pointing to the same builtin function
 494
 495
 496 ]])
 497
 498 AT_DATA([[experr]],
 499 [[m4trace: -1- define(`my_define', <define>) -> `'
 500 m4trace: -1- define(`my_define', <define>) -> `'
 501 m4trace: -1- define(`foo', `bar') -> `'
 502 ]])
 503
 504 AT_CHECK_M4([-t define -daeq trace3.m4], 0, expout, experr)
 505
 506 AT_CLEANUP
 507
 508
 509 ## --------------------- ##
 510 ## Renamesyms collisions ##
 511 ## --------------------- ##
 512
 513 AT_SETUP([Renamesyms collisions])
 514
 515 dnl FIXME - We should gracefully detect rename collisions, rather than
 516 dnl violating the invariants of the symbol table.
 517 AT_XFAIL_IF([:])
 518
 519 AT_DATA([in], [[define(`bar', `1')define(`baz', `2')dnl
 520 renamesyms(`^ba.$', `baa')
 521 ]])
 522
 523 AT_CHECK_M4([in], [0], [[
 524 ]], [ignore])
 525
 526 AT_CLEANUP
 527
 528
 529 ## ----------------- ##
 530 ## Rescanning macros ##
 531 ## ----------------- ##
 532
 533 AT_SETUP([Rescanning macros])
 534
 535 dnl This is a series of tests that used to be included as undocumented tests
 536 dnl in the branch m4.texinfo.  They exercise rescanning issues not stressed
 537 dnl anywhere else in the suite, but which are used by autoconf.
 538 AT_DATA([in], [[define(`x1', `len(`$1'')dnl
 539 define(`y1', ``$1')')dnl
 540 x1(`01234567890123456789')y1(`98765432109876543210')
 541 ]])
 542
 543 AT_CHECK_M4([in], [0], [[40
 544 ]])
 545
 546 AT_DATA([in], [[define(`echo', `$@')dnl
 547 define(`foo', echo(`01234567890123456789')echo(`98765432109876543210'))dnl
 548 foo
 549 ]])
 550
 551 AT_CHECK_M4([in], [0], [[0123456789012345678998765432109876543210
 552 ]])
 553
 554 AT_DATA([in], [[define(`a', `A')define(`echo', `$@')define(`join', `$1$2')dnl
 555 define(`abcdefghijklmnopqrstuvwxyz', `Z')dnl
 556 join(`a', `bcdefghijklmnopqrstuvwxyz')
 557 join(`a', echo(`bcdefghijklmnopqrstuvwxyz'))
 558 ]])
 559
 560 AT_CHECK_M4([in], [0], [[Z
 561 Z
 562 ]])
 563
 564 AT_DATA([in], [[define(`echo', `$@')dnl
 565 echo(echo(`01234567890123456789', `01234567890123456789')
 566 echo(`98765432109876543210', `98765432109876543210'))
 567 len((echo(`01234567890123456789',
 568           `01234567890123456789')echo(`98765432109876543210',
 569                                       `98765432109876543210')))
 570 indir(`echo', indir(`echo', `01234567890123456789',
 571                             `01234567890123456789')
 572 indir(`echo', `98765432109876543210', `98765432109876543210'))
 573 define(`argn', `$#')dnl
 574 define(`echo1', `-$@-')define(`echo2', `,$@,')dnl
 575 echo1(`1', `2', `3') argn(echo1(`1', `2', `3'))
 576 echo2(`1', `2', `3') argn(echo2(`1', `2', `3'))
 577 ]])
 578
 579 AT_CHECK_M4([in], [0], [[01234567890123456789,01234567890123456789
 580 98765432109876543210,98765432109876543210
 581 84
 582 01234567890123456789,01234567890123456789
 583 98765432109876543210,98765432109876543210
 584 -1,2,3- 3
 585 ,1,2,3, 5
 586 ]])
 587
 588 AT_CLEANUP