source/m4/kpse-pkgs.m4

   1 # Private macros for the TeX Live (TL) tree.
   2 # Copyright (C) 2009-2015 Peter Breitenlohner <tex-live@tug.org>
   3 #
   4 # This file is free software; the copyright holder
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 ## ------------------------------ ##
   9 ## Define lists of sub-packages.  ##
  10 ## ------------------------------ ##
  11
  12 # Hopefully these lists are defined here and nowhere else.
  13 # Note: directories in these lists need not exist.
  14
  15 # KPSE_LIBS_PKGS()
  16 # ----------------
  17 # Define two lists of library sub-packages:
  18 #   generic libraries, i.e., subdirs 'libs/*', that can be used by
  19 #   utility and TeXk sub-packages
  20 # and
  21 #   TeX specific libraries, i.e., subdirs 'texk/*', that can only
  22 #   be used by TeXk sub-packages and can't use generic libraries
  23 # Each library must precede required other libraries (if any).
  24 AC_DEFUN([KPSE_LIBS_PKGS], [dnl
  25 m4_define([kpse_libs_pkgs], [dnl
  26 harfbuzz
  27 icu
  28 teckit
  29 graphite2
  30 zziplib
  31 xpdf
  32 poppler
  33 mpfr
  34 gmp
  35 cairo
  36 pixman
  37 potrace
  38 gd
  39 freetype2
  40 libpng
  41 libpaper
  42 luajit
  43 lua52
  44 zlib
  45 ])[]dnl
  46 m4_define([kpse_texlibs_pkgs], [dnl
  47 ptexenc
  48 kpathsea
  49 ])]) # KPSE_LIBS_PKGS
  50
  51 # KPSE_ALL_SYSTEM_FLAGS()
  52 # -----------------------
  53 # Generate flags for all potential system libraries available,
  54 # only used at top-level.
  55 AC_DEFUN([KPSE_ALL_SYSTEM_FLAGS], [dnl
  56 AC_REQUIRE([KPSE_LIBS_PREPARE])[]dnl
  57 AC_REQUIRE([KPSE_KPATHSEA_SYSTEM_FLAGS])[]dnl
  58 AC_REQUIRE([KPSE_PTEXENC_SYSTEM_FLAGS])[]dnl
  59 AC_REQUIRE([KPSE_ZLIB_SYSTEM_FLAGS])[]dnl
  60 AC_REQUIRE([KPSE_LIBPAPER_SYSTEM_FLAGS])[]dnl
  61 AC_REQUIRE([KPSE_LIBPNG_SYSTEM_FLAGS])[]dnl
  62 AC_REQUIRE([KPSE_FREETYPE2_SYSTEM_FLAGS])[]dnl
  63 AC_REQUIRE([KPSE_GD_SYSTEM_FLAGS])[]dnl
  64 AC_REQUIRE([KPSE_POTRACE_SYSTEM_FLAGS])[]dnl
  65 AC_REQUIRE([KPSE_PIXMAN_SYSTEM_FLAGS])[]dnl
  66 AC_REQUIRE([KPSE_CAIRO_SYSTEM_FLAGS])[]dnl
  67 AC_REQUIRE([KPSE_GMP_SYSTEM_FLAGS])[]dnl
  68 AC_REQUIRE([KPSE_MPFR_SYSTEM_FLAGS])[]dnl
  69 AC_REQUIRE([KPSE_POPPLER_SYSTEM_FLAGS])[]dnl
  70 AC_REQUIRE([KPSE_XPDF_SYSTEM_FLAGS])[]dnl
  71 AC_REQUIRE([KPSE_ZZIPLIB_SYSTEM_FLAGS])[]dnl
  72 AC_REQUIRE([KPSE_GRAPHITE2_SYSTEM_FLAGS])[]dnl
  73 AC_REQUIRE([KPSE_TECKIT_SYSTEM_FLAGS])[]dnl
  74 AC_REQUIRE([KPSE_ICU_SYSTEM_FLAGS])[]dnl
  75 AC_REQUIRE([KPSE_HARFBUZZ_SYSTEM_FLAGS])[]dnl
  76 ]) # KPSE_ALL_SYSTEM_FLAGS
  77
  78 # KPSE_UTILS_PKGS()
  79 # -----------------
  80 # Define the list of utility sub-packages, i.e., subdirs 'utils/*'.
  81 AC_DEFUN([KPSE_UTILS_PKGS], [dnl
  82 m4_define([kpse_utils_pkgs], [dnl
  83 devnag
  84 lacheck
  85 m-tx
  86 pmx
  87 ps2eps
  88 t1utils
  89 texdoctk
  90 tpic2pdftex
  91 vlna
  92 xindy
  93 xpdfopen
  94 ])]) # KPSE_UTILS_PKGS
  95
  96 # KPSE_TEXK_PKGS()
  97 # ----------------
  98 # Define the list of TeXk sub-packages, i.e., subdirs 'texk/*',
  99 # excluding 'texk/kpathsea'.
 100 AC_DEFUN([KPSE_TEXK_PKGS], [dnl
 101 m4_define([kpse_texk_pkgs], [dnl
 102 web2c
 103 afm2pl
 104 bibtex-x
 105 chktex
 106 cjkutils
 107 detex
 108 dtl
 109 dvi2tty
 110 dvidvi
 111 dviljk
 112 dvipdfm-x
 113 dvipng
 114 dvipos
 115 dvipsk
 116 dvisvgm
 117 gregorio
 118 gsftopk
 119 lcdf-typetools
 120 makeindexk
 121 makejvf
 122 mendexk
 123 musixtnt
 124 ps2pk
 125 psutils
 126 seetexk
 127 tex4htk
 128 ttf2pk2
 129 ttfdump
 130 upmendex
 131 xdvik
 132 texlive
 133 ])]) # KPSE_TEXK_PKGS
 134
 135
 136
 137 ## ------------------------------- ##
 138 ##  Loop over one of these lists.  ##
 139 ## ------------------------------- ##
 140
 141 # KPSE_FOR_PKGS(LIST, ACTION)
 142 # ---------------------------
 143 # Run the shell code ACTION for each element Kpse_Pkg in kpse_LIST_pkgs,
 144 # with Kpse_pkg a sanitized version of Kpse_Pkg for shell variables and
 145 # Kpse_PKG a sanitized (upper case) version for make variables.
 146 AC_DEFUN([KPSE_FOR_PKGS],
 147 [AC_REQUIRE([KPSE_LIBS_PKGS])AC_REQUIRE([KPSE_UTILS_PKGS])AC_REQUIRE([KPSE_TEXK_PKGS])[]dnl
 148 AC_FOREACH([Kpse_Pkg], kpse_$1_pkgs,
 149 [m4_pushdef([Kpse_pkg], AS_TR_SH(Kpse_Pkg))[]dnl
 150 m4_pushdef([Kpse_PKG], AS_TR_CPP(Kpse_Pkg))[]dnl
 151 $2[]dnl
 152 m4_popdef([Kpse_pkg])m4_popdef([Kpse_PKG])[]dnl
 153 ])]) # KPSE_FOR_PKGS