source/m4/kpse-macos-framework.m4

   1 # Public macros for the TeX Live (TL) tree.
   2 # Copyright (C) 2005 - 2008 Jonathan Kew <...@...>
   3 # Copyright (C) 2009 Peter Breitenlohner <tex-live@tug.org>
   4 #
   5 # This file is free software; the copyright holders
   6 # give unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # serial 0
  10
  11 # KPSE_CHECK_FRAMEWORK(FRAMEWORK, BODY)
  12 # -------------------------------------
  13 # Check for mthe Mac OS X framework FRAMEWORK (using BODY) and if found,
  14 # set kpse_cv_have_FRAMEWORK to yes and define HAVE_FRAMEWORK.
  15 AC_DEFUN([KPSE_CHECK_FRAMEWORK],
  16 [AC_CACHE_CHECK([for Mac OS X $1 framework],
  17                 [kpse_cv_have_$1],
  18                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$1/$1.h>]],
  19                                                     [[$2]])],
  20                                    [kpse_cv_have_$1=yes],
  21                                    [kpse_cv_have_$1=no])])
  22 AS_IF([test "x$kpse_cv_have_$1" = xyes],
  23       [AC_DEFINE([HAVE_]AS_TR_CPP([$1]), 1,
  24                  [Define to 1 if you have the Mac OS X $1 framework.])])
  25 ]) # KPSE_CHECK_FRAMEWORK