source/m4/kpse-largefile.m4

   1 # Public macros for the TeX Live (TL) tree.
   2 # Copyright (C) 2013 Peter Breitenlohner <tex-live@tug.org>
   3 #
   4 # This file is free software; the copyright holder
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # KPSE_LARGEFILE(MAKE-VAR,[EXTRA-DEFINE])
   9 # ---------------------------------------
  10 # Append -D's required for largefile support to MAKE-VAR.
  11 AC_DEFUN([KPSE_LARGEFILE], [dnl
  12 AC_REQUIRE([AC_SYS_LARGEFILE])[]dnl
  13 AC_REQUIRE([AC_FUNC_FSEEKO])[]dnl
  14 if test "x$enable_largefile" != xno; then
  15   AS_CASE([$ac_cv_sys_file_offset_bits],
  16           [no], [],
  17           [unknown], [AS_CASE([$ac_cv_sys_large_files],
  18                               [no | unknown], [],
  19                               [$1="$$1 -D_LARGE_FILES"])],
  20           [$1="$$1 m4_ifval([$2], [-D$2 ])-D_FILE_OFFSET_BITS=64"])
  21 fi
  22 AS_CASE([$ac_cv_sys_largefile_source],
  23         [no | unknown], [],
  24         [$1="$$1 -D_LARGEFILE_SOURCE"])
  25 ]) # KPSE_LARGEFILE