| blob | 9af0bbf5d5c1c794d31bffe729f428f891803697 |
1 dnl ______ /usr/share/aclocal/guidod-cvs/ax_create_pkgconfig_info.m4 ______
2 dnl @synopsis AX_CREATE_PKGCONFIG_INFO [(outputfile, [requires [,libs [,summary [,cflags [, ldflags]]]]])]
3 dnl
4 dnl defaults:
5 dnl
6 dnl $1 = $PACKAGE_NAME.pc
7 dnl $2 = (empty)
8 dnl $3 = $PACKAGE_LIBS $LIBS (as set at that point in configure.ac)
9 dnl $4 = $PACKAGE_SUMMARY (or $1 Library)
10 dnl $5 = $CPPFLAGS $PACKAGE_CFLAGS (as set at the point in configure.ac)
11 dnl $6 = $LDFLAGS $PACKAGE_LDFLAGS (as set at the point in configure.ac)
12 dnl
13 dnl PACKAGE_NAME defaults to $PACKAGE if not set.
14 dnl PACKAGE_LIBS defaults to -l$PACKAGE_NAME if not set.
15 dnl
16 dnl the resulting file is called $PACKAGE.pc.in / $PACKAGE.pc
17 dnl
18 dnl You will find this macro most useful in conjunction with
19 dnl ax_spec_defaults that can read good initializers from the .spec
20 dnl file. In consequencd, most of the generatable installable stuff can
21 dnl be made from information being updated in a single place for the
22 dnl whole project.
23 dnl
24 dnl @category InstalledPackages
25 dnl @author Sven Verdoolaege <skimo*liacs.nl>
26 dnl @author Guido U. Draheim <guidod@gmx.de>
27 dnl @version 2003-10-19
28 dnl @license GPLWithACException
30 AC_DEFUN([AX_CREATE_PKGCONFIG_INFO],[dnl
31 AS_VAR_PUSHDEF([PKGCONFIG_suffix],[ax_create_pkgconfig_suffix])dnl
32 AS_VAR_PUSHDEF([PKGCONFIG_libdir],[ax_create_pkgconfig_libdir])dnl
33 AS_VAR_PUSHDEF([PKGCONFIG_libfile],[ax_create_pkgconfig_libfile])dnl
34 AS_VAR_PUSHDEF([PKGCONFIG_libname],[ax_create_pkgconfig_libname])dnl
35 AS_VAR_PUSHDEF([PKGCONFIG_version],[ax_create_pkgconfig_version])dnl
36 AS_VAR_PUSHDEF([PKGCONFIG_description],[ax_create_pkgconfig_description])dnl
37 AS_VAR_PUSHDEF([PKGCONFIG_requires],[ax_create_pkgconfig_requires])dnl
38 AS_VAR_PUSHDEF([PKGCONFIG_pkglibs],[ax_create_pkgconfig_pkglibs])dnl
39 AS_VAR_PUSHDEF([PKGCONFIG_libs],[ax_create_pkgconfig_libs])dnl
40 AS_VAR_PUSHDEF([PKGCONFIG_ldflags],[ax_create_pkgconfig_ldflags])dnl
41 AS_VAR_PUSHDEF([PKGCONFIG_cppflags],[ax_create_pkgconfig_cppflags])dnl
42 AS_VAR_PUSHDEF([PKGCONFIG_generate],[ax_create_pkgconfig_generate])dnl
43 AS_VAR_PUSHDEF([PKGCONFIG_src_libdir],[ax_create_pkgconfig_src_libdir])dnl
44 AS_VAR_PUSHDEF([PKGCONFIG_src_headers],[ax_create_pkgconfig_src_headers])dnl
46 # we need the expanded forms...
47 test "x$prefix" = xNONE && prefix=$ac_default_prefix
48 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
50 AC_MSG_CHECKING(our pkgconfig libname)
51 test ".$PKGCONFIG_libname" != "." || \
52 PKGCONFIG_libname="ifelse($1,,${PACKAGE_NAME},`basename $1 .pc`)"
53 test ".$PKGCONFIG_libname" != "." || \
54 PKGCONFIG_libname="$PACKAGE"
55 PKGCONFIG_libname=`eval echo "$PKGCONFIG_libname"`
56 PKGCONFIG_libname=`eval echo "$PKGCONFIG_libname"`
57 AC_MSG_RESULT($PKGCONFIG_libname)
59 AC_MSG_CHECKING(our pkgconfig version)
60 test ".$PKGCONFIG_version" != "." || \
61 PKGCONFIG_version="${PACKAGE_VERSION}"
62 test ".$PKGCONFIG_version" != "." || \
63 PKGCONFIG_version="$VERSION"
64 PKGCONFIG_version=`eval echo "$PKGCONFIG_version"`
65 PKGCONFIG_version=`eval echo "$PKGCONFIG_version"`
66 AC_MSG_RESULT($PKGCONFIG_version)
68 AC_MSG_CHECKING(our pkgconfig_libdir)
69 test ".$pkgconfig_libdir" = "." && \
70 pkgconfig_libdir='${libdir}/pkgconfig'
71 PKGCONFIG_libdir=`eval echo "$pkgconfig_libdir"`
72 PKGCONFIG_libdir=`eval echo "$PKGCONFIG_libdir"`
73 PKGCONFIG_libdir=`eval echo "$PKGCONFIG_libdir"`
74 AC_MSG_RESULT($pkgconfig_libdir)
75 test "$pkgconfig_libdir" != "$PKGCONFIG_libdir" && (
76 AC_MSG_RESULT(expanded our pkgconfig_libdir... $PKGCONFIG_libdir))
77 AC_SUBST([pkgconfig_libdir])
79 AC_MSG_CHECKING(our pkgconfig_libfile)
80 test ".$pkgconfig_libfile" != "." || \
81 pkgconfig_libfile="ifelse($1,,$PKGCONFIG_libname.pc,`basename $1`)"
82 PKGCONFIG_libfile=`eval echo "$pkgconfig_libfile"`
83 PKGCONFIG_libfile=`eval echo "$PKGCONFIG_libfile"`
84 AC_MSG_RESULT($pkgconfig_libfile)
85 test "$pkgconfig_libfile" != "$PKGCONFIG_libfile" && (
86 AC_MSG_RESULT(expanded our pkgconfig_libfile... $PKGCONFIG_libfile))
87 AC_SUBST([pkgconfig_libfile])
89 AC_MSG_CHECKING(our package / suffix)
90 PKGCONFIG_suffix="$program_suffix"
91 test ".$PKGCONFIG_suffix" != .NONE || PKGCONFIG_suffix=""
92 AC_MSG_RESULT(${PACKAGE_NAME} / ${PKGCONFIG_suffix})
94 AC_MSG_CHECKING(our pkgconfig description)
95 PKGCONFIG_description="ifelse($4,,$PACKAGE_SUMMARY,$4)"
96 test ".$PKGCONFIG_description" != "." || \
97 PKGCONFIG_description="$PKGCONFIG_libname Library"
98 PKGCONFIG_description=`eval echo "$PKGCONFIG_description"`
99 PKGCONFIG_description=`eval echo "$PKGCONFIG_description"`
100 AC_MSG_RESULT($PKGCONFIG_description)
102 AC_MSG_CHECKING(our pkgconfig requires)
103 PKGCONFIG_requires="ifelse($2,,$PACKAGE_REQUIRES,$2)"
104 PKGCONFIG_requires=`eval echo "$PKGCONFIG_requires"`
105 PKGCONFIG_requires=`eval echo "$PKGCONFIG_requires"`
106 AC_MSG_RESULT($PKGCONFIG_requires)
108 AC_MSG_CHECKING(our pkgconfig ext libs)
109 PKGCONFIG_pkglibs="$PACKAGE_LIBS"
110 test ".$PKGCONFIG_pkglibs" != "." || PKGCONFIG_pkglibs="-l$PKGCONFIG_libname"
111 PKGCONFIG_libs="ifelse($3,,$PKGCONFIG_pkglibs $LIBS,$3)"
112 PKGCONFIG_libs=`eval echo "$PKGCONFIG_libs"`
113 PKGCONFIG_libs=`eval echo "$PKGCONFIG_libs"`
114 AC_MSG_RESULT($PKGCONFIG_libs)
116 AC_MSG_CHECKING(our pkgconfig cppflags)
117 PKGCONFIG_cppflags="ifelse($5,,$CPPFLAGS $PACKAGE_CFLAGS,$5)"
118 PKGCONFIG_cppflags=`eval echo "$PKGCONFIG_cppflags"`
119 PKGCONFIG_cppflags=`eval echo "$PKGCONFIG_cppflags"`
120 AC_MSG_RESULT($PKGCONFIG_cppflags)
122 AC_MSG_CHECKING(our pkgconfig ldflags)
123 PKGCONFIG_ldflags="ifelse($6,,$LDFLAGS $PACKAGE_LDFLAGS,$5)"
124 PKGCONFIG_ldflags=`eval echo "$PKGCONFIG_ldflags"`
125 PKGCONFIG_ldflags=`eval echo "$PKGCONFIG_ldflags"`
126 AC_MSG_RESULT($PKGCONFIG_ldflags)
128 test ".$PKGCONFIG_generate" != "." || \
129 PKGCONFIG_generate="ifelse($1,,$PKGCONFIG_libname.pc,$1)"
130 PKGCONFIG_generate=`eval echo "$PKGCONFIG_generate"`
131 PKGCONFIG_generate=`eval echo "$PKGCONFIG_generate"`
132 test "$pkgconfig_libfile" != "$PKGCONFIG_generate" && (
133 AC_MSG_RESULT(generate the pkgconfig later... $PKGCONFIG_generate))
135 if test ".$PKGCONFIG_src_libdir" = "." ; then
136 PKGCONFIG_src_libdir=`pwd`
137 PKGCONFIG_src_libdir=`AS_DIRNAME("$PKGCONFIG_src_libdir/$PKGCONFIG_generate")`
138 test ! -d $PKGCONFIG_src_libdir/src || \
139 PKGCONFIG_src_libdir="$PKGCONFIG_src_libdir/src"
140 case ".$objdir" in
141 *libs) PKGCONFIG_src_libdir="$PKGCONFIG_src_libdir/$objdir" ;; esac
142 AC_MSG_RESULT(noninstalled pkgconfig -L $PKGCONFIG_src_libdir)
143 fi
145 if test ".$PKGCONFIG_src_headers" = "." ; then
146 PKGCONFIG_src_headers=`pwd`
147 v="$ac_top_srcdir" ;
148 test ".$v" != "." || v="$ax_spec_dir"
149 test ".$v" != "." || v="$srcdir"
150 case "$v" in /*) PKGCONFIG_src_headers="" ;; esac
151 PKGCONFIG_src_headers=`AS_DIRNAME("$PKGCONFIG_src_headers/$v/x")`
152 test ! -d $PKGCONFIG_src_headers/incl[]ude || \
153 PKGCONFIG_src_headers="$PKGCONFIG_src_headers/incl[]ude"
154 AC_MSG_RESULT(noninstalled pkgconfig -I $PKGCONFIG_src_headers)
155 fi
158 dnl AC_CONFIG_COMMANDS crap disallows to use $PKGCONFIG_libfile here...
159 AC_CONFIG_COMMANDS([$ax_create_pkgconfig_generate],[
160 pkgconfig_generate="$ax_create_pkgconfig_generate"
161 if test ! -f "$pkgconfig_generate.in"
162 then generate="true"
163 elif grep ' generated by configure ' $pkgconfig_generate.in >/dev/null
164 then generate="true"
165 else generate="false";
166 fi
167 if $generate ; then
168 AC_MSG_NOTICE(creating $pkgconfig_generate.in)
169 cat > $pkgconfig_generate.in <<AXEOF
170 # generated by configure / remove this line to disable regeneration
171 prefix=@prefix@
172 exec_prefix=@exec_prefix@
173 bindir=@bindir@
174 libdir=@libdir@
175 datarootdir=@datarootdir@
176 datadir=@datadir@
177 sysconfdir=@sysconfdir@
178 includedir=@includedir@
179 package=@PACKAGE@
180 suffix=@suffix@
182 Name: @PACKAGE_NAME@
183 Description: @PACKAGE_DESCRIPTION@
184 Version: @PACKAGE_VERSION@
185 Requires: @PACKAGE_REQUIRES@
186 Libs: -L\${libdir} @LDFLAGS@ @LIBS@
187 Cflags: -I\${includedir} @CPPFLAGS@
188 AXEOF
189 fi # DONE generate $pkgconfig_generate.in
190 AC_MSG_NOTICE(creating $pkgconfig_generate)
191 cat >conftest.sed <<AXEOF
192 s|@prefix@|${pkgconfig_prefix}|
193 s|@exec_prefix@|${pkgconfig_execprefix}|
194 s|@bindir@|${pkgconfig_bindir}|
195 s|@libdir@|${pkgconfig_libdir}|
196 s|@datarootdir@|${pkgconfig_datarootdir}|
197 s|@datadir@|${pkgconfig_datadir}|
198 s|@sysconfdir@|${pkgconfig_sysconfdir}|
199 s|@includedir@|${pkgconfig_includedir}|
200 s|@suffix@|${pkgconfig_suffix}|
201 s|@PACKAGE@|${pkgconfig_package}|
202 s|@PACKAGE_NAME@|${pkgconfig_libname}|
203 s|@PACKAGE_DESCRIPTION@|${pkgconfig_description}|
204 s|@PACKAGE_VERSION@|${pkgconfig_version}|
205 s|@PACKAGE_REQUIRES@|${pkgconfig_requires}|
206 s|@LIBS@|${pkgconfig_libs}|
207 s|@LDFLAGS@|${pkgconfig_ldflags}|
208 s|@CPPFLAGS@|${pkgconfig_cppflags}|
209 AXEOF
210 sed -f conftest.sed $pkgconfig_generate.in > $pkgconfig_generate
211 if test ! -s $pkgconfig_generate ; then
212 AC_MSG_ERROR([$pkgconfig_generate is empty])
213 fi ; rm conftest.sed # DONE generate $pkgconfig_generate
214 pkgconfig_uninstalled=`echo $pkgconfig_generate |sed 's/.pc$/-uninstalled.pc/'`
215 AC_MSG_NOTICE(creating $pkgconfig_uninstalled)
216 cat >conftest.sed <<AXEOF
217 s|@prefix@|${pkgconfig_prefix}|
218 s|@exec_prefix@|${pkgconfig_execprefix}|
219 s|@bindir@|${pkgconfig_bindir}|
220 s|@libdir@|${pkgconfig_src_libdir}|
221 s|@datarootdir@|${pkgconfig_datarootdir}|
222 s|@datadir@|${pkgconfig_datadir}|
223 s|@sysconfdir@|${pkgconfig_sysconfdir}|
224 s|@includedir@|${pkgconfig_src_headers}|
225 s|@suffix@|${pkgconfig_suffix}|
226 s|@PACKAGE@|${pkgconfig_package}|
227 s|@PACKAGE_NAME@|${pkgconfig_libname}|
228 s|@PACKAGE_DESCRIPTION@|${pkgconfig_description}|
229 s|@PACKAGE_VERSION@|${pkgconfig_version}|
230 s|@PACKAGE_REQUIRES@|${pkgconfig_requires}|
231 s|@LIBS@|${pkgconfig_libs}|
232 s|@LDFLAGS@|${pkgconfig_ldflags}|
233 s|@CPPFLAGS@|${pkgconfig_cppflags}|
234 AXEOF
235 sed -f conftest.sed $pkgconfig_generate.in > $pkgconfig_uninstalled
236 if test ! -s $pkgconfig_uninstalled ; then
237 AC_MSG_ERROR([$pkgconfig_uninstalled is empty])
238 fi ; rm conftest.sed # DONE generate $pkgconfig_uninstalled
239 pkgconfig_requires_add=`echo ${pkgconfig_requires}`
240 if test ".$pkgconfig_requires_add" != "." ; then
241 pkgconfig_requires_add="pkg-config $pkgconfig_requires_add"
242 else pkgconfig_requires_add=":" ; fi
243 pkgconfig_uninstalled=`echo $pkgconfig_generate |sed 's/.pc$/-uninstalled.sh/'`
244 AC_MSG_NOTICE(creating $pkgconfig_uninstalled)
245 cat >conftest.sed <<AXEOF
246 s|@prefix@|\"${pkgconfig_prefix}\"|
247 s|@exec_prefix@|\"${pkgconfig_execprefix}\"|
248 s|@bindir@|\"${pkgconfig_bindir}\"|
249 s|@libdir@|\"${pkgconfig_src_libdir}\"|
250 s|@datarootdir@|\"${pkgconfig_datarootdir}\"|
251 s|@datadir@|\"${pkgconfig_datadir}\"|
252 s|@sysconfdir@|\"${pkgconfig_sysconfdir}\"|
253 s|@includedir@|\"${pkgconfig_src_headers}\"|
254 s|@suffix@|\"${pkgconfig_suffix}\"|
255 s|@PACKAGE@|\"${pkgconfig_package}\"|
256 s|@PACKAGE_NAME@|\"${pkgconfig_libname}\"|
257 s|@PACKAGE_DESCRIPTION@|\"${pkgconfig_description}\"|
258 s|@PACKAGE_VERSION@|\"${pkgconfig_version}\"|
259 s|@PACKAGE_REQUIRES@|\"${pkgconfig_requires}\"|
260 s|@LIBS@|\"${pkgconfig_libs}\"|
261 s|@LDFLAGS@|\"${pkgconfig_ldflags}\"|
262 s|@CPPFLAGS@|\"${pkgconfig_cppflags}\"|
263 s>Name:>for option\\; do case \"\$option\" in --list-all|--name) echo >
264 s>Description: *>\\;\\; --help) pkg-config --help \\; echo Buildscript Of >
265 s>Version: *>\\;\\; --modversion|--version) echo >
266 s>Requires:>\\;\\; --requires) echo $pkgconfig_requires_add>
267 s>Libs: *>\\;\\; --libs) echo >
268 s>Cflags: *>\\;\\; --cflags) echo >
269 /--libs)/a\\
270 $pkgconfig_requires_add
271 /--cflags)/a\\
272 $pkgconfig_requires_add\\
273 ;; --variable=*) eval echo '\$'\`echo \$option | sed -e 's/.*=//'\`\\
274 ;; --uninstalled) exit 0 \\
275 ;; *) ;; esac done
276 AXEOF
277 sed -f conftest.sed $pkgconfig_generate.in > $pkgconfig_uninstalled
278 if test ! -s $pkgconfig_uninstalled ; then
279 AC_MSG_ERROR([$pkgconfig_uninstalled is empty])
280 fi ; rm conftest.sed # DONE generate $pkgconfig_uninstalled
281 ],[
282 dnl AC_CONFIG_COMMANDS crap, the AS_PUSHVAR defines are invalid here...
283 ax_create_pkgconfig_generate="$ax_create_pkgconfig_generate"
284 pkgconfig_prefix='$prefix'
285 pkgconfig_execprefix='$exec_prefix'
286 pkgconfig_bindir='$bindir'
287 pkgconfig_libdir='$libdir'
288 pkgconfig_includedir='$includedir'
289 pkgconfig_datarootdir='$datarootdir'
290 pkgconfig_datadir='$datadir'
291 pkgconfig_sysconfdir='$sysconfdir'
292 pkgconfig_suffix='$ax_create_pkgconfig_suffix'
293 pkgconfig_package='$PACKAGE_NAME'
294 pkgconfig_libname='$ax_create_pkgconfig_libname'
295 pkgconfig_description='$ax_create_pkgconfig_description'
296 pkgconfig_version='$ax_create_pkgconfig_version'
297 pkgconfig_requires='$ax_create_pkgconfig_requires'
298 pkgconfig_libs='$ax_create_pkgconfig_libs'
299 pkgconfig_ldflags='$ax_create_pkgconfig_ldflags'
300 pkgconfig_cppflags='$ax_create_pkgconfig_cppflags'
301 pkgconfig_src_libdir='$ax_create_pkgconfig_src_libdir'
302 pkgconfig_src_headers='$ax_create_pkgconfig_src_headers'
303 ])dnl
304 AS_VAR_POPDEF([PKGCONFIG_suffix])dnl
305 AS_VAR_POPDEF([PKGCONFIG_libdir])dnl
306 AS_VAR_POPDEF([PKGCONFIG_libfile])dnl
307 AS_VAR_POPDEF([PKGCONFIG_libname])dnl
308 AS_VAR_POPDEF([PKGCONFIG_version])dnl
309 AS_VAR_POPDEF([PKGCONFIG_description])dnl
310 AS_VAR_POPDEF([PKGCONFIG_requires])dnl
311 AS_VAR_POPDEF([PKGCONFIG_pkglibs])dnl
312 AS_VAR_POPDEF([PKGCONFIG_libs])dnl
313 AS_VAR_POPDEF([PKGCONFIG_ldflags])dnl
314 AS_VAR_POPDEF([PKGCONFIG_cppflags])dnl
315 AS_VAR_POPDEF([PKGCONFIG_generate])dnl
316 AS_VAR_POPDEF([PKGCONFIG_src_libdir])dnl
317 AS_VAR_POPDEF([PKGCONFIG_src_headers])dnl
318 ])