source/libs/zziplib/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2010-2014 Peter Breitenlohner <tex-live@tug.org>
   4 dnl
   5 dnl   based on zziplib-0.13.58:
   6 dnl     Copyright (C) 2009 Guido Draheim <guido@gmx.de> for ZZipLib.SF.net
   7 dnl
   8 dnl   This file is free software; the copyright holder
   9 dnl   gives unlimited permission to copy and/or distribute it,
  10 dnl   with or without modifications, as long as this notice is preserved.
  11 dnl
  12 m4_include([version.ac])[] dnl define zziplib_version
  13 AC_INIT([zziplib (TeX Live)], zziplib_version, [tex-k@tug.org])
  14 AC_PREREQ([2.65])
  15 AC_CONFIG_SRCDIR([zziplib-]zziplib_version[/zziplib.spec])
  16 AC_CONFIG_AUX_DIR([../../build-aux])
  17 AC_CONFIG_MACRO_DIRS([../../m4 m4])
  18
  19 KPSE_BASIC([zziplib])
  20
  21 AC_CANONICAL_HOST
  22
  23 # Checks for programs.
  24 AC_PROG_CC
  25 AC_PROG_RANLIB
  26 AC_PROG_LN_S
  27
  28 KPSE_COMPILER_VISIBILITY
  29
  30 # Checks for header files.
  31 AC_HEADER_STDC
  32 AC_HEADER_DIRENT
  33 AC_CHECK_HEADERS([stdint.h unistd.h windows.h sys/int_types.h])
  34 AC_CHECK_HEADERS([winnt.h winbase.h], , , [#include <windows.h>])
  35 AC_CHECK_HEADERS([sys/types.h sys/mman.h sys/stat.h sys/param.h]) dnl posix'ish
  36 AC_CHECK_HEADERS([io.h direct.h byteswap.h])
  37 AC_CHECK_HEADERS([fnmatch.h])
  38
  39 # ---------------------------------------------------------------
  40 AC_MSG_CHECKING([whether can use mmap for file scanning])
  41 enable_mmap='no (just a bit slower)'
  42 test "x$ac_cv_header_winbase_h" = xyes && enable_mmap="yes, winbase.h"
  43 test "x$ac_cv_header_sys_mman_h" = xyes && enable_mmap="yes, sys/mman.h"
  44 AS_CASE([$enable_mmap],
  45         [yes*], [ZZIPLIB_DEFINES='-D_USE_MMAP'])
  46 AC_MSG_RESULT([$enable_mmap])
  47 AC_SUBST([ZZIPLIB_DEFINES])
  48
  49 AC_SYS_LARGEFILE_SENSITIVE
  50 AC_FUNC_FSEEKO
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_INLINE
  54 AC_C_CONST
  55 AC_C_RESTRICT
  56 AC_TYPE_SIZE_T
  57 AC_CHECK_TYPE([ssize_t], [int])
  58 AC_CHECK_TYPE([off64_t], [_zzip_off_t])
  59 AC_CHECK_TYPE([__int64], [long long])
  60 AC_CHECK_SIZEOF([short])
  61 AC_CHECK_SIZEOF([int])
  62 AC_CHECK_SIZEOF([long])
  63 AC_C_BIGENDIAN
  64 ZZIPLIB_CHECK_ALIGNED_ACCESS
  65
  66 # Checks for library functions.
  67 AC_CHECK_FUNCS([strcasecmp strndup])
  68
  69 KPSE_ZLIB_FLAGS
  70
  71 AM_CONDITIONAL([build], [test "x$enable_build" != xno])
  72
  73 if test "x$enable_build" != xno || test -f config.force; then
  74
  75 KPSE_ADD_FLAGS([zlib])
  76 AC_CHECK_HEADERS([zlib.h])
  77 AC_CHECK_FUNC([zlibVersion], , [AC_ERROR([zlib not found])])
  78 KPSE_RESTORE_FLAGS
  79
  80 echo timestamp >config.force
  81 fi
  82
  83 AC_SUBST([ZZIPLIB_TREE], [zziplib-]zziplib_version)
  84
  85 # -----------------------------------------------------------------------
  86 AC_MSG_RESULT([creating include/zzip/_msvc.in via zzip/_msvc.sed of config.h.in])
  87 test -d include || mkdir include
  88 sed -f $srcdir/$ZZIPLIB_TREE/zzip/_msvc.sed $srcdir/config.h.in >include/_msvc.in
  89 AC_CONFIG_HEADERS([config.h])
  90 AX_PREFIX_CONFIG_H([include/zzip/_config.h],[zzip],[config.h])
  91 AX_PREFIX_CONFIG_H([include/zzip/_msvc.h],[zzip],[include/_msvc.in])
  92
  93 AC_CONFIG_FILES([Makefile include/zzip/Makefile])
  94
  95 AC_OUTPUT