source/libs/luajit/m4/lj-system.m4

   1 # Autoconf macros for luajit.
   2 # Copyright (C) 2014, 2015 Peter Breitenlohner <tex-live@tug.org>
   3 #
   4 # This file is free software; the copyright holder
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # _LJ_ARCH
   9 # --------
  10 # Internal subroutine.
  11 # Preprocess <lj_arch.h> and extract system characteristics.
  12 m4_define([_LJ_ARCH], [dnl
  13 rm -f dynasm_flags native_flags
  14 AC_MSG_CHECKING([for architecture])
  15 cp conftest.i system_flags
  16 LUAJIT_CFLAGS='-fomit-frame-pointer'
  17 AS_IF([grep 'LJ_TARGET_X64 ' conftest.i >/dev/null 2>&1],
  18         [LJARCH=x64],
  19       [grep 'LJ_TARGET_X86 ' conftest.i >/dev/null 2>&1],
  20         [LJARCH=x86
  21          LUAJIT_CFLAGS="$LUAJIT_CFLAGS -march=i686 -msse -msse2 -mfpmath=sse"],
  22       [grep 'LJ_TARGET_ARM ' conftest.i >/dev/null 2>&1],
  23         [LJARCH=arm],
  24       [grep 'LJ_TARGET_ARM64 ' conftest.i >/dev/null 2>&1],
  25         [LJARCH=arm64
  26          AS_IF([test "x$LJHOST" = xiOS],
  27                [LUAJIT_CFLAGS='-fno-omit-frame-pointer'])],
  28       [grep 'LJ_TARGET_PPC ' conftest.i >/dev/null 2>&1],
  29         [LJARCH=ppc
  30          AS_IF([grep 'LJ_LE 1' conftest.i >/dev/null 2>&1],
  31                  [echo '-DLJ_ARCH_ENDIAN=LUAJIT_LE' >>native_flags],
  32                  [echo '-DLJ_ARCH_ENDIAN=LUAJIT_BE' >>native_flags])],
  33       [grep 'LJ_TARGET_MIPS ' conftest.i >/dev/null 2>&1],
  34         [LJARCH=mips
  35          AS_IF([grep 'MIPSEL ' conftest.i >/dev/null 2>&1],
  36                  [echo '-D__MIPSEL__=1' >>native_flags])],
  37         [AC_MSG_ERROR([Sorry, unsupported architecture])])
  38 AS_IF([grep 'LJ_TARGET_PS3 1'conftest.i >/dev/null 2>&1],
  39         [LJHOST='PS3'
  40          echo '-D__CELLOS_LV2__' >>native_flags
  41          LUAJIT_DEFINES="$LUAJIT_DEFINES -DLUAJIT_USE_SYSMALLOC"])
  42 AS_IF([grep 'LJ_NO_UNWIND 1' conftest.i >/dev/null 2>&1],
  43         [echo '-D NO_UNWIND' >>dynasm_flags
  44          echo '-DLUAJIT_NO_UNWIND' >>native_flags])
  45 echo "-DLUAJIT_TARGET=LUAJIT_ARCH_$LJARCH" >>native_flags
  46 AS_IF([grep 'LJ_ARCH_BITS 64' conftest.i >/dev/null 2>&1],
  47         [echo '-D P64' >>dynasm_flags
  48          AS_IF([test "x$LJHOST" = xLinux],
  49                [LUAJIT_DEFINES="$LUAJIT_DEFINES -DMAP_32BIT=0x40"])])
  50 AS_IF([grep 'LJ_HASJIT 1' conftest.i >/dev/null 2>&1],
  51         [echo '-D JIT' >>dynasm_flags])
  52 AS_IF([grep 'LJ_HASFFI 1' conftest.i >/dev/null 2>&1],
  53         [echo '-D FFI' >>dynasm_flags])
  54 AS_IF([grep 'LJ_DUALNUM 1' conftest.i >/dev/null 2>&1],
  55         [echo '-D DUALNUM' >>dynasm_flags])
  56 AS_IF([grep 'LJ_ARCH_HASFPU 1' conftest.i >/dev/null 2>&1],
  57         [echo '-D FPU' >>dynasm_flags
  58          echo '-DLJ_ARCH_HASFPU=1' >>native_flags],
  59         [echo '-DLJ_ARCH_HASFPU=0' >>native_flags])
  60 AS_IF([grep 'LJ_ABI_SOFTFP 1' conftest.i >/dev/null 2>&1],
  61         [echo '-DDLJ_ABI_SOFTFP=1' >>native_flags],
  62         [echo '-D HFABI' >>dynasm_flags
  63          echo '-DLJ_ABI_SOFTFP=0' >>native_flags])
  64 echo '-D VER='`grep 'LJ_ARCH_VERSION ' conftest.i 2>&1 | \
  65                sed 's/^.*LJ_ARCH_VERSION //'` >>dynasm_flags
  66 AS_IF([test "x$LJHOST" = xWindows],
  67       [echo '-D WIN' >>dynasm_flags])
  68 DASM_ARCH=$LJARCH
  69 AS_CASE([$LJARCH],
  70         [x64], [AS_IF([grep 'LJ_FR2 1' conftest.i >/dev/null 2>&1],
  71                       [], [DASM_ARCH=x86])],
  72         [arm], [AS_IF([test "x$LJHOST" = xiOS],
  73                       [echo '-D IOS' >>dynasm_flags])],
  74         [ppc], [AS_IF([grep 'LJ_ARCH_SQRT 1' conftest.i >/dev/null 2>&1],
  75                       [echo '-D SQRT' >>dynasm_flags])
  76                 AS_IF([grep 'LJ_ARCH_ROUND 1' conftest.i >/dev/null 2>&1],
  77                       [echo '-D ROUND' >>dynasm_flags])
  78                 AS_IF([grep 'LJ_ARCH_PPC32ON64 1' conftest.i >/dev/null 2>&1],
  79                       [echo '-D GPR64' >>dynasm_flags])
  80                 AS_IF([grep 'LJ_ARCH_PPC64 ' conftest.i >/dev/null 2>&1],
  81                       [DASM_ARCH=ppc64])
  82                 AS_IF([test "x$LJHOST" = xPS3],
  83                       [echo '-D PPE -D TOC' >>dynasm_flags])])
  84 AS_CASE([$LJHOST],
  85         [Windows], [echo '-DLUAJIT_OS=LUAJIT_OS_WINDOWS' >>native_flags],
  86         [Darwin | iOS], [echo '-DLUAJIT_OS=LUAJIT_OS_OSX' >>native_flags],
  87         [Linux], [echo '-DLUAJIT_OS=LUAJIT_OS_LINUX' >>native_flags],
  88                  [echo '-DLUAJIT_OS=LUAJIT_OS_OTHER' >>native_flags])
  89 AC_MSG_RESULT([$LJHOST $LJARCH $DASM_ARCH])
  90 ]) # _LJ_ARCH
  91
  92 # LJ_ARCH
  93 # -------
  94 # Determine host and build system characteristics.
  95 AC_DEFUN([LJ_ARCH], [dnl
  96 lj_save_CPPFLAGS=$CPPFLAGS
  97 CPPFLAGS="$CPPFLAGS -I$srcdir/LuaJIT-src/src $LUAJIT_DEFINES -dM"
  98 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <lj_arch.h>]])],
  99                   [lj_cpp=ok; _LJ_ARCH])
 100 CPPFLAGS=$lj_save_CPPFLAGS
 101 AC_SUBST([LJARCH])
 102 AC_SUBST([DASM_ARCH])
 103 ]) # LJ_ARCH
 104