source/libs/luajit/LuaJIT-src/src/psvitabuild.bat

   1 @rem Script to build LuaJIT with the PS Vita SDK.\r
   2 @rem Donated to the public domain.\r
   3 @rem\r
   4 @rem Open a "Visual Studio .NET Command Prompt" (32 bit host compiler)\r
   5 @rem Then cd to this directory and run this script.\r
   6 \r
   7 @if not defined INCLUDE goto :FAIL\r
   8 @if not defined SCE_PSP2_SDK_DIR goto :FAIL\r
   9 \r
  10 @setlocal\r
  11 @rem ---- Host compiler ----\r
  12 @set LJCOMPILE=cl /nologo /c /MD /O2 /W3 /D_CRT_SECURE_NO_DEPRECATE\r
  13 @set LJLINK=link /nologo\r
  14 @set LJMT=mt /nologo\r
  15 @set DASMDIR=..\dynasm\r
  16 @set DASM=%DASMDIR%\dynasm.lua\r
  17 @set ALL_LIB=lib_base.c lib_math.c lib_bit.c lib_string.c lib_table.c lib_io.c lib_os.c lib_package.c lib_debug.c lib_jit.c lib_ffi.c\r
  18 \r
  19 %LJCOMPILE% host\minilua.c\r
  20 @if errorlevel 1 goto :BAD\r
  21 %LJLINK% /out:minilua.exe minilua.obj\r
  22 @if errorlevel 1 goto :BAD\r
  23 if exist minilua.exe.manifest^\r
  24   %LJMT% -manifest minilua.exe.manifest -outputresource:minilua.exe\r
  25 \r
  26 @rem Check for 32 bit host compiler.\r
  27 @minilua\r
  28 @if errorlevel 8 goto :FAIL\r
  29 \r
  30 @set DASMFLAGS=-D FPU -D HFABI\r
  31 minilua %DASM% -LN %DASMFLAGS% -o host\buildvm_arch.h vm_arm.dasc\r
  32 @if errorlevel 1 goto :BAD\r
  33 \r
  34 %LJCOMPILE% /I "." /I %DASMDIR% -DLUAJIT_TARGET=LUAJIT_ARCH_ARM -DLUAJIT_OS=LUAJIT_OS_OTHER -DLUAJIT_DISABLE_JIT -DLUAJIT_DISABLE_FFI -DLJ_TARGET_PSVITA=1 host\buildvm*.c\r
  35 @if errorlevel 1 goto :BAD\r
  36 %LJLINK% /out:buildvm.exe buildvm*.obj\r
  37 @if errorlevel 1 goto :BAD\r
  38 if exist buildvm.exe.manifest^\r
  39   %LJMT% -manifest buildvm.exe.manifest -outputresource:buildvm.exe\r
  40 \r
  41 buildvm -m elfasm -o lj_vm.s\r
  42 @if errorlevel 1 goto :BAD\r
  43 buildvm -m bcdef -o lj_bcdef.h %ALL_LIB%\r
  44 @if errorlevel 1 goto :BAD\r
  45 buildvm -m ffdef -o lj_ffdef.h %ALL_LIB%\r
  46 @if errorlevel 1 goto :BAD\r
  47 buildvm -m libdef -o lj_libdef.h %ALL_LIB%\r
  48 @if errorlevel 1 goto :BAD\r
  49 buildvm -m recdef -o lj_recdef.h %ALL_LIB%\r
  50 @if errorlevel 1 goto :BAD\r
  51 buildvm -m vmdef -o jit\vmdef.lua %ALL_LIB%\r
  52 @if errorlevel 1 goto :BAD\r
  53 buildvm -m folddef -o lj_folddef.h lj_opt_fold.c\r
  54 @if errorlevel 1 goto :BAD\r
  55 \r
  56 @rem ---- Cross compiler ----\r
  57 @set LJCOMPILE="%SCE_PSP2_SDK_DIR%\host_tools\build\bin\psp2snc" -c -w -DLUAJIT_DISABLE_FFI -DLUAJIT_USE_SYSMALLOC\r
  58 @set LJLIB="%SCE_PSP2_SDK_DIR%\host_tools\build\bin\psp2ld32" -r --output=\r
  59 @set INCLUDE=""\r
  60 \r
  61 "%SCE_PSP2_SDK_DIR%\host_tools\build\bin\psp2as" -o lj_vm.o lj_vm.s\r
  62 \r
  63 @if "%1" neq "debug" goto :NODEBUG\r
  64 @shift\r
  65 @set LJCOMPILE=%LJCOMPILE% -g -O0\r
  66 @set TARGETLIB=libluajitD.a\r
  67 goto :BUILD\r
  68 :NODEBUG\r
  69 @set LJCOMPILE=%LJCOMPILE% -O2\r
  70 @set TARGETLIB=libluajit.a\r
  71 :BUILD\r
  72 del %TARGETLIB%\r
  73 \r
  74 %LJCOMPILE% ljamalg.c\r
  75 @if errorlevel 1 goto :BAD\r
  76 %LJLIB%%TARGETLIB% ljamalg.o lj_vm.o\r
  77 @if errorlevel 1 goto :BAD\r
  78 \r
  79 @del *.o *.obj *.manifest minilua.exe buildvm.exe\r
  80 @echo.\r
  81 @echo === Successfully built LuaJIT for PS Vita ===\r
  82 \r
  83 @goto :END\r
  84 :BAD\r
  85 @echo.\r
  86 @echo *******************************************************\r
  87 @echo *** Build FAILED -- Please check the error messages ***\r
  88 @echo *******************************************************\a\r
  89 @goto :END\r
  90 :FAIL\r
  91 @echo To run this script you must open a "Visual Studio .NET Command Prompt"\r
  92 @echo (32 bit host compiler). The PS Vita SDK must be installed, too.\r
  93 :END\r