source/libs/gmp/m4/gmp-extern-inline.m4

   1 # Autoconf macros for the GNU MP Library.
   2 # Copyright (C) 2000-2014 Free Software Foundation, Inc.
   3 #
   4 # Copyright (C) 2014 Peter Breitenlohner <tex-live@tug.org>
   5 # Extracted from gmp-6.0.0/acinclude.m4 and adapted for TeX Live.
   6 #
   7 # This file is free software; the copyright holders
   8 # give unlimited permission to copy and/or distribute it,
   9 # with or without modifications, as long as this notice is preserved.
  10
  11 #  GMP_H_EXTERN_INLINE
  12 #  -------------------
  13 #  If the compiler has an "inline" of some sort, check whether the
  14 #  #ifdef's in gmp.h recognise it.
  15
  16 AC_DEFUN([GMP_H_EXTERN_INLINE], [dnl
  17 AC_REQUIRE([AC_C_INLINE])
  18 AS_CASE([$ac_cv_c_inline],
  19         [no], [],
  20         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define __GMP_WITHIN_CONFIGURE_INLINE 1
  21 #include "gmp-tmp.h"
  22 #ifndef __GMP_EXTERN_INLINE
  23 die die die
  24 #endif]],
  25                                             [])],
  26                            [], [dnl
  27 AS_CASE([$ac_cv_c_inline],
  28         [yes], [tmp_inline=inline],
  29                [tmp_inline=$ac_cv_c_inline])
  30 AC_MSG_WARN([gmp.h doesnt recognise compiler "$tmp_inline", inlines will be unavailable])])])
  31 ])
  32
  33