source/libs/gmp/gmp-src/mpn/s390_32/mul_1.asm

   1 dnl  S/390 mpn_mul_1 -- Multiply a limb vector with a limb and store the
   2 dnl  result in a second limb vector.
   3
   4 dnl  Copyright 2001 Free Software Foundation, Inc.
   5
   6 dnl  This file is part of the GNU MP Library.
   7 dnl
   8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of either:
  10 dnl
  11 dnl    * the GNU Lesser General Public License as published by the Free
  12 dnl      Software Foundation; either version 3 of the License, or (at your
  13 dnl      option) any later version.
  14 dnl
  15 dnl  or
  16 dnl
  17 dnl    * the GNU General Public License as published by the Free Software
  18 dnl      Foundation; either version 2 of the License, or (at your option) any
  19 dnl      later version.
  20 dnl
  21 dnl  or both in parallel, as here.
  22 dnl
  23 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  24 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  25 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  26 dnl  for more details.
  27 dnl
  28 dnl  You should have received copies of the GNU General Public License and the
  29 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  30 dnl  see https://www.gnu.org/licenses/.
  31
  32 include(`../config.m4')
  33
  34 define(`rp',2)
  35 define(`up',3)
  36 define(`n',4)
  37 define(`vlimb',5)
  38 define(`cylimb',7)
  39
  40 ASM_START()
  41 PROLOGUE(mpn_mul_1)
  42         stm     6,7,24(15)
  43         slr     cylimb,cylimb   # clear cylimb
  44         ltr     vlimb,vlimb
  45         jnl     .Loopp
  46
  47 .Loopn: l       1,0(up)         # load from u
  48         lr      6,1             #
  49         mr      0,vlimb         # multiply signed
  50         alr     0,6             # add vlimb to phi
  51         sra     6,31            # make mask
  52         nr      6,vlimb         # 0 or vlimb
  53         alr     0,6             # conditionally add vlimb to phi
  54         alr     1,cylimb        # add carry limb to plo
  55         brc     8+4,+8          # branch if not carry
  56         ahi     0,1             # increment phi
  57         lr      cylimb,0        # new cylimb
  58         st      1,0(rp)         # store
  59         la      up,4(,up)
  60         la      rp,4(,rp)
  61         brct    n,.Loopn
  62
  63         lr      2,cylimb
  64         lm      6,7,24(15)
  65         br      14
  66
  67 .Loopp: l       1,0(up)         # load from u
  68         lr      6,1             #
  69         mr      0,vlimb         # multiply signed
  70         sra     6,31            # make mask
  71         nr      6,vlimb         # 0 or vlimb
  72         alr     0,6             # conditionally add vlimb to phi
  73         alr     1,cylimb        # add carry limb to plo
  74         brc     8+4,+8          # branch if not carry
  75         ahi     0,1             # increment phi
  76         lr      cylimb,0        # new cylimb
  77         st      1,0(rp)         # store
  78         la      up,4(,up)
  79         la      rp,4(,rp)
  80         brct    n,.Loopp
  81
  82         lr      2,cylimb
  83         lm      6,7,24(15)
  84         br      14
  85 EPILOGUE(mpn_mul_1)