source/libs/gmp/gmp-src/mpn/s390_32/addmul_1.asm

   1 dnl  S/390 mpn_addmul_1 -- Multiply a limb vector with a limb and add the
   2 dnl  result to a second limb vector.
   3
   4 dnl  Copyright 2001 Free Software Foundation, Inc.
   5
   6 dnl  This file is part of the GNU MP Library.
   7 dnl
   8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of either:
  10 dnl
  11 dnl    * the GNU Lesser General Public License as published by the Free
  12 dnl      Software Foundation; either version 3 of the License, or (at your
  13 dnl      option) any later version.
  14 dnl
  15 dnl  or
  16 dnl
  17 dnl    * the GNU General Public License as published by the Free Software
  18 dnl      Foundation; either version 2 of the License, or (at your option) any
  19 dnl      later version.
  20 dnl
  21 dnl  or both in parallel, as here.
  22 dnl
  23 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  24 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  25 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  26 dnl  for more details.
  27 dnl
  28 dnl  You should have received copies of the GNU General Public License and the
  29 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  30 dnl  see https://www.gnu.org/licenses/.
  31
  32 include(`../config.m4')
  33
  34 define(`rp',2)
  35 define(`up',3)
  36 define(`n',4)
  37 define(`vlimb',5)
  38 define(`cylimb',7)
  39
  40 ASM_START()
  41 PROLOGUE(mpn_addmul_1)
  42         stm     6,7,24(15)
  43         slr     cylimb,cylimb   # clear cylimb
  44         ltr     vlimb,vlimb
  45         jnl     .Loopp
  46
  47 .Loopn: l       1,0(up)         # load from u
  48         lr      6,1             #
  49         mr      0,vlimb         # multiply signed
  50         alr     0,6             # add vlimb to phi
  51         sra     6,31            # make mask
  52         nr      6,vlimb         # 0 or vlimb
  53         alr     0,6             # conditionally add vlimb to phi
  54         alr     1,cylimb        # add carry limb to plo
  55         brc     8+4,+8          # branch if not carry
  56         ahi     0,1             # increment phi
  57         l       6,0(rp)         # load r limb
  58         alr     6,1             # add u limb to plo
  59         brc     8+4,+8          # branch if not carry
  60         ahi     0,1             # increment phi
  61         lr      cylimb,0        # new cylimb
  62         st      6,0(rp)         # store
  63         la      up,4(,up)
  64         la      rp,4(,rp)
  65         brct    n,.Loopn
  66
  67         lr      2,cylimb
  68         lm      6,7,24(15)
  69         br      14
  70
  71 .Loopp: l       1,0(up)         # load from u
  72         lr      6,1             #
  73         mr      0,vlimb         # multiply signed
  74         sra     6,31            # make mask
  75         nr      6,vlimb         # 0 or vlimb
  76         alr     0,6             # conditionally add vlimb to phi
  77         alr     1,cylimb        # add carry limb to plo
  78         brc     8+4,+8          # branch if not carry
  79         ahi     0,1             # increment phi
  80         l       6,0(rp)         # load r limb
  81         alr     6,1             # add u limb to plo
  82         brc     8+4,+8          # branch if not carry
  83         ahi     0,1             # increment phi
  84         lr      cylimb,0        # new cylimb
  85         st      6,0(rp)         # store
  86         la      up,4(,up)
  87         la      rp,4(,rp)
  88         brct    n,.Loopp
  89
  90         lr      2,cylimb
  91         lm      6,7,24(15)
  92         br      14
  93 EPILOGUE(mpn_addmul_1)