source/libs/gmp/gmp-src/mpn/powerpc32/aix.m4

   1 divert(-1)
   2 dnl  m4 macros for AIX 32-bit assembly.
   3
   4 dnl  Copyright 2000-2002, 2005, 2006 Free Software Foundation, Inc.
   5
   6 dnl  This file is part of the GNU MP Library.
   7 dnl
   8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of either:
  10 dnl
  11 dnl    * the GNU Lesser General Public License as published by the Free
  12 dnl      Software Foundation; either version 3 of the License, or (at your
  13 dnl      option) any later version.
  14 dnl
  15 dnl  or
  16 dnl
  17 dnl    * the GNU General Public License as published by the Free Software
  18 dnl      Foundation; either version 2 of the License, or (at your option) any
  19 dnl      later version.
  20 dnl
  21 dnl  or both in parallel, as here.
  22 dnl
  23 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  24 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  25 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  26 dnl  for more details.
  27 dnl
  28 dnl  You should have received copies of the GNU General Public License and the
  29 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  30 dnl  see https://www.gnu.org/licenses/.
  31
  32 define(`ASM_START',
  33 `       .toc')
  34
  35 dnl  Called: PROLOGUE_cpu(GSYM_PREFIX`'foo)
  36 dnl          EPILOGUE_cpu(GSYM_PREFIX`'foo)
  37 dnl
  38 dnl  Don't want ELF style .size in the epilogue.
  39
  40 define(`PROLOGUE_cpu',
  41 m4_assert_numargs(1)
  42         `
  43         .globl  $1
  44         .globl  .$1
  45         .csect  [DS], 2
  46 $1:
  47         .long   .$1, TOC[tc0], 0
  48         .csect  [PR]
  49         .align  2
  50 .$1:')
  51
  52 define(`EPILOGUE_cpu',
  53 m4_assert_numargs(1)
  54 `')
  55
  56 define(`TOC_ENTRY', `')
  57
  58 define(`LEA',
  59 m4_assert_numargs(2)
  60 `define(`TOC_ENTRY',
  61 `       .toc
  62 tc$2:
  63         .tc     $2[TC], $2')'
  64 `       lwz     $1, tc$2(2)')
  65
  66 define(`EXTERN',
  67 m4_assert_numargs(1)
  68 `       .globl  $1')
  69
  70 define(`DEF_OBJECT',
  71 m4_assert_numargs_range(1,2)
  72 `       .csect  [RO], 3
  73         ALIGN(ifelse($#,1,2,$2))
  74 $1:
  75 ')
  76
  77 define(`END_OBJECT',
  78 m4_assert_numargs(1))
  79
  80 define(`ASM_END', `TOC_ENTRY')
  81
  82 divert