source/libs/gmp/gmp-src/mpn/m68k/aors_n.asm

   1 dnl  mc68020 mpn_add_n, mpn_sub_n -- add or subtract limb vectors
   2
   3 dnl  Copyright 1992, 1994, 1996, 1999-2003, 2005 Free Software Foundation, Inc.
   4
   5 dnl  This file is part of the GNU MP Library.
   6 dnl
   7 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   8 dnl  it under the terms of either:
   9 dnl
  10 dnl    * the GNU Lesser General Public License as published by the Free
  11 dnl      Software Foundation; either version 3 of the License, or (at your
  12 dnl      option) any later version.
  13 dnl
  14 dnl  or
  15 dnl
  16 dnl    * the GNU General Public License as published by the Free Software
  17 dnl      Foundation; either version 2 of the License, or (at your option) any
  18 dnl      later version.
  19 dnl
  20 dnl  or both in parallel, as here.
  21 dnl
  22 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  23 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  24 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  25 dnl  for more details.
  26 dnl
  27 dnl  You should have received copies of the GNU General Public License and the
  28 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  29 dnl  see https://www.gnu.org/licenses/.
  30
  31 include(`../config.m4')
  32
  33 C         cycles/limb
  34 C 68040:      6
  35
  36 ifdef(`OPERATION_add_n',`
  37   define(M4_inst,       addxl)
  38   define(M4_function_n, mpn_add_n)
  39 ',`ifdef(`OPERATION_sub_n',`
  40   define(M4_inst,       subxl)
  41   define(M4_function_n, mpn_sub_n)
  42 ',
  43 `m4_error(`Need OPERATION_add_n or OPERATION_sub_n
  44 ')')')
  45
  46 MULFUNC_PROLOGUE(mpn_add_n mpn_sub_n)
  47
  48
  49 C INPUT PARAMETERS
  50 C res_ptr       (sp + 4)
  51 C s1_ptr        (sp + 8)
  52 C s2_ptr        (sp + 12)
  53 C size          (sp + 16)
  54
  55
  56 PROLOGUE(M4_function_n)
  57
  58 C Save used registers on the stack.
  59         movel   d2, M(-,sp)
  60         movel   a2, M(-,sp)
  61
  62 C Copy the arguments to registers.  Better use movem?
  63         movel   M(sp,12), a2
  64         movel   M(sp,16), a0
  65         movel   M(sp,20), a1
  66         movel   M(sp,24), d2
  67
  68         eorw    #1, d2
  69         lsrl    #1, d2
  70         bcc     L(L1)
  71         subql   #1, d2  C clears cy as side effect
  72
  73 L(Loop):
  74         movel   M(a0,+), d0
  75         movel   M(a1,+), d1
  76         M4_inst d1, d0
  77         movel   d0, M(a2,+)
  78 L(L1):  movel   M(a0,+), d0
  79         movel   M(a1,+), d1
  80         M4_inst d1, d0
  81         movel   d0, M(a2,+)
  82
  83         dbf     d2, L(Loop)             C loop until 16 lsb of %4 == -1
  84         subxl   d0, d0                  C d0 <= -cy; save cy as 0 or -1 in d0
  85         subl    #0x10000, d2
  86         bcs     L(L2)
  87         addl    d0, d0                  C restore cy
  88         bra     L(Loop)
  89
  90 L(L2):
  91         negl    d0
  92
  93 C Restore used registers from stack frame.
  94         movel   M(sp,+), a2
  95         movel   M(sp,+), d2
  96
  97         rts
  98
  99 EPILOGUE(M4_function_n)