source/libs/gmp/gmp-src/mpn/arm/rshift.asm

   1 dnl  ARM mpn_rshift.
   2
   3 dnl  Contributed to the GNU project by Torbjörn Granlund.
   4
   5 dnl  Copyright 1997, 2000, 2001, 2012 Free Software Foundation, Inc.
   6
   7 dnl  This file is part of the GNU MP Library.
   8 dnl
   9 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
  10 dnl  it under the terms of either:
  11 dnl
  12 dnl    * the GNU Lesser General Public License as published by the Free
  13 dnl      Software Foundation; either version 3 of the License, or (at your
  14 dnl      option) any later version.
  15 dnl
  16 dnl  or
  17 dnl
  18 dnl    * the GNU General Public License as published by the Free Software
  19 dnl      Foundation; either version 2 of the License, or (at your option) any
  20 dnl      later version.
  21 dnl
  22 dnl  or both in parallel, as here.
  23 dnl
  24 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  25 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  26 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  27 dnl  for more details.
  28 dnl
  29 dnl  You should have received copies of the GNU General Public License and the
  30 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  31 dnl  see https://www.gnu.org/licenses/.
  32
  33 include(`../config.m4')
  34
  35 C            cycles/limb
  36 C StrongARM      ?
  37 C XScale         ?
  38 C Cortex-A7      ?
  39 C Cortex-A8      ?
  40 C Cortex-A9      3.5
  41 C Cortex-A15     ?
  42
  43 define(`rp',  `r0')
  44 define(`up',  `r1')
  45 define(`n',   `r2')
  46 define(`cnt', `r3')
  47 define(`tnc', `r12')
  48
  49 ASM_START()
  50 PROLOGUE(mpn_rshift)
  51         push    {r4, r6, r7, r8}
  52         ldr     r4, [up]
  53         rsb     tnc, cnt, #32
  54
  55         mov     r7, r4, lsr cnt
  56         tst     n, #1
  57         beq     L(evn)                  C n even
  58
  59 L(odd): subs    n, n, #2
  60         bcc     L(1)                    C n = 1
  61         ldr     r8, [up, #4]!
  62         b       L(mid)
  63
  64 L(evn): ldr     r6, [up, #4]!
  65         subs    n, n, #2
  66         beq     L(end)
  67
  68 L(top): ldr     r8, [up, #4]!
  69         orr     r7, r7, r6, lsl tnc
  70         str     r7, [rp], #4
  71         mov     r7, r6, lsr cnt
  72 L(mid): ldr     r6, [up, #4]!
  73         orr     r7, r7, r8, lsl tnc
  74         str     r7, [rp], #4
  75         mov     r7, r8, lsr cnt
  76         subs    n, n, #2
  77         bgt     L(top)
  78
  79 L(end): orr     r7, r7, r6, lsl tnc
  80         str     r7, [rp], #4
  81         mov     r7, r6, lsr cnt
  82 L(1):   str     r7, [rp]
  83         mov     r0, r4, lsl tnc
  84         pop     {r4, r6, r7, r8}
  85         bx      r14
  86 EPILOGUE()