source/libs/gmp/gmp-src/mpn/arm/com.asm

   1 dnl  ARM mpn_com.
   2
   3 dnl  Copyright 2003, 2012 Free Software Foundation, Inc.
   4
   5 dnl  This file is part of the GNU MP Library.
   6 dnl
   7 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   8 dnl  it under the terms of either:
   9 dnl
  10 dnl    * the GNU Lesser General Public License as published by the Free
  11 dnl      Software Foundation; either version 3 of the License, or (at your
  12 dnl      option) any later version.
  13 dnl
  14 dnl  or
  15 dnl
  16 dnl    * the GNU General Public License as published by the Free Software
  17 dnl      Foundation; either version 2 of the License, or (at your option) any
  18 dnl      later version.
  19 dnl
  20 dnl  or both in parallel, as here.
  21 dnl
  22 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  23 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  24 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  25 dnl  for more details.
  26 dnl
  27 dnl  You should have received copies of the GNU General Public License and the
  28 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  29 dnl  see https://www.gnu.org/licenses/.
  30
  31 include(`../config.m4')
  32
  33 C            cycles/limb
  34 C StrongARM      ?
  35 C XScale         ?
  36 C Cortex-A7      ?
  37 C Cortex-A8      ?
  38 C Cortex-A9      2.0
  39 C Cortex-A15     1.75
  40
  41 define(`rp', `r0')
  42 define(`up', `r1')
  43 define(`n',  `r2')
  44
  45 ASM_START()
  46 PROLOGUE(mpn_com)
  47         tst     n, #1
  48         beq     L(skip1)
  49         ldr     r3, [up], #4
  50         mvn     r3, r3
  51         str     r3, [rp], #4
  52 L(skip1):
  53         tst     n, #2
  54         beq     L(skip2)
  55         ldmia   up!, { r3, r12 }                C load 2 limbs
  56         mvn     r3, r3
  57         mvn     r12, r12
  58         stmia   rp!, { r3, r12 }                C store 2 limbs
  59 L(skip2):
  60         bics    n, n, #3
  61         beq     L(rtn)
  62         stmfd   sp!, { r7, r8, r9 }             C save regs on stack
  63
  64 L(top): ldmia   up!, { r3, r8, r9, r12 }        C load 4 limbs
  65         subs    n, n, #4
  66         mvn     r3, r3
  67         mvn     r8, r8
  68         mvn     r9, r9
  69         mvn     r12, r12
  70         stmia   rp!, { r3, r8, r9, r12 }        C store 4 limbs
  71         bne     L(top)
  72
  73         ldmfd   sp!, { r7, r8, r9 }             C restore regs from stack
  74 L(rtn): bx      lr
  75 EPILOGUE()