source/libs/gmp/gmp-src/mpn/alpha/default.m4

   1 divert(-1)
   2
   3 dnl  m4 macros for alpha assembler (everywhere except unicos).
   4
   5
   6 dnl  Copyright 2000, 2002-2004, 2013 Free Software Foundation, Inc.
   7
   8 dnl  This file is part of the GNU MP Library.
   9 dnl
  10 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
  11 dnl  it under the terms of either:
  12 dnl
  13 dnl    * the GNU Lesser General Public License as published by the Free
  14 dnl      Software Foundation; either version 3 of the License, or (at your
  15 dnl      option) any later version.
  16 dnl
  17 dnl  or
  18 dnl
  19 dnl    * the GNU General Public License as published by the Free Software
  20 dnl      Foundation; either version 2 of the License, or (at your option) any
  21 dnl      later version.
  22 dnl
  23 dnl  or both in parallel, as here.
  24 dnl
  25 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  26 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  27 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  28 dnl  for more details.
  29 dnl
  30 dnl  You should have received copies of the GNU General Public License and the
  31 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  32 dnl  see https://www.gnu.org/licenses/.
  33
  34
  35 dnl  Usage: ASM_START()
  36 define(`ASM_START',
  37 m4_assert_numargs(0)
  38 `       .set noreorder
  39         .set noat')
  40
  41 dnl  Usage: X(value)
  42 define(`X',
  43 m4_assert_numargs(1)
  44 `0x$1')
  45
  46 dnl  Usage: FLOAT64(label,value)
  47 define(`FLOAT64',
  48 m4_assert_numargs(2)
  49 `       .align  3
  50 $1:     .t_floating $2')
  51
  52
  53 dnl  Called: PROLOGUE_cpu(GSYM_PREFIX`'foo[,gp|noalign])
  54 dnl          EPILOGUE_cpu(GSYM_PREFIX`'foo)
  55
  56 define(`PROLOGUE_cpu',
  57 m4_assert_numargs_range(1,2)
  58 `ifelse(`$2',gp,,
  59 `ifelse(`$2',noalign,,
  60 `ifelse(`$2',,,`m4_error(`Unrecognised PROLOGUE parameter
  61 ')')')')dnl
  62         .text
  63 ifelse(`$2',noalign,,`  ALIGN(16)')
  64         .globl  $1
  65         .ent    $1
  66 $1:
  67         .frame r30,0,r26,0
  68 ifelse(`$2',gp,`        ldgp    r29, 0(r27)
  69 `$'$1..ng:')
  70         .prologue ifelse(`$2',gp,1,0)')
  71
  72 define(`EPILOGUE_cpu',
  73 m4_assert_numargs(1)
  74 `       .end    $1')
  75
  76
  77 dnl  Usage: LDGP(dst,src)
  78 dnl
  79 dnl  Emit an "ldgp dst,src", but only if the system uses a GOT.
  80
  81 define(LDGP,
  82 m4_assert_numargs(2)
  83 `ldgp   `$1', `$2'')
  84
  85
  86 dnl  Usage: EXTERN(variable_name)
  87 define(`EXTERN',
  88 m4_assert_numargs(1)
  89 )
  90
  91 dnl  Usage: r0 ... r31
  92 dnl         f0 ... f31
  93 dnl
  94 dnl  Map register names r0 to $0, and f0 to $f0, etc.
  95 dnl  This is needed on all systems but Unicos
  96 dnl
  97 dnl  defreg() is used to protect the $ in $0 (otherwise it would represent a
  98 dnl  macro argument).  Double quoting is used to protect the f0 in $f0
  99 dnl  (otherwise it would be an infinite recursion).
 100
 101 forloop(i,0,31,`defreg(`r'i,$i)')
 102 forloop(i,0,31,`deflit(`f'i,``$f''i)')
 103
 104
 105 dnl  Usage: DATASTART(name,align)  or  DATASTART(name)
 106 dnl         DATAEND()
 107
 108 define(`DATASTART',
 109 m4_assert_numargs_range(1,2)
 110 `       RODATA
 111         ALIGN(ifelse($#,1,2,$2))
 112 $1:')
 113 define(`DATAEND',
 114 m4_assert_numargs(0)
 115 )
 116
 117 dnl  Load a symbolic address into a register
 118 define(`LEA',
 119 m4_assert_numargs(2)
 120 `lda    $1, $2')
 121
 122 dnl  Usage: ASM_END()
 123 define(`ASM_END',
 124 m4_assert_numargs(0)
 125 )
 126
 127 divert