source/texk/web2c/ac/web2c.ac

   1 ## texk/web2c/ac/web2c.ac: configure.ac fragment for the TeX Live subdirectory texk/web2c/
   2 dnl
   3 dnl Copyright (C) 2009-2015 Peter Breitenlohner <tex-live@tug.org>
   4 dnl You may freely use, modify and/or distribute this file.
   5 dnl
   6 ## configure options for TeX and MF
   7 m4_define_default([kpse_indent_26], [26])[]dnl
   8 AC_ARG_WITH([banner-add],
   9             AS_HELP_STRING([--with-banner-add=STR],
  10                            [add STR to version string appended to banner lines]))[]dnl
  11 AC_ARG_WITH([editor],
  12             AS_HELP_STRING([--with-editor=CMD],
  13                            [invoke CMD from the `e' option @<:@vi +%d '%s'@:>@
  14                             or @<:@texworks --position=%d "%s"@:>@]))[]dnl
  15 AC_ARG_ENABLE([auto-core],
  16               AS_HELP_STRING([--enable-auto-core],
  17                              [cause TeX&MF to dump core, given a certain filename],
  18                              kpse_indent_26))[]dnl
  19 AC_ARG_ENABLE([dump-share],
  20               AS_HELP_STRING([--disable-dump-share],
  21                              [make fmt/base files architecture-dependent],
  22                              kpse_indent_26))[]dnl
  23 ## configure options for TeX
  24 AC_ARG_ENABLE([ipc],
  25               AS_HELP_STRING([--disable-ipc],
  26                              [disable TeX's --ipc option, i.e., pipe to a program],
  27                              kpse_indent_26))[]dnl
  28 dnl [PROG, BUILD-OR-NO, SYNC-OR-NO, TEXT, REQUIRED-LIBS]
  29 m4_define([kpse_tex_progs], [dnl
  30 [[tex],       [yes], [no],  [TeX],        []],
  31 [[etex],      [no],  [yes], [e-TeX],      []],
  32 [[ptex],      [yes], [yes], [pTeX],       [ptexenc]],
  33 [[eptex],     [yes], [yes], [e-pTeX],     [ptexenc]],
  34 [[uptex],     [yes], [yes], [upTeX],      [ptexenc]],
  35 [[euptex],    [yes], [yes], [e-upTeX],    [ptexenc]],
  36 [[aleph],     [yes], [],    [Aleph],      []],
  37 [[pdftex],    [yes], [yes], [pdfTeX],     [xpdf libpng]],
  38 [[luatex],    [yes], [],    [LuaTeX],     [poppler mpfr cairo libpng zziplib lua52]],
  39 [[luajittex], [yes], [],    [LuaJITTeX],  [poppler mpfr cairo libpng zziplib luajit]],
  40 [[mp],        [yes], [],    [MetaPost],   [mpfr cairo libpng]],
  41 [[pmp],       [yes], [],    [pMetaPost],  [mpfr cairo libpng ptexenc]],
  42 [[upmp],      [yes], [],    [upMetaPost], [mpfr cairo libpng ptexenc]],
  43 [[xetex],     [yes], [yes], [XeTeX],      [poppler libpng freetype2 teckit harfbuzz]],
  44 ])[]dnl
  45 m4_foreach([Kpse_Prog], [kpse_tex_progs],
  46            [m4_ifset([Kpse_Prog],
  47                      [KPSE_WITH_XTEX(Kpse_Prog)])])[]dnl
  48 ## configure options for MF
  49 dnl [PROG, BUILD-OR-NO, NOWIN-OR-NO, TEXT, REQUIRED-LIBS]
  50 m4_define([kpse_mf_progs], [dnl
  51 [[mf],       [yes], [yes], [METAFONT], []],
  52 [[mflua],    [yes], [no],  [MFLua],    [lua52]],
  53 [[mfluajit], [yes], [no],  [MFLuaJIT], [luajit]],
  54 ])[]dnl
  55 m4_foreach([Kpse_Prog], [kpse_mf_progs],
  56            [m4_ifset([Kpse_Prog],
  57                      [KPSE_WITH_XMF(Kpse_Prog)])])[]dnl
  58 AC_ARG_WITH([mf-x-toolkit],
  59             AS_HELP_STRING([--with-mf-x-toolkit],
  60                            [use X toolkit for METAFONT]))[]dnl
  61 m4_define([kpse_mf_win], [dnl
  62 [[epsf],      [EPSF],      [EPSF pseudo]],
  63 [[hp2627],    [HP2627],    [HP 2627]],
  64 [[mftalk],    [MFTALK],    [mftalk (generic server)]],
  65 [[next],      [NEXT],      [NeXT]],
  66 [[regis],     [REGIS],     [Regis]],
  67 [[suntools],  [SUN],       [old Suntools (not X)]],
  68 [[tektronix], [TEKTRONIX], [Tektronix]],
  69 [[uniterm],   [UNITERM],   [Uniterm]],
  70 ])[]dnl
  71 m4_foreach([Kpse_Win], [kpse_mf_win],
  72            [m4_ifset([Kpse_Win],
  73                      [KPSE_WITH_MFWIN(Kpse_Win)])])[]dnl
  74 ## configure options for WEB programs
  75 AC_ARG_ENABLE([web-progs],
  76               AS_HELP_STRING([--disable-web-progs],
  77                              [do not build WEB programs bibtex ... weave],
  78                              kpse_indent_26))[]dnl
  79 ## configure option for the SyncTeX library and tool
  80 AC_ARG_ENABLE([synctex],
  81               AS_HELP_STRING([--disable-synctex],
  82                              [do not build the SyncTeX library and tool],
  83                              kpse_indent_26))[]dnl
  84