source/libs/gmp/gmp-src/mpn/sh/sh2/addmul_1.asm

   1 dnl  SH2 mpn_addmul_1 -- Multiply a limb vector with a limb and add the result
   2 dnl  to a second limb vector.
   3
   4 dnl  Copyright 1995, 2000, 2011 Free Software Foundation, Inc.
   5
   6 dnl  This file is part of the GNU MP Library.
   7 dnl
   8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of either:
  10 dnl
  11 dnl    * the GNU Lesser General Public License as published by the Free
  12 dnl      Software Foundation; either version 3 of the License, or (at your
  13 dnl      option) any later version.
  14 dnl
  15 dnl  or
  16 dnl
  17 dnl    * the GNU General Public License as published by the Free Software
  18 dnl      Foundation; either version 2 of the License, or (at your option) any
  19 dnl      later version.
  20 dnl
  21 dnl  or both in parallel, as here.
  22 dnl
  23 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  24 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  25 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  26 dnl  for more details.
  27 dnl
  28 dnl  You should have received copies of the GNU General Public License and the
  29 dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
  30 dnl  see https://www.gnu.org/licenses/.
  31
  32
  33 include(`../config.m4')
  34
  35 C INPUT PARAMETERS
  36 C res_ptr       r4
  37 C s1_ptr        r5
  38 C size          r6
  39 C s2_limb       r7
  40
  41 changecom(blah)                 C disable # to make all C comments below work
  42
  43 ASM_START()
  44 PROLOGUE(mpn_addmul_1)
  45         mov     #0,r2           C cy_limb = 0
  46         mov     #0,r0           C Keep r0 = 0 for entire loop
  47         clrt
  48
  49 L(top): mov.l   @r5+,r3
  50         dmulu.l r3,r7
  51         sts     macl,r1
  52         addc    r2,r1           C lo_prod += old cy_limb
  53         sts     mach,r2         C new cy_limb = hi_prod
  54         mov.l   @r4,r3
  55         addc    r0,r2           C cy_limb += T, T = 0
  56         addc    r3,r1
  57         addc    r0,r2           C cy_limb += T, T = 0
  58         dt      r6
  59         mov.l   r1,@r4
  60         bf.s    L(top)
  61         add     #4,r4
  62
  63         rts
  64         mov     r2,r0
  65 EPILOGUE()