src/vm_mips.dasc

   1 |// Low-level VM code for MIPS CPUs.
   2 |// Bytecode interpreter, fast functions and helper functions.
   3 |// Copyright (C) 2005-2012 Mike Pall. See Copyright Notice in luajit.h
   4 |
   5 |.arch mips
   6 |.section code_op, code_sub
   7 |
   8 |.actionlist build_actionlist
   9 |.globals GLOB_
  10 |.globalnames globnames
  11 |.externnames extnames
  12 |
  13 |// Note: The ragged indentation of the instructions is intentional.
  14 |//       The starting columns indicate data dependencies.
  15 |
  16 |//-----------------------------------------------------------------------
  17 |
  18 |// Fixed register assignments for the interpreter.
  19 |// Don't use: r0 = 0, r26/r27 = reserved, r28 = gp, r29 = sp, r31 = ra
  20 |
  21 |// The following must be C callee-save (but BASE is often refetched).
  22 |.define BASE,          r16     // Base of current Lua stack frame.
  23 |.define KBASE,         r17     // Constants of current Lua function.
  24 |.define PC,            r18     // Next PC.
  25 |.define DISPATCH,      r19     // Opcode dispatch table.
  26 |.define LREG,          r20     // Register holding lua_State (also in SAVE_L).
  27 |.define MULTRES,       r21     // Size of multi-result: (nresults+1)*8.
  28 |// NYI: r22 currently unused.
  29 |
  30 |.define JGL,           r30     // On-trace: global_State + 32768.
  31 |
  32 |// Constants for type-comparisons, stores and conversions. C callee-save.
  33 |.define TISNIL,        r30
  34 |.define TOBIT,         f30     // 2^52 + 2^51.
  35 |
  36 |// The following temporaries are not saved across C calls, except for RA.
  37 |.define RA,            r23     // Callee-save.
  38 |.define RB,            r8
  39 |.define RC,            r9
  40 |.define RD,            r10
  41 |.define INS,           r11
  42 |
  43 |.define AT,            r1      // Assembler temporary.
  44 |.define TMP0,          r12
  45 |.define TMP1,          r13
  46 |.define TMP2,          r14
  47 |.define TMP3,          r15
  48 |
  49 |// Calling conventions.
  50 |.define CFUNCADDR,     r25
  51 |.define CARG1,         r4
  52 |.define CARG2,         r5
  53 |.define CARG3,         r6
  54 |.define CARG4,         r7
  55 |
  56 |.define CRET1,         r2
  57 |.define CRET2,         r3
  58 |
  59 |.define FARG1,         f12
  60 |.define FARG2,         f14
  61 |
  62 |.define FRET1,         f0
  63 |.define FRET2,         f2
  64 |
  65 |// Stack layout while in interpreter. Must match with lj_frame.h.
  66 |.define CFRAME_SPACE,  112     // Delta for sp.
  67 |
  68 |.define SAVE_ERRF,     124(sp) // 32 bit C frame info.
  69 |.define SAVE_NRES,     120(sp)
  70 |.define SAVE_CFRAME,   116(sp)
  71 |.define SAVE_L,        112(sp)
  72 |//----- 8 byte aligned, ^^^^ 16 byte register save area, owned by interpreter.
  73 |.define SAVE_GPR_,     72      // .. 72+10*4: 32 bit GPR saves.
  74 |.define SAVE_FPR_,     24      // .. 24+6*8: 64 bit FPR saves.
  75 |.define SAVE_PC,       20(sp)
  76 |.define ARG5,          16(sp)
  77 |.define CSAVE_4,       12(sp)
  78 |.define CSAVE_3,       8(sp)
  79 |.define CSAVE_2,       4(sp)
  80 |.define CSAVE_1,       0(sp)
  81 |//----- 8 byte aligned, ^^^^ 16 byte register save area, owned by callee.
  82 |
  83 |.define ARG5_OFS,      16
  84 |.define SAVE_MULTRES,  ARG5
  85 |
  86 |.macro saveregs
  87 |  addiu sp, sp, -CFRAME_SPACE
  88 |  sw ra, SAVE_GPR_+9*4(sp)
  89 |  sw r30, SAVE_GPR_+8*4(sp)
  90 |   sdc1 f30, SAVE_FPR_+5*8(sp)
  91 |  sw r23, SAVE_GPR_+7*4(sp)
  92 |  sw r22, SAVE_GPR_+6*4(sp)
  93 |   sdc1 f28, SAVE_FPR_+4*8(sp)
  94 |  sw r21, SAVE_GPR_+5*4(sp)
  95 |  sw r20, SAVE_GPR_+4*4(sp)
  96 |   sdc1 f26, SAVE_FPR_+3*8(sp)
  97 |  sw r19, SAVE_GPR_+3*4(sp)
  98 |  sw r18, SAVE_GPR_+2*4(sp)
  99 |   sdc1 f24, SAVE_FPR_+2*8(sp)
 100 |  sw r17, SAVE_GPR_+1*4(sp)
 101 |  sw r16, SAVE_GPR_+0*4(sp)
 102 |   sdc1 f22, SAVE_FPR_+1*8(sp)
 103 |   sdc1 f20, SAVE_FPR_+0*8(sp)
 104 |.endmacro
 105 |
 106 |.macro restoreregs_ret
 107 |  lw ra, SAVE_GPR_+9*4(sp)
 108 |  lw r30, SAVE_GPR_+8*4(sp)
 109 |   ldc1 f30, SAVE_FPR_+5*8(sp)
 110 |  lw r23, SAVE_GPR_+7*4(sp)
 111 |  lw r22, SAVE_GPR_+6*4(sp)
 112 |   ldc1 f28, SAVE_FPR_+4*8(sp)
 113 |  lw r21, SAVE_GPR_+5*4(sp)
 114 |  lw r20, SAVE_GPR_+4*4(sp)
 115 |   ldc1 f26, SAVE_FPR_+3*8(sp)
 116 |  lw r19, SAVE_GPR_+3*4(sp)
 117 |  lw r18, SAVE_GPR_+2*4(sp)
 118 |   ldc1 f24, SAVE_FPR_+2*8(sp)
 119 |  lw r17, SAVE_GPR_+1*4(sp)
 120 |  lw r16, SAVE_GPR_+0*4(sp)
 121 |   ldc1 f22, SAVE_FPR_+1*8(sp)
 122 |   ldc1 f20, SAVE_FPR_+0*8(sp)
 123 |  jr ra
 124 |  addiu sp, sp, CFRAME_SPACE
 125 |.endmacro
 126 |
 127 |// Type definitions. Some of these are only used for documentation.
 128 |.type L,               lua_State,      LREG
 129 |.type GL,              global_State
 130 |.type TVALUE,          TValue
 131 |.type GCOBJ,           GCobj
 132 |.type STR,             GCstr
 133 |.type TAB,             GCtab
 134 |.type LFUNC,           GCfuncL
 135 |.type CFUNC,           GCfuncC
 136 |.type PROTO,           GCproto
 137 |.type UPVAL,           GCupval
 138 |.type NODE,            Node
 139 |.type NARGS8,          int
 140 |.type TRACE,           GCtrace
 141 |
 142 |//-----------------------------------------------------------------------
 143 |
 144 |// Trap for not-yet-implemented parts.
 145 |.macro NYI; .long 0xf0f0f0f0; .endmacro
 146 |
 147 |// Macros to mark delay slots.
 148 |.macro ., a; a; .endmacro
 149 |.macro ., a,b; a,b; .endmacro
 150 |.macro ., a,b,c; a,b,c; .endmacro
 151 |
 152 |//-----------------------------------------------------------------------
 153 |
 154 |// Endian-specific defines.
 155 |.define FRAME_PC,      LJ_ENDIAN_SELECT(-4,-8)
 156 |.define FRAME_FUNC,    LJ_ENDIAN_SELECT(-8,-4)
 157 |.define HI,            LJ_ENDIAN_SELECT(4,0)
 158 |.define LO,            LJ_ENDIAN_SELECT(0,4)
 159 |.define OFS_RD,        LJ_ENDIAN_SELECT(2,0)
 160 |.define OFS_RA,        LJ_ENDIAN_SELECT(1,2)
 161 |.define OFS_OP,        LJ_ENDIAN_SELECT(0,3)
 162 |
 163 |// Instruction decode.
 164 |.macro decode_OP1, dst, ins; andi dst, ins, 0xff; .endmacro
 165 |.macro decode_OP4a, dst, ins; andi dst, ins, 0xff; .endmacro
 166 |.macro decode_OP4b, dst; sll dst, dst, 2; .endmacro
 167 |.macro decode_RC4a, dst, ins; srl dst, ins, 14; .endmacro
 168 |.macro decode_RC4b, dst; andi dst, dst, 0x3fc; .endmacro
 169 |.macro decode_RD4b, dst; sll dst, dst, 2; .endmacro
 170 |.macro decode_RA8a, dst, ins; srl dst, ins, 5; .endmacro
 171 |.macro decode_RA8b, dst; andi dst, dst, 0x7f8; .endmacro
 172 |.macro decode_RB8a, dst, ins; srl dst, ins, 21; .endmacro
 173 |.macro decode_RB8b, dst; andi dst, dst, 0x7f8; .endmacro
 174 |.macro decode_RD8a, dst, ins; srl dst, ins, 16; .endmacro
 175 |.macro decode_RD8b, dst; sll dst, dst, 3; .endmacro
 176 |.macro decode_RDtoRC8, dst, src; andi dst, src, 0x7f8; .endmacro
 177 |
 178 |// Instruction fetch.
 179 |.macro ins_NEXT1
 180 |  lw INS, 0(PC)
 181 |   addiu PC, PC, 4
 182 |.endmacro
 183 |// Instruction decode+dispatch.
 184 |.macro ins_NEXT2
 185 |  decode_OP4a TMP1, INS
 186 |  decode_OP4b TMP1
 187 |  addu TMP0, DISPATCH, TMP1
 188 |   decode_RD8a RD, INS
 189 |  lw AT, 0(TMP0)
 190 |   decode_RA8a RA, INS
 191 |   decode_RD8b RD
 192 |  jr AT
 193 |   decode_RA8b RA
 194 |.endmacro
 195 |.macro ins_NEXT
 196 |  ins_NEXT1
 197 |  ins_NEXT2
 198 |.endmacro
 199 |
 200 |// Instruction footer.
 201 |.if 1
 202 |  // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
 203 |  .define ins_next, ins_NEXT
 204 |  .define ins_next_, ins_NEXT
 205 |  .define ins_next1, ins_NEXT1
 206 |  .define ins_next2, ins_NEXT2
 207 |.else
 208 |  // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
 209 |  // Affects only certain kinds of benchmarks (and only with -j off).
 210 |  .macro ins_next
 211 |    b ->ins_next
 212 |  .endmacro
 213 |  .macro ins_next1
 214 |  .endmacro
 215 |  .macro ins_next2
 216 |    b ->ins_next
 217 |  .endmacro
 218 |  .macro ins_next_
 219 |  ->ins_next:
 220 |    ins_NEXT
 221 |  .endmacro
 222 |.endif
 223 |
 224 |// Call decode and dispatch.
 225 |.macro ins_callt
 226 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 227 |  lw PC, LFUNC:RB->pc
 228 |  lw INS, 0(PC)
 229 |   addiu PC, PC, 4
 230 |  decode_OP4a TMP1, INS
 231 |   decode_RA8a RA, INS
 232 |  decode_OP4b TMP1
 233 |   decode_RA8b RA
 234 |  addu TMP0, DISPATCH, TMP1
 235 |  lw TMP0, 0(TMP0)
 236 |  jr TMP0
 237 |   addu RA, RA, BASE
 238 |.endmacro
 239 |
 240 |.macro ins_call
 241 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
 242 |  sw PC, FRAME_PC(BASE)
 243 |  ins_callt
 244 |.endmacro
 245 |
 246 |//-----------------------------------------------------------------------
 247 |
 248 |.macro branch_RD
 249 |  srl TMP0, RD, 1
 250 |  lui AT, (-(BCBIAS_J*4 >> 16) & 65535)
 251 |  addu TMP0, TMP0, AT
 252 |  addu PC, PC, TMP0
 253 |.endmacro
 254 |
 255 |// Assumes DISPATCH is relative to GL.
 256 #define DISPATCH_GL(field)      (GG_DISP2G + (int)offsetof(global_State, field))
 257 #define DISPATCH_J(field)       (GG_DISP2J + (int)offsetof(jit_State, field))
 258 #define GG_DISP2GOT             (GG_OFS(got) - GG_OFS(dispatch))
 259 #define DISPATCH_GOT(name)      (GG_DISP2GOT + 4*LJ_GOT_##name)
 260 |
 261 #define PC2PROTO(field)  ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
 262 |
 263 |.macro load_got, func
 264 |  lw CFUNCADDR, DISPATCH_GOT(func)(DISPATCH)
 265 |.endmacro
 266 |// Much faster. Sadly, there's no easy way to force the required code layout.
 267 |// .macro call_intern, func; bal extern func; .endmacro
 268 |.macro call_intern, func; jalr CFUNCADDR; .endmacro
 269 |.macro call_extern; jalr CFUNCADDR; .endmacro
 270 |.macro jmp_extern; jr CFUNCADDR; .endmacro
 271 |
 272 |.macro hotcheck, delta, target
 273 |  srl TMP1, PC, 1
 274 |  andi TMP1, TMP1, 126
 275 |  addu TMP1, TMP1, DISPATCH
 276 |  lhu TMP2, GG_DISP2HOT(TMP1)
 277 |  addiu TMP2, TMP2, -delta
 278 |  bltz TMP2, target
 279 |.  sh TMP2, GG_DISP2HOT(TMP1)
 280 |.endmacro
 281 |
 282 |.macro hotloop
 283 |  hotcheck HOTCOUNT_LOOP, ->vm_hotloop
 284 |.endmacro
 285 |
 286 |.macro hotcall
 287 |  hotcheck HOTCOUNT_CALL, ->vm_hotcall
 288 |.endmacro
 289 |
 290 |// Set current VM state. Uses TMP0.
 291 |.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
 292 |.macro st_vmstate; sw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
 293 |
 294 |// Move table write barrier back. Overwrites mark and tmp.
 295 |.macro barrierback, tab, mark, tmp, target
 296 |  lw tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
 297 |   andi mark, mark, ~LJ_GC_BLACK & 255         // black2gray(tab)
 298 |  sw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
 299 |   sb mark, tab->marked
 300 |  b target
 301 |.  sw tmp, tab->gclist
 302 |.endmacro
 303 |
 304 |//-----------------------------------------------------------------------
 305
 306 /* Generate subroutines used by opcodes and other parts of the VM. */
 307 /* The .code_sub section should be last to help static branch prediction. */
 308 static void build_subroutines(BuildCtx *ctx)
 309 {
 310   |.code_sub
 311   |
 312   |//-----------------------------------------------------------------------
 313   |//-- Return handling ----------------------------------------------------
 314   |//-----------------------------------------------------------------------
 315   |
 316   |->vm_returnp:
 317   |  // See vm_return. Also: TMP2 = previous base.
 318   |  andi AT, PC, FRAME_P
 319   |  beqz AT, ->cont_dispatch
 320   |.  li TMP1, LJ_TTRUE
 321   |
 322   |  // Return from pcall or xpcall fast func.
 323   |  lw PC, FRAME_PC(TMP2)              // Fetch PC of previous frame.
 324   |  move BASE, TMP2                    // Restore caller base.
 325   |  // Prepending may overwrite the pcall frame, so do it at the end.
 326   |   sw TMP1, FRAME_PC(RA)             // Prepend true to results.
 327   |   addiu RA, RA, -8
 328   |
 329   |->vm_returnc:
 330   |  andi TMP0, PC, FRAME_TYPE
 331   |   addiu RD, RD, 8                   // RD = (nresults+1)*8.
 332   |  beqz TMP0, ->BC_RET_Z              // Handle regular return to Lua.
 333   |.  move MULTRES, RD
 334   |
 335   |->vm_return:
 336   |  // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
 337   |  // TMP0 = PC & FRAME_TYPE
 338   |   li TMP2, -8
 339   |  xori AT, TMP0, FRAME_C
 340   |   and TMP2, PC, TMP2
 341   |  bnez AT, ->vm_returnp
 342   |   subu TMP2, BASE, TMP2             // TMP2 = previous base.
 343   |
 344   |  addiu TMP1, RD, -8
 345   |   sw TMP2, L->base
 346   |    li_vmstate C
 347   |   lw TMP2, SAVE_NRES
 348   |   addiu BASE, BASE, -8
 349   |    st_vmstate
 350   |  beqz TMP1, >2
 351   |.   sll TMP2, TMP2, 3
 352   |1:
 353   |  addiu TMP1, TMP1, -8
 354   |   ldc1 f0, 0(RA)
 355   |    addiu RA, RA, 8
 356   |   sdc1 f0, 0(BASE)
 357   |  bnez TMP1, <1
 358   |.  addiu BASE, BASE, 8
 359   |
 360   |2:
 361   |  bne TMP2, RD, >6
 362   |3:
 363   |.  sw BASE, L->top                   // Store new top.
 364   |
 365   |->vm_leave_cp:
 366   |  lw TMP0, SAVE_CFRAME               // Restore previous C frame.
 367   |   move CRET1, r0                    // Ok return status for vm_pcall.
 368   |  sw TMP0, L->cframe
 369   |
 370   |->vm_leave_unw:
 371   |  restoreregs_ret
 372   |
 373   |6:
 374   |  lw TMP1, L->maxstack
 375   |  slt AT, TMP2, RD
 376   |  bnez AT, >7                        // Less results wanted?
 377   |  // More results wanted. Check stack size and fill up results with nil.
 378   |.  slt AT, BASE, TMP1
 379   |  beqz AT, >8
 380   |.  nop
 381   |  sw TISNIL, HI(BASE)
 382   |  addiu RD, RD, 8
 383   |  b <2
 384   |.  addiu BASE, BASE, 8
 385   |
 386   |7:  // Less results wanted.
 387   |  subu TMP0, RD, TMP2
 388   |  subu TMP0, BASE, TMP0              // Either keep top or shrink it.
 389   |  b <3
 390   |.  movn BASE, TMP0, TMP2             // LUA_MULTRET+1 case?
 391   |
 392   |8:  // Corner case: need to grow stack for filling up results.
 393   |  // This can happen if:
 394   |  // - A C function grows the stack (a lot).
 395   |  // - The GC shrinks the stack in between.
 396   |  // - A return back from a lua_call() with (high) nresults adjustment.
 397   |  load_got lj_state_growstack
 398   |   move MULTRES, RD
 399   |  move CARG2, TMP2
 400   |  call_intern lj_state_growstack     // (lua_State *L, int n)
 401   |.  move CARG1, L
 402   |    lw TMP2, SAVE_NRES
 403   |  lw BASE, L->top                    // Need the (realloced) L->top in BASE.
 404   |   move RD, MULTRES
 405   |  b <2
 406   |.   sll TMP2, TMP2, 3
 407   |
 408   |->vm_unwind_c:                       // Unwind C stack, return from vm_pcall.
 409   |  // (void *cframe, int errcode)
 410   |  move sp, CARG1
 411   |  move CRET1, CARG2
 412   |->vm_unwind_c_eh:                    // Landing pad for external unwinder.
 413   |  lw L, SAVE_L
 414   |   li TMP0, ~LJ_VMST_C
 415   |  lw GL:TMP1, L->glref
 416   |  b ->vm_leave_unw
 417   |.  sw TMP0, GL:TMP1->vmstate
 418   |
 419   |->vm_unwind_ff:                      // Unwind C stack, return from ff pcall.
 420   |  // (void *cframe)
 421   |  li AT, -4
 422   |  and sp, CARG1, AT
 423   |->vm_unwind_ff_eh:                   // Landing pad for external unwinder.
 424   |  lw L, SAVE_L
 425   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 426   |     li TISNIL, LJ_TNIL
 427   |  lw BASE, L->base
 428   |   lw DISPATCH, L->glref             // Setup pointer to dispatch table.
 429   |     mtc1 TMP3, TOBIT
 430   |  li TMP1, LJ_TFALSE
 431   |    li_vmstate INTERP
 432   |  lw PC, FRAME_PC(BASE)              // Fetch PC of previous frame.
 433   |     cvt.d.s TOBIT, TOBIT
 434   |  addiu RA, BASE, -8                 // Results start at BASE-8.
 435   |   addiu DISPATCH, DISPATCH, GG_G2DISP
 436   |  sw TMP1, HI(RA)                    // Prepend false to error message.
 437   |    st_vmstate
 438   |  b ->vm_returnc
 439   |.  li RD, 16                         // 2 results: false + error message.
 440   |
 441   |//-----------------------------------------------------------------------
 442   |//-- Grow stack for calls -----------------------------------------------
 443   |//-----------------------------------------------------------------------
 444   |
 445   |->vm_growstack_c:                    // Grow stack for C function.
 446   |  b >2
 447   |.  li CARG2, LUA_MINSTACK
 448   |
 449   |->vm_growstack_l:                    // Grow stack for Lua function.
 450   |  // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
 451   |  addu RC, BASE, RC
 452   |   subu RA, RA, BASE
 453   |  sw BASE, L->base
 454   |   addiu PC, PC, 4                   // Must point after first instruction.
 455   |  sw RC, L->top
 456   |   srl CARG2, RA, 3
 457   |2:
 458   |  // L->base = new base, L->top = top
 459   |  load_got lj_state_growstack
 460   |   sw PC, SAVE_PC
 461   |  call_intern lj_state_growstack     // (lua_State *L, int n)
 462   |.  move CARG1, L
 463   |  lw BASE, L->base
 464   |  lw RC, L->top
 465   |  lw LFUNC:RB, FRAME_FUNC(BASE)
 466   |  subu RC, RC, BASE
 467   |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 468   |  ins_callt                          // Just retry the call.
 469   |
 470   |//-----------------------------------------------------------------------
 471   |//-- Entry points into the assembler VM ---------------------------------
 472   |//-----------------------------------------------------------------------
 473   |
 474   |->vm_resume:                         // Setup C frame and resume thread.
 475   |  // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
 476   |  saveregs
 477   |  move L, CARG1
 478   |    lw DISPATCH, L->glref            // Setup pointer to dispatch table.
 479   |  move BASE, CARG2
 480   |    lbu TMP1, L->status
 481   |   sw L, SAVE_L
 482   |  li PC, FRAME_CP
 483   |  addiu TMP0, sp, CFRAME_RESUME
 484   |    addiu DISPATCH, DISPATCH, GG_G2DISP
 485   |   sw r0, SAVE_NRES
 486   |   sw r0, SAVE_ERRF
 487   |  sw TMP0, L->cframe
 488   |   sw r0, SAVE_CFRAME
 489   |    beqz TMP1, >3
 490   |.  sw CARG1, SAVE_PC         // Any value outside of bytecode is ok.
 491   |
 492   |  // Resume after yield (like a return).
 493   |  move RA, BASE
 494   |   lw BASE, L->base
 495   |   lw TMP1, L->top
 496   |  lw PC, FRAME_PC(BASE)
 497   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 498   |   subu RD, TMP1, BASE
 499   |     mtc1 TMP3, TOBIT
 500   |    sb r0, L->status
 501   |     cvt.d.s TOBIT, TOBIT
 502   |    li_vmstate INTERP
 503   |   addiu RD, RD, 8
 504   |    st_vmstate
 505   |   move MULTRES, RD
 506   |  andi TMP0, PC, FRAME_TYPE
 507   |  beqz TMP0, ->BC_RET_Z
 508   |.    li TISNIL, LJ_TNIL
 509   |  b ->vm_return
 510   |.  nop
 511   |
 512   |->vm_pcall:                          // Setup protected C frame and enter VM.
 513   |  // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
 514   |  saveregs
 515   |  sw CARG4, SAVE_ERRF
 516   |  b >1
 517   |.  li PC, FRAME_CP
 518   |
 519   |->vm_call:                           // Setup C frame and enter VM.
 520   |  // (lua_State *L, TValue *base, int nres1)
 521   |  saveregs
 522   |  li PC, FRAME_C
 523   |
 524   |1:  // Entry point for vm_pcall above (PC = ftype).
 525   |  lw TMP1, L:CARG1->cframe
 526   |   sw CARG3, SAVE_NRES
 527   |    move L, CARG1
 528   |   sw CARG1, SAVE_L
 529   |    move BASE, CARG2
 530   |  sw sp, L->cframe                   // Add our C frame to cframe chain.
 531   |    lw DISPATCH, L->glref            // Setup pointer to dispatch table.
 532   |   sw CARG1, SAVE_PC         // Any value outside of bytecode is ok.
 533   |  sw TMP1, SAVE_CFRAME
 534   |    addiu DISPATCH, DISPATCH, GG_G2DISP
 535   |
 536   |3:  // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
 537   |  lw TMP2, L->base                   // TMP2 = old base (used in vmeta_call).
 538   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 539   |   lw TMP1, L->top
 540   |     mtc1 TMP3, TOBIT
 541   |  addu PC, PC, BASE
 542   |   subu NARGS8:RC, TMP1, BASE
 543   |  subu PC, PC, TMP2                  // PC = frame delta + frame type
 544   |     cvt.d.s TOBIT, TOBIT
 545   |    li_vmstate INTERP
 546   |     li TISNIL, LJ_TNIL
 547   |    st_vmstate
 548   |
 549   |->vm_call_dispatch:
 550   |  // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
 551   |  lw TMP0, FRAME_PC(BASE)
 552   |  li AT, LJ_TFUNC
 553   |  bne TMP0, AT, ->vmeta_call
 554   |.  lw LFUNC:RB, FRAME_FUNC(BASE)
 555   |
 556   |->vm_call_dispatch_f:
 557   |  ins_call
 558   |  // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
 559   |
 560   |->vm_cpcall:                         // Setup protected C frame, call C.
 561   |  // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
 562   |  saveregs
 563   |  move L, CARG1
 564   |   lw TMP0, L:CARG1->stack
 565   |  sw CARG1, SAVE_L
 566   |   lw TMP1, L->top
 567   |  sw CARG1, SAVE_PC                  // Any value outside of bytecode is ok.
 568   |   subu TMP0, TMP0, TMP1             // Compute -savestack(L, L->top).
 569   |    lw TMP1, L->cframe
 570   |    sw sp, L->cframe                 // Add our C frame to cframe chain.
 571   |   sw TMP0, SAVE_NRES                // Neg. delta means cframe w/o frame.
 572   |  sw r0, SAVE_ERRF                   // No error function.
 573   |  move CFUNCADDR, CARG4
 574   |  jalr CARG4                 // (lua_State *L, lua_CFunction func, void *ud)
 575   |.   sw TMP1, SAVE_CFRAME
 576   |  move BASE, CRET1
 577   |   lw DISPATCH, L->glref             // Setup pointer to dispatch table.
 578   |    li PC, FRAME_CP
 579   |  bnez CRET1, <3                     // Else continue with the call.
 580   |.  addiu DISPATCH, DISPATCH, GG_G2DISP
 581   |  b ->vm_leave_cp                    // No base? Just remove C frame.
 582   |.  nop
 583   |
 584   |//-----------------------------------------------------------------------
 585   |//-- Metamethod handling ------------------------------------------------
 586   |//-----------------------------------------------------------------------
 587   |
 588   |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
 589   |// stack, so BASE doesn't need to be reloaded across these calls.
 590   |
 591   |//-- Continuation dispatch ----------------------------------------------
 592   |
 593   |->cont_dispatch:
 594   |  // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
 595   |  lw TMP0, -16+LO(BASE)              // Continuation.
 596   |   move RB, BASE
 597   |   move BASE, TMP2                   // Restore caller BASE.
 598   |    lw LFUNC:TMP1, FRAME_FUNC(TMP2)
 599   |.if FFI
 600   |  sltiu AT, TMP0, 2
 601   |.endif
 602   |     lw PC, -16+HI(RB)               // Restore PC from [cont|PC].
 603   |   addu TMP2, RA, RD
 604   |    lw TMP1, LFUNC:TMP1->pc
 605   |.if FFI
 606   |  bnez AT, >1
 607   |.endif
 608   |.  sw TISNIL, -8+HI(TMP2)            // Ensure one valid arg.
 609   |  // BASE = base, RA = resultptr, RB = meta base
 610   |  jr TMP0                            // Jump to continuation.
 611   |.  lw KBASE, PC2PROTO(k)(TMP1)
 612   |
 613   |.if FFI
 614   |1:
 615   |  bnez TMP0, ->cont_ffi_callback     // cont = 1: return from FFI callback.
 616   |  // cont = 0: tailcall from C function.
 617   |.  addiu TMP1, RB, -16
 618   |  b ->vm_call_tail
 619   |.  subu RC, TMP1, BASE
 620   |.endif
 621   |
 622   |->cont_cat:                          // RA = resultptr, RB = meta base
 623   |  lw INS, -4(PC)
 624   |   addiu CARG2, RB, -16
 625   |   ldc1 f0, 0(RA)
 626   |  decode_RB8a MULTRES, INS
 627   |   decode_RA8a RA, INS
 628   |  decode_RB8b MULTRES
 629   |   decode_RA8b RA
 630   |  addu TMP1, BASE, MULTRES
 631   |   sw BASE, L->base
 632   |   subu CARG3, CARG2, TMP1
 633   |  bne TMP1, CARG2, ->BC_CAT_Z
 634   |.  sdc1 f0, 0(CARG2)
 635   |  addu RA, BASE, RA
 636   |  b ->cont_nop
 637   |.  sdc1 f0, 0(RA)
 638   |
 639   |//-- Table indexing metamethods -----------------------------------------
 640   |
 641   |->vmeta_tgets1:
 642   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 643   |  li TMP0, LJ_TSTR
 644   |  sw STR:RC, LO(CARG3)
 645   |  b >1
 646   |.  sw TMP0, HI(CARG3)
 647   |
 648   |->vmeta_tgets:
 649   |  addiu CARG2, DISPATCH, DISPATCH_GL(tmptv)
 650   |  li TMP0, LJ_TTAB
 651   |  sw TAB:RB, LO(CARG2)
 652   |   addiu CARG3, DISPATCH, DISPATCH_GL(tmptv2)
 653   |  sw TMP0, HI(CARG2)
 654   |   li TMP1, LJ_TSTR
 655   |   sw STR:RC, LO(CARG3)
 656   |  b >1
 657   |.  sw TMP1, HI(CARG3)
 658   |
 659   |->vmeta_tgetb:                       // TMP0 = index
 660   |  mtc1 TMP0, f0
 661   |  cvt.d.w f0, f0
 662   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 663   |  sdc1 f0, 0(CARG3)
 664   |
 665   |->vmeta_tgetv:
 666   |1:
 667   |  load_got lj_meta_tget
 668   |  sw BASE, L->base
 669   |  sw PC, SAVE_PC
 670   |  call_intern lj_meta_tget           // (lua_State *L, TValue *o, TValue *k)
 671   |.  move CARG1, L
 672   |  // Returns TValue * (finished) or NULL (metamethod).
 673   |  beqz CRET1, >3
 674   |.  addiu TMP1, BASE, -FRAME_CONT
 675   |  ldc1 f0, 0(CRET1)
 676   |  ins_next1
 677   |   sdc1 f0, 0(RA)
 678   |  ins_next2
 679   |
 680   |3:  // Call __index metamethod.
 681   |  // BASE = base, L->top = new base, stack = cont/func/t/k
 682   |  lw BASE, L->top
 683   |  sw PC, -16+HI(BASE)                // [cont|PC]
 684   |   subu PC, BASE, TMP1
 685   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 686   |  b ->vm_call_dispatch_f
 687   |.  li NARGS8:RC, 16                  // 2 args for func(t, k).
 688   |
 689   |//-----------------------------------------------------------------------
 690   |
 691   |->vmeta_tsets1:
 692   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 693   |  li TMP0, LJ_TSTR
 694   |  sw STR:RC, LO(CARG3)
 695   |  b >1
 696   |.  sw TMP0, HI(CARG3)
 697   |
 698   |->vmeta_tsets:
 699   |  addiu CARG2, DISPATCH, DISPATCH_GL(tmptv)
 700   |  li TMP0, LJ_TTAB
 701   |  sw TAB:RB, LO(CARG2)
 702   |   addiu CARG3, DISPATCH, DISPATCH_GL(tmptv2)
 703   |  sw TMP0, HI(CARG2)
 704   |   li TMP1, LJ_TSTR
 705   |   sw STR:RC, LO(CARG3)
 706   |  b >1
 707   |.  sw TMP1, HI(CARG3)
 708   |
 709   |->vmeta_tsetb:                       // TMP0 = index
 710   |  mtc1 TMP0, f0
 711   |  cvt.d.w f0, f0
 712   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 713   |  sdc1 f0, 0(CARG3)
 714   |
 715   |->vmeta_tsetv:
 716   |1:
 717   |  load_got lj_meta_tset
 718   |  sw BASE, L->base
 719   |  sw PC, SAVE_PC
 720   |  call_intern lj_meta_tset           // (lua_State *L, TValue *o, TValue *k)
 721   |.  move CARG1, L
 722   |  // Returns TValue * (finished) or NULL (metamethod).
 723   |  beqz CRET1, >3
 724   |.  ldc1 f0, 0(RA)
 725   |  // NOBARRIER: lj_meta_tset ensures the table is not black.
 726   |  ins_next1
 727   |   sdc1 f0, 0(CRET1)
 728   |  ins_next2
 729   |
 730   |3:  // Call __newindex metamethod.
 731   |  // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
 732   |  addiu TMP1, BASE, -FRAME_CONT
 733   |  lw BASE, L->top
 734   |  sw PC, -16+HI(BASE)                // [cont|PC]
 735   |   subu PC, BASE, TMP1
 736   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 737   |  sdc1 f0, 16(BASE)                  // Copy value to third argument.
 738   |  b ->vm_call_dispatch_f
 739   |.  li NARGS8:RC, 24                  // 3 args for func(t, k, v)
 740   |
 741   |//-- Comparison metamethods ---------------------------------------------
 742   |
 743   |->vmeta_comp:
 744   |  // CARG2, CARG3 are already set by BC_ISLT/BC_ISGE/BC_ISLE/BC_ISGT.
 745   |  load_got lj_meta_comp
 746   |  addiu PC, PC, -4
 747   |  sw BASE, L->base
 748   |  sw PC, SAVE_PC
 749   |  decode_OP1 CARG4, INS
 750   |  call_intern lj_meta_comp   // (lua_State *L, TValue *o1, *o2, int op)
 751   |.  move CARG1, L
 752   |  // Returns 0/1 or TValue * (metamethod).
 753   |3:
 754   |  sltiu AT, CRET1, 2
 755   |  beqz AT, ->vmeta_binop
 756   |   negu TMP2, CRET1
 757   |4:
 758   |  lhu RD, OFS_RD(PC)
 759   |   addiu PC, PC, 4
 760   |   lui TMP1, (-(BCBIAS_J*4 >> 16) & 65535)
 761   |  sll RD, RD, 2
 762   |  addu RD, RD, TMP1
 763   |  and RD, RD, TMP2
 764   |  addu PC, PC, RD
 765   |->cont_nop:
 766   |  ins_next
 767   |
 768   |->cont_ra:                           // RA = resultptr
 769   |  lbu TMP1, -4+OFS_RA(PC)
 770   |   ldc1 f0, 0(RA)
 771   |  sll TMP1, TMP1, 3
 772   |  addu TMP1, BASE, TMP1
 773   |  b ->cont_nop
 774   |.  sdc1 f0, 0(TMP1)
 775   |
 776   |->cont_condt:                        // RA = resultptr
 777   |  lw TMP0, HI(RA)
 778   |  sltiu AT, TMP0, LJ_TISTRUECOND
 779   |  b <4
 780   |.  negu TMP2, AT                     // Branch if result is true.
 781   |
 782   |->cont_condf:                        // RA = resultptr
 783   |  lw TMP0, HI(RA)
 784   |  sltiu AT, TMP0, LJ_TISTRUECOND
 785   |  b <4
 786   |.  addiu TMP2, AT, -1                // Branch if result is false.
 787   |
 788   |->vmeta_equal:
 789   |  // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
 790   |  load_got lj_meta_equal
 791   |  addiu PC, PC, -4
 792   |   sw BASE, L->base
 793   |   sw PC, SAVE_PC
 794   |  call_intern lj_meta_equal  // (lua_State *L, GCobj *o1, *o2, int ne)
 795   |.  move CARG1, L
 796   |  // Returns 0/1 or TValue * (metamethod).
 797   |  b <3
 798   |.  nop
 799   |
 800   |->vmeta_equal_cd:
 801   |.if FFI
 802   |  load_got lj_meta_equal_cd
 803   |  move CARG2, INS
 804   |  addiu PC, PC, -4
 805   |   sw BASE, L->base
 806   |   sw PC, SAVE_PC
 807   |  call_intern lj_meta_equal_cd       // (lua_State *L, BCIns op)
 808   |.  move CARG1, L
 809   |  // Returns 0/1 or TValue * (metamethod).
 810   |  b <3
 811   |.  nop
 812   |.endif
 813   |
 814   |//-- Arithmetic metamethods ---------------------------------------------
 815   |
 816   |->vmeta_unm:
 817   |  move CARG4, CARG3
 818   |
 819   |->vmeta_arith:
 820   |  load_got lj_meta_arith
 821   |  decode_OP1 TMP0, INS
 822   |   sw BASE, L->base
 823   |   sw PC, SAVE_PC
 824   |  move CARG2, RA
 825   |  sw TMP0, ARG5
 826   |  call_intern lj_meta_arith  // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
 827   |.  move CARG1, L
 828   |  // Returns NULL (finished) or TValue * (metamethod).
 829   |  beqz CRET1, ->cont_nop
 830   |.  nop
 831   |
 832   |  // Call metamethod for binary op.
 833   |->vmeta_binop:
 834   |  // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
 835   |  subu TMP1, CRET1, BASE
 836   |   sw PC, -16+HI(CRET1)              // [cont|PC]
 837   |   move TMP2, BASE
 838   |  addiu PC, TMP1, FRAME_CONT
 839   |   move BASE, CRET1
 840   |  b ->vm_call_dispatch
 841   |.  li NARGS8:RC, 16                  // 2 args for func(o1, o2).
 842   |
 843   |->vmeta_len:
 844   |  // CARG2 already set by BC_LEN.
 845 #if LJ_52
 846   |  move MULTRES, CARG1
 847 #endif
 848   |  load_got lj_meta_len
 849   |   sw BASE, L->base
 850   |   sw PC, SAVE_PC
 851   |  call_intern lj_meta_len            // (lua_State *L, TValue *o)
 852   |.  move CARG1, L
 853   |  // Returns NULL (retry) or TValue * (metamethod base).
 854 #if LJ_52
 855   |  bnez CRET1, ->vmeta_binop          // Binop call for compatibility.
 856   |.  nop
 857   |  b ->BC_LEN_Z
 858   |.  move CARG1, MULTRES
 859 #else
 860   |  b ->vmeta_binop                    // Binop call for compatibility.
 861   |.  nop
 862 #endif
 863   |
 864   |//-- Call metamethod ----------------------------------------------------
 865   |
 866   |->vmeta_call:                        // Resolve and call __call metamethod.
 867   |  // TMP2 = old base, BASE = new base, RC = nargs*8
 868   |  load_got lj_meta_call
 869   |   sw TMP2, L->base                  // This is the callers base!
 870   |  addiu CARG2, BASE, -8
 871   |   sw PC, SAVE_PC
 872   |  addu CARG3, BASE, RC
 873   |   move MULTRES, NARGS8:RC
 874   |  call_intern lj_meta_call   // (lua_State *L, TValue *func, TValue *top)
 875   |.  move CARG1, L
 876   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 877   |   addiu NARGS8:RC, MULTRES, 8       // Got one more argument now.
 878   |  ins_call
 879   |
 880   |->vmeta_callt:                       // Resolve __call for BC_CALLT.
 881   |  // BASE = old base, RA = new base, RC = nargs*8
 882   |  load_got lj_meta_call
 883   |   sw BASE, L->base
 884   |  addiu CARG2, RA, -8
 885   |   sw PC, SAVE_PC
 886   |  addu CARG3, RA, RC
 887   |   move MULTRES, NARGS8:RC
 888   |  call_intern lj_meta_call   // (lua_State *L, TValue *func, TValue *top)
 889   |.  move CARG1, L
 890   |  lw TMP1, FRAME_PC(BASE)
 891   |   lw LFUNC:RB, FRAME_FUNC(RA)       // Guaranteed to be a function here.
 892   |  b ->BC_CALLT_Z
 893   |.  addiu NARGS8:RC, MULTRES, 8       // Got one more argument now.
 894   |
 895   |//-- Argument coercion for 'for' statement ------------------------------
 896   |
 897   |->vmeta_for:
 898   |  load_got lj_meta_for
 899   |   sw BASE, L->base
 900   |  move CARG2, RA
 901   |   sw PC, SAVE_PC
 902   |  move MULTRES, INS
 903   |  call_intern lj_meta_for    // (lua_State *L, TValue *base)
 904   |.  move CARG1, L
 905   |.if JIT
 906   |  decode_OP1 TMP0, MULTRES
 907   |  li AT, BC_JFORI
 908   |.endif
 909   |  decode_RA8a RA, MULTRES
 910   |   decode_RD8a RD, MULTRES
 911   |  decode_RA8b RA
 912   |.if JIT
 913   |  beq TMP0, AT, =>BC_JFORI
 914   |.  decode_RD8b RD
 915   |  b =>BC_FORI
 916   |.  nop
 917   |.else
 918   |  b =>BC_FORI
 919   |.  decode_RD8b RD
 920   |.endif
 921   |
 922   |//-----------------------------------------------------------------------
 923   |//-- Fast functions -----------------------------------------------------
 924   |//-----------------------------------------------------------------------
 925   |
 926   |.macro .ffunc, name
 927   |->ff_ .. name:
 928   |.endmacro
 929   |
 930   |.macro .ffunc_1, name
 931   |->ff_ .. name:
 932   |  beqz NARGS8:RC, ->fff_fallback
 933   |.  lw CARG3, HI(BASE)
 934   |    lw CARG1, LO(BASE)
 935   |.endmacro
 936   |
 937   |.macro .ffunc_2, name
 938   |->ff_ .. name:
 939   |  sltiu AT, NARGS8:RC, 16
 940   |   lw CARG3, HI(BASE)
 941   |  bnez AT, ->fff_fallback
 942   |.   lw CARG4, 8+HI(BASE)
 943   |   lw CARG1, LO(BASE)
 944   |    lw CARG2, 8+LO(BASE)
 945   |.endmacro
 946   |
 947   |.macro .ffunc_n, name        // Caveat: has delay slot!
 948   |->ff_ .. name:
 949   |  lw CARG3, HI(BASE)
 950   |  beqz NARGS8:RC, ->fff_fallback
 951   |.  ldc1 FARG1, 0(BASE)
 952   |  sltiu AT, CARG3, LJ_TISNUM
 953   |  beqz AT, ->fff_fallback
 954   |.endmacro
 955   |
 956   |.macro .ffunc_nn, name       // Caveat: has delay slot!
 957   |->ff_ .. name:
 958   |  sltiu AT, NARGS8:RC, 16
 959   |   lw CARG3, HI(BASE)
 960   |  bnez AT, ->fff_fallback
 961   |.  lw CARG4, 8+HI(BASE)
 962   |  ldc1 FARG1, 0(BASE)
 963   |  ldc1 FARG2, 8(BASE)
 964   |  sltiu TMP0, CARG3, LJ_TISNUM
 965   |  sltiu TMP1, CARG4, LJ_TISNUM
 966   |  and TMP0, TMP0, TMP1
 967   |  beqz TMP0, ->fff_fallback
 968   |.endmacro
 969   |
 970   |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1 and has delay slot!
 971   |.macro ffgccheck
 972   |  lw TMP0, DISPATCH_GL(gc.total)(DISPATCH)
 973   |  lw TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
 974   |  subu AT, TMP0, TMP1
 975   |  bgezal AT, ->fff_gcstep
 976   |.endmacro
 977   |
 978   |//-- Base library: checks -----------------------------------------------
 979   |
 980   |.ffunc_1 assert
 981   |  sltiu AT, CARG3, LJ_TISTRUECOND
 982   |  beqz AT, ->fff_fallback
 983   |.  addiu RA, BASE, -8
 984   |  lw PC, FRAME_PC(BASE)
 985   |  addiu RD, NARGS8:RC, 8             // Compute (nresults+1)*8.
 986   |  addu TMP2, RA, NARGS8:RC
 987   |   sw CARG3, HI(RA)
 988   |  addiu TMP1, BASE, 8
 989   |  beq BASE, TMP2, ->fff_res          // Done if exactly 1 argument.
 990   |.  sw CARG1, LO(RA)
 991   |1:
 992   |  ldc1 f0, 0(TMP1)
 993   |  sdc1 f0, -8(TMP1)
 994   |  bne TMP1, TMP2, <1
 995   |.  addiu TMP1, TMP1, 8
 996   |  b ->fff_res
 997   |.  nop
 998   |
 999   |.ffunc type
1000   |  lw CARG3, HI(BASE)
1001   |  li TMP1, LJ_TISNUM
1002   |  beqz NARGS8:RC, ->fff_fallback
1003   |.  sltiu TMP0, CARG3, LJ_TISNUM
1004   |  movz TMP1, CARG3, TMP0
1005   |  not TMP1, TMP1
1006   |  sll TMP1, TMP1, 3
1007   |  addu TMP1, CFUNC:RB, TMP1
1008   |  b ->fff_resn
1009   |.  ldc1 FRET1, CFUNC:TMP1->upvalue
1010   |
1011   |//-- Base library: getters and setters ---------------------------------
1012   |
1013   |.ffunc_1 getmetatable
1014   |  li AT, LJ_TTAB
1015   |  bne CARG3, AT, >6
1016   |.  li AT, LJ_TUDATA
1017   |1:  // Field metatable must be at same offset for GCtab and GCudata!
1018   |  lw TAB:CARG1, TAB:CARG1->metatable
1019   |2:
1020   |  lw STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
1021   |  beqz TAB:CARG1, ->fff_restv
1022   |.  li CARG3, LJ_TNIL
1023   |  lw TMP0, TAB:CARG1->hmask
1024   |   li CARG3, LJ_TTAB                 // Use metatable as default result.
1025   |  lw TMP1, STR:RC->hash
1026   |  lw NODE:TMP2, TAB:CARG1->node
1027   |  and TMP1, TMP1, TMP0               // idx = str->hash & tab->hmask
1028   |  sll TMP0, TMP1, 5
1029   |  sll TMP1, TMP1, 3
1030   |  subu TMP1, TMP0, TMP1
1031   |  addu NODE:TMP2, NODE:TMP2, TMP1    // node = tab->node + (idx*32-idx*8)
1032   |  li AT, LJ_TSTR
1033   |3:  // Rearranged logic, because we expect _not_ to find the key.
1034   |  lw CARG4, offsetof(Node, key)+HI(NODE:TMP2)
1035   |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
1036   |    lw NODE:TMP3, NODE:TMP2->next
1037   |  bne CARG4, AT, >4
1038   |.    lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
1039   |  beq TMP0, STR:RC, >5
1040   |.    lw TMP1, offsetof(Node, val)+LO(NODE:TMP2)
1041   |4:
1042   |  beqz NODE:TMP3, ->fff_restv        // Not found, keep default result.
1043   |.  move NODE:TMP2, NODE:TMP3
1044   |  b <3
1045   |.  nop
1046   |5:
1047   |  beq CARG2, TISNIL, ->fff_restv     // Ditto for nil value.
1048   |.  nop
1049   |  move CARG3, CARG2                  // Return value of mt.__metatable.
1050   |  b ->fff_restv
1051   |.  move CARG1, TMP1
1052   |
1053   |6:
1054   |  beq CARG3, AT, <1
1055   |.  sltiu TMP0, CARG3, LJ_TISNUM
1056   |  li TMP1, LJ_TISNUM
1057   |  movz TMP1, CARG3, TMP0
1058   |  not TMP1, TMP1
1059   |  sll TMP1, TMP1, 2
1060   |  addu TMP1, DISPATCH, TMP1
1061   |  b <2
1062   |.  lw TAB:CARG1, DISPATCH_GL(gcroot[GCROOT_BASEMT])(TMP1)
1063   |
1064   |.ffunc_2 setmetatable
1065   |  // Fast path: no mt for table yet and not clearing the mt.
1066   |  li AT, LJ_TTAB
1067   |  bne CARG3, AT, ->fff_fallback
1068   |.  addiu CARG4, CARG4, -LJ_TTAB
1069   |  lw TAB:TMP1, TAB:CARG1->metatable
1070   |   lbu TMP3, TAB:CARG1->marked
1071   |  or AT, CARG4, TAB:TMP1
1072   |  bnez AT, ->fff_fallback
1073   |.  andi AT, TMP3, LJ_GC_BLACK        // isblack(table)
1074   |  beqz AT, ->fff_restv
1075   |.  sw TAB:CARG2, TAB:CARG1->metatable
1076   |  barrierback TAB:CARG1, TMP3, TMP0, ->fff_restv
1077   |
1078   |.ffunc rawget
1079   |  lw CARG4, HI(BASE)
1080   |   sltiu AT, NARGS8:RC, 16
1081   |    lw TAB:CARG2, LO(BASE)
1082   |  load_got lj_tab_get
1083   |  addiu CARG4, CARG4, -LJ_TTAB
1084   |  or AT, AT, CARG4
1085   |  bnez AT, ->fff_fallback
1086   |   addiu CARG3, BASE, 8
1087   |  call_intern lj_tab_get     // (lua_State *L, GCtab *t, cTValue *key)
1088   |.  move CARG1, L
1089   |  // Returns cTValue *.
1090   |  b ->fff_resn
1091   |.  ldc1 FRET1, 0(CRET1)
1092   |
1093   |//-- Base library: conversions ------------------------------------------
1094   |
1095   |.ffunc tonumber
1096   |  // Only handles the number case inline (without a base argument).
1097   |  lw CARG1, HI(BASE)
1098   |  xori AT, NARGS8:RC, 8
1099   |  sltiu CARG1, CARG1, LJ_TISNUM
1100   |  movn CARG1, r0, AT
1101   |  beqz CARG1, ->fff_fallback         // Exactly one number argument.
1102   |.  ldc1 FRET1, 0(BASE)
1103   |  b ->fff_resn
1104   |.  nop
1105   |
1106   |.ffunc_1 tostring
1107   |  // Only handles the string or number case inline.
1108   |  li AT, LJ_TSTR
1109   |  // A __tostring method in the string base metatable is ignored.
1110   |  beq CARG3, AT, ->fff_restv                 // String key?
1111   |  // Handle numbers inline, unless a number base metatable is present.
1112   |.  lw TMP1, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1113   |  sltiu TMP0, CARG3, LJ_TISNUM
1114   |  sltiu TMP1, TMP1, 1
1115   |  and TMP0, TMP0, TMP1
1116   |  beqz TMP0, ->fff_fallback
1117   |.  sw BASE, L->base                  // Add frame since C call can throw.
1118   |  ffgccheck
1119   |.  sw PC, SAVE_PC                    // Redundant (but a defined value).
1120   |  load_got lj_str_fromnum
1121   |  move CARG1, L
1122   |  call_intern lj_str_fromnum         // (lua_State *L, lua_Number *np)
1123   |.  move CARG2, BASE
1124   |  // Returns GCstr *.
1125   |  li CARG3, LJ_TSTR
1126   |  b ->fff_restv
1127   |.  move CARG1, CRET1
1128   |
1129   |//-- Base library: iterators -------------------------------------------
1130   |
1131   |.ffunc next
1132   |  lw CARG1, HI(BASE)
1133   |   lw TAB:CARG2, LO(BASE)
1134   |  beqz NARGS8:RC, ->fff_fallback
1135   |.  addu TMP2, BASE, NARGS8:RC
1136   |  li AT, LJ_TTAB
1137   |   sw TISNIL, HI(TMP2)               // Set missing 2nd arg to nil.
1138   |  bne CARG1, AT, ->fff_fallback
1139   |.  lw PC, FRAME_PC(BASE)
1140   |  load_got lj_tab_next
1141   |   sw BASE, L->base                  // Add frame since C call can throw.
1142   |   sw BASE, L->top                   // Dummy frame length is ok.
1143   |  addiu CARG3, BASE, 8
1144   |   sw PC, SAVE_PC
1145   |  call_intern lj_tab_next            // (lua_State *L, GCtab *t, TValue *key)
1146   |.  move CARG1, L
1147   |  // Returns 0 at end of traversal.
1148   |  beqz CRET1, ->fff_restv            // End of traversal: return nil.
1149   |.  li CARG3, LJ_TNIL
1150   |  ldc1 f0, 8(BASE)                   // Copy key and value to results.
1151   |    addiu RA, BASE, -8
1152   |   ldc1 f2, 16(BASE)
1153   |    li RD, (2+1)*8
1154   |  sdc1 f0, 0(RA)
1155   |  b ->fff_res
1156   |.  sdc1 f2, 8(RA)
1157   |
1158   |.ffunc_1 pairs
1159   |  li AT, LJ_TTAB
1160   |  bne CARG3, AT, ->fff_fallback
1161   |.  lw PC, FRAME_PC(BASE)
1162 #if LJ_52
1163   |  lw TAB:TMP2, TAB:CARG1->metatable
1164   |   ldc1 f0, CFUNC:RB->upvalue[0]
1165   |  bnez TAB:TMP2, ->fff_fallback
1166 #else
1167   |  ldc1 f0, CFUNC:RB->upvalue[0]
1168 #endif
1169   |.  addiu RA, BASE, -8
1170   |   sw TISNIL, 8+HI(BASE)
1171   |  li RD, (3+1)*8
1172   |  b ->fff_res
1173   |.  sdc1 f0, 0(RA)
1174   |
1175   |.ffunc ipairs_aux
1176   |  sltiu AT, NARGS8:RC, 16
1177   |   lw CARG3, HI(BASE)
1178   |    lw TAB:CARG1, LO(BASE)
1179   |   lw CARG4, 8+HI(BASE)
1180   |  bnez AT, ->fff_fallback
1181   |.  ldc1 FARG2, 8(BASE)
1182   |   addiu CARG3, CARG3, -LJ_TTAB
1183   |  sltiu AT, CARG4, LJ_TISNUM
1184   |   li TMP0, 1
1185   |  movn AT, r0, CARG3
1186   |   mtc1 TMP0, FARG1
1187   |  beqz AT, ->fff_fallback
1188   |.  lw PC, FRAME_PC(BASE)
1189   |   cvt.w.d FRET1, FARG2
1190   |  cvt.d.w FARG1, FARG1
1191   |   lw TMP0, TAB:CARG1->asize
1192   |   lw TMP1, TAB:CARG1->array
1193   |  mfc1 TMP2, FRET1
1194   |   addiu RA, BASE, -8
1195   |  add.d FARG2, FARG2, FARG1
1196   |  addiu TMP2, TMP2, 1
1197   |  sltu AT, TMP2, TMP0
1198   |   sll TMP3, TMP2, 3
1199   |   addu TMP3, TMP1, TMP3
1200   |  beqz AT, >2                        // Not in array part?
1201   |.  sdc1 FARG2, 0(RA)
1202   |  lw TMP2, HI(TMP3)
1203   |  ldc1 f0, 0(TMP3)
1204   |1:
1205   |  beq TMP2, TISNIL, ->fff_res        // End of iteration, return 0 results.
1206   |.  li RD, (0+1)*8
1207   |   li RD, (2+1)*8
1208   |  b ->fff_res
1209   |.  sdc1 f0, 8(RA)
1210   |2:  // Check for empty hash part first. Otherwise call C function.
1211   |  lw TMP0, TAB:CARG1->hmask
1212   |  load_got lj_tab_getinth
1213   |  beqz TMP0, ->fff_res
1214   |.  li RD, (0+1)*8
1215   |  call_intern lj_tab_getinth         // (GCtab *t, int32_t key)
1216   |.  move CARG2, TMP2
1217   |  // Returns cTValue * or NULL.
1218   |  beqz CRET1, ->fff_res
1219   |.  li RD, (0+1)*8
1220   |  lw TMP2, HI(CRET1)
1221   |  b <1
1222   |.  ldc1 f0, 0(CRET1)
1223   |
1224   |.ffunc_1 ipairs
1225   |  li AT, LJ_TTAB
1226   |  bne CARG3, AT, ->fff_fallback
1227   |.  lw PC, FRAME_PC(BASE)
1228 #if LJ_52
1229   |  lw TAB:TMP2, TAB:CARG1->metatable
1230   |   ldc1 f0, CFUNC:RB->upvalue[0]
1231   |  bnez TAB:TMP2, ->fff_fallback
1232 #else
1233   |  ldc1 f0, CFUNC:RB->upvalue[0]
1234 #endif
1235   |.  addiu RA, BASE, -8
1236   |   sw r0, 8+HI(BASE)
1237   |   sw r0, 8+LO(BASE)
1238   |  li RD, (3+1)*8
1239   |  b ->fff_res
1240   |.  sdc1 f0, 0(RA)
1241   |
1242   |//-- Base library: catch errors ----------------------------------------
1243   |
1244   |.ffunc pcall
1245   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1246   |  beqz NARGS8:RC, ->fff_fallback
1247   |   move TMP2, BASE
1248   |   addiu BASE, BASE, 8
1249   |  // Remember active hook before pcall.
1250   |  srl TMP3, TMP3, HOOK_ACTIVE_SHIFT
1251   |  andi TMP3, TMP3, 1
1252   |  addiu PC, TMP3, 8+FRAME_PCALL
1253   |  b ->vm_call_dispatch
1254   |.  addiu NARGS8:RC, NARGS8:RC, -8
1255   |
1256   |.ffunc xpcall
1257   |    sltiu AT, NARGS8:RC, 16
1258   |  lw CARG4, 8+HI(BASE)
1259   |    bnez AT, ->fff_fallback
1260   |.  ldc1 FARG2, 8(BASE)
1261   |   ldc1 FARG1, 0(BASE)
1262   |    lbu TMP1, DISPATCH_GL(hookmask)(DISPATCH)
1263   |  li AT, LJ_TFUNC
1264   |   move TMP2, BASE
1265   |  bne CARG4, AT, ->fff_fallback  // Traceback must be a function.
1266   |   addiu BASE, BASE, 16
1267   |  // Remember active hook before pcall.
1268   |  srl TMP3, TMP3, HOOK_ACTIVE_SHIFT
1269   |   sdc1 FARG2, 0(TMP2)               // Swap function and traceback.
1270   |  andi TMP3, TMP3, 1
1271   |   sdc1 FARG1, 8(TMP2)
1272   |  addiu PC, TMP3, 16+FRAME_PCALL
1273   |  b ->vm_call_dispatch
1274   |.  addiu NARGS8:RC, NARGS8:RC, -16
1275   |
1276   |//-- Coroutine library --------------------------------------------------
1277   |
1278   |.macro coroutine_resume_wrap, resume
1279   |.if resume
1280   |.ffunc_1 coroutine_resume
1281   |  li AT, LJ_TTHREAD
1282   |  bne CARG3, AT, ->fff_fallback
1283   |.else
1284   |.ffunc coroutine_wrap_aux
1285   |  lw L:CARG1, CFUNC:RB->upvalue[0].gcr
1286   |.endif
1287   |  lbu TMP0, L:CARG1->status
1288   |   lw TMP1, L:CARG1->cframe
1289   |    lw CARG2, L:CARG1->top
1290   |    lw TMP2, L:CARG1->base
1291   |  addiu TMP3, TMP0, -LUA_YIELD
1292   |  bgtz TMP3, ->fff_fallback          // st > LUA_YIELD?
1293   |.   xor TMP2, TMP2, CARG2
1294   |  bnez TMP1, ->fff_fallback          // cframe != 0?
1295   |.  or AT, TMP2, TMP0
1296   |  lw TMP0, L:CARG1->maxstack
1297   |  beqz AT, ->fff_fallback            // base == top && st == 0?
1298   |.  lw PC, FRAME_PC(BASE)
1299   |  addu TMP2, CARG2, NARGS8:RC
1300   |  sltu AT, TMP0, TMP2
1301   |  bnez AT, ->fff_fallback            // Stack overflow?
1302   |.  sw PC, SAVE_PC
1303   |   sw BASE, L->base
1304   |1:
1305   |.if resume
1306   |  addiu BASE, BASE, 8                // Keep resumed thread in stack for GC.
1307   |  addiu NARGS8:RC, NARGS8:RC, -8
1308   |  addiu TMP2, TMP2, -8
1309   |.endif
1310   |  sw TMP2, L:CARG1->top
1311   |  addu TMP1, BASE, NARGS8:RC
1312   |  move CARG3, CARG2
1313   |  sw BASE, L->top
1314   |2:  // Move args to coroutine.
1315   |   ldc1 f0, 0(BASE)
1316   |  sltu AT, BASE, TMP1
1317   |  beqz AT, >3
1318   |.  addiu BASE, BASE, 8
1319   |   sdc1 f0, 0(CARG3)
1320   |  b <2
1321   |.  addiu CARG3, CARG3, 8
1322   |3:
1323   |  bal ->vm_resume                    // (lua_State *L, TValue *base, 0, 0)
1324   |.  move L:RA, L:CARG1
1325   |  // Returns thread status.
1326   |4:
1327   |  lw TMP2, L:RA->base
1328   |   sltiu AT, CRET1, LUA_YIELD+1
1329   |  lw TMP3, L:RA->top
1330   |    li_vmstate INTERP
1331   |  lw BASE, L->base
1332   |    st_vmstate
1333   |   beqz AT, >8
1334   |. subu RD, TMP3, TMP2
1335   |   lw TMP0, L->maxstack
1336   |  beqz RD, >6                        // No results?
1337   |.  addu TMP1, BASE, RD
1338   |  sltu AT, TMP0, TMP1
1339   |  bnez AT, >9                        // Need to grow stack?
1340   |.  addu TMP3, TMP2, RD
1341   |  sw TMP2, L:RA->top                 // Clear coroutine stack.
1342   |  move TMP1, BASE
1343   |5:  // Move results from coroutine.
1344   |   ldc1 f0, 0(TMP2)
1345   |  addiu TMP2, TMP2, 8
1346   |  sltu AT, TMP2, TMP3
1347   |   sdc1 f0, 0(TMP1)
1348   |  bnez AT, <5
1349   |.  addiu TMP1, TMP1, 8
1350   |6:
1351   |  andi TMP0, PC, FRAME_TYPE
1352   |.if resume
1353   |  li TMP1, LJ_TTRUE
1354   |   addiu RA, BASE, -8
1355   |  sw TMP1, -8+HI(BASE)               // Prepend true to results.
1356   |  addiu RD, RD, 16
1357   |.else
1358   |  move RA, BASE
1359   |  addiu RD, RD, 8
1360   |.endif
1361   |7:
1362   |  sw PC, SAVE_PC
1363   |  beqz TMP0, ->BC_RET_Z
1364   |.  move MULTRES, RD
1365   |  b ->vm_return
1366   |.  nop
1367   |
1368   |8:  // Coroutine returned with error (at co->top-1).
1369   |.if resume
1370   |  addiu TMP3, TMP3, -8
1371   |   li TMP1, LJ_TFALSE
1372   |  ldc1 f0, 0(TMP3)
1373   |   sw TMP3, L:RA->top                // Remove error from coroutine stack.
1374   |    li RD, (2+1)*8
1375   |   sw TMP1, -8+HI(BASE)              // Prepend false to results.
1376   |    addiu RA, BASE, -8
1377   |  sdc1 f0, 0(BASE)                   // Copy error message.
1378   |  b <7
1379   |.  andi TMP0, PC, FRAME_TYPE
1380   |.else
1381   |  load_got lj_ffh_coroutine_wrap_err
1382   |  move CARG2, L:RA
1383   |  call_intern lj_ffh_coroutine_wrap_err  // (lua_State *L, lua_State *co)
1384   |.  move CARG1, L
1385   |.endif
1386   |
1387   |9:  // Handle stack expansion on return from yield.
1388   |  load_got lj_state_growstack
1389   |  srl CARG2, RD, 3
1390   |  call_intern lj_state_growstack     // (lua_State *L, int n)
1391   |.  move CARG1, L
1392   |  b <4
1393   |.  li CRET1, 0
1394   |.endmacro
1395   |
1396   |  coroutine_resume_wrap 1            // coroutine.resume
1397   |  coroutine_resume_wrap 0            // coroutine.wrap
1398   |
1399   |.ffunc coroutine_yield
1400   |  lw TMP0, L->cframe
1401   |   addu TMP1, BASE, NARGS8:RC
1402   |   sw BASE, L->base
1403   |  andi TMP0, TMP0, CFRAME_RESUME
1404   |   sw TMP1, L->top
1405   |  beqz TMP0, ->fff_fallback
1406   |.   li CRET1, LUA_YIELD
1407   |  sw r0, L->cframe
1408   |  b ->vm_leave_unw
1409   |.   sb CRET1, L->status
1410   |
1411   |//-- Math library -------------------------------------------------------
1412   |
1413   |.ffunc_n math_abs
1414   |.  abs.d FRET1, FARG1
1415   |->fff_resn:
1416   |  lw PC, FRAME_PC(BASE)
1417   |  addiu RA, BASE, -8
1418   |  b ->fff_res1
1419   |.  sdc1 FRET1, -8(BASE)
1420   |
1421   |->fff_restv:
1422   |  // CARG3/CARG1 = TValue result.
1423   |  lw PC, FRAME_PC(BASE)
1424   |   sw CARG3, -8+HI(BASE)
1425   |  addiu RA, BASE, -8
1426   |   sw CARG1, -8+LO(BASE)
1427   |->fff_res1:
1428   |  // RA = results, PC = return.
1429   |  li RD, (1+1)*8
1430   |->fff_res:
1431   |  // RA = results, RD = (nresults+1)*8, PC = return.
1432   |  andi TMP0, PC, FRAME_TYPE
1433   |  bnez TMP0, ->vm_return
1434   |.  move MULTRES, RD
1435   |  lw INS, -4(PC)
1436   |  decode_RB8a RB, INS
1437   |  decode_RB8b RB
1438   |5:
1439   |  sltu AT, RD, RB
1440   |  bnez AT, >6                        // More results expected?
1441   |.  decode_RA8a TMP0, INS
1442   |  decode_RA8b TMP0
1443   |  ins_next1
1444   |  // Adjust BASE. KBASE is assumed to be set for the calling frame.
1445   |   subu BASE, RA, TMP0
1446   |  ins_next2
1447   |
1448   |6:  // Fill up results with nil.
1449   |  addu TMP1, RA, RD
1450   |   addiu RD, RD, 8
1451   |  b <5
1452   |.  sw TISNIL, -8+HI(TMP1)
1453   |
1454   |.macro math_extern, func
1455   |->ff_math_ .. func:
1456   |  lw CARG3, HI(BASE)
1457   |  beqz NARGS8:RC, ->fff_fallback
1458   |.  load_got func
1459   |  sltiu AT, CARG3, LJ_TISNUM
1460   |  beqz AT, ->fff_fallback
1461   |.  nop
1462   |  call_extern
1463   |.  ldc1 FARG1, 0(BASE)
1464   |  b ->fff_resn
1465   |.  nop
1466   |.endmacro
1467   |
1468   |.macro math_extern2, func
1469   |  .ffunc_nn math_ .. func
1470   |.  load_got func
1471   |  call_extern
1472   |.  nop
1473   |  b ->fff_resn
1474   |.  nop
1475   |.endmacro
1476   |
1477   |.macro math_round, func
1478   |  .ffunc_n math_ .. func
1479   |.  nop
1480   |  bal ->vm_ .. func
1481   |.  nop
1482   |  b ->fff_resn
1483   |.  nop
1484   |.endmacro
1485   |
1486   |  math_round floor
1487   |  math_round ceil
1488   |
1489   |  math_extern log
1490   |  math_extern log10
1491   |  math_extern exp
1492   |  math_extern sin
1493   |  math_extern cos
1494   |  math_extern tan
1495   |  math_extern asin
1496   |  math_extern acos
1497   |  math_extern atan
1498   |  math_extern sinh
1499   |  math_extern cosh
1500   |  math_extern tanh
1501   |  math_extern2 pow
1502   |  math_extern2 atan2
1503   |  math_extern2 fmod
1504   |
1505   |.ffunc_n math_sqrt
1506   |.  sqrt.d FRET1, FARG1
1507   |  b ->fff_resn
1508   |.  nop
1509   |
1510   |->ff_math_deg:
1511   |.ffunc_n math_rad
1512   |.  ldc1 FARG2, CFUNC:RB->upvalue[0]
1513   |  b ->fff_resn
1514   |.  mul.d FRET1, FARG1, FARG2
1515   |
1516   |.ffunc_nn math_ldexp
1517   |  cvt.w.d FARG2, FARG2
1518   |  load_got ldexp
1519   |  mfc1 CARG3, FARG2
1520   |  call_extern
1521   |.  nop
1522   |  b ->fff_resn
1523   |.  nop
1524   |
1525   |.ffunc_n math_frexp
1526   |  load_got frexp
1527   |   lw PC, FRAME_PC(BASE)
1528   |  call_extern
1529   |.  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
1530   |   lw TMP1, DISPATCH_GL(tmptv)(DISPATCH)
1531   |  addiu RA, BASE, -8
1532   |   mtc1 TMP1, FARG2
1533   |  sdc1 FRET1, 0(RA)
1534   |   cvt.d.w FARG2, FARG2
1535   |   sdc1 FARG2, 8(RA)
1536   |  b ->fff_res
1537   |.  li RD, (2+1)*8
1538   |
1539   |.ffunc_n math_modf
1540   |  load_got modf
1541   |   lw PC, FRAME_PC(BASE)
1542   |  call_extern
1543   |.  addiu CARG3, BASE, -8
1544   |  addiu RA, BASE, -8
1545   |  sdc1 FRET1, 0(BASE)
1546   |  b ->fff_res
1547   |.  li RD, (2+1)*8
1548   |
1549   |.macro math_minmax, name, ismax
1550   |->ff_ .. name:
1551   |  lw CARG3, HI(BASE)
1552   |  beqz NARGS8:RC, ->fff_fallback
1553   |.  ldc1 FRET1, 0(BASE)
1554   |  sltiu AT, CARG3, LJ_TISNUM
1555   |  beqz AT, ->fff_fallback
1556   |.  addu TMP2, BASE, NARGS8:RC
1557   |  addiu TMP1, BASE, 8
1558   |  beq TMP1, TMP2, ->fff_resn
1559   |1:
1560   |.  lw CARG3, HI(TMP1)
1561   |  ldc1 FARG1, 0(TMP1)
1562   |   addiu TMP1, TMP1, 8
1563   |  sltiu AT, CARG3, LJ_TISNUM
1564   |  beqz AT, ->fff_fallback
1565   |.if ismax
1566   |.  c.olt.d FARG1, FRET1
1567   |.else
1568   |.  c.olt.d FRET1, FARG1
1569   |.endif
1570   |  bne TMP1, TMP2, <1
1571   |.  movf.d FRET1, FARG1
1572   |  b ->fff_resn
1573   |.  nop
1574   |.endmacro
1575   |
1576   |  math_minmax math_min, 0
1577   |  math_minmax math_max, 1
1578   |
1579   |//-- String library -----------------------------------------------------
1580   |
1581   |.ffunc_1 string_len
1582   |  li AT, LJ_TSTR
1583   |  bne CARG3, AT, ->fff_fallback
1584   |.  nop
1585   |  b ->fff_resi
1586   |.  lw CRET1, STR:CARG1->len
1587   |
1588   |.ffunc string_byte                   // Only handle the 1-arg case here.
1589   |  lw CARG3, HI(BASE)
1590   |   lw STR:CARG1, LO(BASE)
1591   |  xori AT, NARGS8:RC, 8
1592   |  addiu CARG3, CARG3, -LJ_TSTR
1593   |  or AT, AT, CARG3
1594   |  bnez AT, ->fff_fallback            // Need exactly 1 string argument.
1595   |.  nop
1596   |  lw TMP0, STR:CARG1->len
1597   |   lbu TMP1, STR:CARG1[1]            // Access is always ok (NUL at end).
1598   |    addiu RA, BASE, -8
1599   |  sltu RD, r0, TMP0
1600   |   mtc1 TMP1, f0
1601   |  addiu RD, RD, 1
1602   |   cvt.d.w f0, f0
1603   |  lw PC, FRAME_PC(BASE)
1604   |  sll RD, RD, 3                      // RD = ((str->len != 0)+1)*8
1605   |  b ->fff_res
1606   |.  sdc1 f0, 0(RA)
1607   |
1608   |.ffunc string_char                   // Only handle the 1-arg case here.
1609   |  ffgccheck
1610   |  lw CARG3, HI(BASE)
1611   |   ldc1 FARG1, 0(BASE)
1612   |  li AT, 8
1613   |  bne NARGS8:RC, AT, ->fff_fallback  // Exactly 1 argument.
1614   |.  sltiu AT, CARG3, LJ_TISNUM
1615   |  beqz AT, ->fff_fallback
1616   |.  li CARG3, 1
1617   |   cvt.w.d FARG1, FARG1
1618   |  addiu CARG2, sp, ARG5_OFS
1619   |  sltiu AT, TMP0, 256
1620   |   mfc1 TMP0, FARG1
1621   |  beqz AT, ->fff_fallback
1622   |.  sw TMP0, ARG5
1623   |->fff_newstr:
1624   |  load_got lj_str_new
1625   |   sw BASE, L->base
1626   |   sw PC, SAVE_PC
1627   |  call_intern lj_str_new             // (lua_State *L, char *str, size_t l)
1628   |.  move CARG1, L
1629   |  // Returns GCstr *.
1630   |  lw BASE, L->base
1631   |  move CARG1, CRET1
1632   |  b ->fff_restv
1633   |.  li CARG3, LJ_TSTR
1634   |
1635   |.ffunc string_sub
1636   |  ffgccheck
1637   |  addiu AT, NARGS8:RC, -16
1638   |   lw CARG3, 16+HI(BASE)
1639   |    ldc1 f0, 16(BASE)
1640   |   lw TMP0, HI(BASE)
1641   |    lw STR:CARG1, LO(BASE)
1642   |  bltz AT, ->fff_fallback
1643   |   lw CARG2, 8+HI(BASE)
1644   |    ldc1 f2, 8(BASE)
1645   |  beqz AT, >1
1646   |.  li CARG4, -1
1647   |   cvt.w.d f0, f0
1648   |  sltiu AT, CARG3, LJ_TISNUM
1649   |  beqz AT, ->fff_fallback
1650   |.  mfc1 CARG4, f0
1651   |1:
1652   |  sltiu AT, CARG2, LJ_TISNUM
1653   |  beqz AT, ->fff_fallback
1654   |.  li AT, LJ_TSTR
1655   |  cvt.w.d f2, f2
1656   |  bne TMP0, AT, ->fff_fallback
1657   |.  lw CARG2, STR:CARG1->len
1658   |  mfc1 CARG3, f2
1659   |  // STR:CARG1 = str, CARG2 = str->len, CARG3 = start, CARG4 = end
1660   |  slt AT, CARG4, r0
1661   |  addiu TMP0, CARG2, 1
1662   |  addu TMP1, CARG4, TMP0
1663   |   slt TMP3, CARG3, r0
1664   |  movn CARG4, TMP1, AT               // if (end < 0) end += len+1
1665   |   addu TMP1, CARG3, TMP0
1666   |   movn CARG3, TMP1, TMP3            // if (start < 0) start += len+1
1667   |   li TMP2, 1
1668   |  slt AT, CARG4, r0
1669   |   slt TMP3, r0, CARG3
1670   |  movn CARG4, r0, AT                 // if (end < 0) end = 0
1671   |   movz CARG3, TMP2, TMP3            // if (start < 1) start = 1
1672   |  slt AT, CARG2, CARG4
1673   |  movn CARG4, CARG2, AT              // if (end > len) end = len
1674   |   addu CARG2, STR:CARG1, CARG3
1675   |  subu CARG3, CARG4, CARG3           // len = end - start
1676   |   addiu CARG2, CARG2, sizeof(GCstr)-1
1677   |  bgez CARG3, ->fff_newstr
1678   |.  addiu CARG3, CARG3, 1             // len++
1679   |->fff_emptystr:  // Return empty string.
1680   |  addiu STR:CARG1, DISPATCH, DISPATCH_GL(strempty)
1681   |  b ->fff_restv
1682   |.  li CARG3, LJ_TSTR
1683   |
1684   |.ffunc string_rep                    // Only handle the 1-char case inline.
1685   |  ffgccheck
1686   |  lw TMP0, HI(BASE)
1687   |   sltiu AT, NARGS8:RC, 16
1688   |  lw CARG4, 8+HI(BASE)
1689   |   lw STR:CARG1, LO(BASE)
1690   |  addiu TMP0, TMP0, -LJ_TSTR
1691   |   ldc1 f0, 8(BASE)
1692   |  or AT, AT, TMP0
1693   |  bnez AT, ->fff_fallback
1694   |.  sltiu AT, CARG4, LJ_TISNUM
1695   |   cvt.w.d f0, f0
1696   |  beqz AT, ->fff_fallback
1697   |.  lw TMP0, STR:CARG1->len
1698   |   mfc1 CARG3, f0
1699   |  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1700   |  li AT, 1
1701   |   blez CARG3, ->fff_emptystr        // Count <= 0?
1702   |.   sltu AT, AT, TMP0
1703   |  beqz TMP0, ->fff_emptystr          // Zero length string?
1704   |.  sltu TMP0, TMP1, CARG3
1705   |  or AT, AT, TMP0
1706   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1707   |  bnez AT, ->fff_fallback            // Fallback for > 1-char strings.
1708   |.  lbu TMP0, STR:CARG1[1]
1709   |  addu TMP2, CARG2, CARG3
1710   |1:  // Fill buffer with char. Yes, this is suboptimal code (do you care?).
1711   |  addiu TMP2, TMP2, -1
1712   |  sltu AT, CARG2, TMP2
1713   |  bnez AT, <1
1714   |.  sb TMP0, 0(TMP2)
1715   |  b ->fff_newstr
1716   |.  nop
1717   |
1718   |.ffunc string_reverse
1719   |  ffgccheck
1720   |  lw CARG3, HI(BASE)
1721   |   lw STR:CARG1, LO(BASE)
1722   |  beqz NARGS8:RC, ->fff_fallback
1723   |.  li AT, LJ_TSTR
1724   |  bne CARG3, AT, ->fff_fallback
1725   |.  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1726   |  lw CARG3, STR:CARG1->len
1727   |   addiu CARG1, STR:CARG1, #STR
1728   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1729   |  sltu AT, TMP1, CARG3
1730   |  bnez AT, ->fff_fallback
1731   |.  addu TMP3, CARG1, CARG3
1732   |  addu CARG4, CARG2, CARG3
1733   |1:  // Reverse string copy.
1734   |   lbu TMP1, 0(CARG1)
1735   |  sltu AT, CARG1, TMP3
1736   |  beqz AT, ->fff_newstr
1737   |.  addiu CARG1, CARG1, 1
1738   |  addiu CARG4, CARG4, -1
1739   |  b <1
1740   |   sb TMP1, 0(CARG4)
1741   |
1742   |.macro ffstring_case, name, lo
1743   |  .ffunc name
1744   |  ffgccheck
1745   |  lw CARG3, HI(BASE)
1746   |   lw STR:CARG1, LO(BASE)
1747   |  beqz NARGS8:RC, ->fff_fallback
1748   |.  li AT, LJ_TSTR
1749   |  bne CARG3, AT, ->fff_fallback
1750   |.  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1751   |  lw CARG3, STR:CARG1->len
1752   |   addiu CARG1, STR:CARG1, #STR
1753   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1754   |  sltu AT, TMP1, CARG3
1755   |  bnez AT, ->fff_fallback
1756   |.  addu TMP3, CARG1, CARG3
1757   |  move CARG4, CARG2
1758   |1:  // ASCII case conversion.
1759   |   lbu TMP1, 0(CARG1)
1760   |  sltu AT, CARG1, TMP3
1761   |  beqz AT, ->fff_newstr
1762   |.  addiu TMP0, TMP1, -lo
1763   |   xori TMP2, TMP1, 0x20
1764   |   sltiu AT, TMP0, 26
1765   |   movn TMP1, TMP2, AT
1766   |  addiu CARG1, CARG1, 1
1767   |   sb TMP1, 0(CARG4)
1768   |  b <1
1769   |.  addiu CARG4, CARG4, 1
1770   |.endmacro
1771   |
1772   |ffstring_case string_lower, 65
1773   |ffstring_case string_upper, 97
1774   |
1775   |//-- Table library ------------------------------------------------------
1776   |
1777   |.ffunc_1 table_getn
1778   |  li AT, LJ_TTAB
1779   |  bne CARG3, AT, ->fff_fallback
1780   |.  load_got lj_tab_len
1781   |  call_intern lj_tab_len             // (GCtab *t)
1782   |.  nop
1783   |  // Returns uint32_t (but less than 2^31).
1784   |  b ->fff_resi
1785   |.  nop
1786   |
1787   |//-- Bit library --------------------------------------------------------
1788   |
1789   |.macro .ffunc_bit, name
1790   |  .ffunc_n bit_..name
1791   |.  add.d FARG1, FARG1, TOBIT
1792   |  mfc1 CRET1, FARG1
1793   |.endmacro
1794   |
1795   |.macro .ffunc_bit_op, name, ins
1796   |  .ffunc_bit name
1797   |  addiu TMP1, BASE, 8
1798   |  addu TMP2, BASE, NARGS8:RC
1799   |1:
1800   |  lw CARG4, HI(TMP1)
1801   |  beq TMP1, TMP2, ->fff_resi
1802   |.  ldc1 FARG1, 0(TMP1)
1803   |  sltiu AT, CARG4, LJ_TISNUM
1804   |  beqz AT, ->fff_fallback
1805   |  add.d FARG1, FARG1, TOBIT
1806   |  mfc1 CARG2, FARG1
1807   |  ins CRET1, CRET1, CARG2
1808   |  b <1
1809   |.  addiu TMP1, TMP1, 8
1810   |.endmacro
1811   |
1812   |.ffunc_bit_op band, and
1813   |.ffunc_bit_op bor, or
1814   |.ffunc_bit_op bxor, xor
1815   |
1816   |.ffunc_bit bswap
1817   |  srl TMP0, CRET1, 24
1818   |   srl TMP2, CRET1, 8
1819   |  sll TMP1, CRET1, 24
1820   |   andi TMP2, TMP2, 0xff00
1821   |  or TMP0, TMP0, TMP1
1822   |   andi CRET1, CRET1, 0xff00
1823   |  or TMP0, TMP0, TMP2
1824   |   sll CRET1, CRET1, 8
1825   |  b ->fff_resi
1826   |.  or CRET1, TMP0, CRET1
1827   |
1828   |.ffunc_bit bnot
1829   |  b ->fff_resi
1830   |.  not CRET1, CRET1
1831   |
1832   |.macro .ffunc_bit_sh, name, ins, shmod
1833   |  .ffunc_nn bit_..name
1834   |.  add.d FARG1, FARG1, TOBIT
1835   |  add.d FARG2, FARG2, TOBIT
1836   |  mfc1 CARG1, FARG1
1837   |  mfc1 CARG2, FARG2
1838   |.if shmod == 1
1839   |  li AT, 32
1840   |  subu TMP0, AT, CARG2
1841   |  sllv CARG2, CARG1, CARG2
1842   |  srlv CARG1, CARG1, TMP0
1843   |.elif shmod == 2
1844   |  li AT, 32
1845   |  subu TMP0, AT, CARG2
1846   |  srlv CARG2, CARG1, CARG2
1847   |  sllv CARG1, CARG1, TMP0
1848   |.endif
1849   |  b ->fff_resi
1850   |.  ins CRET1, CARG1, CARG2
1851   |.endmacro
1852   |
1853   |.ffunc_bit_sh lshift, sllv, 0
1854   |.ffunc_bit_sh rshift, srlv, 0
1855   |.ffunc_bit_sh arshift, srav, 0
1856   |// Can't use rotrv, since it's only in MIPS32R2.
1857   |.ffunc_bit_sh rol, or, 1
1858   |.ffunc_bit_sh ror, or, 2
1859   |
1860   |.ffunc_bit tobit
1861   |->fff_resi:
1862   |  mtc1 CRET1, FRET1
1863   |  b ->fff_resn
1864   |.  cvt.d.w FRET1, FRET1
1865   |
1866   |//-----------------------------------------------------------------------
1867   |
1868   |->fff_fallback:                      // Call fast function fallback handler.
1869   |  // BASE = new base, RB = CFUNC, RC = nargs*8
1870   |  lw TMP3, CFUNC:RB->f
1871   |    addu TMP1, BASE, NARGS8:RC
1872   |   lw PC, FRAME_PC(BASE)             // Fallback may overwrite PC.
1873   |    addiu TMP0, TMP1, 8*LUA_MINSTACK
1874   |     lw TMP2, L->maxstack
1875   |   sw PC, SAVE_PC                    // Redundant (but a defined value).
1876   |  sltu AT, TMP2, TMP0
1877   |     sw BASE, L->base
1878   |    sw TMP1, L->top
1879   |  bnez AT, >5                        // Need to grow stack.
1880   |.  move CFUNCADDR, TMP3
1881   |  jalr TMP3                          // (lua_State *L)
1882   |.  move CARG1, L
1883   |  // Either throws an error, or recovers and returns -1, 0 or nresults+1.
1884   |  lw BASE, L->base
1885   |   sll RD, CRET1, 3
1886   |  bgtz CRET1, ->fff_res              // Returned nresults+1?
1887   |.  addiu RA, BASE, -8
1888   |1:  // Returned 0 or -1: retry fast path.
1889   |  lw TMP0, L->top
1890   |   lw LFUNC:RB, FRAME_FUNC(BASE)
1891   |  bnez CRET1, ->vm_call_tail         // Returned -1?
1892   |.  subu NARGS8:RC, TMP0, BASE
1893   |  ins_callt                          // Returned 0: retry fast path.
1894   |
1895   |// Reconstruct previous base for vmeta_call during tailcall.
1896   |->vm_call_tail:
1897   |  andi TMP0, PC, FRAME_TYPE
1898   |   li AT, -4
1899   |  bnez TMP0, >3
1900   |.  and TMP1, PC, AT
1901   |  lbu TMP1, OFS_RA(PC)
1902   |  sll TMP1, TMP1, 3
1903   |  addiu TMP1, TMP1, 8
1904   |3:
1905   |  b ->vm_call_dispatch               // Resolve again for tailcall.
1906   |.  subu TMP2, BASE, TMP1
1907   |
1908   |5:  // Grow stack for fallback handler.
1909   |  load_got lj_state_growstack
1910   |  li CARG2, LUA_MINSTACK
1911   |  call_intern lj_state_growstack     // (lua_State *L, int n)
1912   |.  move CARG1, L
1913   |  lw BASE, L->base
1914   |  b <1
1915   |.  li CRET1, 0                       // Force retry.
1916   |
1917   |->fff_gcstep:                        // Call GC step function.
1918   |  // BASE = new base, RC = nargs*8
1919   |  move MULTRES, ra
1920   |  load_got lj_gc_step
1921   |   sw BASE, L->base
1922   |  addu TMP0, BASE, NARGS8:RC
1923   |   sw PC, SAVE_PC                    // Redundant (but a defined value).
1924   |  sw TMP0, L->top
1925   |  call_intern lj_gc_step             // (lua_State *L)
1926   |.  move CARG1, L
1927   |   lw BASE, L->base
1928   |  move ra, MULTRES
1929   |    lw TMP0, L->top
1930   |  lw CFUNC:RB, FRAME_FUNC(BASE)
1931   |  jr ra
1932   |.  subu NARGS8:RC, TMP0, BASE
1933   |
1934   |//-----------------------------------------------------------------------
1935   |//-- Special dispatch targets -------------------------------------------
1936   |//-----------------------------------------------------------------------
1937   |
1938   |->vm_record:                         // Dispatch target for recording phase.
1939   |.if JIT
1940   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1941   |  andi AT, TMP3, HOOK_VMEVENT        // No recording while in vmevent.
1942   |  bnez AT, >5
1943   |  // Decrement the hookcount for consistency, but always do the call.
1944   |.  lw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1945   |  andi AT, TMP3, HOOK_ACTIVE
1946   |  bnez AT, >1
1947   |.  addiu TMP2, TMP2, -1
1948   |  andi AT, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
1949   |  beqz AT, >1
1950   |.  nop
1951   |  b >1
1952   |.  sw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1953   |.endif
1954   |
1955   |->vm_rethook:                        // Dispatch target for return hooks.
1956   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1957   |  andi AT, TMP3, HOOK_ACTIVE         // Hook already active?
1958   |  beqz AT, >1
1959   |5:  // Re-dispatch to static ins.
1960   |.  lw AT, GG_DISP2STATIC(TMP0)       // Assumes TMP0 holds DISPATCH+OP*4.
1961   |  jr AT
1962   |.  nop
1963   |
1964   |->vm_inshook:                        // Dispatch target for instr/line hooks.
1965   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1966   |  lw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1967   |  andi AT, TMP3, HOOK_ACTIVE         // Hook already active?
1968   |  bnez AT, <5
1969   |.  andi AT, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
1970   |  beqz AT, <5
1971   |.  addiu TMP2, TMP2, -1
1972   |  beqz TMP2, >1
1973   |.  sw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1974   |  andi AT, TMP3, LUA_MASKLINE
1975   |  beqz AT, <5
1976   |1:
1977   |.  load_got lj_dispatch_ins
1978   |   sw MULTRES, SAVE_MULTRES
1979   |  move CARG2, PC
1980   |   sw BASE, L->base
1981   |  // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
1982   |  call_intern lj_dispatch_ins        // (lua_State *L, const BCIns *pc)
1983   |.  move CARG1, L
1984   |3:
1985   |  lw BASE, L->base
1986   |4:  // Re-dispatch to static ins.
1987   |  lw INS, -4(PC)
1988   |  decode_OP4a TMP1, INS
1989   |  decode_OP4b TMP1
1990   |  addu TMP0, DISPATCH, TMP1
1991   |   decode_RD8a RD, INS
1992   |  lw AT, GG_DISP2STATIC(TMP0)
1993   |   decode_RA8a RA, INS
1994   |   decode_RD8b RD
1995   |  jr AT
1996   |   decode_RA8b RA
1997   |
1998   |->cont_hook:                         // Continue from hook yield.
1999   |  addiu PC, PC, 4
2000   |  b <4
2001   |.  lw MULTRES, -24+LO(RB)            // Restore MULTRES for *M ins.
2002   |
2003   |->vm_hotloop:                        // Hot loop counter underflow.
2004   |.if JIT
2005   |  lw LFUNC:TMP1, FRAME_FUNC(BASE)
2006   |   addiu CARG1, DISPATCH, GG_DISP2J
2007   |   sw PC, SAVE_PC
2008   |  lw TMP1, LFUNC:TMP1->pc
2009   |   move CARG2, PC
2010   |   sw L, DISPATCH_J(L)(DISPATCH)
2011   |  lbu TMP1, PC2PROTO(framesize)(TMP1)
2012   |  load_got lj_trace_hot
2013   |   sw BASE, L->base
2014   |  sll TMP1, TMP1, 3
2015   |  addu TMP1, BASE, TMP1
2016   |  call_intern lj_trace_hot           // (jit_State *J, const BCIns *pc)
2017   |.  sw TMP1, L->top
2018   |  b <3
2019   |.  nop
2020   |.endif
2021   |
2022   |->vm_callhook:                       // Dispatch target for call hooks.
2023   |.if JIT
2024   |  b >1
2025   |.endif
2026   |.  move CARG2, PC
2027   |
2028   |->vm_hotcall:                        // Hot call counter underflow.
2029   |.if JIT
2030   |  ori CARG2, PC, 1
2031   |1:
2032   |.endif
2033   |  load_got lj_dispatch_call
2034   |  addu TMP0, BASE, RC
2035   |   sw PC, SAVE_PC
2036   |   sw BASE, L->base
2037   |  subu RA, RA, BASE
2038   |   sw TMP0, L->top
2039   |  call_intern lj_dispatch_call       // (lua_State *L, const BCIns *pc)
2040   |.  move CARG1, L
2041   |  // Returns ASMFunction.
2042   |  lw BASE, L->base
2043   |   lw TMP0, L->top
2044   |   sw r0, SAVE_PC                    // Invalidate for subsequent line hook.
2045   |  subu NARGS8:RC, TMP0, BASE
2046   |  addu RA, BASE, RA
2047   |  lw LFUNC:RB, FRAME_FUNC(BASE)
2048   |  jr CRET1
2049   |.  lw INS, -4(PC)
2050   |
2051   |//-----------------------------------------------------------------------
2052   |//-- Trace exit handler -------------------------------------------------
2053   |//-----------------------------------------------------------------------
2054   |
2055   |.macro savex_, a, b
2056   |  sdc1 f..a, 16+a*8(sp)
2057   |  sw r..a, 16+32*8+a*4(sp)
2058   |  sw r..b, 16+32*8+b*4(sp)
2059   |.endmacro
2060   |
2061   |->vm_exit_handler:
2062   |.if JIT
2063   |  addiu sp, sp, -(16+32*8+32*4)
2064   |  savex_ 0, 1
2065   |  savex_ 2, 3
2066   |  savex_ 4, 5
2067   |  savex_ 6, 7
2068   |  savex_ 8, 9
2069   |  savex_ 10, 11
2070   |  savex_ 12, 13
2071   |  savex_ 14, 15
2072   |  savex_ 16, 17
2073   |  savex_ 18, 19
2074   |  savex_ 20, 21
2075   |  savex_ 22, 23
2076   |  savex_ 24, 25
2077   |  savex_ 26, 27
2078   |  sdc1 f28, 16+28*8(sp)
2079   |  sw r28, 16+32*8+28*4(sp)
2080   |  sdc1 f30, 16+30*8(sp)
2081   |  sw r30, 16+32*8+30*4(sp)
2082   |  sw r0, 16+32*8+31*4(sp)            // Clear RID_TMP.
2083   |  li_vmstate EXIT
2084   |   addiu TMP2, sp, 16+32*8+32*4      // Recompute original value of sp.
2085   |  addiu DISPATCH, JGL, -GG_DISP2G-32768
2086   |  lw TMP1, 0(TMP2)                   // Load exit number.
2087   |  st_vmstate
2088   |   sw TMP2, 16+32*8+29*4(sp)         // Store sp in RID_SP.
2089   |  lw L, DISPATCH_GL(jit_L)(DISPATCH)
2090   |  lw BASE, DISPATCH_GL(jit_base)(DISPATCH)
2091   |  load_got lj_trace_exit
2092   |  sw L, DISPATCH_J(L)(DISPATCH)
2093   |  sw ra, DISPATCH_J(parent)(DISPATCH)  // Store trace number.
2094   |  sw TMP1, DISPATCH_J(exitno)(DISPATCH)  // Store exit number.
2095   |  addiu CARG1, DISPATCH, GG_DISP2J
2096   |  sw BASE, L->base
2097   |  call_intern lj_trace_exit          // (jit_State *J, ExitState *ex)
2098   |.  addiu CARG2, sp, 16
2099   |  // Returns MULTRES (unscaled) or negated error code.
2100   |  lw TMP1, L->cframe
2101   |  li AT, -4
2102   |   lw BASE, L->base
2103   |  and sp, TMP1, AT
2104   |   lw PC, SAVE_PC                    // Get SAVE_PC.
2105   |  b >1
2106   |.  sw L, SAVE_L                      // Set SAVE_L (on-trace resume/yield).
2107   |.endif
2108   |->vm_exit_interp:
2109   |.if JIT
2110   |  // CRET1 = MULTRES or negated error code, BASE, PC and JGL set.
2111   |  lw L, SAVE_L
2112   |  addiu DISPATCH, JGL, -GG_DISP2G-32768
2113   |1:
2114   |  bltz CRET1, >3                     // Check for error from exit.
2115   |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
2116   |    lui TMP3, 0x59c0                 // TOBIT = 2^52 + 2^51 (float).
2117   |  sll MULTRES, CRET1, 3
2118   |    li TISNIL, LJ_TNIL
2119   |  sw MULTRES, SAVE_MULTRES
2120   |    mtc1 TMP3, TOBIT
2121   |  lw TMP1, LFUNC:TMP1->pc
2122   |   sw r0, DISPATCH_GL(jit_L)(DISPATCH)
2123   |  lw KBASE, PC2PROTO(k)(TMP1)
2124   |    cvt.d.s TOBIT, TOBIT
2125   |  // Modified copy of ins_next which handles function header dispatch, too.
2126   |  lw INS, 0(PC)
2127   |   addiu PC, PC, 4
2128   |    // Assumes TISNIL == ~LJ_VMST_INTERP == -1
2129   |    sw TISNIL, DISPATCH_GL(vmstate)(DISPATCH)
2130   |  decode_OP4a TMP1, INS
2131   |  decode_OP4b TMP1
2132   |    sltiu TMP2, TMP1, BC_FUNCF*4     // Function header?
2133   |  addu TMP0, DISPATCH, TMP1
2134   |   decode_RD8a RD, INS
2135   |  lw AT, 0(TMP0)
2136   |   decode_RA8a RA, INS
2137   |    beqz TMP2, >2
2138   |.  decode_RA8b RA
2139   |  jr AT
2140   |.  decode_RD8b RD
2141   |2:
2142   |  addiu RC, MULTRES, -8
2143   |  jr AT
2144   |.  add RA, RA, BASE
2145   |
2146   |3:  // Rethrow error from the right C frame.
2147   |  load_got lj_err_throw
2148   |  negu CARG2, CRET1
2149   |  call_intern lj_err_throw           // (lua_State *L, int errcode)
2150   |.  move CARG1, L
2151   |.endif
2152   |
2153   |//-----------------------------------------------------------------------
2154   |//-- Math helper functions ----------------------------------------------
2155   |//-----------------------------------------------------------------------
2156   |
2157   |// Modifies AT, TMP0, FRET1, FRET2, f4. Keeps all others incl. FARG1.
2158   |.macro vm_round, func
2159   |  lui TMP0, 0x4330                   // Hiword of 2^52 (double).
2160   |  mtc1 r0, f4
2161   |  mtc1 TMP0, f5
2162   |  abs.d FRET2, FARG1                 // |x|
2163   |    mfc1 AT, f13
2164   |  c.olt.d 0, FRET2, f4
2165   |   add.d FRET1, FRET2, f4            // (|x| + 2^52) - 2^52
2166   |  bc1f 0, >1                         // Truncate only if |x| < 2^52.
2167   |.  sub.d FRET1, FRET1, f4
2168   |    slt AT, AT, r0
2169   |.if "func" == "ceil"
2170   |   lui TMP0, 0xbff0                  // Hiword of -1 (double). Preserves -0.
2171   |.else
2172   |   lui TMP0, 0x3ff0                  // Hiword of +1 (double).
2173   |.endif
2174   |.if "func" == "trunc"
2175   |   mtc1 TMP0, f5
2176   |  c.olt.d 0, FRET2, FRET1            // |x| < result?
2177   |   sub.d FRET2, FRET1, f4
2178   |  movt.d FRET1, FRET2, 0             // If yes, subtract +1.
2179   |  neg.d FRET2, FRET1
2180   |  jr ra
2181   |.  movn.d FRET1, FRET2, AT           // Merge sign bit back in.
2182   |.else
2183   |  neg.d FRET2, FRET1
2184   |   mtc1 TMP0, f5
2185   |  movn.d FRET1, FRET2, AT            // Merge sign bit back in.
2186   |.if "func" == "ceil"
2187   |  c.olt.d 0, FRET1, FARG1            // x > result?
2188   |.else
2189   |  c.olt.d 0, FARG1, FRET1            // x < result?
2190   |.endif
2191   |   sub.d FRET2, FRET1, f4            // If yes, subtract +-1.
2192   |  jr ra
2193   |.  movt.d FRET1, FRET2, 0
2194   |.endif
2195   |1:
2196   |  jr ra
2197   |.  mov.d FRET1, FARG1
2198   |.endmacro
2199   |
2200   |->vm_floor:
2201   |  vm_round floor
2202   |->vm_ceil:
2203   |  vm_round ceil
2204   |->vm_trunc:
2205   |.if JIT
2206   |  vm_round trunc
2207   |.endif
2208   |
2209   |//-----------------------------------------------------------------------
2210   |//-- Miscellaneous functions --------------------------------------------
2211   |//-----------------------------------------------------------------------
2212   |
2213   |//-----------------------------------------------------------------------
2214   |//-- FFI helper functions -----------------------------------------------
2215   |//-----------------------------------------------------------------------
2216   |
2217   |// Handler for callback functions. Callback slot number in r1, g in r2.
2218   |->vm_ffi_callback:
2219   |.if FFI
2220   |.type CTSTATE, CTState, PC
2221   |  saveregs
2222   |  lw CTSTATE, GL:r2->ctype_state
2223   |   addiu DISPATCH, r2, GG_G2DISP
2224   |  load_got lj_ccallback_enter
2225   |  sw r1, CTSTATE->cb.slot
2226   |  sw CARG1, CTSTATE->cb.gpr[0]
2227   |  sw CARG2, CTSTATE->cb.gpr[1]
2228   |   sdc1 FARG1, CTSTATE->cb.fpr[0]
2229   |  sw CARG3, CTSTATE->cb.gpr[2]
2230   |  sw CARG4, CTSTATE->cb.gpr[3]
2231   |   sdc1 FARG2, CTSTATE->cb.fpr[1]
2232   |  addiu TMP0, sp, CFRAME_SPACE+16
2233   |  sw TMP0, CTSTATE->cb.stack
2234   |  sw r0, SAVE_PC                     // Any value outside of bytecode is ok.
2235   |   move CARG2, sp
2236   |  call_intern lj_ccallback_enter     // (CTState *cts, void *cf)
2237   |.  move CARG1, CTSTATE
2238   |  // Returns lua_State *.
2239   |  lw BASE, L:CRET1->base
2240   |  lw RC, L:CRET1->top
2241   |   move L, CRET1
2242   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
2243   |  lw LFUNC:RB, FRAME_FUNC(BASE)
2244   |     mtc1 TMP3, TOBIT
2245   |    li_vmstate INTERP
2246   |     li TISNIL, LJ_TNIL
2247   |  subu RC, RC, BASE
2248   |    st_vmstate
2249   |     cvt.d.s TOBIT, TOBIT
2250   |  ins_callt
2251   |.endif
2252   |
2253   |->cont_ffi_callback:                 // Return from FFI callback.
2254   |.if FFI
2255   |  load_got lj_ccallback_leave
2256   |  lw CTSTATE, DISPATCH_GL(ctype_state)(DISPATCH)
2257   |   sw BASE, L->base
2258   |   sw RB, L->top
2259   |  sw L, CTSTATE->L
2260   |  move CARG2, RA
2261   |  call_intern lj_ccallback_leave     // (CTState *cts, TValue *o)
2262   |.  move CARG1, CTSTATE
2263   |  lw CRET1, CTSTATE->cb.gpr[0]
2264   |   ldc1 FRET1, CTSTATE->cb.fpr[0]
2265   |  lw CRET2, CTSTATE->cb.gpr[1]
2266   |  b ->vm_leave_unw
2267   |.  ldc1 FRET2, CTSTATE->cb.fpr[1]
2268   |.endif
2269   |
2270   |->vm_ffi_call:                       // Call C function via FFI.
2271   |  // Caveat: needs special frame unwinding, see below.
2272   |.if FFI
2273   |  .type CCSTATE, CCallState, CARG1
2274   |  lw TMP1, CCSTATE->spadj
2275   |   lbu CARG2, CCSTATE->nsp
2276   |  move TMP2, sp
2277   |  subu sp, sp, TMP1
2278   |  sw ra, -4(TMP2)
2279   |   sll CARG2, CARG2, 2
2280   |  sw r16, -8(TMP2)
2281   |  sw CCSTATE, -12(TMP2)
2282   |  move r16, TMP2
2283   |  addiu TMP1, CCSTATE, offsetof(CCallState, stack)
2284   |  addiu TMP2, sp, 16
2285   |  beqz CARG2, >2
2286   |.  addu TMP3, TMP1, CARG2
2287   |1:
2288   |   lw TMP0, 0(TMP1)
2289   |  addiu TMP1, TMP1, 4
2290   |  sltu AT, TMP1, TMP3
2291   |   sw TMP0, 0(TMP2)
2292   |  bnez AT, <1
2293   |.  addiu TMP2, TMP2, 4
2294   |2:
2295   |  lw CFUNCADDR, CCSTATE->func
2296   |  lw CARG2, CCSTATE->gpr[1]
2297   |  lw CARG3, CCSTATE->gpr[2]
2298   |  lw CARG4, CCSTATE->gpr[3]
2299   |  ldc1 FARG1, CCSTATE->fpr[0]
2300   |  ldc1 FARG2, CCSTATE->fpr[1]
2301   |  jalr CFUNCADDR
2302   |.  lw CARG1, CCSTATE->gpr[0]         // Do this last, since CCSTATE is CARG1.
2303   |  lw CCSTATE:TMP1, -12(r16)
2304   |  lw TMP2, -8(r16)
2305   |  lw ra, -4(r16)
2306   |  sw CRET1, CCSTATE:TMP1->gpr[0]
2307   |  sw CRET2, CCSTATE:TMP1->gpr[1]
2308   |  sdc1 FRET1, CCSTATE:TMP1->fpr[0]
2309   |  sdc1 FRET2, CCSTATE:TMP1->fpr[1]
2310   |  move sp, r16
2311   |  jr ra
2312   |.  move r16, TMP2
2313   |.endif
2314   |// Note: vm_ffi_call must be the last function in this object file!
2315   |
2316   |//-----------------------------------------------------------------------
2317 }
2318
2319 /* Generate the code for a single instruction. */
2320 static void build_ins(BuildCtx *ctx, BCOp op, int defop)
2321 {
2322   int vk = 0;
2323   |=>defop:
2324
2325   switch (op) {
2326
2327   /* -- Comparison ops ---------------------------------------------------- */
2328
2329   /* Remember: all ops branch for a true comparison, fall through otherwise. */
2330
2331   case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
2332     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2333     |  addu CARG2, BASE, RA
2334     |   addu CARG3, BASE, RD
2335     |  lw TMP0, HI(CARG2)
2336     |   lw TMP1, HI(CARG3)
2337     |   ldc1 f0, 0(CARG2)
2338     |   ldc1 f2, 0(CARG3)
2339     |  sltiu TMP0, TMP0, LJ_TISNUM
2340     |   sltiu TMP1, TMP1, LJ_TISNUM
2341     |    lhu TMP2, OFS_RD(PC)
2342     |  and TMP0, TMP0, TMP1
2343     |    addiu PC, PC, 4
2344     |  beqz TMP0, ->vmeta_comp
2345     |.   lui TMP1, (-(BCBIAS_J*4 >> 16) & 65535)
2346     |    decode_RD4b TMP2
2347     |    addu TMP2, TMP2, TMP1
2348     if (op == BC_ISLT || op == BC_ISGE) {
2349       |  c.olt.d f0, f2
2350     } else {
2351       |  c.ole.d f0, f2
2352     }
2353     if (op == BC_ISLT || op == BC_ISLE) {
2354       |  movf TMP2, r0
2355     } else {
2356       |  movt TMP2, r0
2357     }
2358     |  addu PC, PC, TMP2
2359     |1:
2360     |  ins_next
2361     break;
2362
2363   case BC_ISEQV: case BC_ISNEV:
2364     vk = op == BC_ISEQV;
2365     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2366     |  addu RA, BASE, RA
2367     |   addiu PC, PC, 4
2368     |  lw TMP0, HI(RA)
2369     |   ldc1 f0, 0(RA)
2370     |  addu RD, BASE, RD
2371     |    lhu TMP2, -4+OFS_RD(PC)
2372     |   lw TMP1, HI(RD)
2373     |   ldc1 f2, 0(RD)
2374     |    lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2375     |  sltiu AT, TMP0, LJ_TISNUM
2376     |  sltiu CARG1, TMP1, LJ_TISNUM
2377     |    decode_RD4b TMP2
2378     |  and AT, AT, CARG1
2379     |  beqz AT, >5
2380     |.   addu TMP2, TMP2, TMP3
2381     |  c.eq.d f0, f2
2382     if (vk) {
2383       |  movf TMP2, r0
2384     } else {
2385       |  movt TMP2, r0
2386     }
2387     |1:
2388     |  addu PC, PC, TMP2
2389     |  ins_next
2390     |5:  // Either or both types are not numbers.
2391     |  lw CARG2, LO(RA)
2392     |  lw CARG3, LO(RD)
2393     |.if FFI
2394     |  li TMP3, LJ_TCDATA
2395     |  beq TMP0, TMP3, ->vmeta_equal_cd
2396     |.endif
2397     |.  sltiu AT, TMP0, LJ_TISPRI               // Not a primitive?
2398     |.if FFI
2399     |  beq TMP1, TMP3, ->vmeta_equal_cd
2400     |.endif
2401     |.  xor TMP3, CARG2, CARG3                  // Same tv?
2402     |  xor TMP1, TMP1, TMP0                     // Same type?
2403     |  sltiu CARG1, TMP0, LJ_TISTABUD+1         // Table or userdata?
2404     |  movz TMP3, r0, AT                        // Ignore tv if primitive.
2405     |  movn CARG1, r0, TMP1                     // Tab/ud and same type?
2406     |  or AT, TMP1, TMP3                        // Same type && (pri||same tv).
2407     |  movz CARG1, r0, AT
2408     |  beqz CARG1, <1   // Done if not tab/ud or not same type or same tv.
2409     if (vk) {
2410       |.  movn TMP2, r0, AT
2411     } else {
2412       |.  movz TMP2, r0, AT
2413     }
2414     |  // Different tables or userdatas. Need to check __eq metamethod.
2415     |  // Field metatable must be at same offset for GCtab and GCudata!
2416     |  lw TAB:TMP1, TAB:CARG2->metatable
2417     |  beqz TAB:TMP1, <1                // No metatable?
2418     |.  nop
2419     |  lbu TMP1, TAB:TMP1->nomm
2420     |  andi TMP1, TMP1, 1<<MM_eq
2421     |  bnez TMP1, <1                    // Or 'no __eq' flag set?
2422     |.  nop
2423     |  b ->vmeta_equal                  // Handle __eq metamethod.
2424     |.  li CARG4, 1-vk                  // ne = 0 or 1.
2425     break;
2426
2427   case BC_ISEQS: case BC_ISNES:
2428     vk = op == BC_ISEQS;
2429     |  // RA = src*8, RD = str_const*8 (~), JMP with RD = target
2430     |  addu RA, BASE, RA
2431     |   addiu PC, PC, 4
2432     |  lw TMP0, HI(RA)
2433     |   srl RD, RD, 1
2434     |  lw STR:TMP3, LO(RA)
2435     |   subu RD, KBASE, RD
2436     |    lhu TMP2, -4+OFS_RD(PC)
2437     |.if FFI
2438     |  li AT, LJ_TCDATA
2439     |  beq TMP0, AT, ->vmeta_equal_cd
2440     |.endif
2441     |.  lw STR:TMP1, -4(RD)             // KBASE-4-str_const*4
2442     |  addiu TMP0, TMP0, -LJ_TSTR
2443     |   decode_RD4b TMP2
2444     |  xor TMP1, STR:TMP1, STR:TMP3
2445     |  or TMP0, TMP0, TMP1
2446     |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2447     |   addu TMP2, TMP2, TMP3
2448     if (vk) {
2449       |  movn TMP2, r0, TMP0
2450     } else {
2451       |  movz TMP2, r0, TMP0
2452     }
2453     |  addu PC, PC, TMP2
2454     |  ins_next
2455     break;
2456
2457   case BC_ISEQN: case BC_ISNEN:
2458     vk = op == BC_ISEQN;
2459     |  // RA = src*8, RD = num_const*8, JMP with RD = target
2460     |  addu RA, BASE, RA
2461     |   addiu PC, PC, 4
2462     |  lw TMP0, HI(RA)
2463     |   ldc1 f0, 0(RA)
2464     |  addu RD, KBASE, RD
2465     |    lhu TMP2, -4+OFS_RD(PC)
2466     |   ldc1 f2, 0(RD)
2467     |    lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2468     |  sltiu AT, TMP0, LJ_TISNUM
2469     |    decode_RD4b TMP2
2470     |.if FFI
2471     |  beqz AT, >5
2472     |.else
2473     |  beqz AT, >1
2474     |.endif
2475     |.   addu TMP2, TMP2, TMP3
2476     |   c.eq.d f0, f2
2477     if (vk) {
2478       |  movf TMP2, r0
2479       |  addu PC, PC, TMP2
2480       |1:
2481     } else {
2482       |  movt TMP2, r0
2483       |1:
2484       |  addu PC, PC, TMP2
2485     }
2486     |  ins_next
2487     |.if FFI
2488     |5:
2489     |  li AT, LJ_TCDATA
2490     |  beq TMP0, AT, ->vmeta_equal_cd
2491     |.  nop
2492     |  b <1
2493     |.  nop
2494     |.endif
2495     break;
2496
2497   case BC_ISEQP: case BC_ISNEP:
2498     vk = op == BC_ISEQP;
2499     |  // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
2500     |  addu RA, BASE, RA
2501     |   srl TMP1, RD, 3
2502     |  lw TMP0, HI(RA)
2503     |    lhu TMP2, OFS_RD(PC)
2504     |   not TMP1, TMP1
2505     |    addiu PC, PC, 4
2506     |.if FFI
2507     |  li AT, LJ_TCDATA
2508     |  beq TMP0, AT, ->vmeta_equal_cd
2509     |.endif
2510     |.  xor TMP0, TMP0, TMP1
2511     |  decode_RD4b TMP2
2512     |  lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2513     |  addu TMP2, TMP2, TMP3
2514     if (vk) {
2515       |  movn TMP2, r0, TMP0
2516     } else {
2517       |  movz TMP2, r0, TMP0
2518     }
2519     |  addu PC, PC, TMP2
2520     |  ins_next
2521     break;
2522
2523   /* -- Unary test and copy ops ------------------------------------------- */
2524
2525   case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
2526     |  // RA = dst*8 or unused, RD = src*8, JMP with RD = target
2527     |  addu RD, BASE, RD
2528     |   lhu TMP2, OFS_RD(PC)
2529     |  lw TMP0, HI(RD)
2530     |   addiu PC, PC, 4
2531     if (op == BC_IST || op == BC_ISF) {
2532       |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2533       |   decode_RD4b TMP2
2534       |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2535       |   addu TMP2, TMP2, TMP3
2536       if (op == BC_IST) {
2537         |  movz TMP2, r0, TMP0
2538       } else {
2539         |  movn TMP2, r0, TMP0
2540       }
2541       |  addu PC, PC, TMP2
2542     } else {
2543       |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2544       |  ldc1 f0, 0(RD)
2545       if (op == BC_ISTC) {
2546         |  beqz TMP0, >1
2547       } else {
2548         |  bnez TMP0, >1
2549       }
2550       |.  addu RA, BASE, RA
2551       |   decode_RD4b TMP2
2552       |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2553       |   addu TMP2, TMP2, TMP3
2554       |  sdc1 f0, 0(RA)
2555       |   addu PC, PC, TMP2
2556       |1:
2557     }
2558     |  ins_next
2559     break;
2560
2561   /* -- Unary ops --------------------------------------------------------- */
2562
2563   case BC_MOV:
2564     |  // RA = dst*8, RD = src*8
2565     |  addu RD, BASE, RD
2566     |  addu RA, BASE, RA
2567     |  ldc1 f0, 0(RD)
2568     |  ins_next1
2569     |  sdc1 f0, 0(RA)
2570     |  ins_next2
2571     break;
2572   case BC_NOT:
2573     |  // RA = dst*8, RD = src*8
2574     |  addu RD, BASE, RD
2575     |   addu RA, BASE, RA
2576     |  lw TMP0, HI(RD)
2577     |   li TMP1, LJ_TFALSE
2578     |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2579     |  addiu TMP1, TMP0, LJ_TTRUE
2580     |  ins_next1
2581     |  sw TMP1, HI(RA)
2582     |  ins_next2
2583     break;
2584   case BC_UNM:
2585     |  // RA = dst*8, RD = src*8
2586     |  addu CARG3, BASE, RD
2587     |   addu RA, BASE, RA
2588     |  lw TMP0, HI(CARG3)
2589     |   ldc1 f0, 0(CARG3)
2590     |  sltiu AT, TMP0, LJ_TISNUM
2591     |  beqz AT, ->vmeta_unm
2592     |.  neg.d f0, f0
2593     |  ins_next1
2594     |   sdc1 f0, 0(RA)
2595     |  ins_next2
2596     break;
2597   case BC_LEN:
2598     |  // RA = dst*8, RD = src*8
2599     |  addu CARG2, BASE, RD
2600     |   addu RA, BASE, RA
2601     |  lw TMP0, HI(CARG2)
2602     |   lw CARG1, LO(CARG2)
2603     |  li AT, LJ_TSTR
2604     |  bne TMP0, AT, >2
2605     |.  li AT, LJ_TTAB
2606     |  lw CRET1, STR:CARG1->len
2607     |1:
2608     |  mtc1 CRET1, f0
2609     |  cvt.d.w f0, f0
2610     |  ins_next1
2611     |  sdc1 f0, 0(RA)
2612     |  ins_next2
2613     |2:
2614     |  bne TMP0, AT, ->vmeta_len
2615     |.  nop
2616 #if LJ_52
2617     |  lw TAB:TMP2, TAB:CARG1->metatable
2618     |  bnez TAB:TMP2, >9
2619     |.  nop
2620     |3:
2621 #endif
2622     |->BC_LEN_Z:
2623     |  load_got lj_tab_len
2624     |  call_intern lj_tab_len           // (GCtab *t)
2625     |.  nop
2626     |  // Returns uint32_t (but less than 2^31).
2627     |  b <1
2628     |.  nop
2629 #if LJ_52
2630     |9:
2631     |  lbu TMP0, TAB:TMP2->nomm
2632     |  andi TMP0, TMP0, 1<<MM_len
2633     |  bnez TMP0, <3                    // 'no __len' flag set: done.
2634     |.  nop
2635     |  b ->vmeta_len
2636     |.  nop
2637 #endif
2638     break;
2639
2640   /* -- Binary ops -------------------------------------------------------- */
2641
2642     |.macro ins_arithpre
2643     ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
2644     |  decode_RB8a RB, INS
2645     |  decode_RB8b RB
2646     |   decode_RDtoRC8 RC, RD
2647     |  // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
2648     ||switch (vk) {
2649     ||case 0:
2650     |   addu CARG3, BASE, RB
2651     |    addu CARG4, KBASE, RC
2652     |   lw TMP1, HI(CARG3)
2653     |   ldc1 f20, 0(CARG3)
2654     |    ldc1 f22, 0(CARG4)
2655     |   sltiu AT, TMP1, LJ_TISNUM
2656     ||  break;
2657     ||case 1:
2658     |   addu CARG4, BASE, RB
2659     |    addu CARG3, KBASE, RC
2660     |   lw TMP1, HI(CARG4)
2661     |   ldc1 f22, 0(CARG4)
2662     |    ldc1 f20, 0(CARG3)
2663     |   sltiu AT, TMP1, LJ_TISNUM
2664     ||  break;
2665     ||default:
2666     |   addu CARG3, BASE, RB
2667     |    addu CARG4, BASE, RC
2668     |   lw TMP1, HI(CARG3)
2669     |    lw TMP2, HI(CARG4)
2670     |   ldc1 f20, 0(CARG3)
2671     |    ldc1 f22, 0(CARG4)
2672     |   sltiu AT, TMP1, LJ_TISNUM
2673     |   sltiu TMP0, TMP2, LJ_TISNUM
2674     |   and AT, AT, TMP0
2675     ||  break;
2676     ||}
2677     |  beqz AT, ->vmeta_arith
2678     |.  addu RA, BASE, RA
2679     |.endmacro
2680     |
2681     |.macro fpmod, a, b, c
2682     |->BC_MODVN_Z:
2683     |  bal ->vm_floor                   // floor(b/c)
2684     |.  div.d FARG1, b, c
2685     |  mul.d a, FRET1, c
2686     |  sub.d a, b, a                    // b - floor(b/c)*c
2687     |.endmacro
2688     |
2689     |.macro ins_arith, ins
2690     |  ins_arithpre
2691     |.if "ins" == "fpmod_"
2692     |  b ->BC_MODVN_Z                   // Avoid 3 copies. It's slow anyway.
2693     |.  nop
2694     |.else
2695     |  ins f0, f20, f22
2696     |  ins_next1
2697     |  sdc1 f0, 0(RA)
2698     |  ins_next2
2699     |.endif
2700     |.endmacro
2701
2702   case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
2703     |  ins_arith add.d
2704     break;
2705   case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
2706     |  ins_arith sub.d
2707     break;
2708   case BC_MULVN: case BC_MULNV: case BC_MULVV:
2709     |  ins_arith mul.d
2710     break;
2711   case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
2712     |  ins_arith div.d
2713     break;
2714   case BC_MODVN:
2715     |  ins_arith fpmod
2716     break;
2717   case BC_MODNV: case BC_MODVV:
2718     |  ins_arith fpmod_
2719     break;
2720   case BC_POW:
2721     |  decode_RB8a RB, INS
2722     |  decode_RB8b RB
2723     |   decode_RDtoRC8 RC, RD
2724     |  addu CARG3, BASE, RB
2725     |   addu CARG4, BASE, RC
2726     |  lw TMP1, HI(CARG3)
2727     |   lw TMP2, HI(CARG4)
2728     |  ldc1 FARG1, 0(CARG3)
2729     |   ldc1 FARG2, 0(CARG4)
2730     |  sltiu AT, TMP1, LJ_TISNUM
2731     |  sltiu TMP0, TMP2, LJ_TISNUM
2732     |  and AT, AT, TMP0
2733     |  load_got pow
2734     |  beqz AT, ->vmeta_arith
2735     |.  addu RA, BASE, RA
2736     |  call_extern
2737     |.  nop
2738     |  ins_next1
2739     |  sdc1 FRET1, 0(RA)
2740     |  ins_next2
2741     break;
2742
2743   case BC_CAT:
2744     |  // RA = dst*8, RB = src_start*8, RC = src_end*8
2745     |  decode_RB8a RB, INS
2746     |  decode_RB8b RB
2747     |   decode_RDtoRC8 RC, RD
2748     |  subu CARG3, RC, RB
2749     |   sw BASE, L->base
2750     |  addu CARG2, BASE, RC
2751     |  move MULTRES, RB
2752     |->BC_CAT_Z:
2753     |  load_got lj_meta_cat
2754     |  srl CARG3, CARG3, 3
2755     |   sw PC, SAVE_PC
2756     |  call_intern lj_meta_cat          // (lua_State *L, TValue *top, int left)
2757     |.  move CARG1, L
2758     |  // Returns NULL (finished) or TValue * (metamethod).
2759     |  bnez CRET1, ->vmeta_binop
2760     |.  lw BASE, L->base
2761     |  addu RB, BASE, MULTRES
2762     |  ldc1 f0, 0(RB)
2763     |   addu RA, BASE, RA
2764     |  ins_next1
2765     |   sdc1 f0, 0(RA)                  // Copy result from RB to RA.
2766     |  ins_next2
2767     break;
2768
2769   /* -- Constant ops ------------------------------------------------------ */
2770
2771   case BC_KSTR:
2772     |  // RA = dst*8, RD = str_const*8 (~)
2773     |  srl TMP1, RD, 1
2774     |  subu TMP1, KBASE, TMP1
2775     |  ins_next1
2776     |  lw TMP0, -4(TMP1)                // KBASE-4-str_const*4
2777     |  addu RA, BASE, RA
2778     |   li TMP2, LJ_TSTR
2779     |  sw TMP0, LO(RA)
2780     |   sw TMP2, HI(RA)
2781     |  ins_next2
2782     break;
2783   case BC_KCDATA:
2784     |.if FFI
2785     |  // RA = dst*8, RD = cdata_const*8 (~)
2786     |  srl TMP1, RD, 1
2787     |  subu TMP1, KBASE, TMP1
2788     |  ins_next1
2789     |  lw TMP0, -4(TMP1)                // KBASE-4-cdata_const*4
2790     |  addu RA, BASE, RA
2791     |   li TMP2, LJ_TCDATA
2792     |  sw TMP0, LO(RA)
2793     |   sw TMP2, HI(RA)
2794     |  ins_next2
2795     |.endif
2796     break;
2797   case BC_KSHORT:
2798     |  // RA = dst*8, RD = int16_literal*8
2799     |  sra RD, INS, 16
2800     |  mtc1 RD, f0
2801     |  addu RA, BASE, RA
2802     |  cvt.d.w f0, f0
2803     |  ins_next1
2804     |  sdc1 f0, 0(RA)
2805     |  ins_next2
2806     break;
2807   case BC_KNUM:
2808     |  // RA = dst*8, RD = num_const*8
2809     |  addu RD, KBASE, RD
2810     |   addu RA, BASE, RA
2811     |  ldc1 f0, 0(RD)
2812     |  ins_next1
2813     |   sdc1 f0, 0(RA)
2814     |  ins_next2
2815     break;
2816   case BC_KPRI:
2817     |  // RA = dst*8, RD = primitive_type*8 (~)
2818     |  srl TMP1, RD, 3
2819     |   addu RA, BASE, RA
2820     |  not TMP0, TMP1
2821     |  ins_next1
2822     |   sw TMP0, HI(RA)
2823     |  ins_next2
2824     break;
2825   case BC_KNIL:
2826     |  // RA = base*8, RD = end*8
2827     |  addu RA, BASE, RA
2828     |  sw TISNIL, HI(RA)
2829     |   addiu RA, RA, 8
2830     |  addu RD, BASE, RD
2831     |1:
2832     |  sw TISNIL, HI(RA)
2833     |  slt AT, RA, RD
2834     |  bnez AT, <1
2835     |.  addiu RA, RA, 8
2836     |  ins_next_
2837     break;
2838
2839   /* -- Upvalue and function ops ------------------------------------------ */
2840
2841   case BC_UGET:
2842     |  // RA = dst*8, RD = uvnum*8
2843     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2844     |   srl RD, RD, 1
2845     |   addu RD, RD, LFUNC:RB
2846     |  lw UPVAL:RB, LFUNC:RD->uvptr
2847     |  ins_next1
2848     |  lw TMP1, UPVAL:RB->v
2849     |  ldc1 f0, 0(TMP1)
2850     |  addu RA, BASE, RA
2851     |  sdc1 f0, 0(RA)
2852     |  ins_next2
2853     break;
2854   case BC_USETV:
2855     |  // RA = uvnum*8, RD = src*8
2856     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2857     |    srl RA, RA, 1
2858     |   addu RD, BASE, RD
2859     |    addu RA, RA, LFUNC:RB
2860     |   ldc1 f0, 0(RD)
2861     |  lw UPVAL:RB, LFUNC:RA->uvptr
2862     |  lbu TMP3, UPVAL:RB->marked
2863     |   lw CARG2, UPVAL:RB->v
2864     |  andi TMP3, TMP3, LJ_GC_BLACK     // isblack(uv)
2865     |  lbu TMP0, UPVAL:RB->closed
2866     |   lw TMP2, HI(RD)
2867     |   sdc1 f0, 0(CARG2)
2868     |  li AT, LJ_GC_BLACK|1
2869     |  or TMP3, TMP3, TMP0
2870     |  beq TMP3, AT, >2                 // Upvalue is closed and black?
2871     |.  addiu TMP2, TMP2, -(LJ_TISNUM+1)
2872     |1:
2873     |  ins_next
2874     |
2875     |2:  // Check if new value is collectable.
2876     |  sltiu AT, TMP2, LJ_TISGCV - (LJ_TISNUM+1)
2877     |  beqz AT, <1                      // tvisgcv(v)
2878     |.  lw TMP1, LO(RD)
2879     |  lbu TMP3, GCOBJ:TMP1->gch.marked
2880     |  andi TMP3, TMP3, LJ_GC_WHITES    // iswhite(v)
2881     |  beqz TMP3, <1
2882     |.  load_got lj_gc_barrieruv
2883     |  // Crossed a write barrier. Move the barrier forward.
2884     |  call_intern lj_gc_barrieruv      // (global_State *g, TValue *tv)
2885     |.  addiu CARG1, DISPATCH, GG_DISP2G
2886     |  b <1
2887     |.  nop
2888     break;
2889   case BC_USETS:
2890     |  // RA = uvnum*8, RD = str_const*8 (~)
2891     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2892     |    srl RA, RA, 1
2893     |   srl TMP1, RD, 1
2894     |    addu RA, RA, LFUNC:RB
2895     |   subu TMP1, KBASE, TMP1
2896     |  lw UPVAL:RB, LFUNC:RA->uvptr
2897     |   lw STR:TMP1, -4(TMP1)           // KBASE-4-str_const*4
2898     |  lbu TMP2, UPVAL:RB->marked
2899     |   lw CARG2, UPVAL:RB->v
2900     |   lbu TMP3, STR:TMP1->marked
2901     |  andi AT, TMP2, LJ_GC_BLACK       // isblack(uv)
2902     |   lbu TMP2, UPVAL:RB->closed
2903     |   li TMP0, LJ_TSTR
2904     |   sw STR:TMP1, LO(CARG2)
2905     |  bnez AT, >2
2906     |.  sw TMP0, HI(CARG2)
2907     |1:
2908     |  ins_next
2909     |
2910     |2:  // Check if string is white and ensure upvalue is closed.
2911     |  beqz TMP2, <1
2912     |.  andi AT, TMP3, LJ_GC_WHITES     // iswhite(str)
2913     |  beqz AT, <1
2914     |.  load_got lj_gc_barrieruv
2915     |  // Crossed a write barrier. Move the barrier forward.
2916     |  call_intern lj_gc_barrieruv      // (global_State *g, TValue *tv)
2917     |.  addiu CARG1, DISPATCH, GG_DISP2G
2918     |  b <1
2919     |.  nop
2920     break;
2921   case BC_USETN:
2922     |  // RA = uvnum*8, RD = num_const*8
2923     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2924     |   srl RA, RA, 1
2925     |    addu RD, KBASE, RD
2926     |   addu RA, RA, LFUNC:RB
2927     |    ldc1 f0, 0(RD)
2928     |  lw UPVAL:RB, LFUNC:RA->uvptr
2929     |  ins_next1
2930     |  lw TMP1, UPVAL:RB->v
2931     |  sdc1 f0, 0(TMP1)
2932     |  ins_next2
2933     break;
2934   case BC_USETP:
2935     |  // RA = uvnum*8, RD = primitive_type*8 (~)
2936     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2937     |   srl RA, RA, 1
2938     |    srl TMP0, RD, 3
2939     |   addu RA, RA, LFUNC:RB
2940     |    not TMP0, TMP0
2941     |  lw UPVAL:RB, LFUNC:RA->uvptr
2942     |  ins_next1
2943     |  lw TMP1, UPVAL:RB->v
2944     |  sw TMP0, HI(TMP1)
2945     |  ins_next2
2946     break;
2947
2948   case BC_UCLO:
2949     |  // RA = level*8, RD = target
2950     |  lw TMP2, L->openupval
2951     |  branch_RD                        // Do this first since RD is not saved.
2952     |  load_got lj_func_closeuv
2953     |   sw BASE, L->base
2954     |  beqz TMP2, >1
2955     |.  move CARG1, L
2956     |  call_intern lj_func_closeuv      // (lua_State *L, TValue *level)
2957     |.  addu CARG2, BASE, RA
2958     |  lw BASE, L->base
2959     |1:
2960     |  ins_next
2961     break;
2962
2963   case BC_FNEW:
2964     |  // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
2965     |  srl TMP1, RD, 1
2966     |  load_got lj_func_newL_gc
2967     |  subu TMP1, KBASE, TMP1
2968     |  lw CARG3, FRAME_FUNC(BASE)
2969     |  lw CARG2, -4(TMP1)               // KBASE-4-tab_const*4
2970     |   sw BASE, L->base
2971     |   sw PC, SAVE_PC
2972     |  // (lua_State *L, GCproto *pt, GCfuncL *parent)
2973     |  call_intern lj_func_newL_gc
2974     |.  move CARG1, L
2975     |  // Returns GCfuncL *.
2976     |  lw BASE, L->base
2977     |   li TMP0, LJ_TFUNC
2978     |  ins_next1
2979     |  addu RA, BASE, RA
2980     |  sw TMP0, HI(RA)
2981     |  sw LFUNC:CRET1, LO(RA)
2982     |  ins_next2
2983     break;
2984
2985   /* -- Table ops --------------------------------------------------------- */
2986
2987   case BC_TNEW:
2988   case BC_TDUP:
2989     |  // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
2990     |  lw TMP0, DISPATCH_GL(gc.total)(DISPATCH)
2991     |  lw TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
2992     |   sw BASE, L->base
2993     |   sw PC, SAVE_PC
2994     |  sltu AT, TMP0, TMP1
2995     |  beqz AT, >5
2996     |1:
2997     if (op == BC_TNEW) {
2998       |  load_got lj_tab_new
2999       |  srl CARG2, RD, 3
3000       |  andi CARG2, CARG2, 0x7ff
3001       |  li TMP0, 0x801
3002       |  addiu AT, CARG2, -0x7ff
3003       |   srl CARG3, RD, 14
3004       |  movz CARG2, TMP0, AT
3005       |  // (lua_State *L, int32_t asize, uint32_t hbits)
3006       |  call_intern lj_tab_new
3007       |.  move CARG1, L
3008       |  // Returns Table *.
3009     } else {
3010       |  load_got lj_tab_dup
3011       |  srl TMP1, RD, 1
3012       |  subu TMP1, KBASE, TMP1
3013       |  move CARG1, L
3014       |  call_intern lj_tab_dup         // (lua_State *L, Table *kt)
3015       |.  lw CARG2, -4(TMP1)            // KBASE-4-str_const*4
3016       |  // Returns Table *.
3017     }
3018     |  lw BASE, L->base
3019     |  ins_next1
3020     |  addu RA, BASE, RA
3021     |   li TMP0, LJ_TTAB
3022     |  sw TAB:CRET1, LO(RA)
3023     |   sw TMP0, HI(RA)
3024     |  ins_next2
3025     |5:
3026     |  load_got lj_gc_step_fixtop
3027     |  move MULTRES, RD
3028     |  call_intern lj_gc_step_fixtop    // (lua_State *L)
3029     |.  move CARG1, L
3030     |  b <1
3031     |.  move RD, MULTRES
3032     break;
3033
3034   case BC_GGET:
3035     |  // RA = dst*8, RD = str_const*8 (~)
3036   case BC_GSET:
3037     |  // RA = src*8, RD = str_const*8 (~)
3038     |  lw LFUNC:TMP2, FRAME_FUNC(BASE)
3039     |   srl TMP1, RD, 1
3040     |   subu TMP1, KBASE, TMP1
3041     |  lw TAB:RB, LFUNC:TMP2->env
3042     |  lw STR:RC, -4(TMP1)              // KBASE-4-str_const*4
3043     if (op == BC_GGET) {
3044       |  b ->BC_TGETS_Z
3045     } else {
3046       |  b ->BC_TSETS_Z
3047     }
3048     |.  addu RA, BASE, RA
3049     break;
3050
3051   case BC_TGETV:
3052     |  // RA = dst*8, RB = table*8, RC = key*8
3053     |  decode_RB8a RB, INS
3054     |  decode_RB8b RB
3055     |   decode_RDtoRC8 RC, RD
3056     |  addu CARG2, BASE, RB
3057     |   addu CARG3, BASE, RC
3058     |  lw TMP1, HI(CARG2)
3059     |   lw TMP2, HI(CARG3)
3060     |    lw TAB:RB, LO(CARG2)
3061     |  li AT, LJ_TTAB
3062     |   ldc1 f0, 0(CARG3)
3063     |  bne TMP1, AT, ->vmeta_tgetv
3064     |.  addu RA, BASE, RA
3065     |  sltiu AT, TMP2, LJ_TISNUM
3066     |  beqz AT, >5
3067     |.  li AT, LJ_TSTR
3068     |
3069     |  // Convert number key to integer, check for integerness and range.
3070     |  cvt.w.d f2, f0
3071     |   lw TMP0, TAB:RB->asize
3072     |  mfc1 TMP2, f2
3073     |  cvt.d.w f4, f2
3074     |   lw TMP1, TAB:RB->array
3075     |  c.eq.d f0, f4
3076     |  sltu AT, TMP2, TMP0
3077     |  movf AT, r0
3078     |   sll TMP2, TMP2, 3
3079     |  beqz AT, ->vmeta_tgetv           // Integer key and in array part?
3080     |.  addu TMP2, TMP1, TMP2
3081     |  lw TMP0, HI(TMP2)
3082     |  beq TMP0, TISNIL, >2
3083     |.  ldc1 f0, 0(TMP2)
3084     |1:
3085     |  ins_next1
3086     |   sdc1 f0, 0(RA)
3087     |  ins_next2
3088     |
3089     |2:  // Check for __index if table value is nil.
3090     |  lw TAB:TMP2, TAB:RB->metatable
3091     |  beqz TAB:TMP2, <1                // No metatable: done.
3092     |.  nop
3093     |  lbu TMP0, TAB:TMP2->nomm
3094     |  andi TMP0, TMP0, 1<<MM_index
3095     |  bnez TMP0, <1                    // 'no __index' flag set: done.
3096     |.  nop
3097     |  b ->vmeta_tgetv
3098     |.  nop
3099     |
3100     |5:
3101     |  bne TMP2, AT, ->vmeta_tgetv
3102     |.  lw STR:RC, LO(CARG3)
3103     |  b ->BC_TGETS_Z                   // String key?
3104     |.  nop
3105     break;
3106   case BC_TGETS:
3107     |  // RA = dst*8, RB = table*8, RC = str_const*4 (~)
3108     |  decode_RB8a RB, INS
3109     |  decode_RB8b RB
3110     |  addu CARG2, BASE, RB
3111     |   decode_RC4a RC, INS
3112     |  lw TMP0, HI(CARG2)
3113     |   decode_RC4b RC
3114     |  li AT, LJ_TTAB
3115     |   lw TAB:RB, LO(CARG2)
3116     |   subu CARG3, KBASE, RC
3117     |   lw STR:RC, -4(CARG3)            // KBASE-4-str_const*4
3118     |  bne TMP0, AT, ->vmeta_tgets1
3119     |.  addu RA, BASE, RA
3120     |->BC_TGETS_Z:
3121     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
3122     |  lw TMP0, TAB:RB->hmask
3123     |  lw TMP1, STR:RC->hash
3124     |  lw NODE:TMP2, TAB:RB->node
3125     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3126     |  sll TMP0, TMP1, 5
3127     |  sll TMP1, TMP1, 3
3128     |  subu TMP1, TMP0, TMP1
3129     |  addu NODE:TMP2, NODE:TMP2, TMP1  // node = tab->node + (idx*32-idx*8)
3130     |1:
3131     |  lw CARG1, offsetof(Node, key)+HI(NODE:TMP2)
3132     |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
3133     |    lw NODE:TMP1, NODE:TMP2->next
3134     |    lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
3135     |  addiu CARG1, CARG1, -LJ_TSTR
3136     |   xor TMP0, TMP0, STR:RC
3137     |  or AT, CARG1, TMP0
3138     |  bnez AT, >4
3139     |.  lw TAB:TMP3, TAB:RB->metatable
3140     |    beq CARG2, TISNIL, >5          // Key found, but nil value?
3141     |.    lw CARG1, offsetof(Node, val)+LO(NODE:TMP2)
3142     |3:
3143     |  ins_next1
3144     |    sw CARG2, HI(RA)
3145     |     sw CARG1, LO(RA)
3146     |  ins_next2
3147     |
3148     |4:  // Follow hash chain.
3149     |  bnez NODE:TMP1, <1
3150     |.  move NODE:TMP2, NODE:TMP1
3151     |  // End of hash chain: key not found, nil result.
3152     |
3153     |5:  // Check for __index if table value is nil.
3154     |  beqz TAB:TMP3, <3                // No metatable: done.
3155     |.  li CARG2, LJ_TNIL
3156     |  lbu TMP0, TAB:TMP3->nomm
3157     |  andi TMP0, TMP0, 1<<MM_index
3158     |  bnez TMP0, <3                    // 'no __index' flag set: done.
3159     |.  nop
3160     |  b ->vmeta_tgets
3161     |.  nop
3162     break;
3163   case BC_TGETB:
3164     |  // RA = dst*8, RB = table*8, RC = index*8
3165     |  decode_RB8a RB, INS
3166     |  decode_RB8b RB
3167     |  addu CARG2, BASE, RB
3168     |   decode_RDtoRC8 RC, RD
3169     |  lw CARG1, HI(CARG2)
3170     |  li AT, LJ_TTAB
3171     |   lw TAB:RB, LO(CARG2)
3172     |   addu RA, BASE, RA
3173     |  bne CARG1, AT, ->vmeta_tgetb
3174     |.  srl TMP0, RC, 3
3175     |  lw TMP1, TAB:RB->asize
3176     |   lw TMP2, TAB:RB->array
3177     |  sltu AT, TMP0, TMP1
3178     |  beqz AT, ->vmeta_tgetb
3179     |.  addu RC, TMP2, RC
3180     |  lw TMP1, HI(RC)
3181     |  beq TMP1, TISNIL, >5
3182     |.  ldc1 f0, 0(RC)
3183     |1:
3184     |  ins_next1
3185     |   sdc1 f0, 0(RA)
3186     |  ins_next2
3187     |
3188     |5:  // Check for __index if table value is nil.
3189     |  lw TAB:TMP2, TAB:RB->metatable
3190     |  beqz TAB:TMP2, <1                // No metatable: done.
3191     |.  nop
3192     |  lbu TMP1, TAB:TMP2->nomm
3193     |  andi TMP1, TMP1, 1<<MM_index
3194     |  bnez TMP1, <1                    // 'no __index' flag set: done.
3195     |.  nop
3196     |  b ->vmeta_tgetb                  // Caveat: preserve TMP0!
3197     |.  nop
3198     break;
3199
3200   case BC_TSETV:
3201     |  // RA = src*8, RB = table*8, RC = key*8
3202     |  decode_RB8a RB, INS
3203     |  decode_RB8b RB
3204     |   decode_RDtoRC8 RC, RD
3205     |  addu CARG2, BASE, RB
3206     |   addu CARG3, BASE, RC
3207     |  lw TMP1, HI(CARG2)
3208     |   lw TMP2, HI(CARG3)
3209     |    lw TAB:RB, LO(CARG2)
3210     |  li AT, LJ_TTAB
3211     |   ldc1 f0, 0(CARG3)
3212     |  bne TMP1, AT, ->vmeta_tsetv
3213     |.  addu RA, BASE, RA
3214     |  sltiu AT, TMP2, LJ_TISNUM
3215     |  beqz AT, >5
3216     |.  li AT, LJ_TSTR
3217     |
3218     |  // Convert number key to integer, check for integerness and range.
3219     |  cvt.w.d f2, f0
3220     |   lw TMP0, TAB:RB->asize
3221     |  mfc1 TMP2, f2
3222     |  cvt.d.w f4, f2
3223     |   lw TMP1, TAB:RB->array
3224     |  c.eq.d f0, f4
3225     |  sltu AT, TMP2, TMP0
3226     |  movf AT, r0
3227     |   sll TMP2, TMP2, 3
3228     |  beqz AT, ->vmeta_tsetv           // Integer key and in array part?
3229     |.  addu TMP1, TMP1, TMP2
3230     |   lbu TMP3, TAB:RB->marked
3231     |  lw TMP0, HI(TMP1)
3232     |  beq TMP0, TISNIL, >3
3233     |.  ldc1 f0, 0(RA)
3234     |1:
3235     |   andi AT, TMP3, LJ_GC_BLACK      // isblack(table)
3236     |   bnez AT, >7
3237     |.  sdc1 f0, 0(TMP1)
3238     |2:
3239     |  ins_next
3240     |
3241     |3:  // Check for __newindex if previous value is nil.
3242     |  lw TAB:TMP2, TAB:RB->metatable
3243     |  beqz TAB:TMP2, <1                // No metatable: done.
3244     |.  nop
3245     |  lbu TMP2, TAB:TMP2->nomm
3246     |  andi TMP2, TMP2, 1<<MM_newindex
3247     |  bnez TMP2, <1                    // 'no __newindex' flag set: done.
3248     |.  nop
3249     |  b ->vmeta_tsetv
3250     |.  nop
3251     |
3252     |5:
3253     |  bne TMP2, AT, ->vmeta_tsetv
3254     |.  lw STR:RC, LO(CARG3)
3255     |  b ->BC_TSETS_Z                   // String key?
3256     |.  nop
3257     |
3258     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3259     |  barrierback TAB:RB, TMP3, TMP0, <2
3260     break;
3261   case BC_TSETS:
3262     |  // RA = src*8, RB = table*8, RC = str_const*8 (~)
3263     |  decode_RB8a RB, INS
3264     |  decode_RB8b RB
3265     |  addu CARG2, BASE, RB
3266     |   decode_RC4a RC, INS
3267     |  lw TMP0, HI(CARG2)
3268     |   decode_RC4b RC
3269     |  li AT, LJ_TTAB
3270     |   subu CARG3, KBASE, RC
3271     |    lw TAB:RB, LO(CARG2)
3272     |   lw STR:RC, -4(CARG3)            // KBASE-4-str_const*4
3273     |  bne TMP0, AT, ->vmeta_tsets1
3274     |.  addu RA, BASE, RA
3275     |->BC_TSETS_Z:
3276     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = BASE+src*8
3277     |  lw TMP0, TAB:RB->hmask
3278     |  lw TMP1, STR:RC->hash
3279     |  lw NODE:TMP2, TAB:RB->node
3280     |   sb r0, TAB:RB->nomm             // Clear metamethod cache.
3281     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3282     |  sll TMP0, TMP1, 5
3283     |  sll TMP1, TMP1, 3
3284     |  subu TMP1, TMP0, TMP1
3285     |  addu NODE:TMP2, NODE:TMP2, TMP1  // node = tab->node + (idx*32-idx*8)
3286     |   ldc1 f20, 0(RA)
3287     |1:
3288     |  lw CARG1, offsetof(Node, key)+HI(NODE:TMP2)
3289     |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
3290     |  li AT, LJ_TSTR
3291     |    lw NODE:TMP1, NODE:TMP2->next
3292     |  bne CARG1, AT, >5
3293     |.   lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
3294     |   bne TMP0, STR:RC, >5
3295     |.    lbu TMP3, TAB:RB->marked
3296     |    beq CARG2, TISNIL, >4          // Key found, but nil value?
3297     |.    lw TAB:TMP0, TAB:RB->metatable
3298     |2:
3299     |  andi AT, TMP3, LJ_GC_BLACK       // isblack(table)
3300     |  bnez AT, >7
3301     |.  sdc1 f20, NODE:TMP2->val
3302     |3:
3303     |  ins_next
3304     |
3305     |4:  // Check for __newindex if previous value is nil.
3306     |  beqz TAB:TMP0, <2                // No metatable: done.
3307     |.  nop
3308     |  lbu TMP0, TAB:TMP0->nomm
3309     |  andi TMP0, TMP0, 1<<MM_newindex
3310     |  bnez TMP0, <2                    // 'no __newindex' flag set: done.
3311     |.  nop
3312     |  b ->vmeta_tsets
3313     |.  nop
3314     |
3315     |5:  // Follow hash chain.
3316     |  bnez NODE:TMP1, <1
3317     |.  move NODE:TMP2, NODE:TMP1
3318     |  // End of hash chain: key not found, add a new one
3319     |
3320     |  // But check for __newindex first.
3321     |  lw TAB:TMP2, TAB:RB->metatable
3322     |  beqz TAB:TMP2, >6                // No metatable: continue.
3323     |.  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
3324     |  lbu TMP0, TAB:TMP2->nomm
3325     |  andi TMP0, TMP0, 1<<MM_newindex
3326     |  beqz TMP0, ->vmeta_tsets         // 'no __newindex' flag NOT set: check.
3327     |.  li AT, LJ_TSTR
3328     |6:
3329     |  load_got lj_tab_newkey
3330     |  sw STR:RC, LO(CARG3)
3331     |  sw AT, HI(CARG3)
3332     |   sw BASE, L->base
3333     |  move CARG2, TAB:RB
3334     |   sw PC, SAVE_PC
3335     |  call_intern lj_tab_newkey        // (lua_State *L, GCtab *t, TValue *k
3336     |.  move CARG1, L
3337     |  // Returns TValue *.
3338     |  lw BASE, L->base
3339     |  b <3                             // No 2nd write barrier needed.
3340     |.  sdc1 f20, 0(CRET1)
3341     |
3342     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3343     |  barrierback TAB:RB, TMP3, TMP0, <3
3344     break;
3345   case BC_TSETB:
3346     |  // RA = src*8, RB = table*8, RC = index*8
3347     |  decode_RB8a RB, INS
3348     |  decode_RB8b RB
3349     |  addu CARG2, BASE, RB
3350     |   decode_RDtoRC8 RC, RD
3351     |  lw CARG1, HI(CARG2)
3352     |  li AT, LJ_TTAB
3353     |   lw TAB:RB, LO(CARG2)
3354     |   addu RA, BASE, RA
3355     |  bne CARG1, AT, ->vmeta_tsetb
3356     |.  srl TMP0, RC, 3
3357     |  lw TMP1, TAB:RB->asize
3358     |   lw TMP2, TAB:RB->array
3359     |  sltu AT, TMP0, TMP1
3360     |  beqz AT, ->vmeta_tsetb
3361     |.  addu RC, TMP2, RC
3362     |  lw TMP1, HI(RC)
3363     |   lbu TMP3, TAB:RB->marked
3364     |  beq TMP1, TISNIL, >5
3365     |.  ldc1 f0, 0(RA)
3366     |1:
3367     |  andi AT, TMP3, LJ_GC_BLACK       // isblack(table)
3368     |  bnez AT, >7
3369     |.  sdc1 f0, 0(RC)
3370     |2:
3371     |  ins_next
3372     |
3373     |5:  // Check for __newindex if previous value is nil.
3374     |  lw TAB:TMP2, TAB:RB->metatable
3375     |  beqz TAB:TMP2, <1                // No metatable: done.
3376     |.  nop
3377     |  lbu TMP1, TAB:TMP2->nomm
3378     |  andi TMP1, TMP1, 1<<MM_newindex
3379     |  bnez TMP1, <1                    // 'no __newindex' flag set: done.
3380     |.  nop
3381     |  b ->vmeta_tsetb                  // Caveat: preserve TMP0!
3382     |.  nop
3383     |
3384     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3385     |  barrierback TAB:RB, TMP3, TMP0, <2
3386     break;
3387
3388   case BC_TSETM:
3389     |  // RA = base*8 (table at base-1), RD = num_const*8 (start index)
3390     |  addu RA, BASE, RA
3391     |1:
3392     |   addu TMP3, KBASE, RD
3393     |  lw TAB:CARG2, -8+LO(RA)          // Guaranteed to be a table.
3394     |    addiu TMP0, MULTRES, -8
3395     |   lw TMP3, LO(TMP3)               // Integer constant is in lo-word.
3396     |    beqz TMP0, >4                  // Nothing to copy?
3397     |.    srl CARG3, TMP0, 3
3398     |  addu CARG3, CARG3, TMP3
3399     |  lw TMP2, TAB:CARG2->asize
3400     |   sll TMP1, TMP3, 3
3401     |    lbu TMP3, TAB:CARG2->marked
3402     |   lw CARG1, TAB:CARG2->array
3403     |  sltu AT, TMP2, CARG3
3404     |  bnez AT, >5
3405     |.  addu TMP2, RA, TMP0
3406     |   addu TMP1, TMP1, CARG1
3407     |  andi TMP0, TMP3, LJ_GC_BLACK     // isblack(table)
3408     |3:  // Copy result slots to table.
3409     |   ldc1 f0, 0(RA)
3410     |    addiu RA, RA, 8
3411     |  sltu AT, RA, TMP2
3412     |   sdc1 f0, 0(TMP1)
3413     |  bnez AT, <3
3414     |.   addiu TMP1, TMP1, 8
3415     |  bnez TMP0, >7
3416     |. nop
3417     |4:
3418     |  ins_next
3419     |
3420     |5:  // Need to resize array part.
3421     |  load_got lj_tab_reasize
3422     |   sw BASE, L->base
3423     |   sw PC, SAVE_PC
3424     |  move BASE, RD
3425     |  call_intern lj_tab_reasize       // (lua_State *L, GCtab *t, int nasize)
3426     |.  move CARG1, L
3427     |  // Must not reallocate the stack.
3428     |  move RD, BASE
3429     |  b <1
3430     |.  lw BASE, L->base        // Reload BASE for lack of a saved register.
3431     |
3432     |7:  // Possible table write barrier for any value. Skip valiswhite check.
3433     |  barrierback TAB:CARG2, TMP3, TMP0, <4
3434     break;
3435
3436   /* -- Calls and vararg handling ----------------------------------------- */
3437
3438   case BC_CALLM:
3439     |  // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
3440     |  decode_RDtoRC8 NARGS8:RC, RD
3441     |  b ->BC_CALL_Z
3442     |.  addu NARGS8:RC, NARGS8:RC, MULTRES
3443     break;
3444   case BC_CALL:
3445     |  // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
3446     |  decode_RDtoRC8 NARGS8:RC, RD
3447     |->BC_CALL_Z:
3448     |  move TMP2, BASE
3449     |  addu BASE, BASE, RA
3450     |   li AT, LJ_TFUNC
3451     |  lw TMP0, HI(BASE)
3452     |   lw LFUNC:RB, LO(BASE)
3453     |   addiu BASE, BASE, 8
3454     |  bne TMP0, AT, ->vmeta_call
3455     |.  addiu NARGS8:RC, NARGS8:RC, -8
3456     |  ins_call
3457     break;
3458
3459   case BC_CALLMT:
3460     |  // RA = base*8, (RB = 0,) RC = extra_nargs*8
3461     |  addu NARGS8:RD, NARGS8:RD, MULTRES       // BC_CALLT gets RC from RD.
3462     |  // Fall through. Assumes BC_CALLT follows.
3463     break;
3464   case BC_CALLT:
3465     |  // RA = base*8, (RB = 0,) RC = (nargs+1)*8
3466     |  addu RA, BASE, RA
3467     |   li AT, LJ_TFUNC
3468     |  lw TMP0, HI(RA)
3469     |   lw LFUNC:RB, LO(RA)
3470     |   move NARGS8:RC, RD
3471     |    lw TMP1, FRAME_PC(BASE)
3472     |   addiu RA, RA, 8
3473     |  bne TMP0, AT, ->vmeta_callt
3474     |.  addiu NARGS8:RC, NARGS8:RC, -8
3475     |->BC_CALLT_Z:
3476     |  andi TMP0, TMP1, FRAME_TYPE      // Caveat: preserve TMP0 until the 'or'.
3477     |   lbu TMP3, LFUNC:RB->ffid
3478     |  bnez TMP0, >7
3479     |.  xori TMP2, TMP1, FRAME_VARG
3480     |1:
3481     |  sw LFUNC:RB, FRAME_FUNC(BASE)    // Copy function down, but keep PC.
3482     |  sltiu AT, TMP3, 2                // (> FF_C) Calling a fast function?
3483     |  move TMP2, BASE
3484     |  beqz NARGS8:RC, >3
3485     |.  move TMP3, NARGS8:RC
3486     |2:
3487     |   ldc1 f0, 0(RA)
3488     |    addiu RA, RA, 8
3489     |  addiu TMP3, TMP3, -8
3490     |   sdc1 f0, 0(TMP2)
3491     |  bnez TMP3, <2
3492     |.   addiu TMP2, TMP2, 8
3493     |3:
3494     |  or TMP0, TMP0, AT
3495     |  beqz TMP0, >5
3496     |.  nop
3497     |4:
3498     |  ins_callt
3499     |
3500     |5:  // Tailcall to a fast function with a Lua frame below.
3501     |  lw INS, -4(TMP1)
3502     |  decode_RA8a RA, INS
3503     |  decode_RA8b RA
3504     |  subu TMP1, BASE, RA
3505     |  lw LFUNC:TMP1, -8+FRAME_FUNC(TMP1)
3506     |  lw TMP1, LFUNC:TMP1->pc
3507     |  b <4
3508     |.  lw KBASE, PC2PROTO(k)(TMP1)     // Need to prepare KBASE.
3509     |
3510     |7:  // Tailcall from a vararg function.
3511     |  andi AT, TMP2, FRAME_TYPEP
3512     |  bnez AT, <1                      // Vararg frame below?
3513     |.  subu TMP2, BASE, TMP2           // Relocate BASE down.
3514     |  move BASE, TMP2
3515     |  lw TMP1, FRAME_PC(TMP2)
3516     |  b <1
3517     |.  andi TMP0, TMP1, FRAME_TYPE
3518     break;
3519
3520   case BC_ITERC:
3521     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
3522     |  move TMP2, BASE
3523     |  addu BASE, BASE, RA
3524     |   li AT, LJ_TFUNC
3525     |  lw TMP1, -24+HI(BASE)
3526     |   lw LFUNC:RB, -24+LO(BASE)
3527     |    ldc1 f2, -8(BASE)
3528     |    ldc1 f0, -16(BASE)
3529     |  sw TMP1, HI(BASE)                // Copy callable.
3530     |   sw LFUNC:RB, LO(BASE)
3531     |    sdc1 f2, 16(BASE)              // Copy control var.
3532     |    sdc1 f0, 8(BASE)               // Copy state.
3533     |   addiu BASE, BASE, 8
3534     |  bne TMP1, AT, ->vmeta_call
3535     |.  li NARGS8:RC, 16                // Iterators get 2 arguments.
3536     |  ins_call
3537     break;
3538
3539   case BC_ITERN:
3540     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
3541     |.if JIT
3542     |  // NYI: add hotloop, record BC_ITERN.
3543     |.endif
3544     |  addu RA, BASE, RA
3545     |  lw TAB:RB, -16+LO(RA)
3546     |  lw RC, -8+LO(RA)                 // Get index from control var.
3547     |  lw TMP0, TAB:RB->asize
3548     |  lw TMP1, TAB:RB->array
3549     |   addiu PC, PC, 4
3550     |1:  // Traverse array part.
3551     |  sltu AT, RC, TMP0
3552     |  beqz AT, >5                      // Index points after array part?
3553     |.  sll TMP3, RC, 3
3554     |  addu TMP3, TMP1, TMP3
3555     |  lw TMP2, HI(TMP3)
3556     |   ldc1 f0, 0(TMP3)
3557     |    mtc1 RC, f2
3558     |     lhu RD, -4+OFS_RD(PC)
3559     |  beq TMP2, TISNIL, <1             // Skip holes in array part.
3560     |.  addiu RC, RC, 1
3561     |    cvt.d.w f2, f2
3562     |     lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
3563     |   sdc1 f0, 8(RA)
3564     |     decode_RD4b RD
3565     |     addu RD, RD, TMP3
3566     |   sw RC, -8+LO(RA)                // Update control var.
3567     |     addu PC, PC, RD
3568     |    sdc1 f2, 0(RA)
3569     |3:
3570     |  ins_next
3571     |
3572     |5:  // Traverse hash part.
3573     |  lw TMP1, TAB:RB->hmask
3574     |  subu RC, RC, TMP0
3575     |   lw TMP2, TAB:RB->node
3576     |6:
3577     |  sltu AT, TMP1, RC                // End of iteration? Branch to ITERL+1.
3578     |  bnez AT, <3
3579     |.  sll TMP3, RC, 5
3580     |   sll RB, RC, 3
3581     |   subu TMP3, TMP3, RB
3582     |  addu NODE:TMP3, TMP3, TMP2
3583     |  lw RB, HI(NODE:TMP3)
3584     |  ldc1 f0, 0(NODE:TMP3)
3585     |     lhu RD, -4+OFS_RD(PC)
3586     |  beq RB, TISNIL, <6               // Skip holes in hash part.
3587     |.  addiu RC, RC, 1
3588     |   ldc1 f2, NODE:TMP3->key
3589     |     lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
3590     |  sdc1 f0, 8(RA)
3591     |    addu RC, RC, TMP0
3592     |     decode_RD4b RD
3593     |     addu RD, RD, TMP3
3594     |   sdc1 f2, 0(RA)
3595     |     addu PC, PC, RD
3596     |  b <3
3597     |.  sw RC, -8+LO(RA)                // Update control var.
3598     break;
3599
3600   case BC_ISNEXT:
3601     |  // RA = base*8, RD = target (points to ITERN)
3602     |  addu RA, BASE, RA
3603     |  lw TMP0, -24+HI(RA)
3604     |  lw CFUNC:TMP1, -24+LO(RA)
3605     |   lw TMP2, -16+HI(RA)
3606     |    lw TMP3, -8+HI(RA)
3607     |  li AT, LJ_TFUNC
3608     |  bne TMP0, AT, >5
3609     |.  addiu TMP2, TMP2, -LJ_TTAB
3610     |  lbu TMP1, CFUNC:TMP1->ffid
3611     |  addiu TMP3, TMP3, -LJ_TNIL
3612     |   srl TMP0, RD, 1
3613     |  or TMP2, TMP2, TMP3
3614     |  addiu TMP1, TMP1, -FF_next_N
3615     |   addu TMP0, PC, TMP0
3616     |  or TMP1, TMP1, TMP2
3617     |  bnez TMP1, >5
3618     |.  lui TMP2, (-(BCBIAS_J*4 >> 16) & 65535)
3619     |  addu PC, TMP0, TMP2
3620     |  lui TMP1, 0xfffe
3621     |  ori TMP1, TMP1, 0x7fff
3622     |  sw r0, -8+LO(RA)                 // Initialize control var.
3623     |  sw TMP1, -8+HI(RA)
3624     |1:
3625     |  ins_next
3626     |5:  // Despecialize bytecode if any of the checks fail.
3627     |  li TMP3, BC_JMP
3628     |   li TMP1, BC_ITERC
3629     |  sb TMP3, -4+OFS_OP(PC)
3630     |   addu PC, TMP0, TMP2
3631     |  b <1
3632     |.  sb TMP1, OFS_OP(PC)
3633     break;
3634
3635   case BC_VARG:
3636     |  // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
3637     |  lw TMP0, FRAME_PC(BASE)
3638     |  decode_RDtoRC8 RC, RD
3639     |   decode_RB8a RB, INS
3640     |  addu RC, BASE, RC
3641     |   decode_RB8b RB
3642     |   addu RA, BASE, RA
3643     |  addiu RC, RC, FRAME_VARG
3644     |   addu TMP2, RA, RB
3645     |  addiu TMP3, BASE, -8             // TMP3 = vtop
3646     |  subu RC, RC, TMP0                // RC = vbase
3647     |  // Note: RC may now be even _above_ BASE if nargs was < numparams.
3648     |  beqz RB, >5                      // Copy all varargs?
3649     |.  subu TMP1, TMP3, RC
3650     |  addiu TMP2, TMP2, -16
3651     |1:  // Copy vararg slots to destination slots.
3652     |  lw CARG1, HI(RC)
3653     |  sltu AT, RC, TMP3
3654     |   lw CARG2, LO(RC)
3655     |    addiu RC, RC, 8
3656     |  movz CARG1, TISNIL, AT
3657     |  sw CARG1, HI(RA)
3658     |   sw CARG2, LO(RA)
3659     |  sltu AT, RA, TMP2
3660     |  bnez AT, <1
3661     |.   addiu RA, RA, 8
3662     |3:
3663     |  ins_next
3664     |
3665     |5:  // Copy all varargs.
3666     |  lw TMP0, L->maxstack
3667     |  blez TMP1, <3                    // No vararg slots?
3668     |.  li MULTRES, 8                   // MULTRES = (0+1)*8
3669     |  addu TMP2, RA, TMP1
3670     |  sltu AT, TMP0, TMP2
3671     |  bnez AT, >7
3672     |.  addiu MULTRES, TMP1, 8
3673     |6:
3674     |  ldc1 f0, 0(RC)
3675     |   addiu RC, RC, 8
3676     |  sdc1 f0, 0(RA)
3677     |  sltu AT, RC, TMP3
3678     |  bnez AT, <6                      // More vararg slots?
3679     |.  addiu RA, RA, 8
3680     |  b <3
3681     |.  nop
3682     |
3683     |7:  // Grow stack for varargs.
3684     |  load_got lj_state_growstack
3685     |   sw RA, L->top
3686     |  subu RA, RA, BASE
3687     |   sw BASE, L->base
3688     |  subu BASE, RC, BASE              // Need delta, because BASE may change.
3689     |   sw PC, SAVE_PC
3690     |  srl CARG2, TMP1, 3
3691     |  call_intern lj_state_growstack   // (lua_State *L, int n)
3692     |.  move CARG1, L
3693     |  move RC, BASE
3694     |  lw BASE, L->base
3695     |  addu RA, BASE, RA
3696     |  addu RC, BASE, RC
3697     |  b <6
3698     |.  addiu TMP3, BASE, -8
3699     break;
3700
3701   /* -- Returns ----------------------------------------------------------- */
3702
3703   case BC_RETM:
3704     |  // RA = results*8, RD = extra_nresults*8
3705     |  addu RD, RD, MULTRES             // MULTRES >= 8, so RD >= 8.
3706     |  // Fall through. Assumes BC_RET follows.
3707     break;
3708
3709   case BC_RET:
3710     |  // RA = results*8, RD = (nresults+1)*8
3711     |  lw PC, FRAME_PC(BASE)
3712     |   addu RA, BASE, RA
3713     |    move MULTRES, RD
3714     |1:
3715     |  andi TMP0, PC, FRAME_TYPE
3716     |  bnez TMP0, ->BC_RETV_Z
3717     |.  xori TMP1, PC, FRAME_VARG
3718     |
3719     |->BC_RET_Z:
3720     |  // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
3721     |   lw INS, -4(PC)
3722     |    addiu TMP2, BASE, -8
3723     |    addiu RC, RD, -8
3724     |  decode_RA8a TMP0, INS
3725     |   decode_RB8a RB, INS
3726     |  decode_RA8b TMP0
3727     |   decode_RB8b RB
3728     |   addu TMP3, TMP2, RB
3729     |  beqz RC, >3
3730     |.  subu BASE, TMP2, TMP0
3731     |2:
3732     |   ldc1 f0, 0(RA)
3733     |    addiu RA, RA, 8
3734     |  addiu RC, RC, -8
3735     |   sdc1 f0, 0(TMP2)
3736     |  bnez RC, <2
3737     |.   addiu TMP2, TMP2, 8
3738     |3:
3739     |  addiu TMP3, TMP3, -8
3740     |5:
3741     |  sltu AT, TMP2, TMP3
3742     |  bnez AT, >6
3743     |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
3744     |  ins_next1
3745     |  lw TMP1, LFUNC:TMP1->pc
3746     |  lw KBASE, PC2PROTO(k)(TMP1)
3747     |  ins_next2
3748     |
3749     |6:  // Fill up results with nil.
3750     |  sw TISNIL, HI(TMP2)
3751     |  b <5
3752     |.  addiu TMP2, TMP2, 8
3753     |
3754     |->BC_RETV_Z:  // Non-standard return case.
3755     |  andi TMP2, TMP1, FRAME_TYPEP
3756     |  bnez TMP2, ->vm_return
3757     |.  nop
3758     |  // Return from vararg function: relocate BASE down.
3759     |  subu BASE, BASE, TMP1
3760     |  b <1
3761     |.  lw PC, FRAME_PC(BASE)
3762     break;
3763
3764   case BC_RET0: case BC_RET1:
3765     |  // RA = results*8, RD = (nresults+1)*8
3766     |  lw PC, FRAME_PC(BASE)
3767     |   addu RA, BASE, RA
3768     |    move MULTRES, RD
3769     |  andi TMP0, PC, FRAME_TYPE
3770     |  bnez TMP0, ->BC_RETV_Z
3771     |.  xori TMP1, PC, FRAME_VARG
3772     |
3773     |  lw INS, -4(PC)
3774     |   addiu TMP2, BASE, -8
3775     if (op == BC_RET1) {
3776       |  ldc1 f0, 0(RA)
3777     }
3778     |  decode_RB8a RB, INS
3779     |   decode_RA8a RA, INS
3780     |  decode_RB8b RB
3781     |   decode_RA8b RA
3782     if (op == BC_RET1) {
3783       |  sdc1 f0, 0(TMP2)
3784     }
3785     |   subu BASE, TMP2, RA
3786     |5:
3787     |  sltu AT, RD, RB
3788     |  bnez AT, >6
3789     |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
3790     |  ins_next1
3791     |  lw TMP1, LFUNC:TMP1->pc
3792     |  lw KBASE, PC2PROTO(k)(TMP1)
3793     |  ins_next2
3794     |
3795     |6:  // Fill up results with nil.
3796     |  addiu TMP2, TMP2, 8
3797     |  addiu RD, RD, 8
3798     |  b <5
3799     if (op == BC_RET1) {
3800       |.  sw TISNIL, HI(TMP2)
3801     } else {
3802       |.  sw TISNIL, -8+HI(TMP2)
3803     }
3804     break;
3805
3806   /* -- Loops and branches ------------------------------------------------ */
3807
3808   case BC_FORL:
3809     |.if JIT
3810     |  hotloop
3811     |.endif
3812     |  // Fall through. Assumes BC_IFORL follows.
3813     break;
3814
3815   case BC_JFORI:
3816   case BC_JFORL:
3817 #if !LJ_HASJIT
3818     break;
3819 #endif
3820   case BC_FORI:
3821   case BC_IFORL:
3822     |  // RA = base*8, RD = target (after end of loop or start of loop)
3823     vk = (op == BC_IFORL || op == BC_JFORL);
3824     |  addu RA, BASE, RA
3825     if (vk) {
3826       |  ldc1 f0, FORL_IDX*8(RA)
3827       |  ldc1 f4, FORL_STEP*8(RA)
3828       |  ldc1 f2, FORL_STOP*8(RA)
3829       |   lw TMP3, FORL_STEP*8+HI(RA)
3830       |  add.d f0, f0, f4
3831       |  sdc1 f0, FORL_IDX*8(RA)
3832     } else {
3833       |  lw TMP1, FORL_IDX*8+HI(RA)
3834       |  lw TMP3, FORL_STEP*8+HI(RA)
3835       |  lw TMP2, FORL_STOP*8+HI(RA)
3836       |  sltiu TMP1, TMP1, LJ_TISNUM
3837       |  sltiu TMP0, TMP3, LJ_TISNUM
3838       |  sltiu TMP2, TMP2, LJ_TISNUM
3839       |  and TMP1, TMP1, TMP0
3840       |  and TMP1, TMP1, TMP2
3841       |   ldc1 f0, FORL_IDX*8(RA)
3842       |  beqz TMP1, ->vmeta_for
3843       |.  ldc1 f2, FORL_STOP*8(RA)
3844     }
3845     if (op != BC_JFORL) {
3846       |  srl RD, RD, 1
3847       |  lui TMP0, (-(BCBIAS_J*4 >> 16) & 65535)
3848     }
3849     |  c.le.d 0, f0, f2
3850     |  c.le.d 1, f2, f0
3851     |  sdc1 f0, FORL_EXT*8(RA)
3852     if (op == BC_JFORI) {
3853       |  li TMP1, 1
3854       |  li TMP2, 1
3855       |   addu TMP0, RD, TMP0
3856       |  slt TMP3, TMP3, r0
3857       |  movf TMP1, r0, 0
3858       |   addu PC, PC, TMP0
3859       |  movf TMP2, r0, 1
3860       |   lhu RD, -4+OFS_RD(PC)
3861       |  movn TMP1, TMP2, TMP3
3862       |  bnez TMP1, =>BC_JLOOP
3863       |.  decode_RD8b RD
3864     } else if (op == BC_JFORL) {
3865       |  li TMP1, 1
3866       |  li TMP2, 1
3867       |  slt TMP3, TMP3, r0
3868       |  movf TMP1, r0, 0
3869       |  movf TMP2, r0, 1
3870       |  movn TMP1, TMP2, TMP3
3871       |  bnez TMP1, =>BC_JLOOP
3872       |.  nop
3873     } else {
3874       |  addu TMP1, RD, TMP0
3875       |  slt TMP3, TMP3, r0
3876       |  move TMP2, TMP1
3877       if (op == BC_FORI) {
3878         |  movt TMP1, r0, 0
3879         |  movt TMP2, r0, 1
3880       } else {
3881         |  movf TMP1, r0, 0
3882         |  movf TMP2, r0, 1
3883       }
3884       |  movn TMP1, TMP2, TMP3
3885       |  addu PC, PC, TMP1
3886     }
3887     |  ins_next
3888     break;
3889
3890   case BC_ITERL:
3891     |.if JIT
3892     |  hotloop
3893     |.endif
3894     |  // Fall through. Assumes BC_IITERL follows.
3895     break;
3896
3897   case BC_JITERL:
3898 #if !LJ_HASJIT
3899     break;
3900 #endif
3901   case BC_IITERL:
3902     |  // RA = base*8, RD = target
3903     |  addu RA, BASE, RA
3904     |  lw TMP1, HI(RA)
3905     |  beq TMP1, TISNIL, >1             // Stop if iterator returned nil.
3906     |.  lw TMP2, LO(RA)
3907     if (op == BC_JITERL) {
3908       |  sw TMP1, -8+HI(RA)
3909       |  b =>BC_JLOOP
3910       |.  sw TMP2, -8+LO(RA)
3911     } else {
3912       |  branch_RD                      // Otherwise save control var + branch.
3913       |  sw TMP1, -8+HI(RA)
3914       |   sw TMP2, -8+LO(RA)
3915     }
3916     |1:
3917     |  ins_next
3918     break;
3919
3920   case BC_LOOP:
3921     |  // RA = base*8, RD = target (loop extent)
3922     |  // Note: RA/RD is only used by trace recorder to determine scope/extent
3923     |  // This opcode does NOT jump, it's only purpose is to detect a hot loop.
3924     |.if JIT
3925     |  hotloop
3926     |.endif
3927     |  // Fall through. Assumes BC_ILOOP follows.
3928     break;
3929
3930   case BC_ILOOP:
3931     |  // RA = base*8, RD = target (loop extent)
3932     |  ins_next
3933     break;
3934
3935   case BC_JLOOP:
3936     |.if JIT
3937     |  // RA = base*8 (ignored), RD = traceno*8
3938     |  lw TMP1, DISPATCH_J(trace)(DISPATCH)
3939     |  srl RD, RD, 1
3940     |   li AT, 0
3941     |  addu TMP1, TMP1, RD
3942     |  // Traces on MIPS don't store the trace number, so use 0.
3943     |   sw AT, DISPATCH_GL(vmstate)(DISPATCH)
3944     |  lw TRACE:TMP2, 0(TMP1)
3945     |   sw BASE, DISPATCH_GL(jit_base)(DISPATCH)
3946     |   sw L, DISPATCH_GL(jit_L)(DISPATCH)
3947     |  lw TMP2, TRACE:TMP2->mcode
3948     |  jr TMP2
3949     |.  addiu JGL, DISPATCH, GG_DISP2G+32768
3950     |.endif
3951     break;
3952
3953   case BC_JMP:
3954     |  // RA = base*8 (only used by trace recorder), RD = target
3955     |  branch_RD
3956     |  ins_next
3957     break;
3958
3959   /* -- Function headers -------------------------------------------------- */
3960
3961   case BC_FUNCF:
3962     |.if JIT
3963     |  hotcall
3964     |.endif
3965   case BC_FUNCV:  /* NYI: compiled vararg functions. */
3966     |  // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
3967     break;
3968
3969   case BC_JFUNCF:
3970 #if !LJ_HASJIT
3971     break;
3972 #endif
3973   case BC_IFUNCF:
3974     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3975     |  lw TMP2, L->maxstack
3976     |   lbu TMP1, -4+PC2PROTO(numparams)(PC)
3977     |    lw KBASE, -4+PC2PROTO(k)(PC)
3978     |  sltu AT, TMP2, RA
3979     |  bnez AT, ->vm_growstack_l
3980     |.  sll TMP1, TMP1, 3
3981     if (op != BC_JFUNCF) {
3982       |  ins_next1
3983     }
3984     |2:
3985     |  sltu AT, NARGS8:RC, TMP1         // Check for missing parameters.
3986     |  bnez AT, >3
3987     |.  addu AT, BASE, NARGS8:RC
3988     if (op == BC_JFUNCF) {
3989       |  decode_RD8a RD, INS
3990       |  b =>BC_JLOOP
3991       |.  decode_RD8b RD
3992     } else {
3993       |  ins_next2
3994     }
3995     |
3996     |3:  // Clear missing parameters.
3997     |  sw TISNIL, HI(AT)
3998     |  b <2
3999     |.  addiu NARGS8:RC, NARGS8:RC, 8
4000     break;
4001
4002   case BC_JFUNCV:
4003 #if !LJ_HASJIT
4004     break;
4005 #endif
4006     |  NYI  // NYI: compiled vararg functions
4007     break;  /* NYI: compiled vararg functions. */
4008
4009   case BC_IFUNCV:
4010     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
4011     |   addu TMP1, BASE, RC
4012     |  lw TMP2, L->maxstack
4013     |  addu TMP0, RA, RC
4014     |   sw LFUNC:RB, LO(TMP1)           // Store copy of LFUNC.
4015     |   addiu TMP3, RC, 8+FRAME_VARG
4016     |  sltu AT, TMP0, TMP2
4017     |    lw KBASE, -4+PC2PROTO(k)(PC)
4018     |  beqz AT, ->vm_growstack_l
4019     |.  sw TMP3, HI(TMP1)               // Store delta + FRAME_VARG.
4020     |  lbu TMP2, -4+PC2PROTO(numparams)(PC)
4021     |   move RA, BASE
4022     |   move RC, TMP1
4023     |  ins_next1
4024     |  beqz TMP2, >3
4025     |.  addiu BASE, TMP1, 8
4026     |1:
4027     |  lw TMP0, HI(RA)
4028     |   lw TMP3, LO(RA)
4029     |  sltu AT, RA, RC                  // Less args than parameters?
4030     |  move CARG1, TMP0
4031     |  movz TMP0, TISNIL, AT            // Clear missing parameters.
4032     |  movn CARG1, TISNIL, AT           // Clear old fixarg slot (help the GC).
4033     |   sw TMP3, 8+LO(TMP1)
4034     |    addiu TMP2, TMP2, -1
4035     |  sw TMP0, 8+HI(TMP1)
4036     |    addiu TMP1, TMP1, 8
4037     |  sw CARG1, HI(RA)
4038     |  bnez TMP2, <1
4039     |.   addiu RA, RA, 8
4040     |3:
4041     |  ins_next2
4042     break;
4043
4044   case BC_FUNCC:
4045   case BC_FUNCCW:
4046     |  // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
4047     if (op == BC_FUNCC) {
4048       |  lw CFUNCADDR, CFUNC:RB->f
4049     } else {
4050       |  lw CFUNCADDR, DISPATCH_GL(wrapf)(DISPATCH)
4051     }
4052     |  addu TMP1, RA, NARGS8:RC
4053     |  lw TMP2, L->maxstack
4054     |   addu RC, BASE, NARGS8:RC
4055     |  sw BASE, L->base
4056     |  sltu AT, TMP2, TMP1
4057     |   sw RC, L->top
4058     |    li_vmstate C
4059     if (op == BC_FUNCCW) {
4060       |  lw CARG2, CFUNC:RB->f
4061     }
4062     |  bnez AT, ->vm_growstack_c        // Need to grow stack.
4063     |.  move CARG1, L
4064     |  jalr CFUNCADDR                   // (lua_State *L [, lua_CFunction f])
4065     |.   st_vmstate
4066     |  // Returns nresults.
4067     |  lw BASE, L->base
4068     |   sll RD, CRET1, 3
4069     |  lw TMP1, L->top
4070     |    li_vmstate INTERP
4071     |  lw PC, FRAME_PC(BASE)            // Fetch PC of caller.
4072     |   subu RA, TMP1, RD               // RA = L->top - nresults*8
4073     |  b ->vm_returnc
4074     |.   st_vmstate
4075     break;
4076
4077   /* ---------------------------------------------------------------------- */
4078
4079   default:
4080     fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
4081     exit(2);
4082     break;
4083   }
4084 }
4085
4086 static int build_backend(BuildCtx *ctx)
4087 {
4088   int op;
4089
4090   dasm_growpc(Dst, BC__MAX);
4091
4092   build_subroutines(ctx);
4093
4094   |.code_op
4095   for (op = 0; op < BC__MAX; op++)
4096     build_ins(ctx, (BCOp)op, op);
4097
4098   return BC__MAX;
4099 }
4100
4101 /* Emit pseudo frame-info for all assembler functions. */
4102 static void emit_asm_debug(BuildCtx *ctx)
4103 {
4104   int fcofs = (int)((uint8_t *)ctx->glob[GLOB_vm_ffi_call] - ctx->code);
4105   int i;
4106   switch (ctx->mode) {
4107   case BUILD_elfasm:
4108     fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
4109     fprintf(ctx->fp,
4110         ".Lframe0:\n"
4111         "\t.4byte .LECIE0-.LSCIE0\n"
4112         ".LSCIE0:\n"
4113         "\t.4byte 0xffffffff\n"
4114         "\t.byte 0x1\n"
4115         "\t.string \"\"\n"
4116         "\t.uleb128 0x1\n"
4117         "\t.sleb128 -4\n"
4118         "\t.byte 31\n"
4119         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4120         "\t.align 2\n"
4121         ".LECIE0:\n\n");
4122     fprintf(ctx->fp,
4123         ".LSFDE0:\n"
4124         "\t.4byte .LEFDE0-.LASFDE0\n"
4125         ".LASFDE0:\n"
4126         "\t.4byte .Lframe0\n"
4127         "\t.4byte .Lbegin\n"
4128         "\t.4byte %d\n"
4129         "\t.byte 0xe\n\t.uleb128 %d\n"
4130         "\t.byte 0x9f\n\t.sleb128 1\n"
4131         "\t.byte 0x9e\n\t.sleb128 2\n",
4132         fcofs, CFRAME_SIZE);
4133     for (i = 23; i >= 16; i--)
4134       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+i, 26-i);
4135     for (i = 30; i >= 20; i -= 2)
4136       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+32+i, 42-i);
4137     fprintf(ctx->fp,
4138         "\t.align 2\n"
4139         ".LEFDE0:\n\n");
4140 #if LJ_HASFFI
4141     fprintf(ctx->fp,
4142         ".LSFDE1:\n"
4143         "\t.4byte .LEFDE1-.LASFDE1\n"
4144         ".LASFDE1:\n"
4145         "\t.4byte .Lframe0\n"
4146         "\t.4byte lj_vm_ffi_call\n"
4147         "\t.4byte %d\n"
4148         "\t.byte 0x9f\n\t.uleb128 1\n"
4149         "\t.byte 0x90\n\t.uleb128 2\n"
4150         "\t.byte 0xd\n\t.uleb128 0x10\n"
4151         "\t.align 2\n"
4152         ".LEFDE1:\n\n", (int)ctx->codesz - fcofs);
4153 #endif
4154     fprintf(ctx->fp, "\t.section .eh_frame,\"aw\",@progbits\n");
4155     fprintf(ctx->fp,
4156         "\t.globl lj_err_unwind_dwarf\n"
4157         ".Lframe1:\n"
4158         "\t.4byte .LECIE1-.LSCIE1\n"
4159         ".LSCIE1:\n"
4160         "\t.4byte 0\n"
4161         "\t.byte 0x1\n"
4162         "\t.string \"zPR\"\n"
4163         "\t.uleb128 0x1\n"
4164         "\t.sleb128 -4\n"
4165         "\t.byte 31\n"
4166         "\t.uleb128 6\n"                        /* augmentation length */
4167         "\t.byte 0\n"
4168         "\t.4byte lj_err_unwind_dwarf\n"
4169         "\t.byte 0\n"
4170         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4171         "\t.align 2\n"
4172         ".LECIE1:\n\n");
4173     fprintf(ctx->fp,
4174         ".LSFDE2:\n"
4175         "\t.4byte .LEFDE2-.LASFDE2\n"
4176         ".LASFDE2:\n"
4177         "\t.4byte .LASFDE2-.Lframe1\n"
4178         "\t.4byte .Lbegin\n"
4179         "\t.4byte %d\n"
4180         "\t.uleb128 0\n"                        /* augmentation length */
4181         "\t.byte 0xe\n\t.uleb128 %d\n"
4182         "\t.byte 0x9f\n\t.sleb128 1\n"
4183         "\t.byte 0x9e\n\t.sleb128 2\n",
4184         fcofs, CFRAME_SIZE);
4185     for (i = 23; i >= 16; i--)
4186       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+i, 26-i);
4187     for (i = 30; i >= 20; i -= 2)
4188       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+32+i, 42-i);
4189     fprintf(ctx->fp,
4190         "\t.align 2\n"
4191         ".LEFDE2:\n\n");
4192 #if LJ_HASFFI
4193     fprintf(ctx->fp,
4194         ".Lframe2:\n"
4195         "\t.4byte .LECIE2-.LSCIE2\n"
4196         ".LSCIE2:\n"
4197         "\t.4byte 0\n"
4198         "\t.byte 0x1\n"
4199         "\t.string \"zR\"\n"
4200         "\t.uleb128 0x1\n"
4201         "\t.sleb128 -4\n"
4202         "\t.byte 31\n"
4203         "\t.uleb128 1\n"                        /* augmentation length */
4204         "\t.byte 0\n"
4205         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4206         "\t.align 2\n"
4207         ".LECIE2:\n\n");
4208     fprintf(ctx->fp,
4209         ".LSFDE3:\n"
4210         "\t.4byte .LEFDE3-.LASFDE3\n"
4211         ".LASFDE3:\n"
4212         "\t.4byte .LASFDE3-.Lframe2\n"
4213         "\t.4byte lj_vm_ffi_call\n"
4214         "\t.4byte %d\n"
4215         "\t.uleb128 0\n"                        /* augmentation length */
4216         "\t.byte 0x9f\n\t.uleb128 1\n"
4217         "\t.byte 0x90\n\t.uleb128 2\n"
4218         "\t.byte 0xd\n\t.uleb128 0x10\n"
4219         "\t.align 2\n"
4220         ".LEFDE3:\n\n", (int)ctx->codesz - fcofs);
4221 #endif
4222     break;
4223   default:
4224     break;
4225   }
4226 }
4227