src/vm_mips.dasc

   1 |// Low-level VM code for MIPS CPUs.
   2 |// Bytecode interpreter, fast functions and helper functions.
   3 |// Copyright (C) 2005-2016 Mike Pall. See Copyright Notice in luajit.h
   4 |
   5 |.arch mips
   6 |.section code_op, code_sub
   7 |
   8 |.actionlist build_actionlist
   9 |.globals GLOB_
  10 |.globalnames globnames
  11 |.externnames extnames
  12 |
  13 |// Note: The ragged indentation of the instructions is intentional.
  14 |//       The starting columns indicate data dependencies.
  15 |
  16 |//-----------------------------------------------------------------------
  17 |
  18 |// Fixed register assignments for the interpreter.
  19 |// Don't use: r0 = 0, r26/r27 = reserved, r28 = gp, r29 = sp, r31 = ra
  20 |
  21 |// The following must be C callee-save (but BASE is often refetched).
  22 |.define BASE,          r16     // Base of current Lua stack frame.
  23 |.define KBASE,         r17     // Constants of current Lua function.
  24 |.define PC,            r18     // Next PC.
  25 |.define DISPATCH,      r19     // Opcode dispatch table.
  26 |.define LREG,          r20     // Register holding lua_State (also in SAVE_L).
  27 |.define MULTRES,       r21     // Size of multi-result: (nresults+1)*8.
  28 |// NYI: r22 currently unused.
  29 |
  30 |.define JGL,           r30     // On-trace: global_State + 32768.
  31 |
  32 |// Constants for type-comparisons, stores and conversions. C callee-save.
  33 |.define TISNIL,        r30
  34 |.define TOBIT,         f30     // 2^52 + 2^51.
  35 |
  36 |// The following temporaries are not saved across C calls, except for RA.
  37 |.define RA,            r23     // Callee-save.
  38 |.define RB,            r8
  39 |.define RC,            r9
  40 |.define RD,            r10
  41 |.define INS,           r11
  42 |
  43 |.define AT,            r1      // Assembler temporary.
  44 |.define TMP0,          r12
  45 |.define TMP1,          r13
  46 |.define TMP2,          r14
  47 |.define TMP3,          r15
  48 |
  49 |// Calling conventions.
  50 |.define CFUNCADDR,     r25
  51 |.define CARG1,         r4
  52 |.define CARG2,         r5
  53 |.define CARG3,         r6
  54 |.define CARG4,         r7
  55 |
  56 |.define CRET1,         r2
  57 |.define CRET2,         r3
  58 |
  59 |.define FARG1,         f12
  60 |.define FARG2,         f14
  61 |
  62 |.define FRET1,         f0
  63 |.define FRET2,         f2
  64 |
  65 |// Stack layout while in interpreter. Must match with lj_frame.h.
  66 |.define CFRAME_SPACE,  112     // Delta for sp.
  67 |
  68 |.define SAVE_ERRF,     124(sp) // 32 bit C frame info.
  69 |.define SAVE_NRES,     120(sp)
  70 |.define SAVE_CFRAME,   116(sp)
  71 |.define SAVE_L,        112(sp)
  72 |//----- 8 byte aligned, ^^^^ 16 byte register save area, owned by interpreter.
  73 |.define SAVE_GPR_,     72      // .. 72+10*4: 32 bit GPR saves.
  74 |.define SAVE_FPR_,     24      // .. 24+6*8: 64 bit FPR saves.
  75 |.define SAVE_PC,       20(sp)
  76 |.define ARG5,          16(sp)
  77 |.define CSAVE_4,       12(sp)
  78 |.define CSAVE_3,       8(sp)
  79 |.define CSAVE_2,       4(sp)
  80 |.define CSAVE_1,       0(sp)
  81 |//----- 8 byte aligned, ^^^^ 16 byte register save area, owned by callee.
  82 |
  83 |.define ARG5_OFS,      16
  84 |.define SAVE_MULTRES,  ARG5
  85 |
  86 |.macro saveregs
  87 |  addiu sp, sp, -CFRAME_SPACE
  88 |  sw ra, SAVE_GPR_+9*4(sp)
  89 |  sw r30, SAVE_GPR_+8*4(sp)
  90 |   sdc1 f30, SAVE_FPR_+5*8(sp)
  91 |  sw r23, SAVE_GPR_+7*4(sp)
  92 |  sw r22, SAVE_GPR_+6*4(sp)
  93 |   sdc1 f28, SAVE_FPR_+4*8(sp)
  94 |  sw r21, SAVE_GPR_+5*4(sp)
  95 |  sw r20, SAVE_GPR_+4*4(sp)
  96 |   sdc1 f26, SAVE_FPR_+3*8(sp)
  97 |  sw r19, SAVE_GPR_+3*4(sp)
  98 |  sw r18, SAVE_GPR_+2*4(sp)
  99 |   sdc1 f24, SAVE_FPR_+2*8(sp)
 100 |  sw r17, SAVE_GPR_+1*4(sp)
 101 |  sw r16, SAVE_GPR_+0*4(sp)
 102 |   sdc1 f22, SAVE_FPR_+1*8(sp)
 103 |   sdc1 f20, SAVE_FPR_+0*8(sp)
 104 |.endmacro
 105 |
 106 |.macro restoreregs_ret
 107 |  lw ra, SAVE_GPR_+9*4(sp)
 108 |  lw r30, SAVE_GPR_+8*4(sp)
 109 |   ldc1 f30, SAVE_FPR_+5*8(sp)
 110 |  lw r23, SAVE_GPR_+7*4(sp)
 111 |  lw r22, SAVE_GPR_+6*4(sp)
 112 |   ldc1 f28, SAVE_FPR_+4*8(sp)
 113 |  lw r21, SAVE_GPR_+5*4(sp)
 114 |  lw r20, SAVE_GPR_+4*4(sp)
 115 |   ldc1 f26, SAVE_FPR_+3*8(sp)
 116 |  lw r19, SAVE_GPR_+3*4(sp)
 117 |  lw r18, SAVE_GPR_+2*4(sp)
 118 |   ldc1 f24, SAVE_FPR_+2*8(sp)
 119 |  lw r17, SAVE_GPR_+1*4(sp)
 120 |  lw r16, SAVE_GPR_+0*4(sp)
 121 |   ldc1 f22, SAVE_FPR_+1*8(sp)
 122 |   ldc1 f20, SAVE_FPR_+0*8(sp)
 123 |  jr ra
 124 |  addiu sp, sp, CFRAME_SPACE
 125 |.endmacro
 126 |
 127 |// Type definitions. Some of these are only used for documentation.
 128 |.type L,               lua_State,      LREG
 129 |.type GL,              global_State
 130 |.type TVALUE,          TValue
 131 |.type GCOBJ,           GCobj
 132 |.type STR,             GCstr
 133 |.type TAB,             GCtab
 134 |.type LFUNC,           GCfuncL
 135 |.type CFUNC,           GCfuncC
 136 |.type PROTO,           GCproto
 137 |.type UPVAL,           GCupval
 138 |.type NODE,            Node
 139 |.type NARGS8,          int
 140 |.type TRACE,           GCtrace
 141 |
 142 |//-----------------------------------------------------------------------
 143 |
 144 |// Trap for not-yet-implemented parts.
 145 |.macro NYI; .long 0xf0f0f0f0; .endmacro
 146 |
 147 |// Macros to mark delay slots.
 148 |.macro ., a; a; .endmacro
 149 |.macro ., a,b; a,b; .endmacro
 150 |.macro ., a,b,c; a,b,c; .endmacro
 151 |
 152 |//-----------------------------------------------------------------------
 153 |
 154 |// Endian-specific defines.
 155 |.define FRAME_PC,      LJ_ENDIAN_SELECT(-4,-8)
 156 |.define FRAME_FUNC,    LJ_ENDIAN_SELECT(-8,-4)
 157 |.define HI,            LJ_ENDIAN_SELECT(4,0)
 158 |.define LO,            LJ_ENDIAN_SELECT(0,4)
 159 |.define OFS_RD,        LJ_ENDIAN_SELECT(2,0)
 160 |.define OFS_RA,        LJ_ENDIAN_SELECT(1,2)
 161 |.define OFS_OP,        LJ_ENDIAN_SELECT(0,3)
 162 |
 163 |// Instruction decode.
 164 |.macro decode_OP1, dst, ins; andi dst, ins, 0xff; .endmacro
 165 |.macro decode_OP4a, dst, ins; andi dst, ins, 0xff; .endmacro
 166 |.macro decode_OP4b, dst; sll dst, dst, 2; .endmacro
 167 |.macro decode_RC4a, dst, ins; srl dst, ins, 14; .endmacro
 168 |.macro decode_RC4b, dst; andi dst, dst, 0x3fc; .endmacro
 169 |.macro decode_RD4b, dst; sll dst, dst, 2; .endmacro
 170 |.macro decode_RA8a, dst, ins; srl dst, ins, 5; .endmacro
 171 |.macro decode_RA8b, dst; andi dst, dst, 0x7f8; .endmacro
 172 |.macro decode_RB8a, dst, ins; srl dst, ins, 21; .endmacro
 173 |.macro decode_RB8b, dst; andi dst, dst, 0x7f8; .endmacro
 174 |.macro decode_RD8a, dst, ins; srl dst, ins, 16; .endmacro
 175 |.macro decode_RD8b, dst; sll dst, dst, 3; .endmacro
 176 |.macro decode_RDtoRC8, dst, src; andi dst, src, 0x7f8; .endmacro
 177 |
 178 |// Instruction fetch.
 179 |.macro ins_NEXT1
 180 |  lw INS, 0(PC)
 181 |   addiu PC, PC, 4
 182 |.endmacro
 183 |// Instruction decode+dispatch.
 184 |.macro ins_NEXT2
 185 |  decode_OP4a TMP1, INS
 186 |  decode_OP4b TMP1
 187 |  addu TMP0, DISPATCH, TMP1
 188 |   decode_RD8a RD, INS
 189 |  lw AT, 0(TMP0)
 190 |   decode_RA8a RA, INS
 191 |   decode_RD8b RD
 192 |  jr AT
 193 |   decode_RA8b RA
 194 |.endmacro
 195 |.macro ins_NEXT
 196 |  ins_NEXT1
 197 |  ins_NEXT2
 198 |.endmacro
 199 |
 200 |// Instruction footer.
 201 |.if 1
 202 |  // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
 203 |  .define ins_next, ins_NEXT
 204 |  .define ins_next_, ins_NEXT
 205 |  .define ins_next1, ins_NEXT1
 206 |  .define ins_next2, ins_NEXT2
 207 |.else
 208 |  // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
 209 |  // Affects only certain kinds of benchmarks (and only with -j off).
 210 |  .macro ins_next
 211 |    b ->ins_next
 212 |  .endmacro
 213 |  .macro ins_next1
 214 |  .endmacro
 215 |  .macro ins_next2
 216 |    b ->ins_next
 217 |  .endmacro
 218 |  .macro ins_next_
 219 |  ->ins_next:
 220 |    ins_NEXT
 221 |  .endmacro
 222 |.endif
 223 |
 224 |// Call decode and dispatch.
 225 |.macro ins_callt
 226 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 227 |  lw PC, LFUNC:RB->pc
 228 |  lw INS, 0(PC)
 229 |   addiu PC, PC, 4
 230 |  decode_OP4a TMP1, INS
 231 |   decode_RA8a RA, INS
 232 |  decode_OP4b TMP1
 233 |   decode_RA8b RA
 234 |  addu TMP0, DISPATCH, TMP1
 235 |  lw TMP0, 0(TMP0)
 236 |  jr TMP0
 237 |   addu RA, RA, BASE
 238 |.endmacro
 239 |
 240 |.macro ins_call
 241 |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
 242 |  sw PC, FRAME_PC(BASE)
 243 |  ins_callt
 244 |.endmacro
 245 |
 246 |//-----------------------------------------------------------------------
 247 |
 248 |.macro branch_RD
 249 |  srl TMP0, RD, 1
 250 |  lui AT, (-(BCBIAS_J*4 >> 16) & 65535)
 251 |  addu TMP0, TMP0, AT
 252 |  addu PC, PC, TMP0
 253 |.endmacro
 254 |
 255 |// Assumes DISPATCH is relative to GL.
 256 #define DISPATCH_GL(field)      (GG_DISP2G + (int)offsetof(global_State, field))
 257 #define DISPATCH_J(field)       (GG_DISP2J + (int)offsetof(jit_State, field))
 258 #define GG_DISP2GOT             (GG_OFS(got) - GG_OFS(dispatch))
 259 #define DISPATCH_GOT(name)      (GG_DISP2GOT + 4*LJ_GOT_##name)
 260 |
 261 #define PC2PROTO(field)  ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
 262 |
 263 |.macro load_got, func
 264 |  lw CFUNCADDR, DISPATCH_GOT(func)(DISPATCH)
 265 |.endmacro
 266 |// Much faster. Sadly, there's no easy way to force the required code layout.
 267 |// .macro call_intern, func; bal extern func; .endmacro
 268 |.macro call_intern, func; jalr CFUNCADDR; .endmacro
 269 |.macro call_extern; jalr CFUNCADDR; .endmacro
 270 |.macro jmp_extern; jr CFUNCADDR; .endmacro
 271 |
 272 |.macro hotcheck, delta, target
 273 |  srl TMP1, PC, 1
 274 |  andi TMP1, TMP1, 126
 275 |  addu TMP1, TMP1, DISPATCH
 276 |  lhu TMP2, GG_DISP2HOT(TMP1)
 277 |  addiu TMP2, TMP2, -delta
 278 |  bltz TMP2, target
 279 |.  sh TMP2, GG_DISP2HOT(TMP1)
 280 |.endmacro
 281 |
 282 |.macro hotloop
 283 |  hotcheck HOTCOUNT_LOOP, ->vm_hotloop
 284 |.endmacro
 285 |
 286 |.macro hotcall
 287 |  hotcheck HOTCOUNT_CALL, ->vm_hotcall
 288 |.endmacro
 289 |
 290 |// Set current VM state. Uses TMP0.
 291 |.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
 292 |.macro st_vmstate; sw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
 293 |
 294 |// Move table write barrier back. Overwrites mark and tmp.
 295 |.macro barrierback, tab, mark, tmp, target
 296 |  lw tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
 297 |   andi mark, mark, ~LJ_GC_BLACK & 255         // black2gray(tab)
 298 |  sw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
 299 |   sb mark, tab->marked
 300 |  b target
 301 |.  sw tmp, tab->gclist
 302 |.endmacro
 303 |
 304 |//-----------------------------------------------------------------------
 305
 306 /* Generate subroutines used by opcodes and other parts of the VM. */
 307 /* The .code_sub section should be last to help static branch prediction. */
 308 static void build_subroutines(BuildCtx *ctx)
 309 {
 310   |.code_sub
 311   |
 312   |//-----------------------------------------------------------------------
 313   |//-- Return handling ----------------------------------------------------
 314   |//-----------------------------------------------------------------------
 315   |
 316   |->vm_returnp:
 317   |  // See vm_return. Also: TMP2 = previous base.
 318   |  andi AT, PC, FRAME_P
 319   |  beqz AT, ->cont_dispatch
 320   |.  li TMP1, LJ_TTRUE
 321   |
 322   |  // Return from pcall or xpcall fast func.
 323   |  lw PC, FRAME_PC(TMP2)              // Fetch PC of previous frame.
 324   |  move BASE, TMP2                    // Restore caller base.
 325   |  // Prepending may overwrite the pcall frame, so do it at the end.
 326   |   sw TMP1, FRAME_PC(RA)             // Prepend true to results.
 327   |   addiu RA, RA, -8
 328   |
 329   |->vm_returnc:
 330   |   addiu RD, RD, 8                   // RD = (nresults+1)*8.
 331   |  andi TMP0, PC, FRAME_TYPE
 332   |   beqz RD, ->vm_unwind_c_eh
 333   |.   li CRET1, LUA_YIELD
 334   |  beqz TMP0, ->BC_RET_Z              // Handle regular return to Lua.
 335   |.  move MULTRES, RD
 336   |
 337   |->vm_return:
 338   |  // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
 339   |  // TMP0 = PC & FRAME_TYPE
 340   |   li TMP2, -8
 341   |  xori AT, TMP0, FRAME_C
 342   |   and TMP2, PC, TMP2
 343   |  bnez AT, ->vm_returnp
 344   |   subu TMP2, BASE, TMP2             // TMP2 = previous base.
 345   |
 346   |  addiu TMP1, RD, -8
 347   |   sw TMP2, L->base
 348   |    li_vmstate C
 349   |   lw TMP2, SAVE_NRES
 350   |   addiu BASE, BASE, -8
 351   |    st_vmstate
 352   |  beqz TMP1, >2
 353   |.   sll TMP2, TMP2, 3
 354   |1:
 355   |  addiu TMP1, TMP1, -8
 356   |   ldc1 f0, 0(RA)
 357   |    addiu RA, RA, 8
 358   |   sdc1 f0, 0(BASE)
 359   |  bnez TMP1, <1
 360   |.  addiu BASE, BASE, 8
 361   |
 362   |2:
 363   |  bne TMP2, RD, >6
 364   |3:
 365   |.  sw BASE, L->top                   // Store new top.
 366   |
 367   |->vm_leave_cp:
 368   |  lw TMP0, SAVE_CFRAME               // Restore previous C frame.
 369   |   move CRET1, r0                    // Ok return status for vm_pcall.
 370   |  sw TMP0, L->cframe
 371   |
 372   |->vm_leave_unw:
 373   |  restoreregs_ret
 374   |
 375   |6:
 376   |  lw TMP1, L->maxstack
 377   |  slt AT, TMP2, RD
 378   |  bnez AT, >7                        // Less results wanted?
 379   |  // More results wanted. Check stack size and fill up results with nil.
 380   |.  slt AT, BASE, TMP1
 381   |  beqz AT, >8
 382   |.  nop
 383   |  sw TISNIL, HI(BASE)
 384   |  addiu RD, RD, 8
 385   |  b <2
 386   |.  addiu BASE, BASE, 8
 387   |
 388   |7:  // Less results wanted.
 389   |  subu TMP0, RD, TMP2
 390   |  subu TMP0, BASE, TMP0              // Either keep top or shrink it.
 391   |  b <3
 392   |.  movn BASE, TMP0, TMP2             // LUA_MULTRET+1 case?
 393   |
 394   |8:  // Corner case: need to grow stack for filling up results.
 395   |  // This can happen if:
 396   |  // - A C function grows the stack (a lot).
 397   |  // - The GC shrinks the stack in between.
 398   |  // - A return back from a lua_call() with (high) nresults adjustment.
 399   |  load_got lj_state_growstack
 400   |   move MULTRES, RD
 401   |  srl CARG2, TMP2, 3
 402   |  call_intern lj_state_growstack     // (lua_State *L, int n)
 403   |.  move CARG1, L
 404   |    lw TMP2, SAVE_NRES
 405   |  lw BASE, L->top                    // Need the (realloced) L->top in BASE.
 406   |   move RD, MULTRES
 407   |  b <2
 408   |.   sll TMP2, TMP2, 3
 409   |
 410   |->vm_unwind_c:                       // Unwind C stack, return from vm_pcall.
 411   |  // (void *cframe, int errcode)
 412   |  move sp, CARG1
 413   |  move CRET1, CARG2
 414   |->vm_unwind_c_eh:                    // Landing pad for external unwinder.
 415   |  lw L, SAVE_L
 416   |   li TMP0, ~LJ_VMST_C
 417   |  lw GL:TMP1, L->glref
 418   |  b ->vm_leave_unw
 419   |.  sw TMP0, GL:TMP1->vmstate
 420   |
 421   |->vm_unwind_ff:                      // Unwind C stack, return from ff pcall.
 422   |  // (void *cframe)
 423   |  li AT, -4
 424   |  and sp, CARG1, AT
 425   |->vm_unwind_ff_eh:                   // Landing pad for external unwinder.
 426   |  lw L, SAVE_L
 427   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 428   |     li TISNIL, LJ_TNIL
 429   |  lw BASE, L->base
 430   |   lw DISPATCH, L->glref             // Setup pointer to dispatch table.
 431   |     mtc1 TMP3, TOBIT
 432   |  li TMP1, LJ_TFALSE
 433   |    li_vmstate INTERP
 434   |  lw PC, FRAME_PC(BASE)              // Fetch PC of previous frame.
 435   |     cvt.d.s TOBIT, TOBIT
 436   |  addiu RA, BASE, -8                 // Results start at BASE-8.
 437   |   addiu DISPATCH, DISPATCH, GG_G2DISP
 438   |  sw TMP1, HI(RA)                    // Prepend false to error message.
 439   |    st_vmstate
 440   |  b ->vm_returnc
 441   |.  li RD, 16                         // 2 results: false + error message.
 442   |
 443   |//-----------------------------------------------------------------------
 444   |//-- Grow stack for calls -----------------------------------------------
 445   |//-----------------------------------------------------------------------
 446   |
 447   |->vm_growstack_c:                    // Grow stack for C function.
 448   |  b >2
 449   |.  li CARG2, LUA_MINSTACK
 450   |
 451   |->vm_growstack_l:                    // Grow stack for Lua function.
 452   |  // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
 453   |  addu RC, BASE, RC
 454   |   subu RA, RA, BASE
 455   |  sw BASE, L->base
 456   |   addiu PC, PC, 4                   // Must point after first instruction.
 457   |  sw RC, L->top
 458   |   srl CARG2, RA, 3
 459   |2:
 460   |  // L->base = new base, L->top = top
 461   |  load_got lj_state_growstack
 462   |   sw PC, SAVE_PC
 463   |  call_intern lj_state_growstack     // (lua_State *L, int n)
 464   |.  move CARG1, L
 465   |  lw BASE, L->base
 466   |  lw RC, L->top
 467   |  lw LFUNC:RB, FRAME_FUNC(BASE)
 468   |  subu RC, RC, BASE
 469   |  // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
 470   |  ins_callt                          // Just retry the call.
 471   |
 472   |//-----------------------------------------------------------------------
 473   |//-- Entry points into the assembler VM ---------------------------------
 474   |//-----------------------------------------------------------------------
 475   |
 476   |->vm_resume:                         // Setup C frame and resume thread.
 477   |  // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
 478   |  saveregs
 479   |  move L, CARG1
 480   |    lw DISPATCH, L->glref            // Setup pointer to dispatch table.
 481   |  move BASE, CARG2
 482   |    lbu TMP1, L->status
 483   |   sw L, SAVE_L
 484   |  li PC, FRAME_CP
 485   |  addiu TMP0, sp, CFRAME_RESUME
 486   |    addiu DISPATCH, DISPATCH, GG_G2DISP
 487   |   sw r0, SAVE_NRES
 488   |   sw r0, SAVE_ERRF
 489   |  sw TMP0, L->cframe
 490   |   sw r0, SAVE_CFRAME
 491   |    beqz TMP1, >3
 492   |.  sw CARG1, SAVE_PC         // Any value outside of bytecode is ok.
 493   |
 494   |  // Resume after yield (like a return).
 495   |  move RA, BASE
 496   |   lw BASE, L->base
 497   |   lw TMP1, L->top
 498   |  lw PC, FRAME_PC(BASE)
 499   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 500   |   subu RD, TMP1, BASE
 501   |     mtc1 TMP3, TOBIT
 502   |    sb r0, L->status
 503   |     cvt.d.s TOBIT, TOBIT
 504   |    li_vmstate INTERP
 505   |   addiu RD, RD, 8
 506   |    st_vmstate
 507   |   move MULTRES, RD
 508   |  andi TMP0, PC, FRAME_TYPE
 509   |  beqz TMP0, ->BC_RET_Z
 510   |.    li TISNIL, LJ_TNIL
 511   |  b ->vm_return
 512   |.  nop
 513   |
 514   |->vm_pcall:                          // Setup protected C frame and enter VM.
 515   |  // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
 516   |  saveregs
 517   |  sw CARG4, SAVE_ERRF
 518   |  b >1
 519   |.  li PC, FRAME_CP
 520   |
 521   |->vm_call:                           // Setup C frame and enter VM.
 522   |  // (lua_State *L, TValue *base, int nres1)
 523   |  saveregs
 524   |  li PC, FRAME_C
 525   |
 526   |1:  // Entry point for vm_pcall above (PC = ftype).
 527   |  lw TMP1, L:CARG1->cframe
 528   |   sw CARG3, SAVE_NRES
 529   |    move L, CARG1
 530   |   sw CARG1, SAVE_L
 531   |    move BASE, CARG2
 532   |  sw sp, L->cframe                   // Add our C frame to cframe chain.
 533   |    lw DISPATCH, L->glref            // Setup pointer to dispatch table.
 534   |   sw CARG1, SAVE_PC         // Any value outside of bytecode is ok.
 535   |  sw TMP1, SAVE_CFRAME
 536   |    addiu DISPATCH, DISPATCH, GG_G2DISP
 537   |
 538   |3:  // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
 539   |  lw TMP2, L->base                   // TMP2 = old base (used in vmeta_call).
 540   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
 541   |   lw TMP1, L->top
 542   |     mtc1 TMP3, TOBIT
 543   |  addu PC, PC, BASE
 544   |   subu NARGS8:RC, TMP1, BASE
 545   |  subu PC, PC, TMP2                  // PC = frame delta + frame type
 546   |     cvt.d.s TOBIT, TOBIT
 547   |    li_vmstate INTERP
 548   |     li TISNIL, LJ_TNIL
 549   |    st_vmstate
 550   |
 551   |->vm_call_dispatch:
 552   |  // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
 553   |  lw TMP0, FRAME_PC(BASE)
 554   |  li AT, LJ_TFUNC
 555   |  bne TMP0, AT, ->vmeta_call
 556   |.  lw LFUNC:RB, FRAME_FUNC(BASE)
 557   |
 558   |->vm_call_dispatch_f:
 559   |  ins_call
 560   |  // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
 561   |
 562   |->vm_cpcall:                         // Setup protected C frame, call C.
 563   |  // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
 564   |  saveregs
 565   |  move L, CARG1
 566   |   lw TMP0, L:CARG1->stack
 567   |  sw CARG1, SAVE_L
 568   |   lw TMP1, L->top
 569   |  sw CARG1, SAVE_PC                  // Any value outside of bytecode is ok.
 570   |   subu TMP0, TMP0, TMP1             // Compute -savestack(L, L->top).
 571   |    lw TMP1, L->cframe
 572   |    sw sp, L->cframe                 // Add our C frame to cframe chain.
 573   |   sw TMP0, SAVE_NRES                // Neg. delta means cframe w/o frame.
 574   |  sw r0, SAVE_ERRF                   // No error function.
 575   |  move CFUNCADDR, CARG4
 576   |  jalr CARG4                 // (lua_State *L, lua_CFunction func, void *ud)
 577   |.   sw TMP1, SAVE_CFRAME
 578   |  move BASE, CRET1
 579   |   lw DISPATCH, L->glref             // Setup pointer to dispatch table.
 580   |    li PC, FRAME_CP
 581   |  bnez CRET1, <3                     // Else continue with the call.
 582   |.  addiu DISPATCH, DISPATCH, GG_G2DISP
 583   |  b ->vm_leave_cp                    // No base? Just remove C frame.
 584   |.  nop
 585   |
 586   |//-----------------------------------------------------------------------
 587   |//-- Metamethod handling ------------------------------------------------
 588   |//-----------------------------------------------------------------------
 589   |
 590   |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
 591   |// stack, so BASE doesn't need to be reloaded across these calls.
 592   |
 593   |//-- Continuation dispatch ----------------------------------------------
 594   |
 595   |->cont_dispatch:
 596   |  // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
 597   |  lw TMP0, -16+LO(BASE)              // Continuation.
 598   |   move RB, BASE
 599   |   move BASE, TMP2                   // Restore caller BASE.
 600   |    lw LFUNC:TMP1, FRAME_FUNC(TMP2)
 601   |.if FFI
 602   |  sltiu AT, TMP0, 2
 603   |.endif
 604   |     lw PC, -16+HI(RB)               // Restore PC from [cont|PC].
 605   |   addu TMP2, RA, RD
 606   |    lw TMP1, LFUNC:TMP1->pc
 607   |.if FFI
 608   |  bnez AT, >1
 609   |.endif
 610   |.  sw TISNIL, -8+HI(TMP2)            // Ensure one valid arg.
 611   |  // BASE = base, RA = resultptr, RB = meta base
 612   |  jr TMP0                            // Jump to continuation.
 613   |.  lw KBASE, PC2PROTO(k)(TMP1)
 614   |
 615   |.if FFI
 616   |1:
 617   |  bnez TMP0, ->cont_ffi_callback     // cont = 1: return from FFI callback.
 618   |  // cont = 0: tailcall from C function.
 619   |.  addiu TMP1, RB, -16
 620   |  b ->vm_call_tail
 621   |.  subu RC, TMP1, BASE
 622   |.endif
 623   |
 624   |->cont_cat:                          // RA = resultptr, RB = meta base
 625   |  lw INS, -4(PC)
 626   |   addiu CARG2, RB, -16
 627   |   ldc1 f0, 0(RA)
 628   |  decode_RB8a MULTRES, INS
 629   |   decode_RA8a RA, INS
 630   |  decode_RB8b MULTRES
 631   |   decode_RA8b RA
 632   |  addu TMP1, BASE, MULTRES
 633   |   sw BASE, L->base
 634   |   subu CARG3, CARG2, TMP1
 635   |  bne TMP1, CARG2, ->BC_CAT_Z
 636   |.  sdc1 f0, 0(CARG2)
 637   |  addu RA, BASE, RA
 638   |  b ->cont_nop
 639   |.  sdc1 f0, 0(RA)
 640   |
 641   |//-- Table indexing metamethods -----------------------------------------
 642   |
 643   |->vmeta_tgets1:
 644   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 645   |  li TMP0, LJ_TSTR
 646   |  sw STR:RC, LO(CARG3)
 647   |  b >1
 648   |.  sw TMP0, HI(CARG3)
 649   |
 650   |->vmeta_tgets:
 651   |  addiu CARG2, DISPATCH, DISPATCH_GL(tmptv)
 652   |  li TMP0, LJ_TTAB
 653   |  sw TAB:RB, LO(CARG2)
 654   |   addiu CARG3, DISPATCH, DISPATCH_GL(tmptv2)
 655   |  sw TMP0, HI(CARG2)
 656   |   li TMP1, LJ_TSTR
 657   |   sw STR:RC, LO(CARG3)
 658   |  b >1
 659   |.  sw TMP1, HI(CARG3)
 660   |
 661   |->vmeta_tgetb:                       // TMP0 = index
 662   |  mtc1 TMP0, f0
 663   |  cvt.d.w f0, f0
 664   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 665   |  sdc1 f0, 0(CARG3)
 666   |
 667   |->vmeta_tgetv:
 668   |1:
 669   |  load_got lj_meta_tget
 670   |  sw BASE, L->base
 671   |  sw PC, SAVE_PC
 672   |  call_intern lj_meta_tget           // (lua_State *L, TValue *o, TValue *k)
 673   |.  move CARG1, L
 674   |  // Returns TValue * (finished) or NULL (metamethod).
 675   |  beqz CRET1, >3
 676   |.  addiu TMP1, BASE, -FRAME_CONT
 677   |  ldc1 f0, 0(CRET1)
 678   |  ins_next1
 679   |   sdc1 f0, 0(RA)
 680   |  ins_next2
 681   |
 682   |3:  // Call __index metamethod.
 683   |  // BASE = base, L->top = new base, stack = cont/func/t/k
 684   |  lw BASE, L->top
 685   |  sw PC, -16+HI(BASE)                // [cont|PC]
 686   |   subu PC, BASE, TMP1
 687   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 688   |  b ->vm_call_dispatch_f
 689   |.  li NARGS8:RC, 16                  // 2 args for func(t, k).
 690   |
 691   |//-----------------------------------------------------------------------
 692   |
 693   |->vmeta_tsets1:
 694   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 695   |  li TMP0, LJ_TSTR
 696   |  sw STR:RC, LO(CARG3)
 697   |  b >1
 698   |.  sw TMP0, HI(CARG3)
 699   |
 700   |->vmeta_tsets:
 701   |  addiu CARG2, DISPATCH, DISPATCH_GL(tmptv)
 702   |  li TMP0, LJ_TTAB
 703   |  sw TAB:RB, LO(CARG2)
 704   |   addiu CARG3, DISPATCH, DISPATCH_GL(tmptv2)
 705   |  sw TMP0, HI(CARG2)
 706   |   li TMP1, LJ_TSTR
 707   |   sw STR:RC, LO(CARG3)
 708   |  b >1
 709   |.  sw TMP1, HI(CARG3)
 710   |
 711   |->vmeta_tsetb:                       // TMP0 = index
 712   |  mtc1 TMP0, f0
 713   |  cvt.d.w f0, f0
 714   |  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
 715   |  sdc1 f0, 0(CARG3)
 716   |
 717   |->vmeta_tsetv:
 718   |1:
 719   |  load_got lj_meta_tset
 720   |  sw BASE, L->base
 721   |  sw PC, SAVE_PC
 722   |  call_intern lj_meta_tset           // (lua_State *L, TValue *o, TValue *k)
 723   |.  move CARG1, L
 724   |  // Returns TValue * (finished) or NULL (metamethod).
 725   |  beqz CRET1, >3
 726   |.  ldc1 f0, 0(RA)
 727   |  // NOBARRIER: lj_meta_tset ensures the table is not black.
 728   |  ins_next1
 729   |   sdc1 f0, 0(CRET1)
 730   |  ins_next2
 731   |
 732   |3:  // Call __newindex metamethod.
 733   |  // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
 734   |  addiu TMP1, BASE, -FRAME_CONT
 735   |  lw BASE, L->top
 736   |  sw PC, -16+HI(BASE)                // [cont|PC]
 737   |   subu PC, BASE, TMP1
 738   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 739   |  sdc1 f0, 16(BASE)                  // Copy value to third argument.
 740   |  b ->vm_call_dispatch_f
 741   |.  li NARGS8:RC, 24                  // 3 args for func(t, k, v)
 742   |
 743   |//-- Comparison metamethods ---------------------------------------------
 744   |
 745   |->vmeta_comp:
 746   |  // CARG2, CARG3 are already set by BC_ISLT/BC_ISGE/BC_ISLE/BC_ISGT.
 747   |  load_got lj_meta_comp
 748   |  addiu PC, PC, -4
 749   |  sw BASE, L->base
 750   |  sw PC, SAVE_PC
 751   |  decode_OP1 CARG4, INS
 752   |  call_intern lj_meta_comp   // (lua_State *L, TValue *o1, *o2, int op)
 753   |.  move CARG1, L
 754   |  // Returns 0/1 or TValue * (metamethod).
 755   |3:
 756   |  sltiu AT, CRET1, 2
 757   |  beqz AT, ->vmeta_binop
 758   |   negu TMP2, CRET1
 759   |4:
 760   |  lhu RD, OFS_RD(PC)
 761   |   addiu PC, PC, 4
 762   |   lui TMP1, (-(BCBIAS_J*4 >> 16) & 65535)
 763   |  sll RD, RD, 2
 764   |  addu RD, RD, TMP1
 765   |  and RD, RD, TMP2
 766   |  addu PC, PC, RD
 767   |->cont_nop:
 768   |  ins_next
 769   |
 770   |->cont_ra:                           // RA = resultptr
 771   |  lbu TMP1, -4+OFS_RA(PC)
 772   |   ldc1 f0, 0(RA)
 773   |  sll TMP1, TMP1, 3
 774   |  addu TMP1, BASE, TMP1
 775   |  b ->cont_nop
 776   |.  sdc1 f0, 0(TMP1)
 777   |
 778   |->cont_condt:                        // RA = resultptr
 779   |  lw TMP0, HI(RA)
 780   |  sltiu AT, TMP0, LJ_TISTRUECOND
 781   |  b <4
 782   |.  negu TMP2, AT                     // Branch if result is true.
 783   |
 784   |->cont_condf:                        // RA = resultptr
 785   |  lw TMP0, HI(RA)
 786   |  sltiu AT, TMP0, LJ_TISTRUECOND
 787   |  b <4
 788   |.  addiu TMP2, AT, -1                // Branch if result is false.
 789   |
 790   |->vmeta_equal:
 791   |  // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
 792   |  load_got lj_meta_equal
 793   |  addiu PC, PC, -4
 794   |   sw BASE, L->base
 795   |   sw PC, SAVE_PC
 796   |  call_intern lj_meta_equal  // (lua_State *L, GCobj *o1, *o2, int ne)
 797   |.  move CARG1, L
 798   |  // Returns 0/1 or TValue * (metamethod).
 799   |  b <3
 800   |.  nop
 801   |
 802   |->vmeta_equal_cd:
 803   |.if FFI
 804   |  load_got lj_meta_equal_cd
 805   |  move CARG2, INS
 806   |  addiu PC, PC, -4
 807   |   sw BASE, L->base
 808   |   sw PC, SAVE_PC
 809   |  call_intern lj_meta_equal_cd       // (lua_State *L, BCIns op)
 810   |.  move CARG1, L
 811   |  // Returns 0/1 or TValue * (metamethod).
 812   |  b <3
 813   |.  nop
 814   |.endif
 815   |
 816   |//-- Arithmetic metamethods ---------------------------------------------
 817   |
 818   |->vmeta_unm:
 819   |  move CARG4, CARG3
 820   |
 821   |->vmeta_arith:
 822   |  load_got lj_meta_arith
 823   |  decode_OP1 TMP0, INS
 824   |   sw BASE, L->base
 825   |   sw PC, SAVE_PC
 826   |  move CARG2, RA
 827   |  sw TMP0, ARG5
 828   |  call_intern lj_meta_arith  // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
 829   |.  move CARG1, L
 830   |  // Returns NULL (finished) or TValue * (metamethod).
 831   |  beqz CRET1, ->cont_nop
 832   |.  nop
 833   |
 834   |  // Call metamethod for binary op.
 835   |->vmeta_binop:
 836   |  // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
 837   |  subu TMP1, CRET1, BASE
 838   |   sw PC, -16+HI(CRET1)              // [cont|PC]
 839   |   move TMP2, BASE
 840   |  addiu PC, TMP1, FRAME_CONT
 841   |   move BASE, CRET1
 842   |  b ->vm_call_dispatch
 843   |.  li NARGS8:RC, 16                  // 2 args for func(o1, o2).
 844   |
 845   |->vmeta_len:
 846   |  // CARG2 already set by BC_LEN.
 847 #if LJ_52
 848   |  move MULTRES, CARG1
 849 #endif
 850   |  load_got lj_meta_len
 851   |   sw BASE, L->base
 852   |   sw PC, SAVE_PC
 853   |  call_intern lj_meta_len            // (lua_State *L, TValue *o)
 854   |.  move CARG1, L
 855   |  // Returns NULL (retry) or TValue * (metamethod base).
 856 #if LJ_52
 857   |  bnez CRET1, ->vmeta_binop          // Binop call for compatibility.
 858   |.  nop
 859   |  b ->BC_LEN_Z
 860   |.  move CARG1, MULTRES
 861 #else
 862   |  b ->vmeta_binop                    // Binop call for compatibility.
 863   |.  nop
 864 #endif
 865   |
 866   |//-- Call metamethod ----------------------------------------------------
 867   |
 868   |->vmeta_call:                        // Resolve and call __call metamethod.
 869   |  // TMP2 = old base, BASE = new base, RC = nargs*8
 870   |  load_got lj_meta_call
 871   |   sw TMP2, L->base                  // This is the callers base!
 872   |  addiu CARG2, BASE, -8
 873   |   sw PC, SAVE_PC
 874   |  addu CARG3, BASE, RC
 875   |   move MULTRES, NARGS8:RC
 876   |  call_intern lj_meta_call   // (lua_State *L, TValue *func, TValue *top)
 877   |.  move CARG1, L
 878   |  lw LFUNC:RB, FRAME_FUNC(BASE)      // Guaranteed to be a function here.
 879   |   addiu NARGS8:RC, MULTRES, 8       // Got one more argument now.
 880   |  ins_call
 881   |
 882   |->vmeta_callt:                       // Resolve __call for BC_CALLT.
 883   |  // BASE = old base, RA = new base, RC = nargs*8
 884   |  load_got lj_meta_call
 885   |   sw BASE, L->base
 886   |  addiu CARG2, RA, -8
 887   |   sw PC, SAVE_PC
 888   |  addu CARG3, RA, RC
 889   |   move MULTRES, NARGS8:RC
 890   |  call_intern lj_meta_call   // (lua_State *L, TValue *func, TValue *top)
 891   |.  move CARG1, L
 892   |  lw TMP1, FRAME_PC(BASE)
 893   |   lw LFUNC:RB, FRAME_FUNC(RA)       // Guaranteed to be a function here.
 894   |  b ->BC_CALLT_Z
 895   |.  addiu NARGS8:RC, MULTRES, 8       // Got one more argument now.
 896   |
 897   |//-- Argument coercion for 'for' statement ------------------------------
 898   |
 899   |->vmeta_for:
 900   |  load_got lj_meta_for
 901   |   sw BASE, L->base
 902   |  move CARG2, RA
 903   |   sw PC, SAVE_PC
 904   |  move MULTRES, INS
 905   |  call_intern lj_meta_for    // (lua_State *L, TValue *base)
 906   |.  move CARG1, L
 907   |.if JIT
 908   |  decode_OP1 TMP0, MULTRES
 909   |  li AT, BC_JFORI
 910   |.endif
 911   |  decode_RA8a RA, MULTRES
 912   |   decode_RD8a RD, MULTRES
 913   |  decode_RA8b RA
 914   |.if JIT
 915   |  beq TMP0, AT, =>BC_JFORI
 916   |.  decode_RD8b RD
 917   |  b =>BC_FORI
 918   |.  nop
 919   |.else
 920   |  b =>BC_FORI
 921   |.  decode_RD8b RD
 922   |.endif
 923   |
 924   |//-----------------------------------------------------------------------
 925   |//-- Fast functions -----------------------------------------------------
 926   |//-----------------------------------------------------------------------
 927   |
 928   |.macro .ffunc, name
 929   |->ff_ .. name:
 930   |.endmacro
 931   |
 932   |.macro .ffunc_1, name
 933   |->ff_ .. name:
 934   |  beqz NARGS8:RC, ->fff_fallback
 935   |.  lw CARG3, HI(BASE)
 936   |    lw CARG1, LO(BASE)
 937   |.endmacro
 938   |
 939   |.macro .ffunc_2, name
 940   |->ff_ .. name:
 941   |  sltiu AT, NARGS8:RC, 16
 942   |   lw CARG3, HI(BASE)
 943   |  bnez AT, ->fff_fallback
 944   |.   lw CARG4, 8+HI(BASE)
 945   |   lw CARG1, LO(BASE)
 946   |    lw CARG2, 8+LO(BASE)
 947   |.endmacro
 948   |
 949   |.macro .ffunc_n, name        // Caveat: has delay slot!
 950   |->ff_ .. name:
 951   |  lw CARG3, HI(BASE)
 952   |  beqz NARGS8:RC, ->fff_fallback
 953   |.  ldc1 FARG1, 0(BASE)
 954   |  sltiu AT, CARG3, LJ_TISNUM
 955   |  beqz AT, ->fff_fallback
 956   |.endmacro
 957   |
 958   |.macro .ffunc_nn, name       // Caveat: has delay slot!
 959   |->ff_ .. name:
 960   |  sltiu AT, NARGS8:RC, 16
 961   |   lw CARG3, HI(BASE)
 962   |  bnez AT, ->fff_fallback
 963   |.  lw CARG4, 8+HI(BASE)
 964   |  ldc1 FARG1, 0(BASE)
 965   |  ldc1 FARG2, 8(BASE)
 966   |  sltiu TMP0, CARG3, LJ_TISNUM
 967   |  sltiu TMP1, CARG4, LJ_TISNUM
 968   |  and TMP0, TMP0, TMP1
 969   |  beqz TMP0, ->fff_fallback
 970   |.endmacro
 971   |
 972   |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1 and has delay slot!
 973   |.macro ffgccheck
 974   |  lw TMP0, DISPATCH_GL(gc.total)(DISPATCH)
 975   |  lw TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
 976   |  subu AT, TMP0, TMP1
 977   |  bgezal AT, ->fff_gcstep
 978   |.endmacro
 979   |
 980   |//-- Base library: checks -----------------------------------------------
 981   |
 982   |.ffunc_1 assert
 983   |  sltiu AT, CARG3, LJ_TISTRUECOND
 984   |  beqz AT, ->fff_fallback
 985   |.  addiu RA, BASE, -8
 986   |  lw PC, FRAME_PC(BASE)
 987   |  addiu RD, NARGS8:RC, 8             // Compute (nresults+1)*8.
 988   |  addu TMP2, RA, NARGS8:RC
 989   |   sw CARG3, HI(RA)
 990   |  addiu TMP1, BASE, 8
 991   |  beq BASE, TMP2, ->fff_res          // Done if exactly 1 argument.
 992   |.  sw CARG1, LO(RA)
 993   |1:
 994   |  ldc1 f0, 0(TMP1)
 995   |  sdc1 f0, -8(TMP1)
 996   |  bne TMP1, TMP2, <1
 997   |.  addiu TMP1, TMP1, 8
 998   |  b ->fff_res
 999   |.  nop
1000   |
1001   |.ffunc type
1002   |  lw CARG3, HI(BASE)
1003   |  li TMP1, LJ_TISNUM
1004   |  beqz NARGS8:RC, ->fff_fallback
1005   |.  sltiu TMP0, CARG3, LJ_TISNUM
1006   |  movz TMP1, CARG3, TMP0
1007   |  not TMP1, TMP1
1008   |  sll TMP1, TMP1, 3
1009   |  addu TMP1, CFUNC:RB, TMP1
1010   |  b ->fff_resn
1011   |.  ldc1 FRET1, CFUNC:TMP1->upvalue
1012   |
1013   |//-- Base library: getters and setters ---------------------------------
1014   |
1015   |.ffunc_1 getmetatable
1016   |  li AT, LJ_TTAB
1017   |  bne CARG3, AT, >6
1018   |.  li AT, LJ_TUDATA
1019   |1:  // Field metatable must be at same offset for GCtab and GCudata!
1020   |  lw TAB:CARG1, TAB:CARG1->metatable
1021   |2:
1022   |  lw STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
1023   |  beqz TAB:CARG1, ->fff_restv
1024   |.  li CARG3, LJ_TNIL
1025   |  lw TMP0, TAB:CARG1->hmask
1026   |   li CARG3, LJ_TTAB                 // Use metatable as default result.
1027   |  lw TMP1, STR:RC->hash
1028   |  lw NODE:TMP2, TAB:CARG1->node
1029   |  and TMP1, TMP1, TMP0               // idx = str->hash & tab->hmask
1030   |  sll TMP0, TMP1, 5
1031   |  sll TMP1, TMP1, 3
1032   |  subu TMP1, TMP0, TMP1
1033   |  addu NODE:TMP2, NODE:TMP2, TMP1    // node = tab->node + (idx*32-idx*8)
1034   |  li AT, LJ_TSTR
1035   |3:  // Rearranged logic, because we expect _not_ to find the key.
1036   |  lw CARG4, offsetof(Node, key)+HI(NODE:TMP2)
1037   |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
1038   |    lw NODE:TMP3, NODE:TMP2->next
1039   |  bne CARG4, AT, >4
1040   |.    lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
1041   |  beq TMP0, STR:RC, >5
1042   |.    lw TMP1, offsetof(Node, val)+LO(NODE:TMP2)
1043   |4:
1044   |  beqz NODE:TMP3, ->fff_restv        // Not found, keep default result.
1045   |.  move NODE:TMP2, NODE:TMP3
1046   |  b <3
1047   |.  nop
1048   |5:
1049   |  beq CARG2, TISNIL, ->fff_restv     // Ditto for nil value.
1050   |.  nop
1051   |  move CARG3, CARG2                  // Return value of mt.__metatable.
1052   |  b ->fff_restv
1053   |.  move CARG1, TMP1
1054   |
1055   |6:
1056   |  beq CARG3, AT, <1
1057   |.  sltiu TMP0, CARG3, LJ_TISNUM
1058   |  li TMP1, LJ_TISNUM
1059   |  movz TMP1, CARG3, TMP0
1060   |  not TMP1, TMP1
1061   |  sll TMP1, TMP1, 2
1062   |  addu TMP1, DISPATCH, TMP1
1063   |  b <2
1064   |.  lw TAB:CARG1, DISPATCH_GL(gcroot[GCROOT_BASEMT])(TMP1)
1065   |
1066   |.ffunc_2 setmetatable
1067   |  // Fast path: no mt for table yet and not clearing the mt.
1068   |  li AT, LJ_TTAB
1069   |  bne CARG3, AT, ->fff_fallback
1070   |.  addiu CARG4, CARG4, -LJ_TTAB
1071   |  lw TAB:TMP1, TAB:CARG1->metatable
1072   |   lbu TMP3, TAB:CARG1->marked
1073   |  or AT, CARG4, TAB:TMP1
1074   |  bnez AT, ->fff_fallback
1075   |.  andi AT, TMP3, LJ_GC_BLACK        // isblack(table)
1076   |  beqz AT, ->fff_restv
1077   |.  sw TAB:CARG2, TAB:CARG1->metatable
1078   |  barrierback TAB:CARG1, TMP3, TMP0, ->fff_restv
1079   |
1080   |.ffunc rawget
1081   |  lw CARG4, HI(BASE)
1082   |   sltiu AT, NARGS8:RC, 16
1083   |    lw TAB:CARG2, LO(BASE)
1084   |  load_got lj_tab_get
1085   |  addiu CARG4, CARG4, -LJ_TTAB
1086   |  or AT, AT, CARG4
1087   |  bnez AT, ->fff_fallback
1088   |   addiu CARG3, BASE, 8
1089   |  call_intern lj_tab_get     // (lua_State *L, GCtab *t, cTValue *key)
1090   |.  move CARG1, L
1091   |  // Returns cTValue *.
1092   |  b ->fff_resn
1093   |.  ldc1 FRET1, 0(CRET1)
1094   |
1095   |//-- Base library: conversions ------------------------------------------
1096   |
1097   |.ffunc tonumber
1098   |  // Only handles the number case inline (without a base argument).
1099   |  lw CARG1, HI(BASE)
1100   |  xori AT, NARGS8:RC, 8
1101   |  sltiu CARG1, CARG1, LJ_TISNUM
1102   |  movn CARG1, r0, AT
1103   |  beqz CARG1, ->fff_fallback         // Exactly one number argument.
1104   |.  ldc1 FRET1, 0(BASE)
1105   |  b ->fff_resn
1106   |.  nop
1107   |
1108   |.ffunc_1 tostring
1109   |  // Only handles the string or number case inline.
1110   |  li AT, LJ_TSTR
1111   |  // A __tostring method in the string base metatable is ignored.
1112   |  beq CARG3, AT, ->fff_restv                 // String key?
1113   |  // Handle numbers inline, unless a number base metatable is present.
1114   |.  lw TMP1, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1115   |  sltiu TMP0, CARG3, LJ_TISNUM
1116   |  sltiu TMP1, TMP1, 1
1117   |  and TMP0, TMP0, TMP1
1118   |  beqz TMP0, ->fff_fallback
1119   |.  sw BASE, L->base                  // Add frame since C call can throw.
1120   |  ffgccheck
1121   |.  sw PC, SAVE_PC                    // Redundant (but a defined value).
1122   |  load_got lj_str_fromnum
1123   |  move CARG1, L
1124   |  call_intern lj_str_fromnum         // (lua_State *L, lua_Number *np)
1125   |.  move CARG2, BASE
1126   |  // Returns GCstr *.
1127   |  li CARG3, LJ_TSTR
1128   |  b ->fff_restv
1129   |.  move CARG1, CRET1
1130   |
1131   |//-- Base library: iterators -------------------------------------------
1132   |
1133   |.ffunc next
1134   |  lw CARG1, HI(BASE)
1135   |   lw TAB:CARG2, LO(BASE)
1136   |  beqz NARGS8:RC, ->fff_fallback
1137   |.  addu TMP2, BASE, NARGS8:RC
1138   |  li AT, LJ_TTAB
1139   |   sw TISNIL, HI(TMP2)               // Set missing 2nd arg to nil.
1140   |  bne CARG1, AT, ->fff_fallback
1141   |.  lw PC, FRAME_PC(BASE)
1142   |  load_got lj_tab_next
1143   |   sw BASE, L->base                  // Add frame since C call can throw.
1144   |   sw BASE, L->top                   // Dummy frame length is ok.
1145   |  addiu CARG3, BASE, 8
1146   |   sw PC, SAVE_PC
1147   |  call_intern lj_tab_next            // (lua_State *L, GCtab *t, TValue *key)
1148   |.  move CARG1, L
1149   |  // Returns 0 at end of traversal.
1150   |  beqz CRET1, ->fff_restv            // End of traversal: return nil.
1151   |.  li CARG3, LJ_TNIL
1152   |  ldc1 f0, 8(BASE)                   // Copy key and value to results.
1153   |    addiu RA, BASE, -8
1154   |   ldc1 f2, 16(BASE)
1155   |    li RD, (2+1)*8
1156   |  sdc1 f0, 0(RA)
1157   |  b ->fff_res
1158   |.  sdc1 f2, 8(RA)
1159   |
1160   |.ffunc_1 pairs
1161   |  li AT, LJ_TTAB
1162   |  bne CARG3, AT, ->fff_fallback
1163   |.  lw PC, FRAME_PC(BASE)
1164 #if LJ_52
1165   |  lw TAB:TMP2, TAB:CARG1->metatable
1166   |   ldc1 f0, CFUNC:RB->upvalue[0]
1167   |  bnez TAB:TMP2, ->fff_fallback
1168 #else
1169   |  ldc1 f0, CFUNC:RB->upvalue[0]
1170 #endif
1171   |.  addiu RA, BASE, -8
1172   |   sw TISNIL, 8+HI(BASE)
1173   |  li RD, (3+1)*8
1174   |  b ->fff_res
1175   |.  sdc1 f0, 0(RA)
1176   |
1177   |.ffunc ipairs_aux
1178   |  sltiu AT, NARGS8:RC, 16
1179   |   lw CARG3, HI(BASE)
1180   |    lw TAB:CARG1, LO(BASE)
1181   |   lw CARG4, 8+HI(BASE)
1182   |  bnez AT, ->fff_fallback
1183   |.  ldc1 FARG2, 8(BASE)
1184   |   addiu CARG3, CARG3, -LJ_TTAB
1185   |  sltiu AT, CARG4, LJ_TISNUM
1186   |   li TMP0, 1
1187   |  movn AT, r0, CARG3
1188   |   mtc1 TMP0, FARG1
1189   |  beqz AT, ->fff_fallback
1190   |.  lw PC, FRAME_PC(BASE)
1191   |   cvt.w.d FRET1, FARG2
1192   |  cvt.d.w FARG1, FARG1
1193   |   lw TMP0, TAB:CARG1->asize
1194   |   lw TMP1, TAB:CARG1->array
1195   |  mfc1 TMP2, FRET1
1196   |   addiu RA, BASE, -8
1197   |  add.d FARG2, FARG2, FARG1
1198   |  addiu TMP2, TMP2, 1
1199   |  sltu AT, TMP2, TMP0
1200   |   sll TMP3, TMP2, 3
1201   |   addu TMP3, TMP1, TMP3
1202   |  beqz AT, >2                        // Not in array part?
1203   |.  sdc1 FARG2, 0(RA)
1204   |  lw TMP2, HI(TMP3)
1205   |  ldc1 f0, 0(TMP3)
1206   |1:
1207   |  beq TMP2, TISNIL, ->fff_res        // End of iteration, return 0 results.
1208   |.  li RD, (0+1)*8
1209   |   li RD, (2+1)*8
1210   |  b ->fff_res
1211   |.  sdc1 f0, 8(RA)
1212   |2:  // Check for empty hash part first. Otherwise call C function.
1213   |  lw TMP0, TAB:CARG1->hmask
1214   |  load_got lj_tab_getinth
1215   |  beqz TMP0, ->fff_res
1216   |.  li RD, (0+1)*8
1217   |  call_intern lj_tab_getinth         // (GCtab *t, int32_t key)
1218   |.  move CARG2, TMP2
1219   |  // Returns cTValue * or NULL.
1220   |  beqz CRET1, ->fff_res
1221   |.  li RD, (0+1)*8
1222   |  lw TMP2, HI(CRET1)
1223   |  b <1
1224   |.  ldc1 f0, 0(CRET1)
1225   |
1226   |.ffunc_1 ipairs
1227   |  li AT, LJ_TTAB
1228   |  bne CARG3, AT, ->fff_fallback
1229   |.  lw PC, FRAME_PC(BASE)
1230 #if LJ_52
1231   |  lw TAB:TMP2, TAB:CARG1->metatable
1232   |   ldc1 f0, CFUNC:RB->upvalue[0]
1233   |  bnez TAB:TMP2, ->fff_fallback
1234 #else
1235   |  ldc1 f0, CFUNC:RB->upvalue[0]
1236 #endif
1237   |.  addiu RA, BASE, -8
1238   |   sw r0, 8+HI(BASE)
1239   |   sw r0, 8+LO(BASE)
1240   |  li RD, (3+1)*8
1241   |  b ->fff_res
1242   |.  sdc1 f0, 0(RA)
1243   |
1244   |//-- Base library: catch errors ----------------------------------------
1245   |
1246   |.ffunc pcall
1247   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1248   |  beqz NARGS8:RC, ->fff_fallback
1249   |   move TMP2, BASE
1250   |   addiu BASE, BASE, 8
1251   |  // Remember active hook before pcall.
1252   |  srl TMP3, TMP3, HOOK_ACTIVE_SHIFT
1253   |  andi TMP3, TMP3, 1
1254   |  addiu PC, TMP3, 8+FRAME_PCALL
1255   |  b ->vm_call_dispatch
1256   |.  addiu NARGS8:RC, NARGS8:RC, -8
1257   |
1258   |.ffunc xpcall
1259   |    sltiu AT, NARGS8:RC, 16
1260   |  lw CARG4, 8+HI(BASE)
1261   |    bnez AT, ->fff_fallback
1262   |.  ldc1 FARG2, 8(BASE)
1263   |   ldc1 FARG1, 0(BASE)
1264   |    lbu TMP1, DISPATCH_GL(hookmask)(DISPATCH)
1265   |  li AT, LJ_TFUNC
1266   |   move TMP2, BASE
1267   |  bne CARG4, AT, ->fff_fallback  // Traceback must be a function.
1268   |   addiu BASE, BASE, 16
1269   |  // Remember active hook before pcall.
1270   |  srl TMP3, TMP3, HOOK_ACTIVE_SHIFT
1271   |   sdc1 FARG2, 0(TMP2)               // Swap function and traceback.
1272   |  andi TMP3, TMP3, 1
1273   |   sdc1 FARG1, 8(TMP2)
1274   |  addiu PC, TMP3, 16+FRAME_PCALL
1275   |  b ->vm_call_dispatch
1276   |.  addiu NARGS8:RC, NARGS8:RC, -16
1277   |
1278   |//-- Coroutine library --------------------------------------------------
1279   |
1280   |.macro coroutine_resume_wrap, resume
1281   |.if resume
1282   |.ffunc_1 coroutine_resume
1283   |  li AT, LJ_TTHREAD
1284   |  bne CARG3, AT, ->fff_fallback
1285   |.else
1286   |.ffunc coroutine_wrap_aux
1287   |  lw L:CARG1, CFUNC:RB->upvalue[0].gcr
1288   |.endif
1289   |  lbu TMP0, L:CARG1->status
1290   |   lw TMP1, L:CARG1->cframe
1291   |    lw CARG2, L:CARG1->top
1292   |    lw TMP2, L:CARG1->base
1293   |  addiu TMP3, TMP0, -LUA_YIELD
1294   |  bgtz TMP3, ->fff_fallback          // st > LUA_YIELD?
1295   |.   xor TMP2, TMP2, CARG2
1296   |  bnez TMP1, ->fff_fallback          // cframe != 0?
1297   |.  or AT, TMP2, TMP0
1298   |  lw TMP0, L:CARG1->maxstack
1299   |  beqz AT, ->fff_fallback            // base == top && st == 0?
1300   |.  lw PC, FRAME_PC(BASE)
1301   |  addu TMP2, CARG2, NARGS8:RC
1302   |  sltu AT, TMP0, TMP2
1303   |  bnez AT, ->fff_fallback            // Stack overflow?
1304   |.  sw PC, SAVE_PC
1305   |   sw BASE, L->base
1306   |1:
1307   |.if resume
1308   |  addiu BASE, BASE, 8                // Keep resumed thread in stack for GC.
1309   |  addiu NARGS8:RC, NARGS8:RC, -8
1310   |  addiu TMP2, TMP2, -8
1311   |.endif
1312   |  sw TMP2, L:CARG1->top
1313   |  addu TMP1, BASE, NARGS8:RC
1314   |  move CARG3, CARG2
1315   |  sw BASE, L->top
1316   |2:  // Move args to coroutine.
1317   |   ldc1 f0, 0(BASE)
1318   |  sltu AT, BASE, TMP1
1319   |  beqz AT, >3
1320   |.  addiu BASE, BASE, 8
1321   |   sdc1 f0, 0(CARG3)
1322   |  b <2
1323   |.  addiu CARG3, CARG3, 8
1324   |3:
1325   |  bal ->vm_resume                    // (lua_State *L, TValue *base, 0, 0)
1326   |.  move L:RA, L:CARG1
1327   |  // Returns thread status.
1328   |4:
1329   |  lw TMP2, L:RA->base
1330   |   sltiu AT, CRET1, LUA_YIELD+1
1331   |  lw TMP3, L:RA->top
1332   |    li_vmstate INTERP
1333   |  lw BASE, L->base
1334   |    st_vmstate
1335   |   beqz AT, >8
1336   |. subu RD, TMP3, TMP2
1337   |   lw TMP0, L->maxstack
1338   |  beqz RD, >6                        // No results?
1339   |.  addu TMP1, BASE, RD
1340   |  sltu AT, TMP0, TMP1
1341   |  bnez AT, >9                        // Need to grow stack?
1342   |.  addu TMP3, TMP2, RD
1343   |  sw TMP2, L:RA->top                 // Clear coroutine stack.
1344   |  move TMP1, BASE
1345   |5:  // Move results from coroutine.
1346   |   ldc1 f0, 0(TMP2)
1347   |  addiu TMP2, TMP2, 8
1348   |  sltu AT, TMP2, TMP3
1349   |   sdc1 f0, 0(TMP1)
1350   |  bnez AT, <5
1351   |.  addiu TMP1, TMP1, 8
1352   |6:
1353   |  andi TMP0, PC, FRAME_TYPE
1354   |.if resume
1355   |  li TMP1, LJ_TTRUE
1356   |   addiu RA, BASE, -8
1357   |  sw TMP1, -8+HI(BASE)               // Prepend true to results.
1358   |  addiu RD, RD, 16
1359   |.else
1360   |  move RA, BASE
1361   |  addiu RD, RD, 8
1362   |.endif
1363   |7:
1364   |  sw PC, SAVE_PC
1365   |  beqz TMP0, ->BC_RET_Z
1366   |.  move MULTRES, RD
1367   |  b ->vm_return
1368   |.  nop
1369   |
1370   |8:  // Coroutine returned with error (at co->top-1).
1371   |.if resume
1372   |  addiu TMP3, TMP3, -8
1373   |   li TMP1, LJ_TFALSE
1374   |  ldc1 f0, 0(TMP3)
1375   |   sw TMP3, L:RA->top                // Remove error from coroutine stack.
1376   |    li RD, (2+1)*8
1377   |   sw TMP1, -8+HI(BASE)              // Prepend false to results.
1378   |    addiu RA, BASE, -8
1379   |  sdc1 f0, 0(BASE)                   // Copy error message.
1380   |  b <7
1381   |.  andi TMP0, PC, FRAME_TYPE
1382   |.else
1383   |  load_got lj_ffh_coroutine_wrap_err
1384   |  move CARG2, L:RA
1385   |  call_intern lj_ffh_coroutine_wrap_err  // (lua_State *L, lua_State *co)
1386   |.  move CARG1, L
1387   |.endif
1388   |
1389   |9:  // Handle stack expansion on return from yield.
1390   |  load_got lj_state_growstack
1391   |  srl CARG2, RD, 3
1392   |  call_intern lj_state_growstack     // (lua_State *L, int n)
1393   |.  move CARG1, L
1394   |  b <4
1395   |.  li CRET1, 0
1396   |.endmacro
1397   |
1398   |  coroutine_resume_wrap 1            // coroutine.resume
1399   |  coroutine_resume_wrap 0            // coroutine.wrap
1400   |
1401   |.ffunc coroutine_yield
1402   |  lw TMP0, L->cframe
1403   |   addu TMP1, BASE, NARGS8:RC
1404   |   sw BASE, L->base
1405   |  andi TMP0, TMP0, CFRAME_RESUME
1406   |   sw TMP1, L->top
1407   |  beqz TMP0, ->fff_fallback
1408   |.   li CRET1, LUA_YIELD
1409   |  sw r0, L->cframe
1410   |  b ->vm_leave_unw
1411   |.   sb CRET1, L->status
1412   |
1413   |//-- Math library -------------------------------------------------------
1414   |
1415   |.ffunc_n math_abs
1416   |.  abs.d FRET1, FARG1
1417   |->fff_resn:
1418   |  lw PC, FRAME_PC(BASE)
1419   |  addiu RA, BASE, -8
1420   |  b ->fff_res1
1421   |.  sdc1 FRET1, -8(BASE)
1422   |
1423   |->fff_restv:
1424   |  // CARG3/CARG1 = TValue result.
1425   |  lw PC, FRAME_PC(BASE)
1426   |   sw CARG3, -8+HI(BASE)
1427   |  addiu RA, BASE, -8
1428   |   sw CARG1, -8+LO(BASE)
1429   |->fff_res1:
1430   |  // RA = results, PC = return.
1431   |  li RD, (1+1)*8
1432   |->fff_res:
1433   |  // RA = results, RD = (nresults+1)*8, PC = return.
1434   |  andi TMP0, PC, FRAME_TYPE
1435   |  bnez TMP0, ->vm_return
1436   |.  move MULTRES, RD
1437   |  lw INS, -4(PC)
1438   |  decode_RB8a RB, INS
1439   |  decode_RB8b RB
1440   |5:
1441   |  sltu AT, RD, RB
1442   |  bnez AT, >6                        // More results expected?
1443   |.  decode_RA8a TMP0, INS
1444   |  decode_RA8b TMP0
1445   |  ins_next1
1446   |  // Adjust BASE. KBASE is assumed to be set for the calling frame.
1447   |   subu BASE, RA, TMP0
1448   |  ins_next2
1449   |
1450   |6:  // Fill up results with nil.
1451   |  addu TMP1, RA, RD
1452   |   addiu RD, RD, 8
1453   |  b <5
1454   |.  sw TISNIL, -8+HI(TMP1)
1455   |
1456   |.macro math_extern, func
1457   |->ff_math_ .. func:
1458   |  lw CARG3, HI(BASE)
1459   |  beqz NARGS8:RC, ->fff_fallback
1460   |.  load_got func
1461   |  sltiu AT, CARG3, LJ_TISNUM
1462   |  beqz AT, ->fff_fallback
1463   |.  nop
1464   |  call_extern
1465   |.  ldc1 FARG1, 0(BASE)
1466   |  b ->fff_resn
1467   |.  nop
1468   |.endmacro
1469   |
1470   |.macro math_extern2, func
1471   |  .ffunc_nn math_ .. func
1472   |.  load_got func
1473   |  call_extern
1474   |.  nop
1475   |  b ->fff_resn
1476   |.  nop
1477   |.endmacro
1478   |
1479   |.macro math_round, func
1480   |  .ffunc_n math_ .. func
1481   |.  nop
1482   |  bal ->vm_ .. func
1483   |.  nop
1484   |  b ->fff_resn
1485   |.  nop
1486   |.endmacro
1487   |
1488   |  math_round floor
1489   |  math_round ceil
1490   |
1491   |.ffunc math_log
1492   |  lw CARG3, HI(BASE)
1493   |  li AT, 8
1494   |  bne NARGS8:RC, AT, ->fff_fallback  // Exactly 1 argument.
1495   |.  load_got log
1496   |  sltiu AT, CARG3, LJ_TISNUM
1497   |  beqz AT, ->fff_fallback
1498   |.  nop
1499   |  call_extern
1500   |.  ldc1 FARG1, 0(BASE)
1501   |  b ->fff_resn
1502   |.  nop
1503   |
1504   |  math_extern log10
1505   |  math_extern exp
1506   |  math_extern sin
1507   |  math_extern cos
1508   |  math_extern tan
1509   |  math_extern asin
1510   |  math_extern acos
1511   |  math_extern atan
1512   |  math_extern sinh
1513   |  math_extern cosh
1514   |  math_extern tanh
1515   |  math_extern2 pow
1516   |  math_extern2 atan2
1517   |  math_extern2 fmod
1518   |
1519   |.ffunc_n math_sqrt
1520   |.  sqrt.d FRET1, FARG1
1521   |  b ->fff_resn
1522   |.  nop
1523   |
1524   |->ff_math_deg:
1525   |.ffunc_n math_rad
1526   |.  ldc1 FARG2, CFUNC:RB->upvalue[0]
1527   |  b ->fff_resn
1528   |.  mul.d FRET1, FARG1, FARG2
1529   |
1530   |.ffunc_nn math_ldexp
1531   |  cvt.w.d FARG2, FARG2
1532   |  load_got ldexp
1533   |  mfc1 CARG3, FARG2
1534   |  call_extern
1535   |.  nop
1536   |  b ->fff_resn
1537   |.  nop
1538   |
1539   |.ffunc_n math_frexp
1540   |  load_got frexp
1541   |   lw PC, FRAME_PC(BASE)
1542   |  call_extern
1543   |.  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
1544   |   lw TMP1, DISPATCH_GL(tmptv)(DISPATCH)
1545   |  addiu RA, BASE, -8
1546   |   mtc1 TMP1, FARG2
1547   |  sdc1 FRET1, 0(RA)
1548   |   cvt.d.w FARG2, FARG2
1549   |   sdc1 FARG2, 8(RA)
1550   |  b ->fff_res
1551   |.  li RD, (2+1)*8
1552   |
1553   |.ffunc_n math_modf
1554   |  load_got modf
1555   |   lw PC, FRAME_PC(BASE)
1556   |  call_extern
1557   |.  addiu CARG3, BASE, -8
1558   |  addiu RA, BASE, -8
1559   |  sdc1 FRET1, 0(BASE)
1560   |  b ->fff_res
1561   |.  li RD, (2+1)*8
1562   |
1563   |.macro math_minmax, name, ismax
1564   |->ff_ .. name:
1565   |  lw CARG3, HI(BASE)
1566   |  beqz NARGS8:RC, ->fff_fallback
1567   |.  ldc1 FRET1, 0(BASE)
1568   |  sltiu AT, CARG3, LJ_TISNUM
1569   |  beqz AT, ->fff_fallback
1570   |.  addu TMP2, BASE, NARGS8:RC
1571   |  addiu TMP1, BASE, 8
1572   |  beq TMP1, TMP2, ->fff_resn
1573   |1:
1574   |.  lw CARG3, HI(TMP1)
1575   |  ldc1 FARG1, 0(TMP1)
1576   |   addiu TMP1, TMP1, 8
1577   |  sltiu AT, CARG3, LJ_TISNUM
1578   |  beqz AT, ->fff_fallback
1579   |.if ismax
1580   |.  c.olt.d FARG1, FRET1
1581   |.else
1582   |.  c.olt.d FRET1, FARG1
1583   |.endif
1584   |  bne TMP1, TMP2, <1
1585   |.  movf.d FRET1, FARG1
1586   |  b ->fff_resn
1587   |.  nop
1588   |.endmacro
1589   |
1590   |  math_minmax math_min, 0
1591   |  math_minmax math_max, 1
1592   |
1593   |//-- String library -----------------------------------------------------
1594   |
1595   |.ffunc_1 string_len
1596   |  li AT, LJ_TSTR
1597   |  bne CARG3, AT, ->fff_fallback
1598   |.  nop
1599   |  b ->fff_resi
1600   |.  lw CRET1, STR:CARG1->len
1601   |
1602   |.ffunc string_byte                   // Only handle the 1-arg case here.
1603   |  lw CARG3, HI(BASE)
1604   |   lw STR:CARG1, LO(BASE)
1605   |  xori AT, NARGS8:RC, 8
1606   |  addiu CARG3, CARG3, -LJ_TSTR
1607   |  or AT, AT, CARG3
1608   |  bnez AT, ->fff_fallback            // Need exactly 1 string argument.
1609   |.  nop
1610   |  lw TMP0, STR:CARG1->len
1611   |   lbu TMP1, STR:CARG1[1]            // Access is always ok (NUL at end).
1612   |    addiu RA, BASE, -8
1613   |  sltu RD, r0, TMP0
1614   |   mtc1 TMP1, f0
1615   |  addiu RD, RD, 1
1616   |   cvt.d.w f0, f0
1617   |  lw PC, FRAME_PC(BASE)
1618   |  sll RD, RD, 3                      // RD = ((str->len != 0)+1)*8
1619   |  b ->fff_res
1620   |.  sdc1 f0, 0(RA)
1621   |
1622   |.ffunc string_char                   // Only handle the 1-arg case here.
1623   |  ffgccheck
1624   |.  nop
1625   |  lw CARG3, HI(BASE)
1626   |   ldc1 FARG1, 0(BASE)
1627   |  li AT, 8
1628   |  bne NARGS8:RC, AT, ->fff_fallback  // Exactly 1 argument.
1629   |.  sltiu AT, CARG3, LJ_TISNUM
1630   |  beqz AT, ->fff_fallback
1631   |.  li CARG3, 1
1632   |   cvt.w.d FARG1, FARG1
1633   |  addiu CARG2, sp, ARG5_OFS
1634   |  sltiu AT, TMP0, 256
1635   |   mfc1 TMP0, FARG1
1636   |  beqz AT, ->fff_fallback
1637   |.  sw TMP0, ARG5
1638   |->fff_newstr:
1639   |  load_got lj_str_new
1640   |   sw BASE, L->base
1641   |   sw PC, SAVE_PC
1642   |  call_intern lj_str_new             // (lua_State *L, char *str, size_t l)
1643   |.  move CARG1, L
1644   |  // Returns GCstr *.
1645   |  lw BASE, L->base
1646   |  move CARG1, CRET1
1647   |  b ->fff_restv
1648   |.  li CARG3, LJ_TSTR
1649   |
1650   |.ffunc string_sub
1651   |  ffgccheck
1652   |.  nop
1653   |  addiu AT, NARGS8:RC, -16
1654   |   lw CARG3, 16+HI(BASE)
1655   |    ldc1 f0, 16(BASE)
1656   |   lw TMP0, HI(BASE)
1657   |    lw STR:CARG1, LO(BASE)
1658   |  bltz AT, ->fff_fallback
1659   |   lw CARG2, 8+HI(BASE)
1660   |    ldc1 f2, 8(BASE)
1661   |  beqz AT, >1
1662   |.  li CARG4, -1
1663   |   cvt.w.d f0, f0
1664   |  sltiu AT, CARG3, LJ_TISNUM
1665   |  beqz AT, ->fff_fallback
1666   |.  mfc1 CARG4, f0
1667   |1:
1668   |  sltiu AT, CARG2, LJ_TISNUM
1669   |  beqz AT, ->fff_fallback
1670   |.  li AT, LJ_TSTR
1671   |  cvt.w.d f2, f2
1672   |  bne TMP0, AT, ->fff_fallback
1673   |.  lw CARG2, STR:CARG1->len
1674   |  mfc1 CARG3, f2
1675   |  // STR:CARG1 = str, CARG2 = str->len, CARG3 = start, CARG4 = end
1676   |  slt AT, CARG4, r0
1677   |  addiu TMP0, CARG2, 1
1678   |  addu TMP1, CARG4, TMP0
1679   |   slt TMP3, CARG3, r0
1680   |  movn CARG4, TMP1, AT               // if (end < 0) end += len+1
1681   |   addu TMP1, CARG3, TMP0
1682   |   movn CARG3, TMP1, TMP3            // if (start < 0) start += len+1
1683   |   li TMP2, 1
1684   |  slt AT, CARG4, r0
1685   |   slt TMP3, r0, CARG3
1686   |  movn CARG4, r0, AT                 // if (end < 0) end = 0
1687   |   movz CARG3, TMP2, TMP3            // if (start < 1) start = 1
1688   |  slt AT, CARG2, CARG4
1689   |  movn CARG4, CARG2, AT              // if (end > len) end = len
1690   |   addu CARG2, STR:CARG1, CARG3
1691   |  subu CARG3, CARG4, CARG3           // len = end - start
1692   |   addiu CARG2, CARG2, sizeof(GCstr)-1
1693   |  bgez CARG3, ->fff_newstr
1694   |.  addiu CARG3, CARG3, 1             // len++
1695   |->fff_emptystr:  // Return empty string.
1696   |  addiu STR:CARG1, DISPATCH, DISPATCH_GL(strempty)
1697   |  b ->fff_restv
1698   |.  li CARG3, LJ_TSTR
1699   |
1700   |.ffunc string_rep                    // Only handle the 1-char case inline.
1701   |  ffgccheck
1702   |.  nop
1703   |  lw TMP0, HI(BASE)
1704   |   addiu AT, NARGS8:RC, -16          // Exactly 2 arguments.
1705   |  lw CARG4, 8+HI(BASE)
1706   |   lw STR:CARG1, LO(BASE)
1707   |  addiu TMP0, TMP0, -LJ_TSTR
1708   |   ldc1 f0, 8(BASE)
1709   |  or AT, AT, TMP0
1710   |  bnez AT, ->fff_fallback
1711   |.  sltiu AT, CARG4, LJ_TISNUM
1712   |   cvt.w.d f0, f0
1713   |  beqz AT, ->fff_fallback
1714   |.  lw TMP0, STR:CARG1->len
1715   |   mfc1 CARG3, f0
1716   |  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1717   |  li AT, 1
1718   |   blez CARG3, ->fff_emptystr        // Count <= 0?
1719   |.   sltu AT, AT, TMP0
1720   |  beqz TMP0, ->fff_emptystr          // Zero length string?
1721   |.  sltu TMP0, TMP1, CARG3
1722   |  or AT, AT, TMP0
1723   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1724   |  bnez AT, ->fff_fallback            // Fallback for > 1-char strings.
1725   |.  lbu TMP0, STR:CARG1[1]
1726   |  addu TMP2, CARG2, CARG3
1727   |1:  // Fill buffer with char. Yes, this is suboptimal code (do you care?).
1728   |  addiu TMP2, TMP2, -1
1729   |  sltu AT, CARG2, TMP2
1730   |  bnez AT, <1
1731   |.  sb TMP0, 0(TMP2)
1732   |  b ->fff_newstr
1733   |.  nop
1734   |
1735   |.ffunc string_reverse
1736   |  ffgccheck
1737   |.  nop
1738   |  lw CARG3, HI(BASE)
1739   |   lw STR:CARG1, LO(BASE)
1740   |  beqz NARGS8:RC, ->fff_fallback
1741   |.  li AT, LJ_TSTR
1742   |  bne CARG3, AT, ->fff_fallback
1743   |.  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1744   |  lw CARG3, STR:CARG1->len
1745   |   addiu CARG1, STR:CARG1, #STR
1746   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1747   |  sltu AT, TMP1, CARG3
1748   |  bnez AT, ->fff_fallback
1749   |.  addu TMP3, CARG1, CARG3
1750   |  addu CARG4, CARG2, CARG3
1751   |1:  // Reverse string copy.
1752   |   lbu TMP1, 0(CARG1)
1753   |  sltu AT, CARG1, TMP3
1754   |  beqz AT, ->fff_newstr
1755   |.  addiu CARG1, CARG1, 1
1756   |  addiu CARG4, CARG4, -1
1757   |  b <1
1758   |   sb TMP1, 0(CARG4)
1759   |
1760   |.macro ffstring_case, name, lo
1761   |  .ffunc name
1762   |  ffgccheck
1763   |.  nop
1764   |  lw CARG3, HI(BASE)
1765   |   lw STR:CARG1, LO(BASE)
1766   |  beqz NARGS8:RC, ->fff_fallback
1767   |.  li AT, LJ_TSTR
1768   |  bne CARG3, AT, ->fff_fallback
1769   |.  lw TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1770   |  lw CARG3, STR:CARG1->len
1771   |   addiu CARG1, STR:CARG1, #STR
1772   |   lw CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1773   |  sltu AT, TMP1, CARG3
1774   |  bnez AT, ->fff_fallback
1775   |.  addu TMP3, CARG1, CARG3
1776   |  move CARG4, CARG2
1777   |1:  // ASCII case conversion.
1778   |   lbu TMP1, 0(CARG1)
1779   |  sltu AT, CARG1, TMP3
1780   |  beqz AT, ->fff_newstr
1781   |.  addiu TMP0, TMP1, -lo
1782   |   xori TMP2, TMP1, 0x20
1783   |   sltiu AT, TMP0, 26
1784   |   movn TMP1, TMP2, AT
1785   |  addiu CARG1, CARG1, 1
1786   |   sb TMP1, 0(CARG4)
1787   |  b <1
1788   |.  addiu CARG4, CARG4, 1
1789   |.endmacro
1790   |
1791   |ffstring_case string_lower, 65
1792   |ffstring_case string_upper, 97
1793   |
1794   |//-- Table library ------------------------------------------------------
1795   |
1796   |.ffunc_1 table_getn
1797   |  li AT, LJ_TTAB
1798   |  bne CARG3, AT, ->fff_fallback
1799   |.  load_got lj_tab_len
1800   |  call_intern lj_tab_len             // (GCtab *t)
1801   |.  nop
1802   |  // Returns uint32_t (but less than 2^31).
1803   |  b ->fff_resi
1804   |.  nop
1805   |
1806   |//-- Bit library --------------------------------------------------------
1807   |
1808   |.macro .ffunc_bit, name
1809   |  .ffunc_n bit_..name
1810   |.  add.d FARG1, FARG1, TOBIT
1811   |  mfc1 CRET1, FARG1
1812   |.endmacro
1813   |
1814   |.macro .ffunc_bit_op, name, ins
1815   |  .ffunc_bit name
1816   |  addiu TMP1, BASE, 8
1817   |  addu TMP2, BASE, NARGS8:RC
1818   |1:
1819   |  lw CARG4, HI(TMP1)
1820   |  beq TMP1, TMP2, ->fff_resi
1821   |.  ldc1 FARG1, 0(TMP1)
1822   |  sltiu AT, CARG4, LJ_TISNUM
1823   |  beqz AT, ->fff_fallback
1824   |  add.d FARG1, FARG1, TOBIT
1825   |  mfc1 CARG2, FARG1
1826   |  ins CRET1, CRET1, CARG2
1827   |  b <1
1828   |.  addiu TMP1, TMP1, 8
1829   |.endmacro
1830   |
1831   |.ffunc_bit_op band, and
1832   |.ffunc_bit_op bor, or
1833   |.ffunc_bit_op bxor, xor
1834   |
1835   |.ffunc_bit bswap
1836   |  srl TMP0, CRET1, 24
1837   |   srl TMP2, CRET1, 8
1838   |  sll TMP1, CRET1, 24
1839   |   andi TMP2, TMP2, 0xff00
1840   |  or TMP0, TMP0, TMP1
1841   |   andi CRET1, CRET1, 0xff00
1842   |  or TMP0, TMP0, TMP2
1843   |   sll CRET1, CRET1, 8
1844   |  b ->fff_resi
1845   |.  or CRET1, TMP0, CRET1
1846   |
1847   |.ffunc_bit bnot
1848   |  b ->fff_resi
1849   |.  not CRET1, CRET1
1850   |
1851   |.macro .ffunc_bit_sh, name, ins, shmod
1852   |  .ffunc_nn bit_..name
1853   |.  add.d FARG1, FARG1, TOBIT
1854   |  add.d FARG2, FARG2, TOBIT
1855   |  mfc1 CARG1, FARG1
1856   |  mfc1 CARG2, FARG2
1857   |.if shmod == 1
1858   |  li AT, 32
1859   |  subu TMP0, AT, CARG2
1860   |  sllv CARG2, CARG1, CARG2
1861   |  srlv CARG1, CARG1, TMP0
1862   |.elif shmod == 2
1863   |  li AT, 32
1864   |  subu TMP0, AT, CARG2
1865   |  srlv CARG2, CARG1, CARG2
1866   |  sllv CARG1, CARG1, TMP0
1867   |.endif
1868   |  b ->fff_resi
1869   |.  ins CRET1, CARG1, CARG2
1870   |.endmacro
1871   |
1872   |.ffunc_bit_sh lshift, sllv, 0
1873   |.ffunc_bit_sh rshift, srlv, 0
1874   |.ffunc_bit_sh arshift, srav, 0
1875   |// Can't use rotrv, since it's only in MIPS32R2.
1876   |.ffunc_bit_sh rol, or, 1
1877   |.ffunc_bit_sh ror, or, 2
1878   |
1879   |.ffunc_bit tobit
1880   |->fff_resi:
1881   |  mtc1 CRET1, FRET1
1882   |  b ->fff_resn
1883   |.  cvt.d.w FRET1, FRET1
1884   |
1885   |//-----------------------------------------------------------------------
1886   |
1887   |->fff_fallback:                      // Call fast function fallback handler.
1888   |  // BASE = new base, RB = CFUNC, RC = nargs*8
1889   |  lw TMP3, CFUNC:RB->f
1890   |    addu TMP1, BASE, NARGS8:RC
1891   |   lw PC, FRAME_PC(BASE)             // Fallback may overwrite PC.
1892   |    addiu TMP0, TMP1, 8*LUA_MINSTACK
1893   |     lw TMP2, L->maxstack
1894   |   sw PC, SAVE_PC                    // Redundant (but a defined value).
1895   |  sltu AT, TMP2, TMP0
1896   |     sw BASE, L->base
1897   |    sw TMP1, L->top
1898   |  bnez AT, >5                        // Need to grow stack.
1899   |.  move CFUNCADDR, TMP3
1900   |  jalr TMP3                          // (lua_State *L)
1901   |.  move CARG1, L
1902   |  // Either throws an error, or recovers and returns -1, 0 or nresults+1.
1903   |  lw BASE, L->base
1904   |   sll RD, CRET1, 3
1905   |  bgtz CRET1, ->fff_res              // Returned nresults+1?
1906   |.  addiu RA, BASE, -8
1907   |1:  // Returned 0 or -1: retry fast path.
1908   |  lw TMP0, L->top
1909   |   lw LFUNC:RB, FRAME_FUNC(BASE)
1910   |  bnez CRET1, ->vm_call_tail         // Returned -1?
1911   |.  subu NARGS8:RC, TMP0, BASE
1912   |  ins_callt                          // Returned 0: retry fast path.
1913   |
1914   |// Reconstruct previous base for vmeta_call during tailcall.
1915   |->vm_call_tail:
1916   |  andi TMP0, PC, FRAME_TYPE
1917   |   li AT, -4
1918   |  bnez TMP0, >3
1919   |.  and TMP1, PC, AT
1920   |  lbu TMP1, OFS_RA(PC)
1921   |  sll TMP1, TMP1, 3
1922   |  addiu TMP1, TMP1, 8
1923   |3:
1924   |  b ->vm_call_dispatch               // Resolve again for tailcall.
1925   |.  subu TMP2, BASE, TMP1
1926   |
1927   |5:  // Grow stack for fallback handler.
1928   |  load_got lj_state_growstack
1929   |  li CARG2, LUA_MINSTACK
1930   |  call_intern lj_state_growstack     // (lua_State *L, int n)
1931   |.  move CARG1, L
1932   |  lw BASE, L->base
1933   |  b <1
1934   |.  li CRET1, 0                       // Force retry.
1935   |
1936   |->fff_gcstep:                        // Call GC step function.
1937   |  // BASE = new base, RC = nargs*8
1938   |  move MULTRES, ra
1939   |  load_got lj_gc_step
1940   |   sw BASE, L->base
1941   |  addu TMP0, BASE, NARGS8:RC
1942   |   sw PC, SAVE_PC                    // Redundant (but a defined value).
1943   |  sw TMP0, L->top
1944   |  call_intern lj_gc_step             // (lua_State *L)
1945   |.  move CARG1, L
1946   |   lw BASE, L->base
1947   |  move ra, MULTRES
1948   |    lw TMP0, L->top
1949   |  lw CFUNC:RB, FRAME_FUNC(BASE)
1950   |  jr ra
1951   |.  subu NARGS8:RC, TMP0, BASE
1952   |
1953   |//-----------------------------------------------------------------------
1954   |//-- Special dispatch targets -------------------------------------------
1955   |//-----------------------------------------------------------------------
1956   |
1957   |->vm_record:                         // Dispatch target for recording phase.
1958   |.if JIT
1959   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1960   |  andi AT, TMP3, HOOK_VMEVENT        // No recording while in vmevent.
1961   |  bnez AT, >5
1962   |  // Decrement the hookcount for consistency, but always do the call.
1963   |.  lw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1964   |  andi AT, TMP3, HOOK_ACTIVE
1965   |  bnez AT, >1
1966   |.  addiu TMP2, TMP2, -1
1967   |  andi AT, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
1968   |  beqz AT, >1
1969   |.  nop
1970   |  b >1
1971   |.  sw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1972   |.endif
1973   |
1974   |->vm_rethook:                        // Dispatch target for return hooks.
1975   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1976   |  andi AT, TMP3, HOOK_ACTIVE         // Hook already active?
1977   |  beqz AT, >1
1978   |5:  // Re-dispatch to static ins.
1979   |.  lw AT, GG_DISP2STATIC(TMP0)       // Assumes TMP0 holds DISPATCH+OP*4.
1980   |  jr AT
1981   |.  nop
1982   |
1983   |->vm_inshook:                        // Dispatch target for instr/line hooks.
1984   |  lbu TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1985   |  lw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1986   |  andi AT, TMP3, HOOK_ACTIVE         // Hook already active?
1987   |  bnez AT, <5
1988   |.  andi AT, TMP3, LUA_MASKLINE|LUA_MASKCOUNT
1989   |  beqz AT, <5
1990   |.  addiu TMP2, TMP2, -1
1991   |  beqz TMP2, >1
1992   |.  sw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1993   |  andi AT, TMP3, LUA_MASKLINE
1994   |  beqz AT, <5
1995   |1:
1996   |.  load_got lj_dispatch_ins
1997   |   sw MULTRES, SAVE_MULTRES
1998   |  move CARG2, PC
1999   |   sw BASE, L->base
2000   |  // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
2001   |  call_intern lj_dispatch_ins        // (lua_State *L, const BCIns *pc)
2002   |.  move CARG1, L
2003   |3:
2004   |  lw BASE, L->base
2005   |4:  // Re-dispatch to static ins.
2006   |  lw INS, -4(PC)
2007   |  decode_OP4a TMP1, INS
2008   |  decode_OP4b TMP1
2009   |  addu TMP0, DISPATCH, TMP1
2010   |   decode_RD8a RD, INS
2011   |  lw AT, GG_DISP2STATIC(TMP0)
2012   |   decode_RA8a RA, INS
2013   |   decode_RD8b RD
2014   |  jr AT
2015   |   decode_RA8b RA
2016   |
2017   |->cont_hook:                         // Continue from hook yield.
2018   |  addiu PC, PC, 4
2019   |  b <4
2020   |.  lw MULTRES, -24+LO(RB)            // Restore MULTRES for *M ins.
2021   |
2022   |->vm_hotloop:                        // Hot loop counter underflow.
2023   |.if JIT
2024   |  lw LFUNC:TMP1, FRAME_FUNC(BASE)
2025   |   addiu CARG1, DISPATCH, GG_DISP2J
2026   |   sw PC, SAVE_PC
2027   |  lw TMP1, LFUNC:TMP1->pc
2028   |   move CARG2, PC
2029   |   sw L, DISPATCH_J(L)(DISPATCH)
2030   |  lbu TMP1, PC2PROTO(framesize)(TMP1)
2031   |  load_got lj_trace_hot
2032   |   sw BASE, L->base
2033   |  sll TMP1, TMP1, 3
2034   |  addu TMP1, BASE, TMP1
2035   |  call_intern lj_trace_hot           // (jit_State *J, const BCIns *pc)
2036   |.  sw TMP1, L->top
2037   |  b <3
2038   |.  nop
2039   |.endif
2040   |
2041   |->vm_callhook:                       // Dispatch target for call hooks.
2042   |.if JIT
2043   |  b >1
2044   |.endif
2045   |.  move CARG2, PC
2046   |
2047   |->vm_hotcall:                        // Hot call counter underflow.
2048   |.if JIT
2049   |  ori CARG2, PC, 1
2050   |1:
2051   |.endif
2052   |  load_got lj_dispatch_call
2053   |  addu TMP0, BASE, RC
2054   |   sw PC, SAVE_PC
2055   |   sw BASE, L->base
2056   |  subu RA, RA, BASE
2057   |   sw TMP0, L->top
2058   |  call_intern lj_dispatch_call       // (lua_State *L, const BCIns *pc)
2059   |.  move CARG1, L
2060   |  // Returns ASMFunction.
2061   |  lw BASE, L->base
2062   |   lw TMP0, L->top
2063   |   sw r0, SAVE_PC                    // Invalidate for subsequent line hook.
2064   |  subu NARGS8:RC, TMP0, BASE
2065   |  addu RA, BASE, RA
2066   |  lw LFUNC:RB, FRAME_FUNC(BASE)
2067   |  jr CRET1
2068   |.  lw INS, -4(PC)
2069   |
2070   |//-----------------------------------------------------------------------
2071   |//-- Trace exit handler -------------------------------------------------
2072   |//-----------------------------------------------------------------------
2073   |
2074   |.macro savex_, a, b
2075   |  sdc1 f..a, 16+a*8(sp)
2076   |  sw r..a, 16+32*8+a*4(sp)
2077   |  sw r..b, 16+32*8+b*4(sp)
2078   |.endmacro
2079   |
2080   |->vm_exit_handler:
2081   |.if JIT
2082   |  addiu sp, sp, -(16+32*8+32*4)
2083   |  savex_ 0, 1
2084   |  savex_ 2, 3
2085   |  savex_ 4, 5
2086   |  savex_ 6, 7
2087   |  savex_ 8, 9
2088   |  savex_ 10, 11
2089   |  savex_ 12, 13
2090   |  savex_ 14, 15
2091   |  savex_ 16, 17
2092   |  savex_ 18, 19
2093   |  savex_ 20, 21
2094   |  savex_ 22, 23
2095   |  savex_ 24, 25
2096   |  savex_ 26, 27
2097   |  sdc1 f28, 16+28*8(sp)
2098   |  sw r28, 16+32*8+28*4(sp)
2099   |  sdc1 f30, 16+30*8(sp)
2100   |  sw r30, 16+32*8+30*4(sp)
2101   |  sw r0, 16+32*8+31*4(sp)            // Clear RID_TMP.
2102   |  li_vmstate EXIT
2103   |   addiu TMP2, sp, 16+32*8+32*4      // Recompute original value of sp.
2104   |  addiu DISPATCH, JGL, -GG_DISP2G-32768
2105   |  lw TMP1, 0(TMP2)                   // Load exit number.
2106   |  st_vmstate
2107   |   sw TMP2, 16+32*8+29*4(sp)         // Store sp in RID_SP.
2108   |  lw L, DISPATCH_GL(jit_L)(DISPATCH)
2109   |  lw BASE, DISPATCH_GL(jit_base)(DISPATCH)
2110   |  load_got lj_trace_exit
2111   |  sw L, DISPATCH_J(L)(DISPATCH)
2112   |  sw ra, DISPATCH_J(parent)(DISPATCH)  // Store trace number.
2113   |  sw TMP1, DISPATCH_J(exitno)(DISPATCH)  // Store exit number.
2114   |  addiu CARG1, DISPATCH, GG_DISP2J
2115   |  sw BASE, L->base
2116   |  call_intern lj_trace_exit          // (jit_State *J, ExitState *ex)
2117   |.  addiu CARG2, sp, 16
2118   |  // Returns MULTRES (unscaled) or negated error code.
2119   |  lw TMP1, L->cframe
2120   |  li AT, -4
2121   |   lw BASE, L->base
2122   |  and sp, TMP1, AT
2123   |   lw PC, SAVE_PC                    // Get SAVE_PC.
2124   |  b >1
2125   |.  sw L, SAVE_L                      // Set SAVE_L (on-trace resume/yield).
2126   |.endif
2127   |->vm_exit_interp:
2128   |.if JIT
2129   |  // CRET1 = MULTRES or negated error code, BASE, PC and JGL set.
2130   |  lw L, SAVE_L
2131   |  addiu DISPATCH, JGL, -GG_DISP2G-32768
2132   |1:
2133   |  bltz CRET1, >3                     // Check for error from exit.
2134   |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
2135   |    lui TMP3, 0x59c0                 // TOBIT = 2^52 + 2^51 (float).
2136   |  sll MULTRES, CRET1, 3
2137   |    li TISNIL, LJ_TNIL
2138   |  sw MULTRES, SAVE_MULTRES
2139   |    mtc1 TMP3, TOBIT
2140   |  lw TMP1, LFUNC:TMP1->pc
2141   |   sw r0, DISPATCH_GL(jit_L)(DISPATCH)
2142   |  lw KBASE, PC2PROTO(k)(TMP1)
2143   |    cvt.d.s TOBIT, TOBIT
2144   |  // Modified copy of ins_next which handles function header dispatch, too.
2145   |  lw INS, 0(PC)
2146   |   addiu PC, PC, 4
2147   |    // Assumes TISNIL == ~LJ_VMST_INTERP == -1
2148   |    sw TISNIL, DISPATCH_GL(vmstate)(DISPATCH)
2149   |  decode_OP4a TMP1, INS
2150   |  decode_OP4b TMP1
2151   |    sltiu TMP2, TMP1, BC_FUNCF*4     // Function header?
2152   |  addu TMP0, DISPATCH, TMP1
2153   |   decode_RD8a RD, INS
2154   |  lw AT, 0(TMP0)
2155   |   decode_RA8a RA, INS
2156   |    beqz TMP2, >2
2157   |.  decode_RA8b RA
2158   |  jr AT
2159   |.  decode_RD8b RD
2160   |2:
2161   |  addiu RC, MULTRES, -8
2162   |  jr AT
2163   |.  addu RA, RA, BASE
2164   |
2165   |3:  // Rethrow error from the right C frame.
2166   |  load_got lj_err_throw
2167   |  negu CARG2, CRET1
2168   |  call_intern lj_err_throw           // (lua_State *L, int errcode)
2169   |.  move CARG1, L
2170   |.endif
2171   |
2172   |//-----------------------------------------------------------------------
2173   |//-- Math helper functions ----------------------------------------------
2174   |//-----------------------------------------------------------------------
2175   |
2176   |// Modifies AT, TMP0, FRET1, FRET2, f4. Keeps all others incl. FARG1.
2177   |.macro vm_round, func
2178   |  lui TMP0, 0x4330                   // Hiword of 2^52 (double).
2179   |  mtc1 r0, f4
2180   |  mtc1 TMP0, f5
2181   |  abs.d FRET2, FARG1                 // |x|
2182   |    mfc1 AT, f13
2183   |  c.olt.d 0, FRET2, f4
2184   |   add.d FRET1, FRET2, f4            // (|x| + 2^52) - 2^52
2185   |  bc1f 0, >1                         // Truncate only if |x| < 2^52.
2186   |.  sub.d FRET1, FRET1, f4
2187   |    slt AT, AT, r0
2188   |.if "func" == "ceil"
2189   |   lui TMP0, 0xbff0                  // Hiword of -1 (double). Preserves -0.
2190   |.else
2191   |   lui TMP0, 0x3ff0                  // Hiword of +1 (double).
2192   |.endif
2193   |.if "func" == "trunc"
2194   |   mtc1 TMP0, f5
2195   |  c.olt.d 0, FRET2, FRET1            // |x| < result?
2196   |   sub.d FRET2, FRET1, f4
2197   |  movt.d FRET1, FRET2, 0             // If yes, subtract +1.
2198   |  neg.d FRET2, FRET1
2199   |  jr ra
2200   |.  movn.d FRET1, FRET2, AT           // Merge sign bit back in.
2201   |.else
2202   |  neg.d FRET2, FRET1
2203   |   mtc1 TMP0, f5
2204   |  movn.d FRET1, FRET2, AT            // Merge sign bit back in.
2205   |.if "func" == "ceil"
2206   |  c.olt.d 0, FRET1, FARG1            // x > result?
2207   |.else
2208   |  c.olt.d 0, FARG1, FRET1            // x < result?
2209   |.endif
2210   |   sub.d FRET2, FRET1, f4            // If yes, subtract +-1.
2211   |  jr ra
2212   |.  movt.d FRET1, FRET2, 0
2213   |.endif
2214   |1:
2215   |  jr ra
2216   |.  mov.d FRET1, FARG1
2217   |.endmacro
2218   |
2219   |->vm_floor:
2220   |  vm_round floor
2221   |->vm_ceil:
2222   |  vm_round ceil
2223   |->vm_trunc:
2224   |.if JIT
2225   |  vm_round trunc
2226   |.endif
2227   |
2228   |//-----------------------------------------------------------------------
2229   |//-- Miscellaneous functions --------------------------------------------
2230   |//-----------------------------------------------------------------------
2231   |
2232   |//-----------------------------------------------------------------------
2233   |//-- FFI helper functions -----------------------------------------------
2234   |//-----------------------------------------------------------------------
2235   |
2236   |// Handler for callback functions. Callback slot number in r1, g in r2.
2237   |->vm_ffi_callback:
2238   |.if FFI
2239   |.type CTSTATE, CTState, PC
2240   |  saveregs
2241   |  lw CTSTATE, GL:r2->ctype_state
2242   |   addiu DISPATCH, r2, GG_G2DISP
2243   |  load_got lj_ccallback_enter
2244   |  sw r1, CTSTATE->cb.slot
2245   |  sw CARG1, CTSTATE->cb.gpr[0]
2246   |  sw CARG2, CTSTATE->cb.gpr[1]
2247   |   sdc1 FARG1, CTSTATE->cb.fpr[0]
2248   |  sw CARG3, CTSTATE->cb.gpr[2]
2249   |  sw CARG4, CTSTATE->cb.gpr[3]
2250   |   sdc1 FARG2, CTSTATE->cb.fpr[1]
2251   |  addiu TMP0, sp, CFRAME_SPACE+16
2252   |  sw TMP0, CTSTATE->cb.stack
2253   |  sw r0, SAVE_PC                     // Any value outside of bytecode is ok.
2254   |   move CARG2, sp
2255   |  call_intern lj_ccallback_enter     // (CTState *cts, void *cf)
2256   |.  move CARG1, CTSTATE
2257   |  // Returns lua_State *.
2258   |  lw BASE, L:CRET1->base
2259   |  lw RC, L:CRET1->top
2260   |   move L, CRET1
2261   |     lui TMP3, 0x59c0                // TOBIT = 2^52 + 2^51 (float).
2262   |  lw LFUNC:RB, FRAME_FUNC(BASE)
2263   |     mtc1 TMP3, TOBIT
2264   |    li_vmstate INTERP
2265   |     li TISNIL, LJ_TNIL
2266   |  subu RC, RC, BASE
2267   |    st_vmstate
2268   |     cvt.d.s TOBIT, TOBIT
2269   |  ins_callt
2270   |.endif
2271   |
2272   |->cont_ffi_callback:                 // Return from FFI callback.
2273   |.if FFI
2274   |  load_got lj_ccallback_leave
2275   |  lw CTSTATE, DISPATCH_GL(ctype_state)(DISPATCH)
2276   |   sw BASE, L->base
2277   |   sw RB, L->top
2278   |  sw L, CTSTATE->L
2279   |  move CARG2, RA
2280   |  call_intern lj_ccallback_leave     // (CTState *cts, TValue *o)
2281   |.  move CARG1, CTSTATE
2282   |  lw CRET1, CTSTATE->cb.gpr[0]
2283   |   ldc1 FRET1, CTSTATE->cb.fpr[0]
2284   |  lw CRET2, CTSTATE->cb.gpr[1]
2285   |  b ->vm_leave_unw
2286   |.  ldc1 FRET2, CTSTATE->cb.fpr[1]
2287   |.endif
2288   |
2289   |->vm_ffi_call:                       // Call C function via FFI.
2290   |  // Caveat: needs special frame unwinding, see below.
2291   |.if FFI
2292   |  .type CCSTATE, CCallState, CARG1
2293   |  lw TMP1, CCSTATE->spadj
2294   |   lbu CARG2, CCSTATE->nsp
2295   |  move TMP2, sp
2296   |  subu sp, sp, TMP1
2297   |  sw ra, -4(TMP2)
2298   |   sll CARG2, CARG2, 2
2299   |  sw r16, -8(TMP2)
2300   |  sw CCSTATE, -12(TMP2)
2301   |  move r16, TMP2
2302   |  addiu TMP1, CCSTATE, offsetof(CCallState, stack)
2303   |  addiu TMP2, sp, 16
2304   |  beqz CARG2, >2
2305   |.  addu TMP3, TMP1, CARG2
2306   |1:
2307   |   lw TMP0, 0(TMP1)
2308   |  addiu TMP1, TMP1, 4
2309   |  sltu AT, TMP1, TMP3
2310   |   sw TMP0, 0(TMP2)
2311   |  bnez AT, <1
2312   |.  addiu TMP2, TMP2, 4
2313   |2:
2314   |  lw CFUNCADDR, CCSTATE->func
2315   |  lw CARG2, CCSTATE->gpr[1]
2316   |  lw CARG3, CCSTATE->gpr[2]
2317   |  lw CARG4, CCSTATE->gpr[3]
2318   |  ldc1 FARG1, CCSTATE->fpr[0]
2319   |  ldc1 FARG2, CCSTATE->fpr[1]
2320   |  jalr CFUNCADDR
2321   |.  lw CARG1, CCSTATE->gpr[0]         // Do this last, since CCSTATE is CARG1.
2322   |  lw CCSTATE:TMP1, -12(r16)
2323   |  lw TMP2, -8(r16)
2324   |  lw ra, -4(r16)
2325   |  sw CRET1, CCSTATE:TMP1->gpr[0]
2326   |  sw CRET2, CCSTATE:TMP1->gpr[1]
2327   |  sdc1 FRET1, CCSTATE:TMP1->fpr[0]
2328   |  sdc1 FRET2, CCSTATE:TMP1->fpr[1]
2329   |  move sp, r16
2330   |  jr ra
2331   |.  move r16, TMP2
2332   |.endif
2333   |// Note: vm_ffi_call must be the last function in this object file!
2334   |
2335   |//-----------------------------------------------------------------------
2336 }
2337
2338 /* Generate the code for a single instruction. */
2339 static void build_ins(BuildCtx *ctx, BCOp op, int defop)
2340 {
2341   int vk = 0;
2342   |=>defop:
2343
2344   switch (op) {
2345
2346   /* -- Comparison ops ---------------------------------------------------- */
2347
2348   /* Remember: all ops branch for a true comparison, fall through otherwise. */
2349
2350   case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
2351     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2352     |  addu CARG2, BASE, RA
2353     |   addu CARG3, BASE, RD
2354     |  lw TMP0, HI(CARG2)
2355     |   lw TMP1, HI(CARG3)
2356     |   ldc1 f0, 0(CARG2)
2357     |   ldc1 f2, 0(CARG3)
2358     |  sltiu TMP0, TMP0, LJ_TISNUM
2359     |   sltiu TMP1, TMP1, LJ_TISNUM
2360     |    lhu TMP2, OFS_RD(PC)
2361     |  and TMP0, TMP0, TMP1
2362     |    addiu PC, PC, 4
2363     |  beqz TMP0, ->vmeta_comp
2364     |.   lui TMP1, (-(BCBIAS_J*4 >> 16) & 65535)
2365     |    decode_RD4b TMP2
2366     |    addu TMP2, TMP2, TMP1
2367     if (op == BC_ISLT || op == BC_ISGE) {
2368       |  c.olt.d f0, f2
2369     } else {
2370       |  c.ole.d f0, f2
2371     }
2372     if (op == BC_ISLT || op == BC_ISLE) {
2373       |  movf TMP2, r0
2374     } else {
2375       |  movt TMP2, r0
2376     }
2377     |  addu PC, PC, TMP2
2378     |1:
2379     |  ins_next
2380     break;
2381
2382   case BC_ISEQV: case BC_ISNEV:
2383     vk = op == BC_ISEQV;
2384     |  // RA = src1*8, RD = src2*8, JMP with RD = target
2385     |  addu RA, BASE, RA
2386     |   addiu PC, PC, 4
2387     |  lw TMP0, HI(RA)
2388     |   ldc1 f0, 0(RA)
2389     |  addu RD, BASE, RD
2390     |    lhu TMP2, -4+OFS_RD(PC)
2391     |   lw TMP1, HI(RD)
2392     |   ldc1 f2, 0(RD)
2393     |    lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2394     |  sltiu AT, TMP0, LJ_TISNUM
2395     |  sltiu CARG1, TMP1, LJ_TISNUM
2396     |    decode_RD4b TMP2
2397     |  and AT, AT, CARG1
2398     |  beqz AT, >5
2399     |.   addu TMP2, TMP2, TMP3
2400     |  c.eq.d f0, f2
2401     if (vk) {
2402       |  movf TMP2, r0
2403     } else {
2404       |  movt TMP2, r0
2405     }
2406     |1:
2407     |  addu PC, PC, TMP2
2408     |  ins_next
2409     |5:  // Either or both types are not numbers.
2410     |  lw CARG2, LO(RA)
2411     |  lw CARG3, LO(RD)
2412     |.if FFI
2413     |  li TMP3, LJ_TCDATA
2414     |  beq TMP0, TMP3, ->vmeta_equal_cd
2415     |.endif
2416     |.  sltiu AT, TMP0, LJ_TISPRI               // Not a primitive?
2417     |.if FFI
2418     |  beq TMP1, TMP3, ->vmeta_equal_cd
2419     |.endif
2420     |.  xor TMP3, CARG2, CARG3                  // Same tv?
2421     |  xor TMP1, TMP1, TMP0                     // Same type?
2422     |  sltiu CARG1, TMP0, LJ_TISTABUD+1         // Table or userdata?
2423     |  movz TMP3, r0, AT                        // Ignore tv if primitive.
2424     |  movn CARG1, r0, TMP1                     // Tab/ud and same type?
2425     |  or AT, TMP1, TMP3                        // Same type && (pri||same tv).
2426     |  movz CARG1, r0, AT
2427     |  beqz CARG1, <1   // Done if not tab/ud or not same type or same tv.
2428     if (vk) {
2429       |.  movn TMP2, r0, AT
2430     } else {
2431       |.  movz TMP2, r0, AT
2432     }
2433     |  // Different tables or userdatas. Need to check __eq metamethod.
2434     |  // Field metatable must be at same offset for GCtab and GCudata!
2435     |  lw TAB:TMP1, TAB:CARG2->metatable
2436     |  beqz TAB:TMP1, <1                // No metatable?
2437     |.  nop
2438     |  lbu TMP1, TAB:TMP1->nomm
2439     |  andi TMP1, TMP1, 1<<MM_eq
2440     |  bnez TMP1, <1                    // Or 'no __eq' flag set?
2441     |.  nop
2442     |  b ->vmeta_equal                  // Handle __eq metamethod.
2443     |.  li CARG4, 1-vk                  // ne = 0 or 1.
2444     break;
2445
2446   case BC_ISEQS: case BC_ISNES:
2447     vk = op == BC_ISEQS;
2448     |  // RA = src*8, RD = str_const*8 (~), JMP with RD = target
2449     |  addu RA, BASE, RA
2450     |   addiu PC, PC, 4
2451     |  lw TMP0, HI(RA)
2452     |   srl RD, RD, 1
2453     |  lw STR:TMP3, LO(RA)
2454     |   subu RD, KBASE, RD
2455     |    lhu TMP2, -4+OFS_RD(PC)
2456     |.if FFI
2457     |  li AT, LJ_TCDATA
2458     |  beq TMP0, AT, ->vmeta_equal_cd
2459     |.endif
2460     |.  lw STR:TMP1, -4(RD)             // KBASE-4-str_const*4
2461     |  addiu TMP0, TMP0, -LJ_TSTR
2462     |   decode_RD4b TMP2
2463     |  xor TMP1, STR:TMP1, STR:TMP3
2464     |  or TMP0, TMP0, TMP1
2465     |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2466     |   addu TMP2, TMP2, TMP3
2467     if (vk) {
2468       |  movn TMP2, r0, TMP0
2469     } else {
2470       |  movz TMP2, r0, TMP0
2471     }
2472     |  addu PC, PC, TMP2
2473     |  ins_next
2474     break;
2475
2476   case BC_ISEQN: case BC_ISNEN:
2477     vk = op == BC_ISEQN;
2478     |  // RA = src*8, RD = num_const*8, JMP with RD = target
2479     |  addu RA, BASE, RA
2480     |   addiu PC, PC, 4
2481     |  lw TMP0, HI(RA)
2482     |   ldc1 f0, 0(RA)
2483     |  addu RD, KBASE, RD
2484     |    lhu TMP2, -4+OFS_RD(PC)
2485     |   ldc1 f2, 0(RD)
2486     |    lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2487     |  sltiu AT, TMP0, LJ_TISNUM
2488     |    decode_RD4b TMP2
2489     |.if FFI
2490     |  beqz AT, >5
2491     |.else
2492     |  beqz AT, >1
2493     |.endif
2494     |.   addu TMP2, TMP2, TMP3
2495     |   c.eq.d f0, f2
2496     if (vk) {
2497       |  movf TMP2, r0
2498       |  addu PC, PC, TMP2
2499       |1:
2500     } else {
2501       |  movt TMP2, r0
2502       |1:
2503       |  addu PC, PC, TMP2
2504     }
2505     |  ins_next
2506     |.if FFI
2507     |5:
2508     |  li AT, LJ_TCDATA
2509     |  beq TMP0, AT, ->vmeta_equal_cd
2510     |.  nop
2511     |  b <1
2512     |.  nop
2513     |.endif
2514     break;
2515
2516   case BC_ISEQP: case BC_ISNEP:
2517     vk = op == BC_ISEQP;
2518     |  // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
2519     |  addu RA, BASE, RA
2520     |   srl TMP1, RD, 3
2521     |  lw TMP0, HI(RA)
2522     |    lhu TMP2, OFS_RD(PC)
2523     |   not TMP1, TMP1
2524     |    addiu PC, PC, 4
2525     |.if FFI
2526     |  li AT, LJ_TCDATA
2527     |  beq TMP0, AT, ->vmeta_equal_cd
2528     |.endif
2529     |.  xor TMP0, TMP0, TMP1
2530     |  decode_RD4b TMP2
2531     |  lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2532     |  addu TMP2, TMP2, TMP3
2533     if (vk) {
2534       |  movn TMP2, r0, TMP0
2535     } else {
2536       |  movz TMP2, r0, TMP0
2537     }
2538     |  addu PC, PC, TMP2
2539     |  ins_next
2540     break;
2541
2542   /* -- Unary test and copy ops ------------------------------------------- */
2543
2544   case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
2545     |  // RA = dst*8 or unused, RD = src*8, JMP with RD = target
2546     |  addu RD, BASE, RD
2547     |   lhu TMP2, OFS_RD(PC)
2548     |  lw TMP0, HI(RD)
2549     |   addiu PC, PC, 4
2550     if (op == BC_IST || op == BC_ISF) {
2551       |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2552       |   decode_RD4b TMP2
2553       |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2554       |   addu TMP2, TMP2, TMP3
2555       if (op == BC_IST) {
2556         |  movz TMP2, r0, TMP0
2557       } else {
2558         |  movn TMP2, r0, TMP0
2559       }
2560       |  addu PC, PC, TMP2
2561     } else {
2562       |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2563       |  ldc1 f0, 0(RD)
2564       if (op == BC_ISTC) {
2565         |  beqz TMP0, >1
2566       } else {
2567         |  bnez TMP0, >1
2568       }
2569       |.  addu RA, BASE, RA
2570       |   decode_RD4b TMP2
2571       |   lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
2572       |   addu TMP2, TMP2, TMP3
2573       |  sdc1 f0, 0(RA)
2574       |   addu PC, PC, TMP2
2575       |1:
2576     }
2577     |  ins_next
2578     break;
2579
2580   /* -- Unary ops --------------------------------------------------------- */
2581
2582   case BC_MOV:
2583     |  // RA = dst*8, RD = src*8
2584     |  addu RD, BASE, RD
2585     |  addu RA, BASE, RA
2586     |  ldc1 f0, 0(RD)
2587     |  ins_next1
2588     |  sdc1 f0, 0(RA)
2589     |  ins_next2
2590     break;
2591   case BC_NOT:
2592     |  // RA = dst*8, RD = src*8
2593     |  addu RD, BASE, RD
2594     |   addu RA, BASE, RA
2595     |  lw TMP0, HI(RD)
2596     |   li TMP1, LJ_TFALSE
2597     |  sltiu TMP0, TMP0, LJ_TISTRUECOND
2598     |  addiu TMP1, TMP0, LJ_TTRUE
2599     |  ins_next1
2600     |  sw TMP1, HI(RA)
2601     |  ins_next2
2602     break;
2603   case BC_UNM:
2604     |  // RA = dst*8, RD = src*8
2605     |  addu CARG3, BASE, RD
2606     |   addu RA, BASE, RA
2607     |  lw TMP0, HI(CARG3)
2608     |   ldc1 f0, 0(CARG3)
2609     |  sltiu AT, TMP0, LJ_TISNUM
2610     |  beqz AT, ->vmeta_unm
2611     |.  neg.d f0, f0
2612     |  ins_next1
2613     |   sdc1 f0, 0(RA)
2614     |  ins_next2
2615     break;
2616   case BC_LEN:
2617     |  // RA = dst*8, RD = src*8
2618     |  addu CARG2, BASE, RD
2619     |   addu RA, BASE, RA
2620     |  lw TMP0, HI(CARG2)
2621     |   lw CARG1, LO(CARG2)
2622     |  li AT, LJ_TSTR
2623     |  bne TMP0, AT, >2
2624     |.  li AT, LJ_TTAB
2625     |  lw CRET1, STR:CARG1->len
2626     |1:
2627     |  mtc1 CRET1, f0
2628     |  cvt.d.w f0, f0
2629     |  ins_next1
2630     |  sdc1 f0, 0(RA)
2631     |  ins_next2
2632     |2:
2633     |  bne TMP0, AT, ->vmeta_len
2634     |.  nop
2635 #if LJ_52
2636     |  lw TAB:TMP2, TAB:CARG1->metatable
2637     |  bnez TAB:TMP2, >9
2638     |.  nop
2639     |3:
2640 #endif
2641     |->BC_LEN_Z:
2642     |  load_got lj_tab_len
2643     |  call_intern lj_tab_len           // (GCtab *t)
2644     |.  nop
2645     |  // Returns uint32_t (but less than 2^31).
2646     |  b <1
2647     |.  nop
2648 #if LJ_52
2649     |9:
2650     |  lbu TMP0, TAB:TMP2->nomm
2651     |  andi TMP0, TMP0, 1<<MM_len
2652     |  bnez TMP0, <3                    // 'no __len' flag set: done.
2653     |.  nop
2654     |  b ->vmeta_len
2655     |.  nop
2656 #endif
2657     break;
2658
2659   /* -- Binary ops -------------------------------------------------------- */
2660
2661     |.macro ins_arithpre
2662     ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
2663     |  decode_RB8a RB, INS
2664     |  decode_RB8b RB
2665     |   decode_RDtoRC8 RC, RD
2666     |  // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
2667     ||switch (vk) {
2668     ||case 0:
2669     |   addu CARG3, BASE, RB
2670     |    addu CARG4, KBASE, RC
2671     |   lw TMP1, HI(CARG3)
2672     |   ldc1 f20, 0(CARG3)
2673     |    ldc1 f22, 0(CARG4)
2674     |   sltiu AT, TMP1, LJ_TISNUM
2675     ||  break;
2676     ||case 1:
2677     |   addu CARG4, BASE, RB
2678     |    addu CARG3, KBASE, RC
2679     |   lw TMP1, HI(CARG4)
2680     |   ldc1 f22, 0(CARG4)
2681     |    ldc1 f20, 0(CARG3)
2682     |   sltiu AT, TMP1, LJ_TISNUM
2683     ||  break;
2684     ||default:
2685     |   addu CARG3, BASE, RB
2686     |    addu CARG4, BASE, RC
2687     |   lw TMP1, HI(CARG3)
2688     |    lw TMP2, HI(CARG4)
2689     |   ldc1 f20, 0(CARG3)
2690     |    ldc1 f22, 0(CARG4)
2691     |   sltiu AT, TMP1, LJ_TISNUM
2692     |   sltiu TMP0, TMP2, LJ_TISNUM
2693     |   and AT, AT, TMP0
2694     ||  break;
2695     ||}
2696     |  beqz AT, ->vmeta_arith
2697     |.  addu RA, BASE, RA
2698     |.endmacro
2699     |
2700     |.macro fpmod, a, b, c
2701     |->BC_MODVN_Z:
2702     |  bal ->vm_floor                   // floor(b/c)
2703     |.  div.d FARG1, b, c
2704     |  mul.d a, FRET1, c
2705     |  sub.d a, b, a                    // b - floor(b/c)*c
2706     |.endmacro
2707     |
2708     |.macro ins_arith, ins
2709     |  ins_arithpre
2710     |.if "ins" == "fpmod_"
2711     |  b ->BC_MODVN_Z                   // Avoid 3 copies. It's slow anyway.
2712     |.  nop
2713     |.else
2714     |  ins f0, f20, f22
2715     |  ins_next1
2716     |  sdc1 f0, 0(RA)
2717     |  ins_next2
2718     |.endif
2719     |.endmacro
2720
2721   case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
2722     |  ins_arith add.d
2723     break;
2724   case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
2725     |  ins_arith sub.d
2726     break;
2727   case BC_MULVN: case BC_MULNV: case BC_MULVV:
2728     |  ins_arith mul.d
2729     break;
2730   case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
2731     |  ins_arith div.d
2732     break;
2733   case BC_MODVN:
2734     |  ins_arith fpmod
2735     break;
2736   case BC_MODNV: case BC_MODVV:
2737     |  ins_arith fpmod_
2738     break;
2739   case BC_POW:
2740     |  decode_RB8a RB, INS
2741     |  decode_RB8b RB
2742     |   decode_RDtoRC8 RC, RD
2743     |  addu CARG3, BASE, RB
2744     |   addu CARG4, BASE, RC
2745     |  lw TMP1, HI(CARG3)
2746     |   lw TMP2, HI(CARG4)
2747     |  ldc1 FARG1, 0(CARG3)
2748     |   ldc1 FARG2, 0(CARG4)
2749     |  sltiu AT, TMP1, LJ_TISNUM
2750     |  sltiu TMP0, TMP2, LJ_TISNUM
2751     |  and AT, AT, TMP0
2752     |  load_got pow
2753     |  beqz AT, ->vmeta_arith
2754     |.  addu RA, BASE, RA
2755     |  call_extern
2756     |.  nop
2757     |  ins_next1
2758     |  sdc1 FRET1, 0(RA)
2759     |  ins_next2
2760     break;
2761
2762   case BC_CAT:
2763     |  // RA = dst*8, RB = src_start*8, RC = src_end*8
2764     |  decode_RB8a RB, INS
2765     |  decode_RB8b RB
2766     |   decode_RDtoRC8 RC, RD
2767     |  subu CARG3, RC, RB
2768     |   sw BASE, L->base
2769     |  addu CARG2, BASE, RC
2770     |  move MULTRES, RB
2771     |->BC_CAT_Z:
2772     |  load_got lj_meta_cat
2773     |  srl CARG3, CARG3, 3
2774     |   sw PC, SAVE_PC
2775     |  call_intern lj_meta_cat          // (lua_State *L, TValue *top, int left)
2776     |.  move CARG1, L
2777     |  // Returns NULL (finished) or TValue * (metamethod).
2778     |  bnez CRET1, ->vmeta_binop
2779     |.  lw BASE, L->base
2780     |  addu RB, BASE, MULTRES
2781     |  ldc1 f0, 0(RB)
2782     |   addu RA, BASE, RA
2783     |  ins_next1
2784     |   sdc1 f0, 0(RA)                  // Copy result from RB to RA.
2785     |  ins_next2
2786     break;
2787
2788   /* -- Constant ops ------------------------------------------------------ */
2789
2790   case BC_KSTR:
2791     |  // RA = dst*8, RD = str_const*8 (~)
2792     |  srl TMP1, RD, 1
2793     |  subu TMP1, KBASE, TMP1
2794     |  ins_next1
2795     |  lw TMP0, -4(TMP1)                // KBASE-4-str_const*4
2796     |  addu RA, BASE, RA
2797     |   li TMP2, LJ_TSTR
2798     |  sw TMP0, LO(RA)
2799     |   sw TMP2, HI(RA)
2800     |  ins_next2
2801     break;
2802   case BC_KCDATA:
2803     |.if FFI
2804     |  // RA = dst*8, RD = cdata_const*8 (~)
2805     |  srl TMP1, RD, 1
2806     |  subu TMP1, KBASE, TMP1
2807     |  ins_next1
2808     |  lw TMP0, -4(TMP1)                // KBASE-4-cdata_const*4
2809     |  addu RA, BASE, RA
2810     |   li TMP2, LJ_TCDATA
2811     |  sw TMP0, LO(RA)
2812     |   sw TMP2, HI(RA)
2813     |  ins_next2
2814     |.endif
2815     break;
2816   case BC_KSHORT:
2817     |  // RA = dst*8, RD = int16_literal*8
2818     |  sra RD, INS, 16
2819     |  mtc1 RD, f0
2820     |  addu RA, BASE, RA
2821     |  cvt.d.w f0, f0
2822     |  ins_next1
2823     |  sdc1 f0, 0(RA)
2824     |  ins_next2
2825     break;
2826   case BC_KNUM:
2827     |  // RA = dst*8, RD = num_const*8
2828     |  addu RD, KBASE, RD
2829     |   addu RA, BASE, RA
2830     |  ldc1 f0, 0(RD)
2831     |  ins_next1
2832     |   sdc1 f0, 0(RA)
2833     |  ins_next2
2834     break;
2835   case BC_KPRI:
2836     |  // RA = dst*8, RD = primitive_type*8 (~)
2837     |  srl TMP1, RD, 3
2838     |   addu RA, BASE, RA
2839     |  not TMP0, TMP1
2840     |  ins_next1
2841     |   sw TMP0, HI(RA)
2842     |  ins_next2
2843     break;
2844   case BC_KNIL:
2845     |  // RA = base*8, RD = end*8
2846     |  addu RA, BASE, RA
2847     |  sw TISNIL, HI(RA)
2848     |   addiu RA, RA, 8
2849     |  addu RD, BASE, RD
2850     |1:
2851     |  sw TISNIL, HI(RA)
2852     |  slt AT, RA, RD
2853     |  bnez AT, <1
2854     |.  addiu RA, RA, 8
2855     |  ins_next_
2856     break;
2857
2858   /* -- Upvalue and function ops ------------------------------------------ */
2859
2860   case BC_UGET:
2861     |  // RA = dst*8, RD = uvnum*8
2862     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2863     |   srl RD, RD, 1
2864     |   addu RD, RD, LFUNC:RB
2865     |  lw UPVAL:RB, LFUNC:RD->uvptr
2866     |  ins_next1
2867     |  lw TMP1, UPVAL:RB->v
2868     |  ldc1 f0, 0(TMP1)
2869     |  addu RA, BASE, RA
2870     |  sdc1 f0, 0(RA)
2871     |  ins_next2
2872     break;
2873   case BC_USETV:
2874     |  // RA = uvnum*8, RD = src*8
2875     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2876     |    srl RA, RA, 1
2877     |   addu RD, BASE, RD
2878     |    addu RA, RA, LFUNC:RB
2879     |   ldc1 f0, 0(RD)
2880     |  lw UPVAL:RB, LFUNC:RA->uvptr
2881     |  lbu TMP3, UPVAL:RB->marked
2882     |   lw CARG2, UPVAL:RB->v
2883     |  andi TMP3, TMP3, LJ_GC_BLACK     // isblack(uv)
2884     |  lbu TMP0, UPVAL:RB->closed
2885     |   lw TMP2, HI(RD)
2886     |   sdc1 f0, 0(CARG2)
2887     |  li AT, LJ_GC_BLACK|1
2888     |  or TMP3, TMP3, TMP0
2889     |  beq TMP3, AT, >2                 // Upvalue is closed and black?
2890     |.  addiu TMP2, TMP2, -(LJ_TNUMX+1)
2891     |1:
2892     |  ins_next
2893     |
2894     |2:  // Check if new value is collectable.
2895     |  sltiu AT, TMP2, LJ_TISGCV - (LJ_TNUMX+1)
2896     |  beqz AT, <1                      // tvisgcv(v)
2897     |.  lw TMP1, LO(RD)
2898     |  lbu TMP3, GCOBJ:TMP1->gch.marked
2899     |  andi TMP3, TMP3, LJ_GC_WHITES    // iswhite(v)
2900     |  beqz TMP3, <1
2901     |.  load_got lj_gc_barrieruv
2902     |  // Crossed a write barrier. Move the barrier forward.
2903     |  call_intern lj_gc_barrieruv      // (global_State *g, TValue *tv)
2904     |.  addiu CARG1, DISPATCH, GG_DISP2G
2905     |  b <1
2906     |.  nop
2907     break;
2908   case BC_USETS:
2909     |  // RA = uvnum*8, RD = str_const*8 (~)
2910     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2911     |    srl RA, RA, 1
2912     |   srl TMP1, RD, 1
2913     |    addu RA, RA, LFUNC:RB
2914     |   subu TMP1, KBASE, TMP1
2915     |  lw UPVAL:RB, LFUNC:RA->uvptr
2916     |   lw STR:TMP1, -4(TMP1)           // KBASE-4-str_const*4
2917     |  lbu TMP2, UPVAL:RB->marked
2918     |   lw CARG2, UPVAL:RB->v
2919     |   lbu TMP3, STR:TMP1->marked
2920     |  andi AT, TMP2, LJ_GC_BLACK       // isblack(uv)
2921     |   lbu TMP2, UPVAL:RB->closed
2922     |   li TMP0, LJ_TSTR
2923     |   sw STR:TMP1, LO(CARG2)
2924     |  bnez AT, >2
2925     |.  sw TMP0, HI(CARG2)
2926     |1:
2927     |  ins_next
2928     |
2929     |2:  // Check if string is white and ensure upvalue is closed.
2930     |  beqz TMP2, <1
2931     |.  andi AT, TMP3, LJ_GC_WHITES     // iswhite(str)
2932     |  beqz AT, <1
2933     |.  load_got lj_gc_barrieruv
2934     |  // Crossed a write barrier. Move the barrier forward.
2935     |  call_intern lj_gc_barrieruv      // (global_State *g, TValue *tv)
2936     |.  addiu CARG1, DISPATCH, GG_DISP2G
2937     |  b <1
2938     |.  nop
2939     break;
2940   case BC_USETN:
2941     |  // RA = uvnum*8, RD = num_const*8
2942     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2943     |   srl RA, RA, 1
2944     |    addu RD, KBASE, RD
2945     |   addu RA, RA, LFUNC:RB
2946     |    ldc1 f0, 0(RD)
2947     |  lw UPVAL:RB, LFUNC:RA->uvptr
2948     |  ins_next1
2949     |  lw TMP1, UPVAL:RB->v
2950     |  sdc1 f0, 0(TMP1)
2951     |  ins_next2
2952     break;
2953   case BC_USETP:
2954     |  // RA = uvnum*8, RD = primitive_type*8 (~)
2955     |  lw LFUNC:RB, FRAME_FUNC(BASE)
2956     |   srl RA, RA, 1
2957     |    srl TMP0, RD, 3
2958     |   addu RA, RA, LFUNC:RB
2959     |    not TMP0, TMP0
2960     |  lw UPVAL:RB, LFUNC:RA->uvptr
2961     |  ins_next1
2962     |  lw TMP1, UPVAL:RB->v
2963     |  sw TMP0, HI(TMP1)
2964     |  ins_next2
2965     break;
2966
2967   case BC_UCLO:
2968     |  // RA = level*8, RD = target
2969     |  lw TMP2, L->openupval
2970     |  branch_RD                        // Do this first since RD is not saved.
2971     |  load_got lj_func_closeuv
2972     |   sw BASE, L->base
2973     |  beqz TMP2, >1
2974     |.  move CARG1, L
2975     |  call_intern lj_func_closeuv      // (lua_State *L, TValue *level)
2976     |.  addu CARG2, BASE, RA
2977     |  lw BASE, L->base
2978     |1:
2979     |  ins_next
2980     break;
2981
2982   case BC_FNEW:
2983     |  // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
2984     |  srl TMP1, RD, 1
2985     |  load_got lj_func_newL_gc
2986     |  subu TMP1, KBASE, TMP1
2987     |  lw CARG3, FRAME_FUNC(BASE)
2988     |  lw CARG2, -4(TMP1)               // KBASE-4-tab_const*4
2989     |   sw BASE, L->base
2990     |   sw PC, SAVE_PC
2991     |  // (lua_State *L, GCproto *pt, GCfuncL *parent)
2992     |  call_intern lj_func_newL_gc
2993     |.  move CARG1, L
2994     |  // Returns GCfuncL *.
2995     |  lw BASE, L->base
2996     |   li TMP0, LJ_TFUNC
2997     |  ins_next1
2998     |  addu RA, BASE, RA
2999     |  sw TMP0, HI(RA)
3000     |  sw LFUNC:CRET1, LO(RA)
3001     |  ins_next2
3002     break;
3003
3004   /* -- Table ops --------------------------------------------------------- */
3005
3006   case BC_TNEW:
3007   case BC_TDUP:
3008     |  // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
3009     |  lw TMP0, DISPATCH_GL(gc.total)(DISPATCH)
3010     |  lw TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
3011     |   sw BASE, L->base
3012     |   sw PC, SAVE_PC
3013     |  sltu AT, TMP0, TMP1
3014     |  beqz AT, >5
3015     |1:
3016     if (op == BC_TNEW) {
3017       |  load_got lj_tab_new
3018       |  srl CARG2, RD, 3
3019       |  andi CARG2, CARG2, 0x7ff
3020       |  li TMP0, 0x801
3021       |  addiu AT, CARG2, -0x7ff
3022       |   srl CARG3, RD, 14
3023       |  movz CARG2, TMP0, AT
3024       |  // (lua_State *L, int32_t asize, uint32_t hbits)
3025       |  call_intern lj_tab_new
3026       |.  move CARG1, L
3027       |  // Returns Table *.
3028     } else {
3029       |  load_got lj_tab_dup
3030       |  srl TMP1, RD, 1
3031       |  subu TMP1, KBASE, TMP1
3032       |  move CARG1, L
3033       |  call_intern lj_tab_dup         // (lua_State *L, Table *kt)
3034       |.  lw CARG2, -4(TMP1)            // KBASE-4-str_const*4
3035       |  // Returns Table *.
3036     }
3037     |  lw BASE, L->base
3038     |  ins_next1
3039     |  addu RA, BASE, RA
3040     |   li TMP0, LJ_TTAB
3041     |  sw TAB:CRET1, LO(RA)
3042     |   sw TMP0, HI(RA)
3043     |  ins_next2
3044     |5:
3045     |  load_got lj_gc_step_fixtop
3046     |  move MULTRES, RD
3047     |  call_intern lj_gc_step_fixtop    // (lua_State *L)
3048     |.  move CARG1, L
3049     |  b <1
3050     |.  move RD, MULTRES
3051     break;
3052
3053   case BC_GGET:
3054     |  // RA = dst*8, RD = str_const*8 (~)
3055   case BC_GSET:
3056     |  // RA = src*8, RD = str_const*8 (~)
3057     |  lw LFUNC:TMP2, FRAME_FUNC(BASE)
3058     |   srl TMP1, RD, 1
3059     |   subu TMP1, KBASE, TMP1
3060     |  lw TAB:RB, LFUNC:TMP2->env
3061     |  lw STR:RC, -4(TMP1)              // KBASE-4-str_const*4
3062     if (op == BC_GGET) {
3063       |  b ->BC_TGETS_Z
3064     } else {
3065       |  b ->BC_TSETS_Z
3066     }
3067     |.  addu RA, BASE, RA
3068     break;
3069
3070   case BC_TGETV:
3071     |  // RA = dst*8, RB = table*8, RC = key*8
3072     |  decode_RB8a RB, INS
3073     |  decode_RB8b RB
3074     |   decode_RDtoRC8 RC, RD
3075     |  addu CARG2, BASE, RB
3076     |   addu CARG3, BASE, RC
3077     |  lw TMP1, HI(CARG2)
3078     |   lw TMP2, HI(CARG3)
3079     |    lw TAB:RB, LO(CARG2)
3080     |  li AT, LJ_TTAB
3081     |   ldc1 f0, 0(CARG3)
3082     |  bne TMP1, AT, ->vmeta_tgetv
3083     |.  addu RA, BASE, RA
3084     |  sltiu AT, TMP2, LJ_TISNUM
3085     |  beqz AT, >5
3086     |.  li AT, LJ_TSTR
3087     |
3088     |  // Convert number key to integer, check for integerness and range.
3089     |  cvt.w.d f2, f0
3090     |   lw TMP0, TAB:RB->asize
3091     |  mfc1 TMP2, f2
3092     |  cvt.d.w f4, f2
3093     |   lw TMP1, TAB:RB->array
3094     |  c.eq.d f0, f4
3095     |  sltu AT, TMP2, TMP0
3096     |  movf AT, r0
3097     |   sll TMP2, TMP2, 3
3098     |  beqz AT, ->vmeta_tgetv           // Integer key and in array part?
3099     |.  addu TMP2, TMP1, TMP2
3100     |  lw TMP0, HI(TMP2)
3101     |  beq TMP0, TISNIL, >2
3102     |.  ldc1 f0, 0(TMP2)
3103     |1:
3104     |  ins_next1
3105     |   sdc1 f0, 0(RA)
3106     |  ins_next2
3107     |
3108     |2:  // Check for __index if table value is nil.
3109     |  lw TAB:TMP2, TAB:RB->metatable
3110     |  beqz TAB:TMP2, <1                // No metatable: done.
3111     |.  nop
3112     |  lbu TMP0, TAB:TMP2->nomm
3113     |  andi TMP0, TMP0, 1<<MM_index
3114     |  bnez TMP0, <1                    // 'no __index' flag set: done.
3115     |.  nop
3116     |  b ->vmeta_tgetv
3117     |.  nop
3118     |
3119     |5:
3120     |  bne TMP2, AT, ->vmeta_tgetv
3121     |.  lw STR:RC, LO(CARG3)
3122     |  b ->BC_TGETS_Z                   // String key?
3123     |.  nop
3124     break;
3125   case BC_TGETS:
3126     |  // RA = dst*8, RB = table*8, RC = str_const*4 (~)
3127     |  decode_RB8a RB, INS
3128     |  decode_RB8b RB
3129     |  addu CARG2, BASE, RB
3130     |   decode_RC4a RC, INS
3131     |  lw TMP0, HI(CARG2)
3132     |   decode_RC4b RC
3133     |  li AT, LJ_TTAB
3134     |   lw TAB:RB, LO(CARG2)
3135     |   subu CARG3, KBASE, RC
3136     |   lw STR:RC, -4(CARG3)            // KBASE-4-str_const*4
3137     |  bne TMP0, AT, ->vmeta_tgets1
3138     |.  addu RA, BASE, RA
3139     |->BC_TGETS_Z:
3140     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
3141     |  lw TMP0, TAB:RB->hmask
3142     |  lw TMP1, STR:RC->hash
3143     |  lw NODE:TMP2, TAB:RB->node
3144     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3145     |  sll TMP0, TMP1, 5
3146     |  sll TMP1, TMP1, 3
3147     |  subu TMP1, TMP0, TMP1
3148     |  addu NODE:TMP2, NODE:TMP2, TMP1  // node = tab->node + (idx*32-idx*8)
3149     |1:
3150     |  lw CARG1, offsetof(Node, key)+HI(NODE:TMP2)
3151     |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
3152     |    lw NODE:TMP1, NODE:TMP2->next
3153     |    lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
3154     |  addiu CARG1, CARG1, -LJ_TSTR
3155     |   xor TMP0, TMP0, STR:RC
3156     |  or AT, CARG1, TMP0
3157     |  bnez AT, >4
3158     |.  lw TAB:TMP3, TAB:RB->metatable
3159     |    beq CARG2, TISNIL, >5          // Key found, but nil value?
3160     |.    lw CARG1, offsetof(Node, val)+LO(NODE:TMP2)
3161     |3:
3162     |  ins_next1
3163     |    sw CARG2, HI(RA)
3164     |     sw CARG1, LO(RA)
3165     |  ins_next2
3166     |
3167     |4:  // Follow hash chain.
3168     |  bnez NODE:TMP1, <1
3169     |.  move NODE:TMP2, NODE:TMP1
3170     |  // End of hash chain: key not found, nil result.
3171     |
3172     |5:  // Check for __index if table value is nil.
3173     |  beqz TAB:TMP3, <3                // No metatable: done.
3174     |.  li CARG2, LJ_TNIL
3175     |  lbu TMP0, TAB:TMP3->nomm
3176     |  andi TMP0, TMP0, 1<<MM_index
3177     |  bnez TMP0, <3                    // 'no __index' flag set: done.
3178     |.  nop
3179     |  b ->vmeta_tgets
3180     |.  nop
3181     break;
3182   case BC_TGETB:
3183     |  // RA = dst*8, RB = table*8, RC = index*8
3184     |  decode_RB8a RB, INS
3185     |  decode_RB8b RB
3186     |  addu CARG2, BASE, RB
3187     |   decode_RDtoRC8 RC, RD
3188     |  lw CARG1, HI(CARG2)
3189     |  li AT, LJ_TTAB
3190     |   lw TAB:RB, LO(CARG2)
3191     |   addu RA, BASE, RA
3192     |  bne CARG1, AT, ->vmeta_tgetb
3193     |.  srl TMP0, RC, 3
3194     |  lw TMP1, TAB:RB->asize
3195     |   lw TMP2, TAB:RB->array
3196     |  sltu AT, TMP0, TMP1
3197     |  beqz AT, ->vmeta_tgetb
3198     |.  addu RC, TMP2, RC
3199     |  lw TMP1, HI(RC)
3200     |  beq TMP1, TISNIL, >5
3201     |.  ldc1 f0, 0(RC)
3202     |1:
3203     |  ins_next1
3204     |   sdc1 f0, 0(RA)
3205     |  ins_next2
3206     |
3207     |5:  // Check for __index if table value is nil.
3208     |  lw TAB:TMP2, TAB:RB->metatable
3209     |  beqz TAB:TMP2, <1                // No metatable: done.
3210     |.  nop
3211     |  lbu TMP1, TAB:TMP2->nomm
3212     |  andi TMP1, TMP1, 1<<MM_index
3213     |  bnez TMP1, <1                    // 'no __index' flag set: done.
3214     |.  nop
3215     |  b ->vmeta_tgetb                  // Caveat: preserve TMP0!
3216     |.  nop
3217     break;
3218
3219   case BC_TSETV:
3220     |  // RA = src*8, RB = table*8, RC = key*8
3221     |  decode_RB8a RB, INS
3222     |  decode_RB8b RB
3223     |   decode_RDtoRC8 RC, RD
3224     |  addu CARG2, BASE, RB
3225     |   addu CARG3, BASE, RC
3226     |  lw TMP1, HI(CARG2)
3227     |   lw TMP2, HI(CARG3)
3228     |    lw TAB:RB, LO(CARG2)
3229     |  li AT, LJ_TTAB
3230     |   ldc1 f0, 0(CARG3)
3231     |  bne TMP1, AT, ->vmeta_tsetv
3232     |.  addu RA, BASE, RA
3233     |  sltiu AT, TMP2, LJ_TISNUM
3234     |  beqz AT, >5
3235     |.  li AT, LJ_TSTR
3236     |
3237     |  // Convert number key to integer, check for integerness and range.
3238     |  cvt.w.d f2, f0
3239     |   lw TMP0, TAB:RB->asize
3240     |  mfc1 TMP2, f2
3241     |  cvt.d.w f4, f2
3242     |   lw TMP1, TAB:RB->array
3243     |  c.eq.d f0, f4
3244     |  sltu AT, TMP2, TMP0
3245     |  movf AT, r0
3246     |   sll TMP2, TMP2, 3
3247     |  beqz AT, ->vmeta_tsetv           // Integer key and in array part?
3248     |.  addu TMP1, TMP1, TMP2
3249     |   lbu TMP3, TAB:RB->marked
3250     |  lw TMP0, HI(TMP1)
3251     |  beq TMP0, TISNIL, >3
3252     |.  ldc1 f0, 0(RA)
3253     |1:
3254     |   andi AT, TMP3, LJ_GC_BLACK      // isblack(table)
3255     |   bnez AT, >7
3256     |.  sdc1 f0, 0(TMP1)
3257     |2:
3258     |  ins_next
3259     |
3260     |3:  // Check for __newindex if previous value is nil.
3261     |  lw TAB:TMP2, TAB:RB->metatable
3262     |  beqz TAB:TMP2, <1                // No metatable: done.
3263     |.  nop
3264     |  lbu TMP2, TAB:TMP2->nomm
3265     |  andi TMP2, TMP2, 1<<MM_newindex
3266     |  bnez TMP2, <1                    // 'no __newindex' flag set: done.
3267     |.  nop
3268     |  b ->vmeta_tsetv
3269     |.  nop
3270     |
3271     |5:
3272     |  bne TMP2, AT, ->vmeta_tsetv
3273     |.  lw STR:RC, LO(CARG3)
3274     |  b ->BC_TSETS_Z                   // String key?
3275     |.  nop
3276     |
3277     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3278     |  barrierback TAB:RB, TMP3, TMP0, <2
3279     break;
3280   case BC_TSETS:
3281     |  // RA = src*8, RB = table*8, RC = str_const*8 (~)
3282     |  decode_RB8a RB, INS
3283     |  decode_RB8b RB
3284     |  addu CARG2, BASE, RB
3285     |   decode_RC4a RC, INS
3286     |  lw TMP0, HI(CARG2)
3287     |   decode_RC4b RC
3288     |  li AT, LJ_TTAB
3289     |   subu CARG3, KBASE, RC
3290     |    lw TAB:RB, LO(CARG2)
3291     |   lw STR:RC, -4(CARG3)            // KBASE-4-str_const*4
3292     |  bne TMP0, AT, ->vmeta_tsets1
3293     |.  addu RA, BASE, RA
3294     |->BC_TSETS_Z:
3295     |  // TAB:RB = GCtab *, STR:RC = GCstr *, RA = BASE+src*8
3296     |  lw TMP0, TAB:RB->hmask
3297     |  lw TMP1, STR:RC->hash
3298     |  lw NODE:TMP2, TAB:RB->node
3299     |   sb r0, TAB:RB->nomm             // Clear metamethod cache.
3300     |  and TMP1, TMP1, TMP0             // idx = str->hash & tab->hmask
3301     |  sll TMP0, TMP1, 5
3302     |  sll TMP1, TMP1, 3
3303     |  subu TMP1, TMP0, TMP1
3304     |  addu NODE:TMP2, NODE:TMP2, TMP1  // node = tab->node + (idx*32-idx*8)
3305     |   ldc1 f20, 0(RA)
3306     |1:
3307     |  lw CARG1, offsetof(Node, key)+HI(NODE:TMP2)
3308     |   lw TMP0, offsetof(Node, key)+LO(NODE:TMP2)
3309     |  li AT, LJ_TSTR
3310     |    lw NODE:TMP1, NODE:TMP2->next
3311     |  bne CARG1, AT, >5
3312     |.   lw CARG2, offsetof(Node, val)+HI(NODE:TMP2)
3313     |   bne TMP0, STR:RC, >5
3314     |.    lbu TMP3, TAB:RB->marked
3315     |    beq CARG2, TISNIL, >4          // Key found, but nil value?
3316     |.    lw TAB:TMP0, TAB:RB->metatable
3317     |2:
3318     |  andi AT, TMP3, LJ_GC_BLACK       // isblack(table)
3319     |  bnez AT, >7
3320     |.  sdc1 f20, NODE:TMP2->val
3321     |3:
3322     |  ins_next
3323     |
3324     |4:  // Check for __newindex if previous value is nil.
3325     |  beqz TAB:TMP0, <2                // No metatable: done.
3326     |.  nop
3327     |  lbu TMP0, TAB:TMP0->nomm
3328     |  andi TMP0, TMP0, 1<<MM_newindex
3329     |  bnez TMP0, <2                    // 'no __newindex' flag set: done.
3330     |.  nop
3331     |  b ->vmeta_tsets
3332     |.  nop
3333     |
3334     |5:  // Follow hash chain.
3335     |  bnez NODE:TMP1, <1
3336     |.  move NODE:TMP2, NODE:TMP1
3337     |  // End of hash chain: key not found, add a new one
3338     |
3339     |  // But check for __newindex first.
3340     |  lw TAB:TMP2, TAB:RB->metatable
3341     |  beqz TAB:TMP2, >6                // No metatable: continue.
3342     |.  addiu CARG3, DISPATCH, DISPATCH_GL(tmptv)
3343     |  lbu TMP0, TAB:TMP2->nomm
3344     |  andi TMP0, TMP0, 1<<MM_newindex
3345     |  beqz TMP0, ->vmeta_tsets         // 'no __newindex' flag NOT set: check.
3346     |.  li AT, LJ_TSTR
3347     |6:
3348     |  load_got lj_tab_newkey
3349     |  sw STR:RC, LO(CARG3)
3350     |  sw AT, HI(CARG3)
3351     |   sw BASE, L->base
3352     |  move CARG2, TAB:RB
3353     |   sw PC, SAVE_PC
3354     |  call_intern lj_tab_newkey        // (lua_State *L, GCtab *t, TValue *k
3355     |.  move CARG1, L
3356     |  // Returns TValue *.
3357     |  lw BASE, L->base
3358     |  b <3                             // No 2nd write barrier needed.
3359     |.  sdc1 f20, 0(CRET1)
3360     |
3361     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3362     |  barrierback TAB:RB, TMP3, TMP0, <3
3363     break;
3364   case BC_TSETB:
3365     |  // RA = src*8, RB = table*8, RC = index*8
3366     |  decode_RB8a RB, INS
3367     |  decode_RB8b RB
3368     |  addu CARG2, BASE, RB
3369     |   decode_RDtoRC8 RC, RD
3370     |  lw CARG1, HI(CARG2)
3371     |  li AT, LJ_TTAB
3372     |   lw TAB:RB, LO(CARG2)
3373     |   addu RA, BASE, RA
3374     |  bne CARG1, AT, ->vmeta_tsetb
3375     |.  srl TMP0, RC, 3
3376     |  lw TMP1, TAB:RB->asize
3377     |   lw TMP2, TAB:RB->array
3378     |  sltu AT, TMP0, TMP1
3379     |  beqz AT, ->vmeta_tsetb
3380     |.  addu RC, TMP2, RC
3381     |  lw TMP1, HI(RC)
3382     |   lbu TMP3, TAB:RB->marked
3383     |  beq TMP1, TISNIL, >5
3384     |.  ldc1 f0, 0(RA)
3385     |1:
3386     |  andi AT, TMP3, LJ_GC_BLACK       // isblack(table)
3387     |  bnez AT, >7
3388     |.  sdc1 f0, 0(RC)
3389     |2:
3390     |  ins_next
3391     |
3392     |5:  // Check for __newindex if previous value is nil.
3393     |  lw TAB:TMP2, TAB:RB->metatable
3394     |  beqz TAB:TMP2, <1                // No metatable: done.
3395     |.  nop
3396     |  lbu TMP1, TAB:TMP2->nomm
3397     |  andi TMP1, TMP1, 1<<MM_newindex
3398     |  bnez TMP1, <1                    // 'no __newindex' flag set: done.
3399     |.  nop
3400     |  b ->vmeta_tsetb                  // Caveat: preserve TMP0!
3401     |.  nop
3402     |
3403     |7:  // Possible table write barrier for the value. Skip valiswhite check.
3404     |  barrierback TAB:RB, TMP3, TMP0, <2
3405     break;
3406
3407   case BC_TSETM:
3408     |  // RA = base*8 (table at base-1), RD = num_const*8 (start index)
3409     |  addu RA, BASE, RA
3410     |1:
3411     |   addu TMP3, KBASE, RD
3412     |  lw TAB:CARG2, -8+LO(RA)          // Guaranteed to be a table.
3413     |    addiu TMP0, MULTRES, -8
3414     |   lw TMP3, LO(TMP3)               // Integer constant is in lo-word.
3415     |    beqz TMP0, >4                  // Nothing to copy?
3416     |.    srl CARG3, TMP0, 3
3417     |  addu CARG3, CARG3, TMP3
3418     |  lw TMP2, TAB:CARG2->asize
3419     |   sll TMP1, TMP3, 3
3420     |    lbu TMP3, TAB:CARG2->marked
3421     |   lw CARG1, TAB:CARG2->array
3422     |  sltu AT, TMP2, CARG3
3423     |  bnez AT, >5
3424     |.  addu TMP2, RA, TMP0
3425     |   addu TMP1, TMP1, CARG1
3426     |  andi TMP0, TMP3, LJ_GC_BLACK     // isblack(table)
3427     |3:  // Copy result slots to table.
3428     |   ldc1 f0, 0(RA)
3429     |    addiu RA, RA, 8
3430     |  sltu AT, RA, TMP2
3431     |   sdc1 f0, 0(TMP1)
3432     |  bnez AT, <3
3433     |.   addiu TMP1, TMP1, 8
3434     |  bnez TMP0, >7
3435     |. nop
3436     |4:
3437     |  ins_next
3438     |
3439     |5:  // Need to resize array part.
3440     |  load_got lj_tab_reasize
3441     |   sw BASE, L->base
3442     |   sw PC, SAVE_PC
3443     |  move BASE, RD
3444     |  call_intern lj_tab_reasize       // (lua_State *L, GCtab *t, int nasize)
3445     |.  move CARG1, L
3446     |  // Must not reallocate the stack.
3447     |  move RD, BASE
3448     |  b <1
3449     |.  lw BASE, L->base        // Reload BASE for lack of a saved register.
3450     |
3451     |7:  // Possible table write barrier for any value. Skip valiswhite check.
3452     |  barrierback TAB:CARG2, TMP3, TMP0, <4
3453     break;
3454
3455   /* -- Calls and vararg handling ----------------------------------------- */
3456
3457   case BC_CALLM:
3458     |  // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
3459     |  decode_RDtoRC8 NARGS8:RC, RD
3460     |  b ->BC_CALL_Z
3461     |.  addu NARGS8:RC, NARGS8:RC, MULTRES
3462     break;
3463   case BC_CALL:
3464     |  // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
3465     |  decode_RDtoRC8 NARGS8:RC, RD
3466     |->BC_CALL_Z:
3467     |  move TMP2, BASE
3468     |  addu BASE, BASE, RA
3469     |   li AT, LJ_TFUNC
3470     |  lw TMP0, HI(BASE)
3471     |   lw LFUNC:RB, LO(BASE)
3472     |   addiu BASE, BASE, 8
3473     |  bne TMP0, AT, ->vmeta_call
3474     |.  addiu NARGS8:RC, NARGS8:RC, -8
3475     |  ins_call
3476     break;
3477
3478   case BC_CALLMT:
3479     |  // RA = base*8, (RB = 0,) RC = extra_nargs*8
3480     |  addu NARGS8:RD, NARGS8:RD, MULTRES       // BC_CALLT gets RC from RD.
3481     |  // Fall through. Assumes BC_CALLT follows.
3482     break;
3483   case BC_CALLT:
3484     |  // RA = base*8, (RB = 0,) RC = (nargs+1)*8
3485     |  addu RA, BASE, RA
3486     |   li AT, LJ_TFUNC
3487     |  lw TMP0, HI(RA)
3488     |   lw LFUNC:RB, LO(RA)
3489     |   move NARGS8:RC, RD
3490     |    lw TMP1, FRAME_PC(BASE)
3491     |   addiu RA, RA, 8
3492     |  bne TMP0, AT, ->vmeta_callt
3493     |.  addiu NARGS8:RC, NARGS8:RC, -8
3494     |->BC_CALLT_Z:
3495     |  andi TMP0, TMP1, FRAME_TYPE      // Caveat: preserve TMP0 until the 'or'.
3496     |   lbu TMP3, LFUNC:RB->ffid
3497     |  bnez TMP0, >7
3498     |.  xori TMP2, TMP1, FRAME_VARG
3499     |1:
3500     |  sw LFUNC:RB, FRAME_FUNC(BASE)    // Copy function down, but keep PC.
3501     |  sltiu AT, TMP3, 2                // (> FF_C) Calling a fast function?
3502     |  move TMP2, BASE
3503     |  beqz NARGS8:RC, >3
3504     |.  move TMP3, NARGS8:RC
3505     |2:
3506     |   ldc1 f0, 0(RA)
3507     |    addiu RA, RA, 8
3508     |  addiu TMP3, TMP3, -8
3509     |   sdc1 f0, 0(TMP2)
3510     |  bnez TMP3, <2
3511     |.   addiu TMP2, TMP2, 8
3512     |3:
3513     |  or TMP0, TMP0, AT
3514     |  beqz TMP0, >5
3515     |.  nop
3516     |4:
3517     |  ins_callt
3518     |
3519     |5:  // Tailcall to a fast function with a Lua frame below.
3520     |  lw INS, -4(TMP1)
3521     |  decode_RA8a RA, INS
3522     |  decode_RA8b RA
3523     |  subu TMP1, BASE, RA
3524     |  lw LFUNC:TMP1, -8+FRAME_FUNC(TMP1)
3525     |  lw TMP1, LFUNC:TMP1->pc
3526     |  b <4
3527     |.  lw KBASE, PC2PROTO(k)(TMP1)     // Need to prepare KBASE.
3528     |
3529     |7:  // Tailcall from a vararg function.
3530     |  andi AT, TMP2, FRAME_TYPEP
3531     |  bnez AT, <1                      // Vararg frame below?
3532     |.  subu TMP2, BASE, TMP2           // Relocate BASE down.
3533     |  move BASE, TMP2
3534     |  lw TMP1, FRAME_PC(TMP2)
3535     |  b <1
3536     |.  andi TMP0, TMP1, FRAME_TYPE
3537     break;
3538
3539   case BC_ITERC:
3540     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
3541     |  move TMP2, BASE
3542     |  addu BASE, BASE, RA
3543     |   li AT, LJ_TFUNC
3544     |  lw TMP1, -24+HI(BASE)
3545     |   lw LFUNC:RB, -24+LO(BASE)
3546     |    ldc1 f2, -8(BASE)
3547     |    ldc1 f0, -16(BASE)
3548     |  sw TMP1, HI(BASE)                // Copy callable.
3549     |   sw LFUNC:RB, LO(BASE)
3550     |    sdc1 f2, 16(BASE)              // Copy control var.
3551     |    sdc1 f0, 8(BASE)               // Copy state.
3552     |   addiu BASE, BASE, 8
3553     |  bne TMP1, AT, ->vmeta_call
3554     |.  li NARGS8:RC, 16                // Iterators get 2 arguments.
3555     |  ins_call
3556     break;
3557
3558   case BC_ITERN:
3559     |  // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
3560     |.if JIT
3561     |  // NYI: add hotloop, record BC_ITERN.
3562     |.endif
3563     |  addu RA, BASE, RA
3564     |  lw TAB:RB, -16+LO(RA)
3565     |  lw RC, -8+LO(RA)                 // Get index from control var.
3566     |  lw TMP0, TAB:RB->asize
3567     |  lw TMP1, TAB:RB->array
3568     |   addiu PC, PC, 4
3569     |1:  // Traverse array part.
3570     |  sltu AT, RC, TMP0
3571     |  beqz AT, >5                      // Index points after array part?
3572     |.  sll TMP3, RC, 3
3573     |  addu TMP3, TMP1, TMP3
3574     |  lw TMP2, HI(TMP3)
3575     |   ldc1 f0, 0(TMP3)
3576     |    mtc1 RC, f2
3577     |     lhu RD, -4+OFS_RD(PC)
3578     |  beq TMP2, TISNIL, <1             // Skip holes in array part.
3579     |.  addiu RC, RC, 1
3580     |    cvt.d.w f2, f2
3581     |     lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
3582     |   sdc1 f0, 8(RA)
3583     |     decode_RD4b RD
3584     |     addu RD, RD, TMP3
3585     |   sw RC, -8+LO(RA)                // Update control var.
3586     |     addu PC, PC, RD
3587     |    sdc1 f2, 0(RA)
3588     |3:
3589     |  ins_next
3590     |
3591     |5:  // Traverse hash part.
3592     |  lw TMP1, TAB:RB->hmask
3593     |  subu RC, RC, TMP0
3594     |   lw TMP2, TAB:RB->node
3595     |6:
3596     |  sltu AT, TMP1, RC                // End of iteration? Branch to ITERL+1.
3597     |  bnez AT, <3
3598     |.  sll TMP3, RC, 5
3599     |   sll RB, RC, 3
3600     |   subu TMP3, TMP3, RB
3601     |  addu NODE:TMP3, TMP3, TMP2
3602     |  lw RB, HI(NODE:TMP3)
3603     |  ldc1 f0, 0(NODE:TMP3)
3604     |     lhu RD, -4+OFS_RD(PC)
3605     |  beq RB, TISNIL, <6               // Skip holes in hash part.
3606     |.  addiu RC, RC, 1
3607     |   ldc1 f2, NODE:TMP3->key
3608     |     lui TMP3, (-(BCBIAS_J*4 >> 16) & 65535)
3609     |  sdc1 f0, 8(RA)
3610     |    addu RC, RC, TMP0
3611     |     decode_RD4b RD
3612     |     addu RD, RD, TMP3
3613     |   sdc1 f2, 0(RA)
3614     |     addu PC, PC, RD
3615     |  b <3
3616     |.  sw RC, -8+LO(RA)                // Update control var.
3617     break;
3618
3619   case BC_ISNEXT:
3620     |  // RA = base*8, RD = target (points to ITERN)
3621     |  addu RA, BASE, RA
3622     |    srl TMP0, RD, 1
3623     |  lw CARG1, -24+HI(RA)
3624     |  lw CFUNC:CARG2, -24+LO(RA)
3625     |    addu TMP0, PC, TMP0
3626     |   lw CARG3, -16+HI(RA)
3627     |   lw CARG4, -8+HI(RA)
3628     |  li AT, LJ_TFUNC
3629     |  bne CARG1, AT, >5
3630     |.   lui TMP2, (-(BCBIAS_J*4 >> 16) & 65535)
3631     |  lbu CARG2, CFUNC:CARG2->ffid
3632     |   addiu CARG3, CARG3, -LJ_TTAB
3633     |   addiu CARG4, CARG4, -LJ_TNIL
3634     |   or CARG3, CARG3, CARG4
3635     |  addiu CARG2, CARG2, -FF_next_N
3636     |  or CARG2, CARG2, CARG3
3637     |  bnez CARG2, >5
3638     |.  lui TMP1, 0xfffe
3639     |  addu PC, TMP0, TMP2
3640     |  ori TMP1, TMP1, 0x7fff
3641     |  sw r0, -8+LO(RA)                 // Initialize control var.
3642     |  sw TMP1, -8+HI(RA)
3643     |1:
3644     |  ins_next
3645     |5:  // Despecialize bytecode if any of the checks fail.
3646     |  li TMP3, BC_JMP
3647     |   li TMP1, BC_ITERC
3648     |  sb TMP3, -4+OFS_OP(PC)
3649     |    addu PC, TMP0, TMP2
3650     |  b <1
3651     |.  sb TMP1, OFS_OP(PC)
3652     break;
3653
3654   case BC_VARG:
3655     |  // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
3656     |  lw TMP0, FRAME_PC(BASE)
3657     |  decode_RDtoRC8 RC, RD
3658     |   decode_RB8a RB, INS
3659     |  addu RC, BASE, RC
3660     |   decode_RB8b RB
3661     |   addu RA, BASE, RA
3662     |  addiu RC, RC, FRAME_VARG
3663     |   addu TMP2, RA, RB
3664     |  addiu TMP3, BASE, -8             // TMP3 = vtop
3665     |  subu RC, RC, TMP0                // RC = vbase
3666     |  // Note: RC may now be even _above_ BASE if nargs was < numparams.
3667     |  beqz RB, >5                      // Copy all varargs?
3668     |.  subu TMP1, TMP3, RC
3669     |  addiu TMP2, TMP2, -16
3670     |1:  // Copy vararg slots to destination slots.
3671     |  lw CARG1, HI(RC)
3672     |  sltu AT, RC, TMP3
3673     |   lw CARG2, LO(RC)
3674     |    addiu RC, RC, 8
3675     |  movz CARG1, TISNIL, AT
3676     |  sw CARG1, HI(RA)
3677     |   sw CARG2, LO(RA)
3678     |  sltu AT, RA, TMP2
3679     |  bnez AT, <1
3680     |.   addiu RA, RA, 8
3681     |3:
3682     |  ins_next
3683     |
3684     |5:  // Copy all varargs.
3685     |  lw TMP0, L->maxstack
3686     |  blez TMP1, <3                    // No vararg slots?
3687     |.  li MULTRES, 8                   // MULTRES = (0+1)*8
3688     |  addu TMP2, RA, TMP1
3689     |  sltu AT, TMP0, TMP2
3690     |  bnez AT, >7
3691     |.  addiu MULTRES, TMP1, 8
3692     |6:
3693     |  ldc1 f0, 0(RC)
3694     |   addiu RC, RC, 8
3695     |  sdc1 f0, 0(RA)
3696     |  sltu AT, RC, TMP3
3697     |  bnez AT, <6                      // More vararg slots?
3698     |.  addiu RA, RA, 8
3699     |  b <3
3700     |.  nop
3701     |
3702     |7:  // Grow stack for varargs.
3703     |  load_got lj_state_growstack
3704     |   sw RA, L->top
3705     |  subu RA, RA, BASE
3706     |   sw BASE, L->base
3707     |  subu BASE, RC, BASE              // Need delta, because BASE may change.
3708     |   sw PC, SAVE_PC
3709     |  srl CARG2, TMP1, 3
3710     |  call_intern lj_state_growstack   // (lua_State *L, int n)
3711     |.  move CARG1, L
3712     |  move RC, BASE
3713     |  lw BASE, L->base
3714     |  addu RA, BASE, RA
3715     |  addu RC, BASE, RC
3716     |  b <6
3717     |.  addiu TMP3, BASE, -8
3718     break;
3719
3720   /* -- Returns ----------------------------------------------------------- */
3721
3722   case BC_RETM:
3723     |  // RA = results*8, RD = extra_nresults*8
3724     |  addu RD, RD, MULTRES             // MULTRES >= 8, so RD >= 8.
3725     |  // Fall through. Assumes BC_RET follows.
3726     break;
3727
3728   case BC_RET:
3729     |  // RA = results*8, RD = (nresults+1)*8
3730     |  lw PC, FRAME_PC(BASE)
3731     |   addu RA, BASE, RA
3732     |    move MULTRES, RD
3733     |1:
3734     |  andi TMP0, PC, FRAME_TYPE
3735     |  bnez TMP0, ->BC_RETV_Z
3736     |.  xori TMP1, PC, FRAME_VARG
3737     |
3738     |->BC_RET_Z:
3739     |  // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
3740     |   lw INS, -4(PC)
3741     |    addiu TMP2, BASE, -8
3742     |    addiu RC, RD, -8
3743     |  decode_RA8a TMP0, INS
3744     |   decode_RB8a RB, INS
3745     |  decode_RA8b TMP0
3746     |   decode_RB8b RB
3747     |   addu TMP3, TMP2, RB
3748     |  beqz RC, >3
3749     |.  subu BASE, TMP2, TMP0
3750     |2:
3751     |   ldc1 f0, 0(RA)
3752     |    addiu RA, RA, 8
3753     |  addiu RC, RC, -8
3754     |   sdc1 f0, 0(TMP2)
3755     |  bnez RC, <2
3756     |.   addiu TMP2, TMP2, 8
3757     |3:
3758     |  addiu TMP3, TMP3, -8
3759     |5:
3760     |  sltu AT, TMP2, TMP3
3761     |  bnez AT, >6
3762     |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
3763     |  ins_next1
3764     |  lw TMP1, LFUNC:TMP1->pc
3765     |  lw KBASE, PC2PROTO(k)(TMP1)
3766     |  ins_next2
3767     |
3768     |6:  // Fill up results with nil.
3769     |  sw TISNIL, HI(TMP2)
3770     |  b <5
3771     |.  addiu TMP2, TMP2, 8
3772     |
3773     |->BC_RETV_Z:  // Non-standard return case.
3774     |  andi TMP2, TMP1, FRAME_TYPEP
3775     |  bnez TMP2, ->vm_return
3776     |.  nop
3777     |  // Return from vararg function: relocate BASE down.
3778     |  subu BASE, BASE, TMP1
3779     |  b <1
3780     |.  lw PC, FRAME_PC(BASE)
3781     break;
3782
3783   case BC_RET0: case BC_RET1:
3784     |  // RA = results*8, RD = (nresults+1)*8
3785     |  lw PC, FRAME_PC(BASE)
3786     |   addu RA, BASE, RA
3787     |    move MULTRES, RD
3788     |  andi TMP0, PC, FRAME_TYPE
3789     |  bnez TMP0, ->BC_RETV_Z
3790     |.  xori TMP1, PC, FRAME_VARG
3791     |
3792     |  lw INS, -4(PC)
3793     |   addiu TMP2, BASE, -8
3794     if (op == BC_RET1) {
3795       |  ldc1 f0, 0(RA)
3796     }
3797     |  decode_RB8a RB, INS
3798     |   decode_RA8a RA, INS
3799     |  decode_RB8b RB
3800     |   decode_RA8b RA
3801     if (op == BC_RET1) {
3802       |  sdc1 f0, 0(TMP2)
3803     }
3804     |   subu BASE, TMP2, RA
3805     |5:
3806     |  sltu AT, RD, RB
3807     |  bnez AT, >6
3808     |.  lw LFUNC:TMP1, FRAME_FUNC(BASE)
3809     |  ins_next1
3810     |  lw TMP1, LFUNC:TMP1->pc
3811     |  lw KBASE, PC2PROTO(k)(TMP1)
3812     |  ins_next2
3813     |
3814     |6:  // Fill up results with nil.
3815     |  addiu TMP2, TMP2, 8
3816     |  addiu RD, RD, 8
3817     |  b <5
3818     if (op == BC_RET1) {
3819       |.  sw TISNIL, HI(TMP2)
3820     } else {
3821       |.  sw TISNIL, -8+HI(TMP2)
3822     }
3823     break;
3824
3825   /* -- Loops and branches ------------------------------------------------ */
3826
3827   case BC_FORL:
3828     |.if JIT
3829     |  hotloop
3830     |.endif
3831     |  // Fall through. Assumes BC_IFORL follows.
3832     break;
3833
3834   case BC_JFORI:
3835   case BC_JFORL:
3836 #if !LJ_HASJIT
3837     break;
3838 #endif
3839   case BC_FORI:
3840   case BC_IFORL:
3841     |  // RA = base*8, RD = target (after end of loop or start of loop)
3842     vk = (op == BC_IFORL || op == BC_JFORL);
3843     |  addu RA, BASE, RA
3844     if (vk) {
3845       |  ldc1 f0, FORL_IDX*8(RA)
3846       |  ldc1 f4, FORL_STEP*8(RA)
3847       |  ldc1 f2, FORL_STOP*8(RA)
3848       |   lw TMP3, FORL_STEP*8+HI(RA)
3849       |  add.d f0, f0, f4
3850       |  sdc1 f0, FORL_IDX*8(RA)
3851     } else {
3852       |  lw TMP1, FORL_IDX*8+HI(RA)
3853       |  lw TMP3, FORL_STEP*8+HI(RA)
3854       |  lw TMP2, FORL_STOP*8+HI(RA)
3855       |  sltiu TMP1, TMP1, LJ_TISNUM
3856       |  sltiu TMP0, TMP3, LJ_TISNUM
3857       |  sltiu TMP2, TMP2, LJ_TISNUM
3858       |  and TMP1, TMP1, TMP0
3859       |  and TMP1, TMP1, TMP2
3860       |   ldc1 f0, FORL_IDX*8(RA)
3861       |  beqz TMP1, ->vmeta_for
3862       |.  ldc1 f2, FORL_STOP*8(RA)
3863     }
3864     if (op != BC_JFORL) {
3865       |  srl RD, RD, 1
3866       |  lui TMP0, (-(BCBIAS_J*4 >> 16) & 65535)
3867     }
3868     |  c.le.d 0, f0, f2
3869     |  c.le.d 1, f2, f0
3870     |  sdc1 f0, FORL_EXT*8(RA)
3871     if (op == BC_JFORI) {
3872       |  li TMP1, 1
3873       |  li TMP2, 1
3874       |   addu TMP0, RD, TMP0
3875       |  slt TMP3, TMP3, r0
3876       |  movf TMP1, r0, 0
3877       |   addu PC, PC, TMP0
3878       |  movf TMP2, r0, 1
3879       |   lhu RD, -4+OFS_RD(PC)
3880       |  movn TMP1, TMP2, TMP3
3881       |  bnez TMP1, =>BC_JLOOP
3882       |.  decode_RD8b RD
3883     } else if (op == BC_JFORL) {
3884       |  li TMP1, 1
3885       |  li TMP2, 1
3886       |  slt TMP3, TMP3, r0
3887       |  movf TMP1, r0, 0
3888       |  movf TMP2, r0, 1
3889       |  movn TMP1, TMP2, TMP3
3890       |  bnez TMP1, =>BC_JLOOP
3891       |.  nop
3892     } else {
3893       |  addu TMP1, RD, TMP0
3894       |  slt TMP3, TMP3, r0
3895       |  move TMP2, TMP1
3896       if (op == BC_FORI) {
3897         |  movt TMP1, r0, 0
3898         |  movt TMP2, r0, 1
3899       } else {
3900         |  movf TMP1, r0, 0
3901         |  movf TMP2, r0, 1
3902       }
3903       |  movn TMP1, TMP2, TMP3
3904       |  addu PC, PC, TMP1
3905     }
3906     |  ins_next
3907     break;
3908
3909   case BC_ITERL:
3910     |.if JIT
3911     |  hotloop
3912     |.endif
3913     |  // Fall through. Assumes BC_IITERL follows.
3914     break;
3915
3916   case BC_JITERL:
3917 #if !LJ_HASJIT
3918     break;
3919 #endif
3920   case BC_IITERL:
3921     |  // RA = base*8, RD = target
3922     |  addu RA, BASE, RA
3923     |  lw TMP1, HI(RA)
3924     |  beq TMP1, TISNIL, >1             // Stop if iterator returned nil.
3925     |.  lw TMP2, LO(RA)
3926     if (op == BC_JITERL) {
3927       |  sw TMP1, -8+HI(RA)
3928       |  b =>BC_JLOOP
3929       |.  sw TMP2, -8+LO(RA)
3930     } else {
3931       |  branch_RD                      // Otherwise save control var + branch.
3932       |  sw TMP1, -8+HI(RA)
3933       |   sw TMP2, -8+LO(RA)
3934     }
3935     |1:
3936     |  ins_next
3937     break;
3938
3939   case BC_LOOP:
3940     |  // RA = base*8, RD = target (loop extent)
3941     |  // Note: RA/RD is only used by trace recorder to determine scope/extent
3942     |  // This opcode does NOT jump, it's only purpose is to detect a hot loop.
3943     |.if JIT
3944     |  hotloop
3945     |.endif
3946     |  // Fall through. Assumes BC_ILOOP follows.
3947     break;
3948
3949   case BC_ILOOP:
3950     |  // RA = base*8, RD = target (loop extent)
3951     |  ins_next
3952     break;
3953
3954   case BC_JLOOP:
3955     |.if JIT
3956     |  // RA = base*8 (ignored), RD = traceno*8
3957     |  lw TMP1, DISPATCH_J(trace)(DISPATCH)
3958     |  srl RD, RD, 1
3959     |   li AT, 0
3960     |  addu TMP1, TMP1, RD
3961     |  // Traces on MIPS don't store the trace number, so use 0.
3962     |   sw AT, DISPATCH_GL(vmstate)(DISPATCH)
3963     |  lw TRACE:TMP2, 0(TMP1)
3964     |   sw BASE, DISPATCH_GL(jit_base)(DISPATCH)
3965     |   sw L, DISPATCH_GL(jit_L)(DISPATCH)
3966     |  lw TMP2, TRACE:TMP2->mcode
3967     |  jr TMP2
3968     |.  addiu JGL, DISPATCH, GG_DISP2G+32768
3969     |.endif
3970     break;
3971
3972   case BC_JMP:
3973     |  // RA = base*8 (only used by trace recorder), RD = target
3974     |  branch_RD
3975     |  ins_next
3976     break;
3977
3978   /* -- Function headers -------------------------------------------------- */
3979
3980   case BC_FUNCF:
3981     |.if JIT
3982     |  hotcall
3983     |.endif
3984   case BC_FUNCV:  /* NYI: compiled vararg functions. */
3985     |  // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
3986     break;
3987
3988   case BC_JFUNCF:
3989 #if !LJ_HASJIT
3990     break;
3991 #endif
3992   case BC_IFUNCF:
3993     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3994     |  lw TMP2, L->maxstack
3995     |   lbu TMP1, -4+PC2PROTO(numparams)(PC)
3996     |    lw KBASE, -4+PC2PROTO(k)(PC)
3997     |  sltu AT, TMP2, RA
3998     |  bnez AT, ->vm_growstack_l
3999     |.  sll TMP1, TMP1, 3
4000     if (op != BC_JFUNCF) {
4001       |  ins_next1
4002     }
4003     |2:
4004     |  sltu AT, NARGS8:RC, TMP1         // Check for missing parameters.
4005     |  bnez AT, >3
4006     |.  addu AT, BASE, NARGS8:RC
4007     if (op == BC_JFUNCF) {
4008       |  decode_RD8a RD, INS
4009       |  b =>BC_JLOOP
4010       |.  decode_RD8b RD
4011     } else {
4012       |  ins_next2
4013     }
4014     |
4015     |3:  // Clear missing parameters.
4016     |  sw TISNIL, HI(AT)
4017     |  b <2
4018     |.  addiu NARGS8:RC, NARGS8:RC, 8
4019     break;
4020
4021   case BC_JFUNCV:
4022 #if !LJ_HASJIT
4023     break;
4024 #endif
4025     |  NYI  // NYI: compiled vararg functions
4026     break;  /* NYI: compiled vararg functions. */
4027
4028   case BC_IFUNCV:
4029     |  // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
4030     |   addu TMP1, BASE, RC
4031     |  lw TMP2, L->maxstack
4032     |  addu TMP0, RA, RC
4033     |   sw LFUNC:RB, LO(TMP1)           // Store copy of LFUNC.
4034     |   addiu TMP3, RC, 8+FRAME_VARG
4035     |  sltu AT, TMP0, TMP2
4036     |    lw KBASE, -4+PC2PROTO(k)(PC)
4037     |  beqz AT, ->vm_growstack_l
4038     |.  sw TMP3, HI(TMP1)               // Store delta + FRAME_VARG.
4039     |  lbu TMP2, -4+PC2PROTO(numparams)(PC)
4040     |   move RA, BASE
4041     |   move RC, TMP1
4042     |  ins_next1
4043     |  beqz TMP2, >3
4044     |.  addiu BASE, TMP1, 8
4045     |1:
4046     |  lw TMP0, HI(RA)
4047     |   lw TMP3, LO(RA)
4048     |  sltu AT, RA, RC                  // Less args than parameters?
4049     |  move CARG1, TMP0
4050     |  movz TMP0, TISNIL, AT            // Clear missing parameters.
4051     |  movn CARG1, TISNIL, AT           // Clear old fixarg slot (help the GC).
4052     |   sw TMP3, 8+LO(TMP1)
4053     |    addiu TMP2, TMP2, -1
4054     |  sw TMP0, 8+HI(TMP1)
4055     |    addiu TMP1, TMP1, 8
4056     |  sw CARG1, HI(RA)
4057     |  bnez TMP2, <1
4058     |.   addiu RA, RA, 8
4059     |3:
4060     |  ins_next2
4061     break;
4062
4063   case BC_FUNCC:
4064   case BC_FUNCCW:
4065     |  // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
4066     if (op == BC_FUNCC) {
4067       |  lw CFUNCADDR, CFUNC:RB->f
4068     } else {
4069       |  lw CFUNCADDR, DISPATCH_GL(wrapf)(DISPATCH)
4070     }
4071     |  addu TMP1, RA, NARGS8:RC
4072     |  lw TMP2, L->maxstack
4073     |   addu RC, BASE, NARGS8:RC
4074     |  sw BASE, L->base
4075     |  sltu AT, TMP2, TMP1
4076     |   sw RC, L->top
4077     |    li_vmstate C
4078     if (op == BC_FUNCCW) {
4079       |  lw CARG2, CFUNC:RB->f
4080     }
4081     |  bnez AT, ->vm_growstack_c        // Need to grow stack.
4082     |.  move CARG1, L
4083     |  jalr CFUNCADDR                   // (lua_State *L [, lua_CFunction f])
4084     |.   st_vmstate
4085     |  // Returns nresults.
4086     |  lw BASE, L->base
4087     |   sll RD, CRET1, 3
4088     |  lw TMP1, L->top
4089     |    li_vmstate INTERP
4090     |  lw PC, FRAME_PC(BASE)            // Fetch PC of caller.
4091     |   subu RA, TMP1, RD               // RA = L->top - nresults*8
4092     |  b ->vm_returnc
4093     |.   st_vmstate
4094     break;
4095
4096   /* ---------------------------------------------------------------------- */
4097
4098   default:
4099     fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
4100     exit(2);
4101     break;
4102   }
4103 }
4104
4105 static int build_backend(BuildCtx *ctx)
4106 {
4107   int op;
4108
4109   dasm_growpc(Dst, BC__MAX);
4110
4111   build_subroutines(ctx);
4112
4113   |.code_op
4114   for (op = 0; op < BC__MAX; op++)
4115     build_ins(ctx, (BCOp)op, op);
4116
4117   return BC__MAX;
4118 }
4119
4120 /* Emit pseudo frame-info for all assembler functions. */
4121 static void emit_asm_debug(BuildCtx *ctx)
4122 {
4123   int fcofs = (int)((uint8_t *)ctx->glob[GLOB_vm_ffi_call] - ctx->code);
4124   int i;
4125   switch (ctx->mode) {
4126   case BUILD_elfasm:
4127     fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
4128     fprintf(ctx->fp,
4129         ".Lframe0:\n"
4130         "\t.4byte .LECIE0-.LSCIE0\n"
4131         ".LSCIE0:\n"
4132         "\t.4byte 0xffffffff\n"
4133         "\t.byte 0x1\n"
4134         "\t.string \"\"\n"
4135         "\t.uleb128 0x1\n"
4136         "\t.sleb128 -4\n"
4137         "\t.byte 31\n"
4138         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4139         "\t.align 2\n"
4140         ".LECIE0:\n\n");
4141     fprintf(ctx->fp,
4142         ".LSFDE0:\n"
4143         "\t.4byte .LEFDE0-.LASFDE0\n"
4144         ".LASFDE0:\n"
4145         "\t.4byte .Lframe0\n"
4146         "\t.4byte .Lbegin\n"
4147         "\t.4byte %d\n"
4148         "\t.byte 0xe\n\t.uleb128 %d\n"
4149         "\t.byte 0x9f\n\t.sleb128 1\n"
4150         "\t.byte 0x9e\n\t.sleb128 2\n",
4151         fcofs, CFRAME_SIZE);
4152     for (i = 23; i >= 16; i--)
4153       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+i, 26-i);
4154     for (i = 30; i >= 20; i -= 2)
4155       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+32+i, 42-i);
4156     fprintf(ctx->fp,
4157         "\t.align 2\n"
4158         ".LEFDE0:\n\n");
4159 #if LJ_HASFFI
4160     fprintf(ctx->fp,
4161         ".LSFDE1:\n"
4162         "\t.4byte .LEFDE1-.LASFDE1\n"
4163         ".LASFDE1:\n"
4164         "\t.4byte .Lframe0\n"
4165         "\t.4byte lj_vm_ffi_call\n"
4166         "\t.4byte %d\n"
4167         "\t.byte 0x9f\n\t.uleb128 1\n"
4168         "\t.byte 0x90\n\t.uleb128 2\n"
4169         "\t.byte 0xd\n\t.uleb128 0x10\n"
4170         "\t.align 2\n"
4171         ".LEFDE1:\n\n", (int)ctx->codesz - fcofs);
4172 #endif
4173     fprintf(ctx->fp, "\t.section .eh_frame,\"aw\",@progbits\n");
4174     fprintf(ctx->fp,
4175         "\t.globl lj_err_unwind_dwarf\n"
4176         ".Lframe1:\n"
4177         "\t.4byte .LECIE1-.LSCIE1\n"
4178         ".LSCIE1:\n"
4179         "\t.4byte 0\n"
4180         "\t.byte 0x1\n"
4181         "\t.string \"zPR\"\n"
4182         "\t.uleb128 0x1\n"
4183         "\t.sleb128 -4\n"
4184         "\t.byte 31\n"
4185         "\t.uleb128 6\n"                        /* augmentation length */
4186         "\t.byte 0\n"
4187         "\t.4byte lj_err_unwind_dwarf\n"
4188         "\t.byte 0\n"
4189         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4190         "\t.align 2\n"
4191         ".LECIE1:\n\n");
4192     fprintf(ctx->fp,
4193         ".LSFDE2:\n"
4194         "\t.4byte .LEFDE2-.LASFDE2\n"
4195         ".LASFDE2:\n"
4196         "\t.4byte .LASFDE2-.Lframe1\n"
4197         "\t.4byte .Lbegin\n"
4198         "\t.4byte %d\n"
4199         "\t.uleb128 0\n"                        /* augmentation length */
4200         "\t.byte 0xe\n\t.uleb128 %d\n"
4201         "\t.byte 0x9f\n\t.sleb128 1\n"
4202         "\t.byte 0x9e\n\t.sleb128 2\n",
4203         fcofs, CFRAME_SIZE);
4204     for (i = 23; i >= 16; i--)
4205       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+i, 26-i);
4206     for (i = 30; i >= 20; i -= 2)
4207       fprintf(ctx->fp, "\t.byte %d\n\t.uleb128 %d\n", 0x80+32+i, 42-i);
4208     fprintf(ctx->fp,
4209         "\t.align 2\n"
4210         ".LEFDE2:\n\n");
4211 #if LJ_HASFFI
4212     fprintf(ctx->fp,
4213         ".Lframe2:\n"
4214         "\t.4byte .LECIE2-.LSCIE2\n"
4215         ".LSCIE2:\n"
4216         "\t.4byte 0\n"
4217         "\t.byte 0x1\n"
4218         "\t.string \"zR\"\n"
4219         "\t.uleb128 0x1\n"
4220         "\t.sleb128 -4\n"
4221         "\t.byte 31\n"
4222         "\t.uleb128 1\n"                        /* augmentation length */
4223         "\t.byte 0\n"
4224         "\t.byte 0xc\n\t.uleb128 29\n\t.uleb128 0\n"
4225         "\t.align 2\n"
4226         ".LECIE2:\n\n");
4227     fprintf(ctx->fp,
4228         ".LSFDE3:\n"
4229         "\t.4byte .LEFDE3-.LASFDE3\n"
4230         ".LASFDE3:\n"
4231         "\t.4byte .LASFDE3-.Lframe2\n"
4232         "\t.4byte lj_vm_ffi_call\n"
4233         "\t.4byte %d\n"
4234         "\t.uleb128 0\n"                        /* augmentation length */
4235         "\t.byte 0x9f\n\t.uleb128 1\n"
4236         "\t.byte 0x90\n\t.uleb128 2\n"
4237         "\t.byte 0xd\n\t.uleb128 0x10\n"
4238         "\t.align 2\n"
4239         ".LEFDE3:\n\n", (int)ctx->codesz - fcofs);
4240 #endif
4241     break;
4242   default:
4243     break;
4244   }
4245 }
4246